WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BattleLemarieWavelet[]

次数3のBattle–Lemariéウェーブレットを表す．

BattleLemarieWavelet[n]

等間隔の区間{-10,10}で評価された次数 n のBattle–Lemariéウェーブレットを表す．

BattleLemarieWavelet[n,lim]

等間隔の区間{-lim,lim}で評価された次数 n のBattle–Lemariéウェーブレットを表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
ウェーブレット変換  
高次元  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

BattleLemarieWavelet

BattleLemarieWavelet[]

次数3のBattle–Lemariéウェーブレットを表す．

BattleLemarieWavelet[n]

等間隔の区間{-10,10}で評価された次数 n のBattle–Lemariéウェーブレットを表す．

BattleLemarieWavelet[n,lim]

等間隔の区間{-lim,lim}で評価された次数 n のBattle–Lemariéウェーブレットを表す．

詳細

例題

すべて開く すべて閉じる

例  (3)

スケーリング関数：

Wolfram Language code: Plot[WaveletPhi[BattleLemarieWavelet[3, 10], x], {x, -10, 10}, PlotRange -> All]
Wolfram Language code: WaveletPhi[BattleLemarieWavelet[3, 10], x]

ウェーブレット関数：

Wolfram Language code: Plot[WaveletPsi[BattleLemarieWavelet[3, 10], x], {x, -10, 10}, PlotRange -> All]
Wolfram Language code: WaveletPsi[BattleLemarieWavelet[3, 10], x]

フィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[BattleLemarieWavelet[3, 5], {"PrimalLowpass", "PrimalHighpass"}]

スコープ  (9)

基本的な用法  (4)

主ローパスフィルタ係数を計算する：

Wolfram Language code: WaveletFilterCoefficients[BattleLemarieWavelet[3, 5], "PrimalLowpass"]

主ハイパスフィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[BattleLemarieWavelet[3, 5], "PrimalHighpass"]

次数2のBattle–Lemariéスケーリング関数：

Wolfram Language code: Plot[WaveletPhi[BattleLemarieWavelet[2, 10], x], {x, -10, 10}, PlotRange -> All]

次数5のBattle–Lemariéスケーリング関数：

Wolfram Language code: Plot[WaveletPhi[BattleLemarieWavelet[5, 10], x], {x, -10, 10}, PlotRange -> All]

次数2のBattle–Lemariéウェーブレット関数：

Wolfram Language code: Plot[WaveletPsi[BattleLemarieWavelet[2, 10], x], {x, -10, 10}, PlotRange -> All]

次数5のBattle–Lemariéウェーブレット関数：

Wolfram Language code: Plot[WaveletPsi[BattleLemarieWavelet[5, 10], x], {x, -10, 10}, PlotRange -> All]

ウェーブレット変換  (4)

DiscreteWaveletTransformを計算する：

Wolfram Language code: data = Table[Sinc[x^2], {x, -3π, 3π, (6π/1023)}];
Wolfram Language code: ListLinePlot[data, PlotRange -> All]
Wolfram Language code: dwt = DiscreteWaveletTransform[data, BattleLemarieWavelet[3, 12], 2]

ウェーブレット係数の木を見る：

Wolfram Language code: dwt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: dwt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[dwt, PlotLayout -> "CommonXAxis"]

BattleLemarieWaveletを使ってDiscreteWaveletPacketTransformを行うことができる：

Wolfram Language code: data = Table[Sinc[t^2], {t, -3π, 3π, (6π/1023)}];
Wolfram Language code: dwpt = DiscreteWaveletPacketTransform[data, BattleLemarieWavelet[3, 12], 2]

ウェーブレット係数の木を見る：

Wolfram Language code: dwpt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: dwpt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[dwpt, PlotLayout -> "CommonXAxis"]

BattleLemarieWaveletを使ってStationaryWaveletTransformを行うことができる：

Wolfram Language code: data = Table[Sinc[t^2], {t, -3π, 3π, (6π/1023)}];
Wolfram Language code: swt = StationaryWaveletTransform[data, BattleLemarieWavelet[3, 12], 2];

ウェーブレット係数の木を見る：

Wolfram Language code: swt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: swt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[swt, PlotLayout -> "CommonXAxis"]

BattleLemarieWaveletを使ってStationaryWaveletPacketTransformを行うことができる：

Wolfram Language code: data = Table[Sinc[t^2], {t, -3π, 3π, (6π/1023)}];
Wolfram Language code: swpt = StationaryWaveletPacketTransform[data, BattleLemarieWavelet[3, 12], 2];

ウェーブレット係数の木を見る：

Wolfram Language code: swpt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: swpt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[swpt, PlotLayout -> "CommonXAxis"]

高次元  (1)

多変量スケーリング関数と多変量ウェーブレット関数はそれぞれその一変量関数の積である：

Wolfram Language code: ϕ = WaveletPhi[BattleLemarieWavelet[3, 8]]; ψ = WaveletPsi[BattleLemarieWavelet[3, 8]];
Wolfram Language code: Plot3D[Evaluate[ϕ[x]ψ[y]], {x, -8, 8}, {y, -8, 8}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ϕ[x]ψ[y]], {x, -8, 8}, {y, -8, 8}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x]ϕ[y]], {x, -8, 8}, {y, -8, 8}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x]ψ[y]], {x, -8, 8}, {y, -8, 8}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]

特性と関係  (11)

ローパスフィルタ係数の総和は単位元にほぼ等しい．：

Wolfram Language code: WaveletFilterCoefficients[BattleLemarieWavelet[4], "PrimalLowpass"][[All, 2]]//Total//Chop

ハイパスフィルタ係数の総和は0にほぼ等しい．：

Wolfram Language code: WaveletFilterCoefficients[BattleLemarieWavelet[4], "PrimalHighpass"][[All, 2]]//Total//Chop

スケーリング関数を積分すると単位元になる．：

Wolfram Language code: ϕ = WaveletPhi[BattleLemarieWavelet[4]];
Wolfram Language code: Integrate[ϕ[x], {x, -∞, ∞}]

ウェーブレット関数を積分すると0になる．：

Wolfram Language code: ψ = WaveletPsi[BattleLemarieWavelet[4, 20]];
Wolfram Language code: Integrate[ψ[x], {x, -∞, ∞}]

偶数次元 n のとき，スケーリング関数は1/2について対称である：

Wolfram Language code: Plot[Evaluate[WaveletPhi[BattleLemarieWavelet[2], x]], {x, -5, 5}, PlotRange -> All, GridLines -> {{1 / 2}, None}, GridLinesStyle -> Directive[Orange, Thick]]

偶数次元 n のとき，ウェーブレット関数は1/2について反対称である：

Wolfram Language code: Plot[Evaluate[WaveletPsi[BattleLemarieWavelet[2], x]], {x, -5, 5}, PlotRange -> All, GridLines -> {{1 / 2}, None}, GridLinesStyle -> Directive[Orange, Thick]]

奇数次元 n のとき，スケーリング関数は0について対称である：

Wolfram Language code: Plot[Evaluate[WaveletPhi[BattleLemarieWavelet[3], x]], {x, -5, 5}, PlotRange -> All, GridLines -> {{0}, None}, GridLinesStyle -> Directive[Orange, Thick]]

奇数次元 n のとき，ウェーブレット関数は1/2について対称である：

Wolfram Language code: Plot[Evaluate[WaveletPsi[BattleLemarieWavelet[3], x]], {x, -5, 5}, PlotRange -> All, GridLines -> {{1 / 2}, None}, GridLinesStyle -> Directive[Orange, Thick]]

は再帰方程式 を満足する：

Wolfram Language code: ϕ = WaveletPhi[BattleLemarieWavelet[3]];
Wolfram Language code: a = WaveletFilterCoefficients[BattleLemarieWavelet[3], "PrimalLowpass"];

要素と再帰の総和をプロットする：

Wolfram Language code: scalet[x_, ϕ_, a_] := 2Table[a[[i, 2]]ϕ[2x - a[[i, 1]]], {i, Length[a]}]
Wolfram Language code: {Plot[Evaluate@scalet[x, ϕ, a], {x, -8, 8}, PlotRange -> All], Plot[{Total@scalet[x, ϕ, a]}, {x, -8, 8}, PlotRange -> All]}

は再帰方程式 を満足する：

Wolfram Language code: ϕ = WaveletPhi[BattleLemarieWavelet[3]];
Wolfram Language code: b = WaveletFilterCoefficients[BattleLemarieWavelet[3], "PrimalHighpass"];

要素と再帰の総和をプロットする：

Wolfram Language code: wavelet[x_, ϕ_, b_] := 2Table[b[[i, 2]]ϕ[2x - b[[i, 1]]], {i, Length[b]}]
Wolfram Language code: {Plot[Evaluate@wavelet[x, ϕ, b], {x, -8, 8}, PlotRange -> All], Plot[Total@wavelet[x, ϕ, b], {x, -8, 8}, PlotRange -> All]}

の周波数応答はで与えられる：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]

フィルタはローパスフィルタである：

Wolfram Language code: Plot[Evaluate[Abs[h[BattleLemarieWavelet[3, 20], ω]]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]

の周波数応答はで与えられる：

Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-I b[[i, 1]]ω], {i, Length[b]}] ]

フィルタはハイパスフィルタである：

Wolfram Language code: Plot[Evaluate[Abs[g[BattleLemarieWavelet[3, 20], ω]]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]

のフーリエ変換はで与えられる：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: fh[wav_, ω_, j_] := Abs[Product[h[wav, (ω/2^i)], {i, j}]]
Wolfram Language code: Plot[Evaluate[fh[BattleLemarieWavelet[3, 20], ω, 10]], {ω, -2Pi, 2Pi}, PlotRange -> All, Ticks -> {Range[-2Pi, 2Pi, 2Pi / 3], {1}}, AxesLabel -> {ω, Abs[ Overscript[ϕ, ^ ][ω]]}]

のフーリエ変換は で与えられる：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-I b[[i, 1]]ω], {i, Length[b]}] ]
Wolfram Language code: fg[wav_, ω_, j_] := Abs[g[wav, (ω/2)]Product[h[wav, (ω/2^i)], {i, 2, j}]]
Wolfram Language code: Plot[Evaluate[fg[BattleLemarieWavelet[3, 20], ω, 10]], {ω, -10, 10}, PlotRange -> All, AxesLabel -> {ω, Abs[ Overscript[ψ, ^ ][ω]]}]

考えられる問題  (1)

BattleLemarieWaveletでは n は15より小さくなければならない：

Wolfram Language code: WaveletPhi[BattleLemarieWavelet[16]]

n が正の機械整数でなければ，BattleLemarieWaveletは定義されない：

Wolfram Language code: WaveletPhi[BattleLemarieWavelet[2 + I]]

おもしろい例題  (2)

スケーリング関数の平行移動と膨張をプロットする：

Wolfram Language code: ϕ[x_, j_, k_] := 2^j / 2WaveletPhi[BattleLemarieWavelet[3], 2^jx - k]
Wolfram Language code: Plot[Evaluate@Table[ϕ[x, j, 0], {j, 0, 2}], {x, -1, 1}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: Plot[Evaluate@Table[ϕ[x, 2, k], {k, 0, 2^2 - 1}], {x, -1, 2}, Filling -> Axis, PlotRange -> All]

ウェーブレット関数の平行移動と膨張をプロットする：

Wolfram Language code: ψ[x_, j_, k_] := 2^j / 2WaveletPsi[BattleLemarieWavelet[3], 2^jx - k]
Wolfram Language code: Plot[Evaluate@Table[ψ[x, j, 0], {j, 0, 2}], {x, -0.5, 1}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: Plot[Evaluate@Table[ψ[x, 2, k], {k, 0, 2^2 - 1}], {x, -0.5, 1.5}, Filling -> Axis, PlotRange -> All]
Wolfram Research (2010), BattleLemarieWavelet, Wolfram言語関数， https://reference.wolfram.com/language/ref/BattleLemarieWavelet.html.

テキスト

Wolfram Research (2010), BattleLemarieWavelet, Wolfram言語関数， https://reference.wolfram.com/language/ref/BattleLemarieWavelet.html.

CMS

Wolfram Language. 2010. "BattleLemarieWavelet." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BattleLemarieWavelet.html.

APA

Wolfram Language. (2010). BattleLemarieWavelet. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BattleLemarieWavelet.html

BibTeX

@misc{reference.wolfram_2026_battlelemariewavelet, author="Wolfram Research", title="{BattleLemarieWavelet}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/BattleLemarieWavelet.html}", note=[Accessed: 11-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_battlelemariewavelet, organization={Wolfram Research}, title={BattleLemarieWavelet}, year={2010}, url={https://reference.wolfram.com/language/ref/BattleLemarieWavelet.html}, note=[Accessed: 11-August-2026]}