WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AudioInstanceQ[audio,obj]

audio がオブジェクト obj の例であるように聞こえる場合はTrueを，それ以外の場合はFalseを与える．

AudioInstanceQ[audio,obj,cat]

audio が指定されたカテゴリ cat の何かであると仮定する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
AcceptanceThreshold  
Masking  
RecognitionPrior  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

AudioInstanceQ

AudioInstanceQ[audio,obj]

audio がオブジェクト obj の例であるように聞こえる場合はTrueを，それ以外の場合はFalseを与える．

AudioInstanceQ[audio,obj,cat]

audio が指定されたカテゴリ cat の何かであると仮定する．

詳細とオプション

  • AudioInstanceQは音声信号が指定されたカテゴリの例かどうかを識別しようとする．
  • 次は，オブジェクト obj とカテゴリ cat 両方で使用可能な形式である．
  • "class""Sound"実体で使われる，名前付きのサウンドクラス
    Entity[…]任意の適切な実体
    category1|category2|…categoryiの任意のもの
  • 次は，使用可能なオプションである．
  • AcceptanceThreshold Automatic許容できるとみなす最低確率
    Masking All関心区間
    PerformanceGoalAutomatic識別において何を最適化するか
    RecognitionPrior 0.5Trueの結果の事前確率
    TargetDevice"CPU"計算するターゲットデバイス
  • AudioInstanceQは機械学習を使う．含まれるメソッド，訓練集合，バイアスはWolfram言語のバージョンによって異なることがあり，与えられる結果も異なる可能性がある．
  • AudioInstanceQはリソースをダウンロードすることがある．ダウンロードされたリソースは，$LocalBaseのローカルなオブジェクトストアに保存され，LocalObjects[]でリストしたりResourceRemoveで削除したりできる．

例題

すべて開く すべて閉じる

例  (2)

音声信号が特定のオブジェクトの例かどうかを調べる：

Wolfram Language code: AudioInstanceQ[ExampleData[{"Audio", "DogBark"}], "dog"]
Wolfram Language code: AudioInstanceQ[ExampleData[{"Audio", "DogBark"}], "cat"]
Wolfram Language code: AudioInstanceQ[Import@"ExampleData/rule30.wav", "guitar"]

音声信号が与えられたカテゴリのどちらかの例かどうかを調べる：

Wolfram Language code: AudioInstanceQ[Import@"ExampleData/rule30.wav", "drum" | "guitar"]

スコープ  (1)

デフォルトで，音声信号のサウンドカテゴリについては何も仮定されない：

Wolfram Language code: AudioInstanceQ[Import["ExampleData/rule30.wav"], "guitar"]

音声信号が特定のサウンドカテゴリに属していると仮定する：

Wolfram Language code: AudioInstanceQ[Import@"ExampleData/rule30.wav", "guitar", "Musical instrument"]

音声信号が特定のサウンドカテゴリの集合に属していると仮定する：

Wolfram Language code: AudioInstanceQ[Import@"ExampleData/rule30.wav", "guitar", "Musical instrument" | "Animal"]

オプション  (3)

AcceptanceThreshold  (1)

デフォルトで，自動許容閾値が使われる：

Wolfram Language code: AudioInstanceQ[ExampleData[{"Audio", "FogHorn"}], "musical instrument"]

許容閾値を指定する：

Wolfram Language code: AudioInstanceQ[ExampleData[{"Audio", "FogHorn"}], "musical instrument", AcceptanceThreshold -> .4]

Masking  (1)

デフォルトで，指定されたオブジェクトに対して音声信号全体がチェックされる：

Wolfram Language code: a = AudioJoin[{ExampleData[{"Audio", "Cat"}], ExampleData[{"Audio", "DogBark"}]}];
Wolfram Language code: AudioInstanceQ[a, "cat"]

テストを特定の区間に限定する：

Wolfram Language code: AudioInstanceQ[a, "cat", Masking -> {Quantity[1, "Seconds"], Quantity[5, "Seconds"]}]

RecognitionPrior  (1)

デフォルトのRecognitionPriorは0.5である：

Wolfram Language code: AudioInstanceQ[Import@"ExampleData/rule30.wav", "drum" | "guitar"]

テストするオブジェクトに非常に低い事前確率を割り当てる：

Wolfram Language code: AudioInstanceQ[Import@"ExampleData/rule30.wav", "drum" | "guitar", RecognitionPrior -> 1 / 20]

アプリケーション  (2)

ExampleData集合の中で楽器と認識されるすべての録音を求める：

Wolfram Language code: exampleData = AssociationMap[ExampleData, ExampleData["Audio"]];
Wolfram Language code: instrumentSounds = Select[exampleData, AudioInstanceQ[#, "musical instrument"]&];
Wolfram Language code: Keys[instrumentSounds]

録音に似ている他の音を求める：

Wolfram Language code: a = ExampleData[{"Audio", "Bird"}];

AudioIdentifyを使ってオブジェクトの識別を計算する：

Wolfram Language code: obj = AudioIdentify[a]

ExampleDataの集合におけるのと同じように識別されたサウンドを求める：

Wolfram Language code: examples = AssociationMap[ExampleData, ExampleData["Audio"]];
Wolfram Language code: sameSounds = Select[DeleteCases[examples, a], AudioInstanceQ[#, obj]&];
Wolfram Language code: Keys[sameSounds]

Entityオブジェクトの幅広いサウンド特性を使ってより一般的なオブジェクトのリストを計算する：

Wolfram Language code: categories = obj["BroaderSounds"]

幅広いカテゴリ内のサウンドを求める：

Wolfram Language code: broaderSounds = Select[DeleteCases[exampleData, a], AudioInstanceQ[#, Alternatives@@categories]&];
Wolfram Language code: Keys[similarSounds]

AudioIdentifyを使って関連するサウンドのより大きいリストを計算する：

Wolfram Language code: categories = DeleteDuplicates@Flatten@Values[AudioIdentify[a, All, All, "BroaderSounds"]]

ExampleData集合の中の似たサウンドを求める：

Wolfram Language code: similarSounds = Select[DeleteCases[exampleData, a], AudioInstanceQ[#, Alternatives@@categories]&];
Wolfram Language code: Keys[similarSounds]

特性と関係  (2)

AudioInstanceQとAudioIdentifyは相補的な機能を提供する：

Wolfram Language code: a = ExampleData[{"Audio", "Drums"}];

最も可能性が高いオブジェクトの識別を計算する：

Wolfram Language code: obj = AudioIdentify[a]

識別をAudioInstanceQに渡す：

Wolfram Language code: AudioInstanceQ[a, obj]

この識別に関連付けられた確率を得る：

Wolfram Language code: AudioIdentify[a, All, 1, "Probability"]
Wolfram Language code: p = First[Values[%]]

最小許容確率はもとの識別における確実性に対応する：

Wolfram Language code: AudioInstanceQ[a, obj, AcceptanceThreshold -> p + $MachineEpsilon]

テスト対象オブジェクトに最小許容確率を指定しても，テスト対象オブジェクトが仮定されたカテゴリ（もし指定されていれば）のいずれかに属さない限り効果がない．

アコースティックギターの録音が動物かどうかテストする：

Wolfram Language code: AudioInstanceQ[Audio["ExampleData/rule30.wav"], "animal"]

非常に低い許容閾値を指定する：

Wolfram Language code: AudioInstanceQ[Audio["ExampleData/rule30.wav"], "animal", AcceptanceThreshold -> .1]

録音が動物の音のカテゴリに属すと仮定した上で，ギターかどうかをテストする：

Wolfram Language code: AudioInstanceQ[Audio["ExampleData/rule30.wav"], "guitar", "animal"]

非常に低い許容閾値を指定しても，「ギター」の音が「動物」のカテゴリには含まれないので，一致しない：

Wolfram Language code: AudioInstanceQ[Audio["ExampleData/rule30.wav"], "guitar", "animal", AcceptanceThreshold -> .1]
Wolfram Research (2020), AudioInstanceQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/AudioInstanceQ.html.

テキスト

Wolfram Research (2020), AudioInstanceQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/AudioInstanceQ.html.

CMS

Wolfram Language. 2020. "AudioInstanceQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AudioInstanceQ.html.

APA

Wolfram Language. (2020). AudioInstanceQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AudioInstanceQ.html

BibTeX

@misc{reference.wolfram_2026_audioinstanceq, author="Wolfram Research", title="{AudioInstanceQ}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/AudioInstanceQ.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_audioinstanceq, organization={Wolfram Research}, title={AudioInstanceQ}, year={2020}, url={https://reference.wolfram.com/language/ref/AudioInstanceQ.html}, note=[Accessed: 18-August-2026]}