Wolfram言語＆システムドキュメントセンター

AsymptoticSum

AsymptoticSum[f,x,xx₀]

x₀を中心とする x についての不定和分の漸近近似を計算する．

AsymptoticSum[f,{x,a,b},αα₀]

α₀を中心とする α についての定和分の漸近近似を計算する．

AsymptoticSum[f,…,{ξ,ξ₀,n}]

漸近近似を次数 n まで計算する．

詳細とオプション

総和の漸近近似は，漸近展開および摂動展開としても知られるものである．これらは，オイラー(Euler)・マクローリン(Maclaurin)法や部分総和法等を計算するための特別のメソッドにも知られている．
漸近近似は，厳密解が求まらない問題を解くため，あるいは，計算，比較，解釈のためにより簡単な答を得るために，使われることが多い．
AsymptoticSum[f,…,xx₀]は，f の総和の漸近展開における最高次数の項を計算する．より多くの項を指定したければSeriesTermGoalを使うとよい．
厳密な結果が g[x]で x₀における次数 n の漸近近似が g_n[x]なら，xx₀のとき，AsymptoticLess[g[x]-g_n[x],g_n[x]-g_n-1[x],xx₀]または g[x]-g_n[x]∈o[g_n[x]-g_n-1[x]]である．
漸近近似 g_n[x]は，しばしば総和 g_n[x]α_kϕ_k[x]として与えられる．ただし，{ϕ₁[x],…,ϕ_n[x]}は xx₀のときの漸近尺度 ϕ₁[x]≻ϕ₂[x]≻⋯>ϕ_n[x]である．xx₀のとき，AsymptoticLess[g[x]-g_n[x],ϕ_n[x],xx₀]または g[x]-g_n[x]∈o[ϕ_n[x]]である．

		xx₀のときのテイラー(Taylor)スケール
		xx₀のときのローラン(Laurent)スケール
		x±∞のときのローランスケール
		xx₀のときのピュイゾー(Puiseux)スケール

漸近近似を表すために使われる尺度は，問題から自動的に推測される．より珍しい尺度が含まれることも多い．
中心 α₀は，任意の有限または無限の実数または複素数でよい．
次数 n は漸近展開の近似次数を指定するもので，正の整数でなければならない．この次数は，多項式次数とは無関係である．
次は，使用可能なオプションである．

AccuracyGoal	Automatic	目標とする絶対確度の桁数
Assumptions	$Assumptions	パラメータについての仮定
GenerateConditions	Automatic	パラメータについての条件を含む答を生成するかどうか
GeneratedParameters	None	生成されたパラメータの名付け方
Method	Automatic	使用するメソッド
PerformanceGoal	$PerformanceGoal	パフォーマンスのどの局面について最適化するか
PrecisionGoal	Automatic	目標精度の桁数
Regularization	None	使用する正規化スキーム
SeriesTermGoal	Automatic	近似における項数
WorkingPrecision	Automatic	内部計算の精度

PerformanceGoalの可能な設定には，$PerformanceGoal，"Quality"，"Speed"がある．"Quality"設定のとき，AsymptoticSumはより多くの問題を解いたりより簡単な結果を与えたりすることが多いが，より多くの時間とメモリが必要になる可能性がある．

例題

すべて開くすべて閉じる

例 (3)

総和について最高次の漸近近似を計算する：

Wolfram Language code: AsymptoticSum[1 / k, {k, 1, n}, n -> ∞]

和の漸近展開を計算する：

Wolfram Language code: AsymptoticSum[1 / Sqrt[k], {k, 1, n}, {n, ∞, 3}]

大きい n についての厳密値と比較する：

Wolfram Language code: % /. {n -> 50.}

Wolfram Language code: Sum[1 / Sqrt[k], {k, 1, 50}]//N

パラメータについての和の漸近展開を計算する：

Wolfram Language code: f[a_] := 1 / (k ^ 2 + a)

Wolfram Language code: DiscretePlot[Sum[f[0.05], {k, 1, n}], {n, 1, 50}]

必要とされる展開を計算する：

Wolfram Language code: AsymptoticSum[f[a], {k, 1, ∞}, {a, 0, 2}]

小さい a についての厳密値と比較する：

Wolfram Language code: {% /. {a -> 0.05}, Sum[f[0.05], {k, 1, ∞}]}

スコープ (13)

不定和分 (5)

有理和について漸近展開を計算する：

Wolfram Language code: AsymptoticSum[1 / (k ^ 2 + 1), k, {k, ∞, 8}]

Sumが与える結果と比較する：

Wolfram Language code: Sum[1 / (k ^ 2 + 1), k]

Wolfram Language code: Series[%, {k, ∞, 8}]//Normal

多項・指数型の和についての漸近展開：

Wolfram Language code: AsymptoticSum[k E ^ k, k, {k, ∞, 3}]

Sumが与える結果と比較する：

Wolfram Language code: Sum[k E ^ k, k]

Wolfram Language code: Series[%, {k, ∞, 3}]//Normal

超幾何和についての漸近展開：

Wolfram Language code: AsymptoticSum[1 / k!, k, {k, ∞, 2}]

ある点における値を推定する：

Wolfram Language code: % /. k -> 20.

NSumが与える値と比較する：

Wolfram Language code: NSum[1 / k!, {k, 1, 20}]

有理・指数型の和についての漸近展開：

Wolfram Language code: expr = E ^ (-5k) / (k + 1) ^ 2;

Wolfram Language code: indef = AsymptoticSum[expr, k, {k, ∞, 3}]

結果を確かめる：

Wolfram Language code: Series[DifferenceDelta[indef, k] - expr, {k, ∞, 2}]//Normal//Simplify

PolyGamma和についての漸近展開：

Wolfram Language code: AsymptoticSum[PolyGamma[k] / (k + 1), k, {k, ∞, 2}]

有限和 (4)

有理和についての漸近展開を計算する：

Wolfram Language code: AsymptoticSum[1 / (k ^ 2 - 1), {k, 2, n}, {n, ∞, 3}]

NSumが与える結果と比較する：

Wolfram Language code: % /. {n -> 50.`20}//N//Chop

Wolfram Language code: NSum[1 / (k ^ 2 - 1), {k, 2, 50}]

Wolfram Language code: DiscretePlot[Sum[1 / (k ^ 2 - 1), {k, 2, n}], {n, 1, 50}]

有理・指数型の和についての漸近展開：

Wolfram Language code: AsymptoticSum[E ^ (-7 k) / (k + 1), {k, 1, n - 1}, {n, ∞, 1}]

NSumが与える結果と比較する：

Wolfram Language code: % /. {n -> 2000.`20}//N

Wolfram Language code: NSum[E ^ (-7 k) / (k + 1), {k, 1, 2000}]

超幾何和の漸近展開を計算する：

Wolfram Language code: AsymptoticSum[Binomial[n, k] ^ 2, {k, 0, n}, {n, ∞, 2}]

厳密な結果と比較する：

Wolfram Language code: % /. n -> 100.//Chop

Wolfram Language code: Sum[Binomial[n, k] ^ 2, {k, 0, n}] /. {n -> 100.}

HarmonicNumber和についての漸近展開：

Wolfram Language code: AsymptoticSum[HarmonicNumber[k] / (k + 1), {k, 1, n - 1}, {n, ∞, 2}]

NSumが与える結果と比較する：

Wolfram Language code: % /. {n -> 2000.`20}//N

Wolfram Language code: NSum[HarmonicNumber[k] / (k + 1), {k, 1, 1999}]

パラメトリック和 (4)

パラメータについての漸近展開を計算する：

Wolfram Language code: expr = 1 / (1 + m k ^ 2);

Wolfram Language code: indef = AsymptoticSum[expr, k, {m, ∞, 4}]

結果を確かめる：

Wolfram Language code: Series[DifferenceDelta[indef, k] - expr, {m, ∞, 4}]//Normal

無限・指数型の和の漸近展開を計算する：

Wolfram Language code: AsymptoticSum[E ^ (-a k), {k, 0, ∞}, {a, 0, 3}]

厳密な結果と比較する：

Wolfram Language code: % /. {a -> 0.7}

Wolfram Language code: Sum[E ^ (-0.7 k), {k, 0, ∞}]

Zetaと関連する和についての漸近展開：

Wolfram Language code: AsymptoticSum[1 / (k ^ (3 / 2) + a), {k, 1, ∞}, {a, 0, 4}]

数値近似と比較する：

Wolfram Language code: % /. a -> 0.07

Wolfram Language code: NSum[1 / (k ^ (3 / 2) + 0.07), {k, 1, ∞}]

ガウスの指数型交代和についての漸近近似：

Wolfram Language code: AsymptoticSum[(-1) ^ k k E ^ (-k ^ 2 x), {k, 1, ∞}, {x, 0, 3}]

数値近似と比較する：

Wolfram Language code: % /. x -> 0.07

Wolfram Language code: NSum[(-1) ^ k k E ^ (-k ^ 2 0.07), {k, 1, ∞}]

オプション (3)

GeneratedParameters (1)

不定和分についての任意の定数を生成する：

Wolfram Language code: AsymptoticSum[1 / (k ^ 2 + 1), k, {k, ∞, 2}, GeneratedParameters -> C]

任意の定数についてのデフォルト値は0である：

Wolfram Language code: % /. {C[1] -> 0}

Wolfram Language code: AsymptoticSum[1 / (k ^ 2 + 1), k, {k, ∞, 2}]

Regularization (2)

アーベル(Abel)の正規化を使って発散する和についての漸近展開を計算する：

Wolfram Language code:

AsymptoticSum[(-1) ^ n * (n + a) ^ 3, {n, 0, Infinity}, {a, 0, 2}, 
	Regularization -> "Abel"]

ボレル(Borel)の正規化を使って発散する和についての漸近展開を計算する：

Wolfram Language code:

AsymptoticSum[(Gamma[3 n + (1/2)] (-1)^n/((2 z^3 / 2/3))^n (2^n 3^3 n Gamma[n + (1/2)] Gamma[n + 1])), {n, 0, ∞}, {z, 0, 1}, Regularization -> "Borel", Assumptions -> z > 0]

アプリケーション (9)

有限和についての近似を計算する：

Wolfram Language code: AsymptoticSum[1 / (2 ^ k + 1), {k, 0, n}, {n, ∞, 1}]

徐々に増加する n の値についての数値近似を計算する：

Wolfram Language code: Table[%, {n, {5, 10, 300}}]//N[#, 20]&//N//Chop

Sumが与える厳密な結果と比較する：

Wolfram Language code: Table[Sum[1 / (2 ^ k + 1), {k, 0, n}], {n, {5, 10, 300}}]//N[#, 20]&//N//Chop

定積分についてのリーマン(Riemann)和近似を計算する：

Wolfram Language code: f[x_] := x E ^ (-x)

Wolfram Language code: riemanns = AsymptoticSum[f[i / n] 1 / n, {i, 0, n}, {n, ∞, 2}]

n の大きい値についての近似を計算する：

Wolfram Language code: Table[riemanns, {n, 100, 5000, 1000}]//N

Integrateが与える結果と比較する：

Wolfram Language code: Integrate[f[x], {x, 0, 1}]

Wolfram Language code: N[%]

DiscreteLimitを使って厳密な結果を得る：

Wolfram Language code: DiscreteLimit[riemanns, n -> ∞]//Together

近似値と厳密値をプロットする：

Wolfram Language code: DiscretePlot[{riemanns, (-2 + E/E)}, {n, 100, 2000, 100}, PlotTheme -> "Scientific", PlotRange -> {0.263, 0.27}]

広義積分の数値近似を計算する：

Wolfram Language code: f[x_] := E ^ (-x ^ 2 / 1500)

Wolfram Language code: Plot[f[x], {x, 1, 100}, Filling -> Axis]

Wolfram Language code: napprox = AsymptoticSum[f[i], {i, 1, n}, {n, ∞, 2}]

n の大きい値についての近似を計算する：

Wolfram Language code: napprox /. {n -> 180.}//Chop

NIntegrateが与える結果と比較する：

Wolfram Language code: NIntegrate[f[x], {x, 1, ∞}]

であることを示す：

Wolfram Language code: AsymptoticSum[1 / k, {k, 1, n}, {n, ∞, 2}]

厳密な結果の展開と比較する：

Wolfram Language code: Sum[1 / k, {k, 1, n}]

Wolfram Language code: Series[%, {n, ∞, 1}]//Normal

についての漸近展開を計算する：

Wolfram Language code: AsymptoticSum[Sqrt[k], {k, 1, n}, {n, ∞, 3}]

についての近似値と厳密値を比較する：

Wolfram Language code: % /. {n -> 200.}//Chop

Wolfram Language code: Sum[Sqrt[k], {k, 1, 200}]//N

ガウス和についての漸近近似を計算する：

Wolfram Language code: AsymptoticSum[E ^ (-k ^ 2), {k, 1, n}, {n, ∞, 2}]

についての近似値と厳密値を比較する：

Wolfram Language code: % /. {n -> 10.}

Wolfram Language code: Sum[E ^ (-k ^ 2), {k, 1, 10}]//N

有理和についての一階漸近近似を計算する：

Wolfram Language code: AsymptoticSum[k / (k + 1), {k, 1, n}, {n, ∞, 1}]

有理・指数型の和：

Wolfram Language code: AsymptoticSum[2 ^ k / k, {k, 1, n}, {n, ∞, 1}]

超幾何和：

Wolfram Language code: AsymptoticSum[2 ^ k / k!, {k, 1, n}, {n, ∞, 1}]

n がInfinityに近付くとき，は1/n と漸近的に等しいことを示す：

Wolfram Language code: AsymptoticSum[1 / (n ^ 2 + k), {k, 1, n}, {n, ∞, 2}]

AsymptoticEquivalentを使って必要とされる等価性を確かめる：

Wolfram Language code: AsymptoticEquivalent[%, 1 / n, n -> ∞]

Sumからの結果を使って結果を確かめる：

Wolfram Language code: Sum[1 / (n ^ 2 + k), {k, 1, n}]

Wolfram Language code: AsymptoticEquivalent[%, 1 / n, n -> ∞]

二項和について漸近近似を計算する：

Wolfram Language code: AsymptoticSum[Binomial[n, k] ^ 3, {k, 0., n}, {n, ∞, 2}]

について近似値と厳密値を計算する：

Wolfram Language code: % /. {n -> 1000.}

Wolfram Language code: Sum[Binomial[1000, k] ^ 3, {k, 0, 1000}]//N

特性と関係 (3)

AsymptoticSumは指定された次数までの和を計算する：

Wolfram Language code: asym = AsymptoticSum[1 / (k ^ 2 - 1), k, {k, ∞, 6}]

Wolfram Language code: exact = (1 - 2 k/2 (-1 + k) k);

Wolfram Language code: Series[asym - exact, {k, ∞, 6}]

Sumを使って和を閉形式で求める：

Wolfram Language code: AsymptoticSum[E ^ (-a k), {k, 0, n}, {a, 0, 2}]

Wolfram Language code: Sum[E ^ (-a k), {k, 0, n}]

Wolfram Language code: Series[%, {a, 0, 2}]//Normal

NSumを使って数値近似を計算する：

Wolfram Language code: AsymptoticSum[1 / k ^ (5 / 2), {k, 1, n}, {n, ∞, 2}]

Wolfram Language code: % /. {n -> 40.`20}//N

Wolfram Language code: NSum[1 / k ^ (5 / 2), {k, 1, 40}]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

AsymptoticSum

詳細とオプション

例題

例 (3)