Wolfram 语言与系统参考资料中心

AudioLoudness

AudioLoudness[audio]

根据 EBU（欧洲广播联盟）瞬时响度的定义计算 audio 的响度.

AudioLoudness[audio,def]

根据定义 def 计算响度.

AudioLoudness[video,…]

计算 video 中第一个音轨的响度.

更多信息和选项

AudioLoudness 试图局部计算感知幅度的度量.
AudioLoudness 返回算出的每个分区响度度量的 TimeSeries.
响度定义 def 的可用设置有：

	"EBUMomentary"	K-滤波，400ms 分区，100ms 偏移（单位为 LUFS）
	"EBUShortTerm"	K-滤波，3000ms 分区，100ms 偏移（单位为 LUFS）
	"VUMeter"	不进行滤波，300ms 分区，100ms 偏移（单位为 VU）
	"Peak"	最大值，400ms 分区，100ms 偏移（单位为 dBFS）
	"TruePeak"	最大值，400ms 分区，100ms 偏移，重新采样到 192 kHz （单位为 dBFS）

Loudness Units Full Scale (LUFS) 是绝对度量. 推荐的目标响度电平通常为 LUFS. 一个 LUFS 等于 1dB. 亦称为 LKFS (Loudness K-weighted Full Scale).
K-滤波是应用近似人的听觉感受的滤波器的过程. 是 EBU 响度定义的积分过程.
Decibels relative to Full Scale (dBFS) 可用来测量幅值或 RMS 电平. 0 dBFS 对应于一个幅值或值为 1 的 RMS.
Volume Unit (VU) 是相对度量. 一个 VU 对应于 1dB. 零值对应于 dBFS.
对于多通道音频信号，使用平均通道值计算响度.
可以指定下列选项：

Alignment	Center	时间戳与分区的对齐方式
Padding	Automatic	填充方案
PaddingSize	Automatic	填充数量
MetaInformation	None	包含额外的元信息
ResamplingMethod	Automatic	用于重新抽样路径的方法

范例

打开所有单元关闭所有单元

基本范例 (1)

计算录音的响度：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}]

Wolfram Language code: AudioLoudness[a]//ListLinePlot

用不同的定义计算响度：

Wolfram Language code: AudioLoudness[a, "VUMeter"]//ListLinePlot

范围 (4)

"EBUMomentary" 和 "EBUShortTerm" 定义的区别仅在于分区的大小不同：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];

Wolfram Language code: AudioLoudness[a, "EBUMomentary"]//ListLinePlot

"EBUShortTerm" 使用较大的分区：

Wolfram Language code: AudioLoudness[a, "EBUShortTerm"]//ListLinePlot

"VUMeter" 的定义与 "EBUMomentary" 有非常相似的特性，但不进行 K-滤波：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];

Wolfram Language code: AudioLoudness[a, "VUMeter"]//ListLinePlot

用 "Peak" 或 "TruePeak" 定义查看信号是否被截断：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];

Wolfram Language code: AudioLoudness[a, "Peak"]//ListLinePlot

处理视频的音轨：

Wolfram Language code: AudioLoudness[\!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-2sfji)"]\)]//ListLinePlot

选项 (5)

Alignment (1)

用 Alignment 选项控制结果中时间戳的位置：

Wolfram Language code:

a = ExampleData[{"Audio", "Apollo11SmallStep"}];Table[AudioLoudness[a, "EBUMomentary", Alignment -> al], {al, {Left, Center, Right}}]//ListLinePlot

MetaInformation (1)

用 MetaInformation 选项在结果在添加元信息：

Wolfram Language code:

a = ExampleData[{"Audio", "Apollo11SmallStep"}];res = AudioLoudness[a, "EBUMomentary", MetaInformation -> {"t" -> "test"}]

Wolfram Language code: res["MetaInformation"]

Padding (1)

用 Padding 选项控制填充方案：

Wolfram Language code:

a = ExampleData[{"Audio", "Apollo11SmallStep"}];AudioLoudness[a, "EBUMomentary", Padding -> "Periodic", PaddingSize -> {0, 4}]//ListLinePlot

PaddingSize (1)

用 PaddingSize 选项控制填充数量：

Wolfram Language code:

a = ExampleData[{"Audio", "Apollo11SmallStep"}];AudioLoudness[a, "EBUMomentary", Padding -> "Periodic", PaddingSize -> {10, 10}]//ListLinePlot

ResamplingMethod (1)

指定重新采样的方法：

Wolfram Language code:

a = ExampleData[{"Audio", "Apollo11SmallStep"}];AudioLoudness[a, "EBUMomentary", ResamplingMethod -> {"Interpolation", InterpolationOrder -> 0}]//ListLinePlot

应用 (2)

计算一段录音的平均响度：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];l = AudioLoudness[a]

Wolfram Language code: Histogram[l, 10]

Wolfram Language code: Mean[l]

计算录音的响度范围：

Wolfram Language code: Max[l] - Min[l]

进行时变 (time-dependent) 响度校正：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];l = AudioLoudness[a]

定义目标响度：

Wolfram Language code: target = -23;

计算信号对目标响度的时变幅值比：

Wolfram Language code: aratio = 10 ^ ((target - l) / 20)

Wolfram Language code: ListLinePlot[%]

用比值乘以原来的信号来获得响度近似恒定的信号：

Wolfram Language code: a * AudioGenerator[TimeSeriesResample[aratio, .01]]

Wolfram Language code: AudioLoudness[%]//ListLinePlot

用原来的信号除以比值来扩展信号的动态范围：

Wolfram Language code: a / AudioGenerator[TimeSeriesResample[aratio, .01]]//AudioNormalize

Wolfram Language code: AudioLoudness[%]//ListLinePlot

属性和关系 (1)

"TruePeak" 进行重新采样，模拟数模转换：

Wolfram Language code: sq = Array[SquareWave[#]&, 40, {0, 3}];

对于方波，所有样本值都在到 1 的范围内：

Wolfram Language code: ListLinePlot[sq]

只要该信号到达数模转换器（如声卡），就进行插值. "TruePeak" 算法使用 4 倍重采样模拟此操作：

Wolfram Language code: resampled = ArrayResample[sq, 4 * Length[sq], Resampling -> "Lanczos"];

即使所有样本值都在可接受的限制范围内，重新采样的信号也会显示有部分信号被剪掉：

Wolfram Language code:

Show[
	ListLinePlot[
	resampled, PlotStyle -> Dashed, DataRange -> {1, 40}, Prolog -> {Red, Opacity[.2], Rectangle[{0, 1}, {40, 2}], Rectangle[{0, -1}, {40, -2}]}], 
	ListPlot[sq, PlotMarkers -> Automatic]
	]

这就是 "Peak" 和 "TruePeak" 算法之间存在差异的原因：

Wolfram Language code: sq = AudioGenerator["Square"];

Wolfram Language code: AudioLoudness[sq, "Peak"]//Max

Wolfram Language code: AudioLoudness[sq, "TruePeak"]//Max

对大多数信号来讲，可忽略此差异：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}];

Wolfram Language code:

AudioLoudness[a, "Peak"]//Max
AudioLoudness[a, "TruePeak"]//Max

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

AudioLoudness

更多信息和选项

范例

基本范例 (1)

范围 (4)

选项 (5)

Alignment (1)

MetaInformation (1)

Padding (1)

PaddingSize (1)

ResamplingMethod (1)

应用 (2)

属性和关系 (1)

文本

CMS

APA

BibTeX

BibLaTeX

AudioLoudness

更多信息和选项

范例

基本范例 (1)

范围 (4)

选项 (5)

Alignment (1)

MetaInformation (1)

Padding (1)

PaddingSize (1)

ResamplingMethod (1)

应用 (2)

属性和关系 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX