WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Ball[p]

点 p を中心とする単位球体を表す．

Ball[p,r]

半径 r で点 p を中心とする球体を表す．

Ball[{p1,p2,…},r]

半径 r の球体の集合を表す．

詳細とオプション
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
グラフィックス  
指定  
スタイリング  
座標  
領域  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

Ball

Ball[p]

点 p を中心とする単位球体を表す．

Ball[p,r]

半径 r で点 p を中心とする球体を表す．

Ball[{p1,p2,…},r]

半径 r の球体の集合を表す．

詳細とオプション

  • Ballは，中心区間，円板，ボール，超球体としても知られている．
  • Ballは，幾何領域および地理プリミティブとして使うことができる．
  • Ball[]はBall[{0,0,0}]に等しい．
  • 整数 n についてのBall[n]は，における単位球体であるBall[{0,…,0}]に等しい．
  • Ballは，塗り潰された球体{x|TemplateBox[{{x, -, p}}, Norm]<=r}を表す．領域は，長さ の点 p について 次元である．
  • Ballでは，点 p が内の任意の点で，r が任意の正の実数でよい．
  • BallはGraphicsおよびGraphics3Dで使うことができる．
  • グラフィックスでは，点 p, piおよび半径 r は，Scaled式およびDynamic式でよい．
  • グラフィックスの描画は，FaceForm，EdgeForm，Specularity，Opacity，色等の指示子の影響を受ける．
  • Ball[{p1,p2,…},{r1,r2,…}]は，中心 pi，半径 riの球面の集合を表す．

予備知識

  • Ballは， 次元空間の球体を表すグラフィックスおよび幾何のプリミティブである．Ball[p,r]はTemplateBox[{}, Reals]^n内の，中心が p で半径が r である（塗り潰された）球体{x:TemplateBox[{{x, -, p}}, Norm]<=r}を表す．r は任意の非負の実数でよく，p は任意の正の距離 を持つ．略記形式のBall[p]はBall[p,1]に，
    Ball[n]はBall[ConstantArray[0, n],1]に等しく，Ball[]を評価すると自動的にBall[{0,0,0}]になる．
  • 半径 が等しい球体オブジェクトの集合（複数の球体）は，Ball[{p1,…,pk},r] を使って効率的に表現することができ，半径が異なる球体はBall[{p1,…,pk},{r1,…,rk}]で表すことができる．
  • Ballオブジェクトは，GraphicsおよびGraphics3Dを使って，それぞれ二次元および三次元で視覚的にフォーマットすることができる．グラフィックス内のBallオブジェクトの外観は，辺指示子EdgeForm（二次元）あるいは面指示子FaceForm（三次元），Red等の色指示子，不透明度／透明度の指示子のOpacityおよびSpecularity，スタイルオプションAntialiasingを指定して変更することができる．
  • Ballは，計算を行うべき領域指定にも使うことができる．例えば，Integrate[1,{x,y,z}∈Ball[{0,0,0},r]]とVolume[Ball[{0,0,0},r]]はどちらも，半径 の三次元の球体の体積を返す．
  • Ballは数多くの他のシンボルと関連がある．Sphereは，RegionBoundary[Ball[{x,y,z},r]]を使って計算できる球体の境界を表す．Ballは任意次元におけるIntervalとDiskの一般化であり，Ellipsoidは，すべての についてBall[{p1,…,pk},1]がEllipsoid[{p1,…,pk},ConstantArray[1,k]]に等しいという意味でBallの一般化である．SphericalShellは，大きい球から同心の小さい球体を除いて得られる塗り潰された殻を与える．3DのBallオブジェクトは，ImplicitRegion[(x-u)2+(y-v)2+(z-w)2≤r2,{u,v,w}]またはParametricRegion[a{Cos[θ]Sin[ϕ],Sin[θ]Sin[ϕ],Cos[ϕ]}-{x,y,z},{{θ,0,2π},{ϕ,0,π},{a,0,r}}]として表される．SolidData["entity", "property"]あるいはEntityValue[Entity["Ball","entity"],"property"]を使って標準位置にある3Dの球体の計算済みの特性とその異体を求めることができる．ただし，"entity"は"Ball"または"HalfBall"である．

例題

すべて開く すべて閉じる

例  (2)

3Dにおける単位球体：

Wolfram Language code: Graphics3D[Ball[]]

2Dにおける単位球体：

Wolfram Language code: Graphics[Ball[2]]

体積と重心：

Wolfram Language code: Volume[Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, r]]
Wolfram Language code: RegionCentroid[Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, r]]

スコープ  (22)

グラフィックス  (12)

指定  (4)

デフォルトは3Dの原点における単位球体である：

Wolfram Language code: Graphics3D[Ball[]]

異なる次元の単位球体：

Wolfram Language code: Graphics[Ball[2]]
Wolfram Language code: Graphics3D[Ball[3]]

位置と半径が異なる球体：

Wolfram Language code: Graphics3D[{Ball[{-1, -1, -1}], Ball[{1, 2, 3}, 2]}]

半径が等しい複数の球体：

Wolfram Language code: Graphics3D[Ball[{{0, 0, 0}, {1, 1, 1}}, 1 / 2]]

スタイリング  (4)

鏡面反射指数が異なる球体：

Wolfram Language code: Table[Graphics3D[{Orange, Specularity[White, n], Ball[]}], {n, {5, 20, 100}}]

赤く輝く黒い球体：

Wolfram Language code: Graphics3D[{Glow[Red], Black, Ball[]}]

Opacityは表面の不透明度を指定する：

Wolfram Language code: Table[Graphics3D[{Opacity[o], Ball[]}], {o, {0.3, 0.5, 0.9}}]

2Dにおけるスタイリング：

Wolfram Language code: Graphics[{EdgeForm[{Thick, Dashed, Blue}], Brown, Ball[2]}]

座標  (4)

プロット範囲との割合で座標を指定する：

Wolfram Language code: Graphics[Ball[Scaled[{0.5, 0.75}], 1], PlotRange -> {{0, 4}, {0, 4}}, Frame -> True]
Wolfram Language code: Graphics3D[Ball[Scaled[{0.5, 0.5, 0.75}], 1], PlotRange -> {{0, 4}, {0, 4}, {0, 4}}, Axes -> True]

プロット範囲との割合で半径を指定する：

Wolfram Language code: Graphics[Ball[{2, 2}, Scaled[0.25]], Frame -> True]
Wolfram Language code: Graphics3D[Ball[{0, 0, 0}, Scaled[0.25]], Axes -> True]

通常の座標からスケールされたオフセットを指定する：

Wolfram Language code: Graphics[Ball[ Scaled[{0.5, 0.25}, {1, 1}], 0.5], Frame -> True]
Wolfram Language code: Graphics3D[Ball[Scaled[{0, 0, 0.5}, {1, 1, 1}]], PlotRange -> {{0, 4}, {0, 4}, {0, 4}}, Axes -> True]

点はDynamicでもよい：

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x], {-0.5, 0.5}], Graphics3D[{Ball[], Ball[{Dynamic[x], 1, 1}, 0.3]}]}]

領域  (10)

埋込み次元は球体がある空間の次元である：

Wolfram Language code: RegionEmbeddingDimension[Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, r]]

幾何次元は形それ自体の次元である：

Wolfram Language code: RegionDimension[Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, r]]

帰属判定：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, 1];
Wolfram Language code: {RegionMember[ℛ, {(1/3), (1/3), (1/3)}], RegionMember[ℛ, {1, 1, 1}]}

点の帰属条件を得る：

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

体積：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, 1];
Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

重心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

点からの距離：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, 1];
Wolfram Language code: {RegionDistance[ℛ, {(1/3), (1/4), (1/5)}], RegionDistance[ℛ, {1, 1, 1}]}

2D球体についての，最近点までの距離：

Wolfram Language code: Plot3D[RegionDistance[Ball[{0, 0}, 1], {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5]

3D球体についての等距離等高線：

Wolfram Language code: ContourPlot3D[Evaluate@RegionDistance[ℛ, {x, y, z}], {x, -2, 2}, {y, 0, 2}, {z, -2, 2}, Mesh -> None, Contours -> {0.25, 0.5, 1}, ContourStyle -> ColorData[94, "ColorList"], Lighting -> "Neutral", BaseStyle -> Opacity[0.5], BoxRatios -> Automatic]

点からの符号付き距離：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, 1];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 1, 1}], SignedRegionDistance[ℛ, {1 / 2, 1 / 2, 1 / 2}]}

2D球体までの符号付き距離：

Wolfram Language code: Plot3D[SignedRegionDistance[Ball[{0, 0}, 1], {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

領域内の最近点：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, 1];
Wolfram Language code: {RegionNearest[ℛ, {1, 1, 1}], RegionNearest[ℛ, {1 / 2, 1 / 2, 1 / 2}]}

包み込んでいる球面までの最近点：

Wolfram Language code: spherePoints[{n_, m_}, c_, r_] := Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];
Wolfram Language code: pl = spherePoints[{16, 8}, RegionCentroid[ℛ], 2]; npl = Table[RegionNearest[ℛ, p], {p, pl}];
Wolfram Language code: Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

球体は有界である：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, 1];
Wolfram Language code: BoundedRegionQ[ℛ]

範囲を求める：

Wolfram Language code: r = RegionBounds[ℛ]
Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[r]}, ℛ}, Boxed -> False]

球体領域で積分する：

Wolfram Language code: ℛ = Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, r];
Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ]

球体領域で最適化する：

Wolfram Language code: ℛ = Ball[{1, 2, 3}, 4];
Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]

球体領域内で方程式を解く：

Wolfram Language code: ℛ = Ball[{1, 2, 3}, 3];
Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && x - y - z == -(1/2) && z^2 == x y + (1/4) && {x, y, z}∈ℛ, {x, y, z}]

アプリケーション  (3)

体積が の球体の最小表面積を求める：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, r];
Wolfram Language code: Minimize[{Area[RegionBoundary[ℛ]], Volume[ℛ] == 2π && r > 0}, {r}]

密度が で与えられる球体領域の総質量を求める：

Wolfram Language code: ℛ = Ball[{a, b, c}, r];
Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ, Assumptions -> r > 0 && (a | b | c)∈Reals]

半径3cmの球体の中のカフェインの質量を求める：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, Quantity[3, "Centimeters"]];

カフェインの密度：

Wolfram Language code: d = ChemicalData["Caffeine", "Density"]

球体の体積：

Wolfram Language code: v = Volume[ℛ]

球体中のカフェインの質量：

Wolfram Language code: FormulaData["MassDensity", {"ρ" -> d, "V" -> N[v]}]

特性と関係  (5)

DiskはBallの特殊ケースである：

Wolfram Language code: RegionMember[Disk[{0, 0}, 1], {x, y}]
Wolfram Language code: RegionMember[Ball[{0, 0}, 1], {x, y}]

SphereはBallのRegionBoundaryである：

Wolfram Language code: RegionBoundary[Ball[{x, y, z}, r]]

EllipsoidはBallを一般化したものである：

Wolfram Language code: Subscript[ℛ, 1] = Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]}, {1, 1, 1, 1}]; Subscript[ℛ, 2] = Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]}, 1];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegionは任意のBallを表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[(Subscript[t, 1] - Subscript[c, 1])^2 + (Subscript[t, 2] - Subscript[c, 2])^2 + (Subscript[t, 3] - Subscript[c, 3])^2 + (Subscript[t, 4] - Subscript[c, 4])^2 ≤ 1, {Subscript[t, 1], Subscript[t, 2], Subscript[t, 3], Subscript[t, 4]}]; Subscript[ℛ, 2] = Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]}, 1];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Ballはユークリッドノルムのノルム球体である：

Wolfram Language code: ℛ = Ball[{0, 0, 0, 0}, 1];
Wolfram Language code: Reduce[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4]}∈ℛ⧦Norm[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4]}] ≤ 1, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4]}, Reals]

おもしろい例題  (1)

ランダムな球体の集合：

Wolfram Language code: Graphics3D[Table[{Hue[RandomReal[]], Ball[RandomReal[1, {3}], RandomReal[0.1]]}, {200}]]
Wolfram Research (2014), Ball, Wolfram言語関数， https://reference.wolfram.com/language/ref/Ball.html.

テキスト

Wolfram Research (2014), Ball, Wolfram言語関数， https://reference.wolfram.com/language/ref/Ball.html.

CMS

Wolfram Language. 2014. "Ball." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Ball.html.

APA

Wolfram Language. (2014). Ball. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Ball.html

BibTeX

@misc{reference.wolfram_2026_ball, author="Wolfram Research", title="{Ball}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Ball.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_ball, organization={Wolfram Research}, title={Ball}, year={2014}, url={https://reference.wolfram.com/language/ref/Ball.html}, note=[Accessed: 10-August-2026]}