WOLFRAM

Wolfram 语言与系统参考资料中心

AsymptoticRSolveValue[eqn,f,x∞]

计算差分方程 eqn 的渐近逼近，f[x] 在 附近.

AsymptoticRSolveValue[{eqn1,eqn2,…},{f1,f2,…},x ∞]

计算差分方程组的渐近逼近.

AsymptoticRSolveValue[eqn,f,x,ϵϵ0]

计算 f[x,ϵ] 的渐近逼近，其中参数 ϵ 以 ϵ0 为中心.

AsymptoticRSolveValue[eqn,f,…,{ξ,ξ0,n}]

计算 n 阶渐近逼近.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
常点  
正则奇点  
非正则奇点  
常微分方程组  
选项  
GeneratedParameters  
应用  
基本应用  
特殊序列  
属性和关系  
参见
相关指南
历史
按以下格式引用：

AsymptoticRSolveValue

AsymptoticRSolveValue[eqn,f,x∞]

计算差分方程 eqn 的渐近逼近，f[x] 在 附近.

AsymptoticRSolveValue[{eqn1,eqn2,…},{f1,f2,…},x ∞]

计算差分方程组的渐近逼近.

AsymptoticRSolveValue[eqn,f,x,ϵϵ0]

计算 f[x,ϵ] 的渐近逼近，其中参数 ϵ 以 ϵ0 为中心.

AsymptoticRSolveValue[eqn,f,…,{ξ,ξ0,n}]

计算 n 阶渐近逼近.

更多信息和选项

  • 差分方程的渐近逼近亦被称为渐近展开式、摄动解、正则摄动等. 也可用计算其中一些式子的特定方法来称呼它们，如泰勒级数和 Frobenius 级数.
  • 渐近逼近通常用于求解无法找到精确解的问题，或者为计算、比较和解释寻求更简单的答案.
  • AsymptoticRSolveValue[eqn,…,xx0] 计算 eqn 的渐近展开式的首项. 用 SeriesTermGoal 可指定计算更多的项.
  • 如果精确结果为 g[x]，在 x0 处的 n 阶渐近逼近为 gn[x]，那么当 xx0 时，结果为 AsymptoticLess[g[x]-gn[x],gn[x]-gn-1[x],xx0] 或 g[x]-gn[x]∈o[gn[x]-gn-1[x]].
  • 渐近逼近 gn[x] 常以和 gn[x]αkϕk[x] 的形式给出，其中 {ϕ1[x],…,ϕn[x]} 是当 xx0 时的渐近尺度 ϕ1[x]≻ϕ2[x]≻⋯>ϕn[x]. 则当 xx0 时，结果为 AsymptoticLess[g[x]-gn[x],ϕn[x],xx0] 或 g[x]-gn[x]∈o[ϕn[x]].
  • 常见的渐近尺度包括：
  • Taylor 尺度，当 xx0 时
    Laurent 尺度，当 xx0 时
    Laurent 尺度，当 x±∞ 时
    Puiseux 尺度，当 xx0 时
  • 用于表示渐近逼近的尺度是从问题中自动推断出来的，通常可以包含更多的奇异尺度.
  • 中心点 x0 可为任意有限或无限大实数或复数.
  • 阶数 n 必须为一个正整数，指定渐近解的近似阶数. 与多项式的次数无关.
  • f∈Vectors[n] 或 f∈Matrices[{m,n}] 可分别用于表明因变量 f 是一个值为向量或矩阵的变量. 也可以用 VectorSymbol 或 MatrixSymbol 指定 f. » »
  • 可以给出以下选项：
  • AccuracyGoalAutomatic寻求的绝对准确度
    Assumptions$Assumptions对参数的设定
    GenerateConditionsAutomatic是否给出与参数的条件有关的答案
    GeneratedParameters None怎样命名生成的参数
    MethodAutomatic所用的方法
    PerformanceGoal$PerformanceGoal优化目标
    PrecisionGoalAutomatic寻求的精度
    SeriesTermGoalAutomatic近似式的项数
    WorkingPrecisionAutomatic内部计算中使用的精度
  • PerformanceGoal 的可能设置包括 $PerformanceGoal、"Quality" 和 "Speed". 当设置为 "Quality" 时， AsymptoticRSolveValue 通常可以解出更多的问题或者产生更简单的结果，但是可能会耗费更多的时间和内存.

范例

打开所有单元 关闭所有单元

基本范例  (4)

计算一个差分方程的渐近近似：

Wolfram Language code: AsymptoticRSolveValue[{{y[n] == y[n - 1] + y[n - 2]}, y[1] == 1, y[2] == 1}, y[n], n -> ∞]

求差分方程的级数解：

Wolfram Language code: AsymptoticRSolveValue[y[n + 1] == (n ^ 2 + 1) / n ^ 2 y[n], y[n], {n, ∞, 3}]

绘制解：

Wolfram Language code: DiscretePlot[% /. {C[1] -> 5}, {n, 1, 100}, PlotRange -> {4, 5}]

求摄动问题的渐近展开式：

Wolfram Language code: AsymptoticRSolveValue[{y[n + 1] - 21 / 23y[n] - ϵ y[n] ^ 2 == 0, y[1] == 1}, y[n], n, {ϵ, 0, 2}]

绘制解：

Wolfram Language code: DiscretePlot[Evaluate[Table[%, {ϵ, {1 / 3., 1 / 4., 1 / 5.}}]], {n, 1, 100}, PlotRange -> All]

求一个函数方程的渐近展开式：

Wolfram Language code: AsymptoticRSolveValue[{a[n] == Sqrt[n]a[Sqrt[n]] + n, a[7] == 3}, a[n], n -> ∞]

范围  (13)

基本用法  (2)

计算常微分方程 (OΔE) 阶数为 2 的级数解：

Wolfram Language code: AsymptoticRSolveValue[y[n + 2] - n y[n + 1] + 2n y[n] == 0, y[n], {n, ∞, 2}]

获取不同项数的级数近似：

Wolfram Language code: AsymptoticRSolveValue[y[n + 1] + 2n y[n] == 0, y[n], {n, ∞, 1}]
Wolfram Language code: AsymptoticRSolveValue[y[n + 1] + 2n y[n] == 0, y[n], {n, ∞, 3}]

常点  (2)

求具有常点 Infinity 的线性一阶常微分方程的级数解：

Wolfram Language code: AsymptoticRSolveValue[{y[n + 1] == ((n ^ 3 + 1) / n ^ 3)y[n]}, y[n], {n, ∞, 2}]

绘制解：

Wolfram Language code: DiscretePlot[% /. {C[1] -> 1 / 100}, {n, 1, 30}]

具有常点 Infinity 的线性二阶常微分方程的级数解：

Wolfram Language code: AsymptoticRSolveValue[n ^ 4y[n + 2] == 2n ^ 3(n - 1) y[n + 1] - (n ^ 4 - 2n ^ 3 - 1)y[n], y[n], {n, ∞, 4}]

绘制解：

Wolfram Language code: DiscretePlot[{(% /. {C[1] -> 1, C[2] -> 3}), 3}, {n, 1, 30}, PlotRange -> {2.7, 4}]

正则奇点  (2)

求具有正则奇点 Infinity 的线性一阶常微分方程的 Frobenius 级数解：

Wolfram Language code: AsymptoticRSolveValue[2n y[n + 1] == (2n + 1)y[n], y[n], {n, ∞, 3}]

绘制解：

Wolfram Language code: DiscretePlot[% /. {C[1] -> 1}, {n, 1, 30}]

具有正则奇点 Infinity 的线性二阶常微分方程的级数解：

Wolfram Language code: AsymptoticRSolveValue[n ^ 4 y[n + 2] - 2 n ^ 4 y[n + 1] + (n ^ 2 - 1) ^ 2 y[n] == 0, y[n], {n, ∞, 5}]

绘制解：

Wolfram Language code: DiscretePlot[% /. {C[1] -> 1, C[2] -> 1}, {n, 1, 30}]

非正则奇点  (3)

具有非正则奇点 Infinity 的线性一阶常微分方程的渐近展开式：

Wolfram Language code: AsymptoticRSolveValue[y[n + 1] == 3n y[n], y[n], {n, ∞, 4}]

具有非正则奇点的线性二阶常微分方程的渐近展开式：

Wolfram Language code: AsymptoticRSolveValue[y[n + 2] == 4n y[n + 1] - 3 n ^ 2 y[n], y[n], {n, ∞, 3}]

具有非正则奇点的线性三阶常微分方程的渐近展开式：

Wolfram Language code: AsymptoticRSolveValue[y[n + 3] - y[n] - (n + 2)y[n + 1] == 0, y[n], {n, ∞, 1}]

用对数尺度绘制解：

Wolfram Language code: DiscretePlot[% /. {C[1] -> 1, C[2] -> 1, C[3] -> 1}, {n, 20, 100}, ScalingFunctions -> "Log"]

常微分方程组  (4)

求由两个一阶常微分方程组成的线性方程组在 n=∞ 处的级数解：

Wolfram Language code: eqns = {y[n + 1] == y[n] + 1 / n z[n], z[n + 1] == 2 / (n + 1) y[n] - z[n]};
Wolfram Language code: sol = AsymptoticRSolveValue[eqns, {y[n], z[n]}, {n, ∞, 1}] /. {C[1] -> 1, C[2] -> 1}

绘制解的分量：

Wolfram Language code: {DiscretePlot[sol[[1]], {n, 2, 100}], DiscretePlot[sol[[2]], {n, 2, 100}]}

求由三个一阶常微分方程组成的线性方程组在 n=∞ 处的级数解：

Wolfram Language code: eqns = {y[n + 1] == w[n] + z[n], z[n + 1] == 2 y[n] - z[n], w[n + 1] == 1 / (n + 1) y[n] + z[n]};
Wolfram Language code: sol = AsymptoticRSolveValue[eqns, {w[n], y[n], z[n]}, {n, ∞, 1}];
Wolfram Language code: Simplify[sol, n∈Integers]

计算任意常数取特定值且 时的解：

Wolfram Language code: % /. {C[1] -> 1, C[2] -> 2, C[3] -> 5, n -> 50.`200}//Chop//N

用 RecurrenceTable 求 时的解：

Wolfram Language code: RecurrenceTable[{eqns, w[50] == %[[1]], y[50] == %[[2]], z[50] == %[[3]]}, {w[n], y[n], z[n]}, {n, 60, 60}]//N

与近似值相比较：

Wolfram Language code: sol /. {C[1] -> 1, C[2] -> 2, C[3] -> 5, n -> 60.`200}//N

使用向量变量在 n=∞ 处求得线性 ODE 方程组的级数解：

Wolfram Language code: a = {{0, 1}, {-1, 0}};
Wolfram Language code: AsymptoticRSolveValue[x[n + 1] == a.x[n], Element[x[n], Vectors[2]], {n, Infinity, 1}]

或者将 定义为 VectorSymbol：

Wolfram Language code: x = VectorSymbol["x", 2]
Wolfram Language code: AsymptoticRSolveValue[x[n + 1] == a.x[n], x[n], {n, Infinity, 1}]

使用矩阵变量在 n=∞ 处计算线性 ODE 方程组的级数解：

Wolfram Language code: a = {{0, 1}, {-1, 0}}; x0 = {{1, 2}, {3, 4}};
Wolfram Language code: AsymptoticRSolveValue[{x[n + 1] == a.x[n], x[0] == x0}, Element[x, Matrices[{2, 2}]], {n, Infinity, 1}]//MatrixForm

或者将 定义为 MatrixSymbol：

Wolfram Language code: x = MatrixSymbol["x", {2, 2}]
Wolfram Language code: AsymptoticRSolveValue[{x[n + 1] == a.x[n], x[0] == x0}, x[n], {n, Infinity, 1}]//MatrixForm

选项  (1)

GeneratedParameters  (1)

使用不同的已命名常数：

Wolfram Language code: AsymptoticRSolveValue[y[n + 1] == (n ^ 2 + 1) / n ^ 2 y[n], y[n], {n, ∞, 3}, GeneratedParameters -> d]

使用有下标的常数：

Wolfram Language code: AsymptoticRSolveValue[y[n + 1] == (n ^ 2 + 1) / n ^ 2 y[n], y[n], {n, ∞, 3}, GeneratedParameters -> (Subscript[d, #]&)]

应用  (6)

基本应用  (2)

计算差分方程的近似解：

Wolfram Language code: AsymptoticRSolveValue[y[n + 1] == (n ^ 3 + 1) / n ^ 3 y[n], y[n], {n, ∞, 3}]

计算高阶近似解：

Wolfram Language code: AsymptoticRSolveValue[y[n + 1] == (n ^ 3 + 1) / n ^ 3 y[n], y[n], {n, ∞, 7}]

求 Gamma 的渐近逼近：

Wolfram Language code: sol[n_] = AsymptoticRSolveValue[{a[n + 1] == n a[n], a[1] == 1}, a[n], {n, ∞, 1}]

求序列中某个项的近似值：

Wolfram Language code: sol[50000]//N[#, 20]&

与精确值相比较：

Wolfram Language code: Gamma[50000.`20]

特殊序列  (4)

求 Fibonacci 序列的渐近逼近，从这个序列满足的差分方程的展开式开始：

Wolfram Language code: fib = Fibonacci[n];
Wolfram Language code: Table[fib, {n, 10}]
Wolfram Language code: Head[DifferenceRootReduce[fib, n]][[1]][a, n][[1]]
Wolfram Language code: sol[n_] = AsymptoticRSolveValue[%, a[n], {n, ∞, 1}]

验证对于较大的 n，展开式的第一个分量趋近于 0：

Wolfram Language code: DiscreteLimit[sol[n] /. {C[2] -> 0}, n -> ∞]
Wolfram Language code: {DiscretePlot[sol[n] /. {C[2] -> 0, C[1] -> 1}, {n, 0, 30}], DiscretePlot[sol[n] /. {C[2] -> 1, C[1] -> 0}, {n, 0, 50}]}

将第一个分量设为 0：

Wolfram Language code: fsol[n_] = sol[n] /. {C[1] -> 0}

为 赋值：

Wolfram Language code: Solve[fsol[1000] == Fibonacci[1000], C[2]]//N[#, 20]&

求序列中某个项的近似值：

Wolfram Language code: fsol[30000] /. %[[1]] //N[#, 20]&

与相应的 Fibonacci 数相比较：

Wolfram Language code: Fibonacci[30000.`20]

求三阶 Fibonacci 序列的渐近逼近，从这个序列满足的差分方程的展开式开始：

Wolfram Language code: sol[n_] = AsymptoticRSolveValue[a[n + 1] == a[n] + a[n - 1] + a[n - 2], a[n], {n, ∞, 1}]

验证对于较大的 n，展开式的第二个和第三个分量趋近于 0：

Wolfram Language code: DiscreteLimit[sol[n], n -> ∞]
Wolfram Language code: {DiscretePlot[Abs[sol[n] /. {C[2] -> 1, C[1] -> 0, C[3] -> 0}], {n, 0, 30}], DiscretePlot[Abs[sol[n] /. {C[2] -> 0, C[1] -> 0, C[3] -> 1}], {n, 0, 30}], DiscretePlot[Abs[sol[n] /. {C[1] -> 1, C[2] -> 0, C[3] -> 0}], {n, 0, 20}]}

将第二个和第三个分量设为 0：

Wolfram Language code: fsol[n_] = sol[n] /. {C[2] -> 0, C[3] -> 0}

为 赋值：

Wolfram Language code: tsol[n_] = RSolveValue[{a[n + 1] == a[n] + a[n - 1] + a[n - 2], a[0] == 0, a[1] == 0, a[2] == 1}, a[n], n]
Wolfram Language code: Solve[fsol[1000] == tsol[1000], C[1]]//N[#, 20]&//Chop

求序列中某个项的近似值：

Wolfram Language code: fsol[30000] /. %[[1]] //N[#, 20]&

与相应的 Fibonacci 数相比较：

Wolfram Language code: tsol[30000.`20]//Chop

求摄动 Fibonacci 序列的渐近逼近，从这个序列满足的差分方程的展开式开始：

Wolfram Language code: sol[n_] = AsymptoticRSolveValue[a[n + 1] == (1 + 1 / n) a[n] + (1 - 1 / n) a[n - 1], a[n], {n, ∞, 1}]

验证对于较大的 n，展开式的第一个分量趋近于 0：

Wolfram Language code: DiscreteLimit[sol[n], n -> ∞]
Wolfram Language code: {DiscretePlot[sol[n] /. {C[2] -> 0, C[1] -> 1}, {n, 1, 30}], DiscretePlot[sol[n] /. {C[2] -> 1, C[1] -> 0}, {n, 1, 50}]}

将第一个分量设为 0：

Wolfram Language code: fsol[n_] = sol[n] /. {C[1] -> 0}

为 赋值：

Wolfram Language code: tsol[n_] = RSolveValue[{a[n + 1] == (1 + 1 / n) a[n] + (1 - 1 / n) a[n - 1], a[1] == 1, a[2] == 1}, a[n], n]
Wolfram Language code: Solve[fsol[1000] == tsol[1000], C[2]]//N[#, 20]&//Chop

求序列中某个项的近似值：

Wolfram Language code: fsol[3000] /. %[[1]] //N[#, 20]&

与相应的摄动 Fibonacci 数相比较：

Wolfram Language code: tsol[3000]//N

计算 Apéry 序列的领头 (leading-order) 渐近项，它满足以下线性二阶差分方程：

Wolfram Language code: apeqn = (n + 2) ^ 3 u[n + 2] - (34 n ^ 3 + 153 n ^ 2 + 231 n + 117)u[n + 1] + (n + 1) ^ 3 u[n] == 0;

获取领头渐近项：

Wolfram Language code: sol[n_] = AsymptoticRSolveValue[apeqn, u[n], {n, Infinity, 1}]

验证对于较大的 n，展开式的第一个分量趋近于 0：

Wolfram Language code: DiscreteLimit[sol[n], n -> ∞]
Wolfram Language code: {DiscretePlot[sol[n] /. {C[2] -> 0, C[1] -> 1}, {n, 1, 20}], DiscretePlot[sol[n] /. {C[2] -> 1, C[1] -> 0}, {n, 1, 20}]}

将第一个分量设为 0：

Wolfram Language code: fsol[n_] = sol[n] /. {C[1] -> 0}

根据序列的定义和 (defining sum) 为 赋值：

Wolfram Language code: tsol[n_] := Sum[Binomial[n, k] ^ 2 Binomial[n + k, k] ^ 2, {k, 0, n}]
Wolfram Language code: Solve[fsol[1000] == tsol[1000], C[2]]//N[#, 20]&//Chop

求序列中某个项的近似值：

Wolfram Language code: fsol[10000] /. %[[1]] //N[#, 20]&

与相应的 Apéry 数相比较：

Wolfram Language code: tsol[10000]//N

属性和关系  (3)

解满足给定阶数的差分方程：

Wolfram Language code: sol = AsymptoticRSolveValue[y[n + 1] == (n ^ 2 + 1) / n ^ 2y[n], y[n], {n, ∞, 6}]
Wolfram Language code: (y[n + 1] - (n ^ 2 + 1) / n ^ 2y[n] /. y -> Function[{n}, Evaluate[sol]])//Simplify
Wolfram Language code: Series[%, {n, ∞, 6}]

用 RSolveValue 求精确解：

Wolfram Language code: asol = AsymptoticRSolveValue[y[n + 1] == (n ^ 2 + 1) / n ^ 2 y[n], y[n], {n, ∞, 4}] /. {C[1] -> 1}
Wolfram Language code: rsol = RSolveValue[y[n + 1] == (n ^ 2 + 1) / n ^ 2 y[n], y[n], n]
Wolfram Language code: (Series[%, {n, ∞, 4}]//Normal) /. {C[1] -> Gamma[1 - I] Gamma[1 + I]}//Apart

用 RecurrenceTable 求数值解：

Wolfram Language code: asol = AsymptoticRSolveValue[{y[n + 1] == y[n] + ϵ y[n] ^ 2, y[1] == 3}, y[n], n, {ϵ, 0, 2}]
Wolfram Language code: Table[% /. {ϵ -> 1 / 400.}, {n, 1, 7}]
Wolfram Language code: nsol = RecurrenceTable[{y[n + 1] == y[n] + 1 / 400. y[n] ^ 2, y[1] == 3}, y[n], {n, 1, 7}]
Wolfram Research (2019)，AsymptoticRSolveValue，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AsymptoticRSolveValue.html （更新于 2025 年）.

文本

Wolfram Research (2019)，AsymptoticRSolveValue，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AsymptoticRSolveValue.html （更新于 2025 年）.

CMS

Wolfram 语言. 2019. "AsymptoticRSolveValue." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2025. https://reference.wolfram.com/language/ref/AsymptoticRSolveValue.html.

APA

Wolfram 语言. (2019). AsymptoticRSolveValue. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AsymptoticRSolveValue.html 年

BibTeX

@misc{reference.wolfram_2026_asymptoticrsolvevalue, author="Wolfram Research", title="{AsymptoticRSolveValue}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/AsymptoticRSolveValue.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_asymptoticrsolvevalue, organization={Wolfram Research}, title={AsymptoticRSolveValue}, year={2025}, url={https://reference.wolfram.com/language/ref/AsymptoticRSolveValue.html}, note=[Accessed: 17-August-2026]}