WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AudioLoudness[audio]

EBUメモリ定義に従って audio のラウドネスを計算する．

AudioLoudness[audio,def]

定義 def に従ってラウドネスを計算する．

AudioLoudness[video,…]

video の最初の音声トラックのラウドネスを計算する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Alignment  
MetaInformation  
Padding  
PaddingSize  
ResamplingMethod  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

AudioLoudness

AudioLoudness[audio]

EBUメモリ定義に従って audio のラウドネスを計算する．

AudioLoudness[audio,def]

定義 def に従ってラウドネスを計算する．

AudioLoudness[video,…]

video の最初の音声トラックのラウドネスを計算する．

詳細とオプション

  • AudioLoudnessは，知覚振幅を局所的に計算しようとする．
  • AudioLoudnessは，各パーティションについて計算されたラウドネス測度値のTimeSeriesを返す．
  • ラウドネス定義 def には次の設定を使うことができる．
  • "EBUMomentary"Kフィルタリング，400msパーティションと100msオフセット（LUFSで）
    "EBUShortTerm"Kフィルタリング，3000msパーティションと100msオフセット（LUFSで）
    "VUMeter"フィルタリングなし，300msパーティションと100msオフセット（VUで）
    "Peak"最大値，400msパーティションと100msオフセット（dBFSで）
    "TruePeak"最大値，400msパーティションと100msオフセット，192kHzまでリサンプリング（dBFSで）
  • ラウドネス単位フルスケール(LUFS)は絶対測度である．推奨される目標のラウドネスレベルは，大抵の場合LUFSである．LUFSの1単位は1dBである．これはLKFS（ラウドネスK重みフルスケール)としても知られている．
  • Kフィルタリングは，人間のラウドネス知覚を近似するためのフィルタを適用する過程のことである．これはEBUによるラウドネス定義の積分部分である．
  • フルスケールと相対的なデシベル(dBFS)を使って振幅あるいはRMSレベルを測ることができる．0dBFSは振幅あるいはRMSの値1に相当する．
  • 音量単位(VU)は相対測度である．1単位のVUは1dBに相当する．0はdBFSに相当するレベルに置かれる．
  • 多チャンネルの音声信号については，ラウドネスはチャンネル値の平均について計算される．
  • 次は，指定可能なオプションである．
  • Alignment Centerパーティションのあるタイムスタンプの揃え方
    Padding Automatic充填法
    PaddingSize Automatic充填量
    MetaInformation None追加的なメタ情報を含む
    ResamplingMethod Automatic経路のリサンプリングに使うメソッド

例題

すべて開く すべて閉じる

例  (1)

録音のラウドネスを計算する：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}]
Wolfram Language code: AudioLoudness[a]//ListLinePlot

別の定義を使ってラウドネスを計算する：

Wolfram Language code: AudioLoudness[a, "VUMeter"]//ListLinePlot

スコープ  (4)

"EBUMomentary"の定義と"EBUShortTerm"の定義はの違いはパーティションサイズのみである：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];
Wolfram Language code: AudioLoudness[a, "EBUMomentary"]//ListLinePlot

"EBUShortTerm"の方が大きいパーティションを使う：

Wolfram Language code: AudioLoudness[a, "EBUShortTerm"]//ListLinePlot

"VUMeter"の定義は"EBUMomentary"の定義と非常によく似た特徴を持つが，Kフィルタリングが行われる：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];
Wolfram Language code: AudioLoudness[a, "VUMeter"]//ListLinePlot

"Peak"あるいは"TruePeak"の定義を使って信号が切り取られる点があるかどうかをチェックする：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];
Wolfram Language code: AudioLoudness[a, "Peak"]//ListLinePlot

動画の音声トラックを処理する：

Wolfram Language code: AudioLoudness[\!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-2sfji)"]\)]//ListLinePlot

オプション  (5)

Alignment  (1)

Alignmentオプションを使って結果のタイムスタンプの位置を制御する：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];Table[AudioLoudness[a, "EBUMomentary", Alignment -> al], {al, {Left, Center, Right}}]//ListLinePlot

MetaInformation  (1)

MetaInformationオプションを使って結果にメタデータ情報を加える：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];res = AudioLoudness[a, "EBUMomentary", MetaInformation -> {"t" -> "test"}]
Wolfram Language code: res["MetaInformation"]

Padding  (1)

Paddingオプションを使って充填方法を制御する：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];AudioLoudness[a, "EBUMomentary", Padding -> "Periodic", PaddingSize -> {0, 4}]//ListLinePlot

PaddingSize  (1)

PaddingSizeオプションを使って充填量を制御する：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];AudioLoudness[a, "EBUMomentary", Padding -> "Periodic", PaddingSize -> {10, 10}]//ListLinePlot

ResamplingMethod  (1)

リサンプリング法を指定する：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];AudioLoudness[a, "EBUMomentary", ResamplingMethod -> {"Interpolation", InterpolationOrder -> 0}]//ListLinePlot

アプリケーション  (2)

録音におけるラウドネスの平均を計算する：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];l = AudioLoudness[a]
Wolfram Language code: Histogram[l, 10]
Wolfram Language code: Mean[l]

録音のラウドネス範囲を計算する：

Wolfram Language code: Max[l] - Min[l]

時間依存ラウドネス補正を行う：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];l = AudioLoudness[a]

目標とするラウドネスを定義する：

Wolfram Language code: target = -23;

信号から目標とするラウドネスまでの時間依存振幅率を計算する：

Wolfram Language code: aratio = 10 ^ ((target - l) / 20)
Wolfram Language code: ListLinePlot[%]

もとの信号にこの率を掛けてほぼ一定のラウドネスの結果を得る：

Wolfram Language code: a * AudioGenerator[TimeSeriesResample[aratio, .01]]
Wolfram Language code: AudioLoudness[%]//ListLinePlot

もとの信号をこの率で割って信号の動的範囲を広げる：

Wolfram Language code: a / AudioGenerator[TimeSeriesResample[aratio, .01]]//AudioNormalize
Wolfram Language code: AudioLoudness[%]//ListLinePlot

特性と関係  (1)

"TruePeak"定義はデジタルをアナログに変換するシミュレーションのリサンプリングを行う：

Wolfram Language code: sq = Array[SquareWave[#]&, 40, {0, 3}];

デジタルからの場合は，すべてのサンプル値がから1の間に収まる：

Wolfram Language code: ListLinePlot[sq]

この信号が（サウンドカードのような）デジタルからアナログへの変換器に達するたびに補間が行われる．"TruePeak"アルゴリズムは4×リサンプリングを使ってこの操作のシミュレーションを行う：

Wolfram Language code: resampled = ArrayResample[sq, 4 * Length[sq], Resampling -> "Lanczos"];

たとえすべてのサンプル値が許容範囲内でも，リサンプルした信号はクリッピングを示す：

Wolfram Language code: Show[ ListLinePlot[ resampled, PlotStyle -> Dashed, DataRange -> {1, 40}, Prolog -> {Red, Opacity[.2], Rectangle[{0, 1}, {40, 2}], Rectangle[{0, -1}, {40, -2}]}], ListPlot[sq, PlotMarkers -> Automatic] ]

これが，"Peak"アルゴリズムと"TruePeak"アルゴリズムの間の相違の理由である：

Wolfram Language code: sq = AudioGenerator["Square"];
Wolfram Language code: AudioLoudness[sq, "Peak"]//Max
Wolfram Language code: AudioLoudness[sq, "TruePeak"]//Max

ほとんどの信号では，この違いは無視することができる：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];
Wolfram Language code: AudioLoudness[a, "Peak"]//Max AudioLoudness[a, "TruePeak"]//Max
Wolfram Research (2017), AudioLoudness, Wolfram言語関数， https://reference.wolfram.com/language/ref/AudioLoudness.html （2024年に更新）.

テキスト

Wolfram Research (2017), AudioLoudness, Wolfram言語関数， https://reference.wolfram.com/language/ref/AudioLoudness.html （2024年に更新）.

CMS

Wolfram Language. 2017. "AudioLoudness." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/AudioLoudness.html.

APA

Wolfram Language. (2017). AudioLoudness. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AudioLoudness.html

BibTeX

@misc{reference.wolfram_2026_audioloudness, author="Wolfram Research", title="{AudioLoudness}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/AudioLoudness.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_audioloudness, organization={Wolfram Research}, title={AudioLoudness}, year={2024}, url={https://reference.wolfram.com/language/ref/AudioLoudness.html}, note=[Accessed: 07-August-2026]}