WOLFRAM

Wolfram 语言与系统参考资料中心

AsymptoticSum[f,x,xx0]

计算不定和 的渐进逼近，其中 x 以 x0 为中心.

AsymptoticSum[f,{x,a,b},αα0]

计算确定和 的渐进逼近，其中 α 以 α0 为中心.

AsymptoticSum[f,…,{ξ,ξ0,n}]

计算 n 阶渐近逼近.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
不定和  
确定和  
参数和  
选项  
GeneratedParameters  
Regularization  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

AsymptoticSum

AsymptoticSum[f,x,xx0]

计算不定和 的渐进逼近，其中 x 以 x0 为中心.

AsymptoticSum[f,{x,a,b},αα0]

计算确定和 的渐进逼近，其中 α 以 α0 为中心.

AsymptoticSum[f,…,{ξ,ξ0,n}]

计算 n 阶渐近逼近.

更多信息和选项

  • 和的渐近逼近亦被称为渐近展开式和摄动展开式. 也可用计算其中一些式子的特定方法来称呼它们，如 Euler–Maclaurin 方法、分部求和法等.
  • 渐近逼近通常用于计算无法找到精确结果的求和问题，或者为计算、比较和解释寻求更简单的答案.
  • AsymptoticSum[f,…,xx0] 计算 f 的渐近展开式的首项. 用 SeriesTermGoal 可指定计算更多的项..
  • 如果精确结果为 g[x]，在 x0 处的 n 阶渐近逼近为 gn[x]，那么当 xx0 时，结果为 AsymptoticLess[g[x]-gn[x],gn[x]-gn-1[x],xx0] 或 g[x]-gn[x]∈o[gn[x]-gn-1[x]].
  • 渐近逼近 gn[x] 常以和 gn[x]αkϕk[x] 的形式给出，其中 {ϕ1[x],…,ϕn[x]} 是当 xx0 时的渐近尺度 ϕ1[x]≻ϕ2[x]≻⋯>ϕn[x]. 则当 xx0 时，结果为 AsymptoticLess[g[x]-gn[x],ϕn[x],xx0] 或 g[x]-gn[x]∈o[ϕn[x]].
  • Taylor 尺度，当 xx0 时
    Laurent 尺度，当 xx0 时
    Laurent 尺度，当 x±∞ 时
    Puiseux 尺度，当 xx0 时
  • 用于表示渐近逼近的尺度是从问题中自动推断出来的，通常可以包含更多的奇异尺度.
  • 中心点 α0 可为任意有限或无限大实数或复数.
  • 阶数 n 必须为一个正整数，指定渐近展开式的近似阶数. 与多项式的次数无关.
  • 可以给出以下选项：
  • AccuracyGoalAutomatic寻求的绝对准确度
    Assumptions$Assumptions对参数的设定
    GenerateConditionsAutomatic是否给出与参数的条件有关的答案
    GeneratedParameters None怎样命名生成的参数
    MethodAutomatic所用的方法
    PerformanceGoal$PerformanceGoal优化目标
    PrecisionGoalAutomatic寻求的精度
    Regularization None所使用的正则化方案
    SeriesTermGoalAutomatic近似式的项数
    WorkingPrecisionAutomatic内部计算中使用的精度
  • PerformanceGoal 的可能设置包括 $PerformanceGoal、"Quality" 和 "Speed". 当设置为 "Quality" 时， AsymptoticSum 通常可以解出更多的问题或者产生更简单的结果，但是可能会耗费更多的时间和内存.

范例

打开所有单元 关闭所有单元

基本范例  (3)

计算和的渐近逼近的首项：

Wolfram Language code: AsymptoticSum[1 / k, {k, 1, n}, n -> ∞]

计算和的渐近展开式：

Wolfram Language code: AsymptoticSum[1 / Sqrt[k], {k, 1, n}, {n, ∞, 3}]

与 n 取较大值时的精确值相比较：

Wolfram Language code: % /. {n -> 50.}
Wolfram Language code: Sum[1 / Sqrt[k], {k, 1, 50}]//N

计算和 (sum) 关于一个参数的渐近展开式：

Wolfram Language code: f[a_] := 1 / (k ^ 2 + a)
Wolfram Language code: DiscretePlot[Sum[f[0.05], {k, 1, n}], {n, 1, 50}]

计算要求的展开式：

Wolfram Language code: AsymptoticSum[f[a], {k, 1, ∞}, {a, 0, 2}]

与 a 取较小值时的精确值相比较：

Wolfram Language code: {% /. {a -> 0.05}, Sum[f[0.05], {k, 1, ∞}]}

范围  (13)

不定和  (5)

计算有理和的渐近展开式：

Wolfram Language code: AsymptoticSum[1 / (k ^ 2 + 1), k, {k, ∞, 8}]

与 Sum 给出的结果相比较：

Wolfram Language code: Sum[1 / (k ^ 2 + 1), k]
Wolfram Language code: Series[%, {k, ∞, 8}]//Normal

多项式指数和的渐近展开式：

Wolfram Language code: AsymptoticSum[k E ^ k, k, {k, ∞, 3}]

与 Sum 给出的结果相比较：

Wolfram Language code: Sum[k E ^ k, k]
Wolfram Language code: Series[%, {k, ∞, 3}]//Normal

超几何和的渐近展开式：

Wolfram Language code: AsymptoticSum[1 / k!, k, {k, ∞, 2}]

估计在一个点的值：

Wolfram Language code: % /. k -> 20.

与 NSum 给出的结果相比较：

Wolfram Language code: NSum[1 / k!, {k, 1, 20}]

有理指数和的渐近展开式：

Wolfram Language code: expr = E ^ (-5k) / (k + 1) ^ 2;
Wolfram Language code: indef = AsymptoticSum[expr, k, {k, ∞, 3}]

验证结果：

Wolfram Language code: Series[DifferenceDelta[indef, k] - expr, {k, ∞, 2}]//Normal//Simplify

PolyGamma 和的渐近展开式：

Wolfram Language code: AsymptoticSum[PolyGamma[k] / (k + 1), k, {k, ∞, 2}]

确定和  (4)

计算有理和的渐近展开式：

Wolfram Language code: AsymptoticSum[1 / (k ^ 2 - 1), {k, 2, n}, {n, ∞, 3}]

与 NSum 给出的结果相比较：

Wolfram Language code: % /. {n -> 50.`20}//N//Chop
Wolfram Language code: NSum[1 / (k ^ 2 - 1), {k, 2, 50}]
Wolfram Language code: DiscretePlot[Sum[1 / (k ^ 2 - 1), {k, 2, n}], {n, 1, 50}]

有理指数和的渐近展开式：

Wolfram Language code: AsymptoticSum[E ^ (-7 k) / (k + 1), {k, 1, n - 1}, {n, ∞, 1}]

与 NSum 给出的结果相比较：

Wolfram Language code: % /. {n -> 2000.`20}//N
Wolfram Language code: NSum[E ^ (-7 k) / (k + 1), {k, 1, 2000}]

计算超几何和的渐近展开式：

Wolfram Language code: AsymptoticSum[Binomial[n, k] ^ 2, {k, 0, n}, {n, ∞, 2}]

与精确结果相比较：

Wolfram Language code: % /. n -> 100.//Chop
Wolfram Language code: Sum[Binomial[n, k] ^ 2, {k, 0, n}] /. {n -> 100.}

HarmonicNumber 和的渐近展开式：

Wolfram Language code: AsymptoticSum[HarmonicNumber[k] / (k + 1), {k, 1, n - 1}, {n, ∞, 2}]

与 NSum 给出的结果相比较：

Wolfram Language code: % /. {n -> 2000.`20}//N
Wolfram Language code: NSum[HarmonicNumber[k] / (k + 1), {k, 1, 1999}]

参数和  (4)

计算关于一个参数的渐近展开式：

Wolfram Language code: expr = 1 / (1 + m k ^ 2);
Wolfram Language code: indef = AsymptoticSum[expr, k, {m, ∞, 4}]

验证结果：

Wolfram Language code: Series[DifferenceDelta[indef, k] - expr, {m, ∞, 4}]//Normal

计算无限指数和的渐近展开式：

Wolfram Language code: AsymptoticSum[E ^ (-a k), {k, 0, ∞}, {a, 0, 3}]

与精确结果相比较：

Wolfram Language code: % /. {a -> 0.7}
Wolfram Language code: Sum[E ^ (-0.7 k), {k, 0, ∞}]

与 Zeta 相关的和的渐近展开式：

Wolfram Language code: AsymptoticSum[1 / (k ^ (3 / 2) + a), {k, 1, ∞}, {a, 0, 4}]

与数值近似相比较：

Wolfram Language code: % /. a -> 0.07
Wolfram Language code: NSum[1 / (k ^ (3 / 2) + 0.07), {k, 1, ∞}]

交替高斯指数和的渐近展开式：

Wolfram Language code: AsymptoticSum[(-1) ^ k k E ^ (-k ^ 2 x), {k, 1, ∞}, {x, 0, 3}]

与数值近似相比较：

Wolfram Language code: % /. x -> 0.07
Wolfram Language code: NSum[(-1) ^ k k E ^ (-k ^ 2 0.07), {k, 1, ∞}]

选项  (3)

GeneratedParameters  (1)

为不定和产生一个任意常数：

Wolfram Language code: AsymptoticSum[1 / (k ^ 2 + 1), k, {k, ∞, 2}, GeneratedParameters -> C]

任意常数的默认值是 0：

Wolfram Language code: % /. {C[1] -> 0}
Wolfram Language code: AsymptoticSum[1 / (k ^ 2 + 1), k, {k, ∞, 2}]

Regularization  (2)

使用 Abel 正则化计算发散和的渐近展开式：

Wolfram Language code: AsymptoticSum[(-1) ^ n * (n + a) ^ 3, {n, 0, Infinity}, {a, 0, 2}, Regularization -> "Abel"]

使用 Borel 正则化计算发散和的渐近展开式：

Wolfram Language code: AsymptoticSum[(Gamma[3 n + (1/2)] (-1)^n/((2 z^3 / 2/3))^n (2^n 3^3 n Gamma[n + (1/2)] Gamma[n + 1])), {n, 0, ∞}, {z, 0, 1}, Regularization -> "Borel", Assumptions -> z > 0]

应用  (9)

计算有限和的近似值：

Wolfram Language code: AsymptoticSum[1 / (2 ^ k + 1), {k, 0, n}, {n, ∞, 1}]

计算 n 增大时的数值近似：

Wolfram Language code: Table[%, {n, {5, 10, 300}}]//N[#, 20]&//N//Chop

与由 Sum 给出的精确结果相比较：

Wolfram Language code: Table[Sum[1 / (2 ^ k + 1), {k, 0, n}], {n, {5, 10, 300}}]//N[#, 20]&//N//Chop

计算定积分的黎曼和近似：

Wolfram Language code: f[x_] := x E ^ (-x)
Wolfram Language code: riemanns = AsymptoticSum[f[i / n] 1 / n, {i, 0, n}, {n, ∞, 2}]

计算 n 取较大值时的近似：

Wolfram Language code: Table[riemanns, {n, 100, 5000, 1000}]//N

与 Integrate 给出的结果相比较：

Wolfram Language code: Integrate[f[x], {x, 0, 1}]
Wolfram Language code: N[%]

用 DiscreteLimit 获取精确结果：

Wolfram Language code: DiscreteLimit[riemanns, n -> ∞]//Together

绘制近似值和精确值：

Wolfram Language code: DiscretePlot[{riemanns, (-2 + E/E)}, {n, 100, 2000, 100}, PlotTheme -> "Scientific", PlotRange -> {0.263, 0.27}]

计算反常积分的数值近似：

Wolfram Language code: f[x_] := E ^ (-x ^ 2 / 1500)
Wolfram Language code: Plot[f[x], {x, 1, 100}, Filling -> Axis]
Wolfram Language code: napprox = AsymptoticSum[f[i], {i, 1, n}, {n, ∞, 2}]

计算 n 取较大值时的近似：

Wolfram Language code: napprox /. {n -> 180.}//Chop

与 NIntegrate 给出的结果相比较：

Wolfram Language code: NIntegrate[f[x], {x, 1, ∞}]

证明 ：

Wolfram Language code: AsymptoticSum[1 / k, {k, 1, n}, {n, ∞, 2}]

与精确结果的展开式相比较：

Wolfram Language code: Sum[1 / k, {k, 1, n}]
Wolfram Language code: Series[%, {n, ∞, 1}]//Normal

计算 的渐近展开式：

Wolfram Language code: AsymptoticSum[Sqrt[k], {k, 1, n}, {n, ∞, 3}]

比较 时的近似值和精确值：

Wolfram Language code: % /. {n -> 200.}//Chop
Wolfram Language code: Sum[Sqrt[k], {k, 1, 200}]//N

计算高斯和的渐近逼近：

Wolfram Language code: AsymptoticSum[E ^ (-k ^ 2), {k, 1, n}, {n, ∞, 2}]

比较 时的近似值和精确值：

Wolfram Language code: % /. {n -> 10.}
Wolfram Language code: Sum[E ^ (-k ^ 2), {k, 1, 10}]//N

计算有理和的一阶渐近逼近：

Wolfram Language code: AsymptoticSum[k / (k + 1), {k, 1, n}, {n, ∞, 1}]

有理指数和：

Wolfram Language code: AsymptoticSum[2 ^ k / k, {k, 1, n}, {n, ∞, 1}]

超几何和：

Wolfram Language code: AsymptoticSum[2 ^ k / k!, {k, 1, n}, {n, ∞, 1}]

证明当 n 趋近于 Infinity 时 渐近逼近于 1/n：

Wolfram Language code: AsymptoticSum[1 / (n ^ 2 + k), {k, 1, n}, {n, ∞, 2}]

用 AsymptoticEquivalent 验证上述等价性：

Wolfram Language code: AsymptoticEquivalent[%, 1 / n, n -> ∞]

用从 Sum 所得的结果进行验证：

Wolfram Language code: Sum[1 / (n ^ 2 + k), {k, 1, n}]
Wolfram Language code: AsymptoticEquivalent[%, 1 / n, n -> ∞]

计算二项式和的渐近逼近：

Wolfram Language code: AsymptoticSum[Binomial[n, k] ^ 3, {k, 0., n}, {n, ∞, 2}]

比较 时的近似值和精确值：

Wolfram Language code: % /. {n -> 1000.}
Wolfram Language code: Sum[Binomial[1000, k] ^ 3, {k, 0, 1000}]//N

属性和关系  (3)

AsymptoticSum 计算给定阶数的和：

Wolfram Language code: asym = AsymptoticSum[1 / (k ^ 2 - 1), k, {k, ∞, 6}]
Wolfram Language code: exact = (1 - 2 k/2 (-1 + k) k);
Wolfram Language code: Series[asym - exact, {k, ∞, 6}]

通过 Sum 用解析式计算和：

Wolfram Language code: AsymptoticSum[E ^ (-a k), {k, 0, n}, {a, 0, 2}]
Wolfram Language code: Sum[E ^ (-a k), {k, 0, n}]
Wolfram Language code: Series[%, {a, 0, 2}]//Normal

用 NSum 计算数值近似：

Wolfram Language code: AsymptoticSum[1 / k ^ (5 / 2), {k, 1, n}, {n, ∞, 2}]
Wolfram Language code: % /. {n -> 40.`20}//N
Wolfram Language code: NSum[1 / k ^ (5 / 2), {k, 1, 40}]
Wolfram Research (2019)，AsymptoticSum，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AsymptoticSum.html （更新于 2020 年）.

文本

Wolfram Research (2019)，AsymptoticSum，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AsymptoticSum.html （更新于 2020 年）.

CMS

Wolfram 语言. 2019. "AsymptoticSum." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2020. https://reference.wolfram.com/language/ref/AsymptoticSum.html.

APA

Wolfram 语言. (2019). AsymptoticSum. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AsymptoticSum.html 年

BibTeX

@misc{reference.wolfram_2026_asymptoticsum, author="Wolfram Research", title="{AsymptoticSum}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/AsymptoticSum.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_asymptoticsum, organization={Wolfram Research}, title={AsymptoticSum}, year={2020}, url={https://reference.wolfram.com/language/ref/AsymptoticSum.html}, note=[Accessed: 11-September-2026]}