WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AsymptoticRSolveValue[eqn,f,x∞]

f[x]についての差分方程式 eqn の の近くの漸近近似を計算する．

AsymptoticRSolveValue[{eqn1,eqn2,…},{f1,f2,…},x ∞]

差分方程式系の漸近近似を計算する．

AsymptoticRSolveValue[eqn,f,x,ϵϵ0]

ϵ0を中心とするパラメータ ϵ の f[x,ϵ]の漸近近似を計算する．

AsymptoticRSolveValue[eqn,f,…,{ξ,ξ0,n}]

漸近近似を次数 n まで計算する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
通常点  
確定特異点  
不確定特異点  
常差分方程式系  
オプション  
GeneratedParameters  
アプリケーション  
基本的なアプリケーション  
特殊数列  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

AsymptoticRSolveValue

AsymptoticRSolveValue[eqn,f,x∞]

f[x]についての差分方程式 eqn の の近くの漸近近似を計算する．

AsymptoticRSolveValue[{eqn1,eqn2,…},{f1,f2,…},x ∞]

差分方程式系の漸近近似を計算する．

AsymptoticRSolveValue[eqn,f,x,ϵϵ0]

ϵ0を中心とするパラメータ ϵ の f[x,ϵ]の漸近近似を計算する．

AsymptoticRSolveValue[eqn,f,…,{ξ,ξ0,n}]

漸近近似を次数 n まで計算する．

詳細とオプション

  • 差分方程式の漸近近似は，漸近展開，摂動解，正則摂動等としても知られるもので，フロベニウス(Frobenius)級数やテイラー(Taylor)級数等を計算する特定のメソッドにも知られている．
  • 漸近近似は，厳密解が求まらない問題を解くため，あるいは，計算，比較，解釈のためにより簡単な答を得るために，使われることが多い．
  • AsymptoticRSolveValue[eqn,…,xx0]は，eqn の漸近展開における最高次数の項を計算する．より多くの項が指定したければSeriesTermGoalを使うとよい．
  • 厳密な結果が g[x]で x0における次数 n の漸近近似が gn[x]であるなら，xx0のときの結果は，AsymptoticLess[g[x]-gn[x],gn[x]-gn-1[x],xx0]または g[x]-gn[x]∈o[gn[x]-gn-1[x]]である．
  • 漸近近似 gn[x]は，しばしば総和 gn[x]αkϕk[x]として与えられる．ただし，{ϕ1[x],…,ϕn[x]}は xx0のときの漸近尺度 ϕ1[x]≻ϕ2[x]≻⋯>ϕn[x]である．結果は，xx0のとき，AsymptoticLess[g[x]-gn[x],ϕn[x],xx0]または g[x]-gn[x]∈o[ϕn[x]]である．
  • 次は，よく使われる漸近尺度である．
  • xx0のときのテイラースケール
    xx0のときのローラン(Laurent)スケール
    x±∞のときのローランスケール
    xx0のときのピュイゾー(Puiseux)スケール
  • 漸近近似を表すために使われる尺度は，問題から自動的に推測される．より珍しい尺度が含まれることも多い．
  • 中心 x0は，任意の有限または無限の実数または複素数でよい．
  • 次数 n は漸近解の近似次数を指定するもので，正の整数でなければならない．この次数は，多項式次数とは無関係である．
  • f∈Vectors[n]あるいは f∈Matrices[{m,n}]という指定を使って従属変数 f がベクトル値あるいは行列値であると示すことができる．f をVectorSymbolまたはMatrixSymbolとして指定することもできる． » »
  • 次は，使用可能なオプションである．
  • AccuracyGoalAutomatic目標とする絶対確度の桁数
    Assumptions$Assumptionsパラメータについての仮定
    GenerateConditionsAutomaticパラメータについての条件を含む答を生成するかどうか
    GeneratedParameters None生成されたパラメータの名付け方
    MethodAutomatic使用するメソッド
    PerformanceGoal$PerformanceGoalパフォーマンスのどの局面について最適化するか
    PrecisionGoalAutomatic目標精度の桁数
    SeriesTermGoalAutomatic近似における項数
    WorkingPrecisionAutomatic内部計算の精度
  • PerformanceGoalの可能な設定には，$PerformanceGoal，"Quality"，"Speed"がある．"Quality"設定のとき，AsymptoticRSolveValueはより多くの問題を解いたりより簡単な結果を与えたりすることが多いが，より多くの時間とメモリが必要になる可能性がある．

例題

すべて開く すべて閉じる

例  (4)

微分方程式の漸近近似を計算する：

Wolfram Language code: AsymptoticRSolveValue[{{y[n] == y[n - 1] + y[n - 2]}, y[1] == 1, y[2] == 1}, y[n], n -> ∞]

差分方程式の級数解を求める：

Wolfram Language code: AsymptoticRSolveValue[y[n + 1] == (n ^ 2 + 1) / n ^ 2 y[n], y[n], {n, ∞, 3}]

解をプロットする：

Wolfram Language code: DiscretePlot[% /. {C[1] -> 5}, {n, 1, 100}, PlotRange -> {4, 5}]

摂動問題の漸近展開を求める：

Wolfram Language code: AsymptoticRSolveValue[{y[n + 1] - 21 / 23y[n] - ϵ y[n] ^ 2 == 0, y[1] == 1}, y[n], n, {ϵ, 0, 2}]

解をプロットする：

Wolfram Language code: DiscretePlot[Evaluate[Table[%, {ϵ, {1 / 3., 1 / 4., 1 / 5.}}]], {n, 1, 100}, PlotRange -> All]

関数方程式についての漸近展開を求める：

Wolfram Language code: AsymptoticRSolveValue[{a[n] == Sqrt[n]a[Sqrt[n]] + n, a[7] == 3}, a[n], n -> ∞]

スコープ  (13)

基本的な用法  (2)

常差分方程式(OΔE)について2次の級数解を計算する：

Wolfram Language code: AsymptoticRSolveValue[y[n + 2] - n y[n + 1] + 2n y[n] == 0, y[n], {n, ∞, 2}]

項数を変えて級数近似を得る：

Wolfram Language code: AsymptoticRSolveValue[y[n + 1] + 2n y[n] == 0, y[n], {n, ∞, 1}]
Wolfram Language code: AsymptoticRSolveValue[y[n + 1] + 2n y[n] == 0, y[n], {n, ∞, 3}]

通常点  (2)

通常点がInfinityである一階線形常差分方程式(OΔE)の級数解を求める：

Wolfram Language code: AsymptoticRSolveValue[{y[n + 1] == ((n ^ 3 + 1) / n ^ 3)y[n]}, y[n], {n, ∞, 2}]

解をプロットする：

Wolfram Language code: DiscretePlot[% /. {C[1] -> 1 / 100}, {n, 1, 30}]

通常点がInfinityである二階線形常差分方程式(OΔE)の級数解：

Wolfram Language code: AsymptoticRSolveValue[n ^ 4y[n + 2] == 2n ^ 3(n - 1) y[n + 1] - (n ^ 4 - 2n ^ 3 - 1)y[n], y[n], {n, ∞, 4}]

解をプロットする：

Wolfram Language code: DiscretePlot[{(% /. {C[1] -> 1, C[2] -> 3}), 3}, {n, 1, 30}, PlotRange -> {2.7, 4}]

確定特異点  (2)

確定特異点をInfinityに持つ一階線形常差分方程式(OΔE)についてのフロベニウスの級数解：

Wolfram Language code: AsymptoticRSolveValue[2n y[n + 1] == (2n + 1)y[n], y[n], {n, ∞, 3}]

解をプロットする：

Wolfram Language code: DiscretePlot[% /. {C[1] -> 1}, {n, 1, 30}]

確定特異点をInfinityに持つ二階線形常差分方程式(OΔE)の級数解：

Wolfram Language code: AsymptoticRSolveValue[n ^ 4 y[n + 2] - 2 n ^ 4 y[n + 1] + (n ^ 2 - 1) ^ 2 y[n] == 0, y[n], {n, ∞, 5}]

解をプロットする：

Wolfram Language code: DiscretePlot[% /. {C[1] -> 1, C[2] -> 1}, {n, 1, 30}]

不確定特異点  (3)

不確定特異点をInfinityに持つ一階線形常差分方程式(OΔE)の漸近展開：

Wolfram Language code: AsymptoticRSolveValue[y[n + 1] == 3n y[n], y[n], {n, ∞, 4}]

不確定特異点を持つ二階線形常差分方程式(OΔE)の漸近展開：

Wolfram Language code: AsymptoticRSolveValue[y[n + 2] == 4n y[n + 1] - 3 n ^ 2 y[n], y[n], {n, ∞, 3}]

不確定特異点を持つ三階線形常差分方程式(OΔE)の漸近展開：

Wolfram Language code: AsymptoticRSolveValue[y[n + 3] - y[n] - (n + 2)y[n + 1] == 0, y[n], {n, ∞, 1}]

対数スケールを使って解をプロットする：

Wolfram Language code: DiscretePlot[% /. {C[1] -> 1, C[2] -> 1, C[3] -> 1}, {n, 20, 100}, ScalingFunctions -> "Log"]

常差分方程式系  (4)

2つの一階常差分方程式(OΔE)からなる線形系について，n=∞における級数解を求める：

Wolfram Language code: eqns = {y[n + 1] == y[n] + 1 / n z[n], z[n + 1] == 2 / (n + 1) y[n] - z[n]};
Wolfram Language code: sol = AsymptoticRSolveValue[eqns, {y[n], z[n]}, {n, ∞, 1}] /. {C[1] -> 1, C[2] -> 1}

解の成分をプロットする：

Wolfram Language code: {DiscretePlot[sol[[1]], {n, 2, 100}], DiscretePlot[sol[[2]], {n, 2, 100}]}

3つの一階線形方程式(OΔE)からなる線形系について，n=∞における級数解を求める：

Wolfram Language code: eqns = {y[n + 1] == w[n] + z[n], z[n + 1] == 2 y[n] - z[n], w[n + 1] == 1 / (n + 1) y[n] + z[n]};
Wolfram Language code: sol = AsymptoticRSolveValue[eqns, {w[n], y[n], z[n]}, {n, ∞, 1}];
Wolfram Language code: Simplify[sol, n∈Integers]

任意の定数および という特定の選択についての解の値を計算する：

Wolfram Language code: % /. {C[1] -> 1, C[2] -> 2, C[3] -> 5, n -> 50.`200}//Chop//N

RecurrenceTableを使って における解の値を求める：

Wolfram Language code: RecurrenceTable[{eqns, w[50] == %[[1]], y[50] == %[[2]], z[50] == %[[3]]}, {w[n], y[n], z[n]}, {n, 60, 60}]//N

近似値と比較する：

Wolfram Language code: sol /. {C[1] -> 1, C[2] -> 2, C[3] -> 5, n -> 60.`200}//N

ベクトル変数を使って n=∞における常微分方程式の線形系の級数解を求める：

Wolfram Language code: a = {{0, 1}, {-1, 0}};
Wolfram Language code: AsymptoticRSolveValue[x[n + 1] == a.x[n], Element[x[n], Vectors[2]], {n, Infinity, 1}]

をVectorSymbolとして定義することもできる：

Wolfram Language code: x = VectorSymbol["x", 2]
Wolfram Language code: AsymptoticRSolveValue[x[n + 1] == a.x[n], x[n], {n, Infinity, 1}]

行列変数を使って n=∞における常微分方程式の線形系の級数解を求める：

Wolfram Language code: a = {{0, 1}, {-1, 0}}; x0 = {{1, 2}, {3, 4}};
Wolfram Language code: AsymptoticRSolveValue[{x[n + 1] == a.x[n], x[0] == x0}, Element[x, Matrices[{2, 2}]], {n, Infinity, 1}]//MatrixForm

をMatrixSymbolとして定義することもできる：

Wolfram Language code: x = MatrixSymbol["x", {2, 2}]
Wolfram Language code: AsymptoticRSolveValue[{x[n + 1] == a.x[n], x[0] == x0}, x[n], {n, Infinity, 1}]//MatrixForm

オプション  (1)

GeneratedParameters  (1)

異なる名前が付いた定数を使う：

Wolfram Language code: AsymptoticRSolveValue[y[n + 1] == (n ^ 2 + 1) / n ^ 2 y[n], y[n], {n, ∞, 3}, GeneratedParameters -> d]

下付き文字が付いた定数を使う：

Wolfram Language code: AsymptoticRSolveValue[y[n + 1] == (n ^ 2 + 1) / n ^ 2 y[n], y[n], {n, ∞, 3}, GeneratedParameters -> (Subscript[d, #]&)]

アプリケーション  (6)

基本的なアプリケーション  (2)

差分方程式の近似解を計算する：

Wolfram Language code: AsymptoticRSolveValue[y[n + 1] == (n ^ 3 + 1) / n ^ 3 y[n], y[n], {n, ∞, 3}]

より高次の近似を計算する：

Wolfram Language code: AsymptoticRSolveValue[y[n + 1] == (n ^ 3 + 1) / n ^ 3 y[n], y[n], {n, ∞, 7}]

Gammaについての漸近近似を求める：

Wolfram Language code: sol[n_] = AsymptoticRSolveValue[{a[n + 1] == n a[n], a[1] == 1}, a[n], {n, ∞, 1}]

数列要素の近似値を得る：

Wolfram Language code: sol[50000]//N[#, 20]&

厳密値と比較する：

Wolfram Language code: Gamma[50000.`20]

特殊数列  (4)

フィボナッチ数列についての漸近近似を，この数列が満足する差分方程式についての展開から始めて求める：

Wolfram Language code: fib = Fibonacci[n];
Wolfram Language code: Table[fib, {n, 10}]
Wolfram Language code: Head[DifferenceRootReduce[fib, n]][[1]][a, n][[1]]
Wolfram Language code: sol[n_] = AsymptoticRSolveValue[%, a[n], {n, ∞, 1}]

展開の第1成分が大きい n について0に近付くことを確かめる：

Wolfram Language code: DiscreteLimit[sol[n] /. {C[2] -> 0}, n -> ∞]
Wolfram Language code: {DiscretePlot[sol[n] /. {C[2] -> 0, C[1] -> 1}, {n, 0, 30}], DiscretePlot[sol[n] /. {C[2] -> 1, C[1] -> 0}, {n, 0, 50}]}

第1成分を0に設定する：

Wolfram Language code: fsol[n_] = sol[n] /. {C[1] -> 0}

に値を割り当てる：

Wolfram Language code: Solve[fsol[1000] == Fibonacci[1000], C[2]]//N[#, 20]&

数列要素について近似値を得る：

Wolfram Language code: fsol[30000] /. %[[1]] //N[#, 20]&

対応するフィボナッチ数と比較する：

Wolfram Language code: Fibonacci[30000.`20]

三次フィボナッチ数列についての漸近近似を，この数列が満足する差分方程式についての展開から始めて求める：

Wolfram Language code: sol[n_] = AsymptoticRSolveValue[a[n + 1] == a[n] + a[n - 1] + a[n - 2], a[n], {n, ∞, 1}]

展開の第2および第3成分が大きい n について0に近付くことを確かめる：

Wolfram Language code: DiscreteLimit[sol[n], n -> ∞]
Wolfram Language code: {DiscretePlot[Abs[sol[n] /. {C[2] -> 1, C[1] -> 0, C[3] -> 0}], {n, 0, 30}], DiscretePlot[Abs[sol[n] /. {C[2] -> 0, C[1] -> 0, C[3] -> 1}], {n, 0, 30}], DiscretePlot[Abs[sol[n] /. {C[1] -> 1, C[2] -> 0, C[3] -> 0}], {n, 0, 20}]}

第1および第3成分を0に設定する：

Wolfram Language code: fsol[n_] = sol[n] /. {C[2] -> 0, C[3] -> 0}

に値を割り当てる：

Wolfram Language code: tsol[n_] = RSolveValue[{a[n + 1] == a[n] + a[n - 1] + a[n - 2], a[0] == 0, a[1] == 0, a[2] == 1}, a[n], n]
Wolfram Language code: Solve[fsol[1000] == tsol[1000], C[1]]//N[#, 20]&//Chop

数列要素についての近似値を得る：

Wolfram Language code: fsol[30000] /. %[[1]] //N[#, 20]&

対応するフィボナッチ数と比較する：

Wolfram Language code: tsol[30000.`20]//Chop

摂動するフィボナッチ数列についての漸近近似を，この数列が満足する差分方程式についての展開から始めて求める：

Wolfram Language code: sol[n_] = AsymptoticRSolveValue[a[n + 1] == (1 + 1 / n) a[n] + (1 - 1 / n) a[n - 1], a[n], {n, ∞, 1}]

展開の第1成分が大きい n について0に近付くことを確かめる：

Wolfram Language code: DiscreteLimit[sol[n], n -> ∞]
Wolfram Language code: {DiscretePlot[sol[n] /. {C[2] -> 0, C[1] -> 1}, {n, 1, 30}], DiscretePlot[sol[n] /. {C[2] -> 1, C[1] -> 0}, {n, 1, 50}]}

第1成分を0に設定する：

Wolfram Language code: fsol[n_] = sol[n] /. {C[1] -> 0}

に値を割り当てる：

Wolfram Language code: tsol[n_] = RSolveValue[{a[n + 1] == (1 + 1 / n) a[n] + (1 - 1 / n) a[n - 1], a[1] == 1, a[2] == 1}, a[n], n]
Wolfram Language code: Solve[fsol[1000] == tsol[1000], C[2]]//N[#, 20]&//Chop

数列要素について近似値を得る：

Wolfram Language code: fsol[3000] /. %[[1]] //N[#, 20]&

対応する摂動フィボナッチ数と比較する：

Wolfram Language code: tsol[3000]//N

次の二階線形差分方程式を満足するアペリー(Apéry)数列の最高次数の漸近項を計算する：

Wolfram Language code: apeqn = (n + 2) ^ 3 u[n + 2] - (34 n ^ 3 + 153 n ^ 2 + 231 n + 117)u[n + 1] + (n + 1) ^ 3 u[n] == 0;

最高次数の漸近項を得る：

Wolfram Language code: sol[n_] = AsymptoticRSolveValue[apeqn, u[n], {n, Infinity, 1}]

展開の第1成分が大きい n について0に近付くことを確かめる：

Wolfram Language code: DiscreteLimit[sol[n], n -> ∞]
Wolfram Language code: {DiscretePlot[sol[n] /. {C[2] -> 0, C[1] -> 1}, {n, 1, 20}], DiscretePlot[sol[n] /. {C[2] -> 1, C[1] -> 0}, {n, 1, 20}]}

第1成分を0に設定する：

Wolfram Language code: fsol[n_] = sol[n] /. {C[1] -> 0}

この数列の定義和に基づいてに値を割り当てる：

Wolfram Language code: tsol[n_] := Sum[Binomial[n, k] ^ 2 Binomial[n + k, k] ^ 2, {k, 0, n}]
Wolfram Language code: Solve[fsol[1000] == tsol[1000], C[2]]//N[#, 20]&//Chop

この数列の要素について近似値を得る：

Wolfram Language code: fsol[10000] /. %[[1]] //N[#, 20]&

対応するアペリー数と比較する：

Wolfram Language code: tsol[10000]//N

特性と関係  (3)

指定の次数までの差分方程式を満足する解：

Wolfram Language code: sol = AsymptoticRSolveValue[y[n + 1] == (n ^ 2 + 1) / n ^ 2y[n], y[n], {n, ∞, 6}]
Wolfram Language code: (y[n + 1] - (n ^ 2 + 1) / n ^ 2y[n] /. y -> Function[{n}, Evaluate[sol]])//Simplify
Wolfram Language code: Series[%, {n, ∞, 6}]

RSolveValueを使って厳密解を求める：

Wolfram Language code: asol = AsymptoticRSolveValue[y[n + 1] == (n ^ 2 + 1) / n ^ 2 y[n], y[n], {n, ∞, 4}] /. {C[1] -> 1}
Wolfram Language code: rsol = RSolveValue[y[n + 1] == (n ^ 2 + 1) / n ^ 2 y[n], y[n], n]
Wolfram Language code: (Series[%, {n, ∞, 4}]//Normal) /. {C[1] -> Gamma[1 - I] Gamma[1 + I]}//Apart

RecurrenceTableを使って数値解を求める：

Wolfram Language code: asol = AsymptoticRSolveValue[{y[n + 1] == y[n] + ϵ y[n] ^ 2, y[1] == 3}, y[n], n, {ϵ, 0, 2}]
Wolfram Language code: Table[% /. {ϵ -> 1 / 400.}, {n, 1, 7}]
Wolfram Language code: nsol = RecurrenceTable[{y[n + 1] == y[n] + 1 / 400. y[n] ^ 2, y[1] == 3}, y[n], {n, 1, 7}]
Wolfram Research (2019), AsymptoticRSolveValue, Wolfram言語関数， https://reference.wolfram.com/language/ref/AsymptoticRSolveValue.html （2025年に更新）.

テキスト

Wolfram Research (2019), AsymptoticRSolveValue, Wolfram言語関数， https://reference.wolfram.com/language/ref/AsymptoticRSolveValue.html （2025年に更新）.

CMS

Wolfram Language. 2019. "AsymptoticRSolveValue." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/AsymptoticRSolveValue.html.

APA

Wolfram Language. (2019). AsymptoticRSolveValue. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AsymptoticRSolveValue.html

BibTeX

@misc{reference.wolfram_2026_asymptoticrsolvevalue, author="Wolfram Research", title="{AsymptoticRSolveValue}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/AsymptoticRSolveValue.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_asymptoticrsolvevalue, organization={Wolfram Research}, title={AsymptoticRSolveValue}, year={2025}, url={https://reference.wolfram.com/language/ref/AsymptoticRSolveValue.html}, note=[Accessed: 10-August-2026]}