WOLFRAM

Wolfram 语言与系统参考资料中心

BattleLemarieWavelet[]

表示阶数为 3 的 Battle-Lemarié 小波.

BattleLemarieWavelet[n]

表示在等间距区间 {-10,10} 上计算的阶数为 n 的 Battle-Lemarié 小波.

BattleLemarieWavelet[n,lim]

表示在等间距区间 {-lim,lim} 上计算的阶数为 n 的 Battle-Lemarié 小波.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用途  
小波变换  
高维度  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

BattleLemarieWavelet

BattleLemarieWavelet[]

表示阶数为 3 的 Battle-Lemarié 小波.

BattleLemarieWavelet[n]

表示在等间距区间 {-10,10} 上计算的阶数为 n 的 Battle-Lemarié 小波.

BattleLemarieWavelet[n,lim]

表示在等间距区间 {-lim,lim} 上计算的阶数为 n 的 Battle-Lemarié 小波.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

尺度函数：

Wolfram Language code: Plot[WaveletPhi[BattleLemarieWavelet[3, 10], x], {x, -10, 10}, PlotRange -> All]
Wolfram Language code: WaveletPhi[BattleLemarieWavelet[3, 10], x]

小波函数：

Wolfram Language code: Plot[WaveletPsi[BattleLemarieWavelet[3, 10], x], {x, -10, 10}, PlotRange -> All]
Wolfram Language code: WaveletPsi[BattleLemarieWavelet[3, 10], x]

滤波器系数：

Wolfram Language code: WaveletFilterCoefficients[BattleLemarieWavelet[3, 5], {"PrimalLowpass", "PrimalHighpass"}]

范围  (9)

基本用途  (4)

计算原低通滤波器系数：

Wolfram Language code: WaveletFilterCoefficients[BattleLemarieWavelet[3, 5], "PrimalLowpass"]

原高通滤波器系数：

Wolfram Language code: WaveletFilterCoefficients[BattleLemarieWavelet[3, 5], "PrimalHighpass"]

阶数为2的 Battle-Lemarié 尺度函数：

Wolfram Language code: Plot[WaveletPhi[BattleLemarieWavelet[2, 10], x], {x, -10, 10}, PlotRange -> All]

阶数为5的 Battle-Lemarié 尺度函数：

Wolfram Language code: Plot[WaveletPhi[BattleLemarieWavelet[5, 10], x], {x, -10, 10}, PlotRange -> All]

阶数为2的 Battle-Lemarié 小波函数：

Wolfram Language code: Plot[WaveletPsi[BattleLemarieWavelet[2, 10], x], {x, -10, 10}, PlotRange -> All]

阶数为5的 Battle-Lemarié 小波函数：

Wolfram Language code: Plot[WaveletPsi[BattleLemarieWavelet[5, 10], x], {x, -10, 10}, PlotRange -> All]

小波变换  (4)

计算一个 DiscreteWaveletTransform：

Wolfram Language code: data = Table[Sinc[x^2], {x, -3π, 3π, (6π/1023)}];
Wolfram Language code: ListLinePlot[data, PlotRange -> All]
Wolfram Language code: dwt = DiscreteWaveletTransform[data, BattleLemarieWavelet[3, 12], 2]

查看小波系数组成的树：

Wolfram Language code: dwt["TreeView"]

获取小波系数的维度：

Wolfram Language code: dwt["Dimensions"]

绘制小波系数：

Wolfram Language code: WaveletListPlot[dwt, PlotLayout -> "CommonXAxis"]

BattleLemarieWavelet 可以用来执行 DiscreteWaveletPacketTransform：

Wolfram Language code: data = Table[Sinc[t^2], {t, -3π, 3π, (6π/1023)}];
Wolfram Language code: dwpt = DiscreteWaveletPacketTransform[data, BattleLemarieWavelet[3, 12], 2]

查看小波系数组成的树：

Wolfram Language code: dwpt["TreeView"]

获取小波系数的维度：

Wolfram Language code: dwpt["Dimensions"]

绘制小波系数：

Wolfram Language code: WaveletListPlot[dwpt, PlotLayout -> "CommonXAxis"]

BattleLemarieWavelet 可以用来执行 StationaryWaveletTransform：

Wolfram Language code: data = Table[Sinc[t^2], {t, -3π, 3π, (6π/1023)}];
Wolfram Language code: swt = StationaryWaveletTransform[data, BattleLemarieWavelet[3, 12], 2];

查看小波系数组成的树：

Wolfram Language code: swt["TreeView"]

获取小波系数的维度：

Wolfram Language code: swt["Dimensions"]

绘制小波系数：

Wolfram Language code: WaveletListPlot[swt, PlotLayout -> "CommonXAxis"]

BattleLemarieWavelet 可以用来执行 StationaryWaveletPacketTransform：

Wolfram Language code: data = Table[Sinc[t^2], {t, -3π, 3π, (6π/1023)}];
Wolfram Language code: swpt = StationaryWaveletPacketTransform[data, BattleLemarieWavelet[3, 12], 2];

查看小波系数组成树：

Wolfram Language code: swpt["TreeView"]

获取小波系数的维度：

Wolfram Language code: swpt["Dimensions"]

绘制小波系数：

Wolfram Language code: WaveletListPlot[swpt, PlotLayout -> "CommonXAxis"]

高维度  (1)

多变量尺度函数和小波函数是单变量的乘积：

Wolfram Language code: ϕ = WaveletPhi[BattleLemarieWavelet[3, 8]]; ψ = WaveletPsi[BattleLemarieWavelet[3, 8]];
Wolfram Language code: Plot3D[Evaluate[ϕ[x]ψ[y]], {x, -8, 8}, {y, -8, 8}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ϕ[x]ψ[y]], {x, -8, 8}, {y, -8, 8}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x]ϕ[y]], {x, -8, 8}, {y, -8, 8}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x]ψ[y]], {x, -8, 8}, {y, -8, 8}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]

属性和关系  (11)

低通滤波器系数的和近似为1；：

Wolfram Language code: WaveletFilterCoefficients[BattleLemarieWavelet[4], "PrimalLowpass"][[All, 2]]//Total//Chop

高通滤波器系数的和近似为0；：

Wolfram Language code: WaveletFilterCoefficients[BattleLemarieWavelet[4], "PrimalHighpass"][[All, 2]]//Total//Chop

尺度函数的积分为1；：

Wolfram Language code: ϕ = WaveletPhi[BattleLemarieWavelet[4]];
Wolfram Language code: Integrate[ϕ[x], {x, -∞, ∞}]

小波函数的积分为0；：

Wolfram Language code: ψ = WaveletPsi[BattleLemarieWavelet[4, 20]];
Wolfram Language code: Integrate[ψ[x], {x, -∞, ∞}]

对于偶数阶数 n，尺度函数关于 1/2 对称：

Wolfram Language code: Plot[Evaluate[WaveletPhi[BattleLemarieWavelet[2], x]], {x, -5, 5}, PlotRange -> All, GridLines -> {{1 / 2}, None}, GridLinesStyle -> Directive[Orange, Thick]]

对于偶数阶数 n，小波函数关于 1/2 反对称：

Wolfram Language code: Plot[Evaluate[WaveletPsi[BattleLemarieWavelet[2], x]], {x, -5, 5}, PlotRange -> All, GridLines -> {{1 / 2}, None}, GridLinesStyle -> Directive[Orange, Thick]]

对于奇数阶数 n，尺度函数关于 0 对称：

Wolfram Language code: Plot[Evaluate[WaveletPhi[BattleLemarieWavelet[3], x]], {x, -5, 5}, PlotRange -> All, GridLines -> {{0}, None}, GridLinesStyle -> Directive[Orange, Thick]]

对于奇数阶数 n，小波函数关于 1/2 对称：

Wolfram Language code: Plot[Evaluate[WaveletPsi[BattleLemarieWavelet[3], x]], {x, -5, 5}, PlotRange -> All, GridLines -> {{1 / 2}, None}, GridLinesStyle -> Directive[Orange, Thick]]

满足递归方程 ：

Wolfram Language code: ϕ = WaveletPhi[BattleLemarieWavelet[3]];
Wolfram Language code: a = WaveletFilterCoefficients[BattleLemarieWavelet[3], "PrimalLowpass"];

绘制分量以及递归和：

Wolfram Language code: scalet[x_, ϕ_, a_] := 2Table[a[[i, 2]]ϕ[2x - a[[i, 1]]], {i, Length[a]}]
Wolfram Language code: {Plot[Evaluate@scalet[x, ϕ, a], {x, -8, 8}, PlotRange -> All], Plot[{Total@scalet[x, ϕ, a]}, {x, -8, 8}, PlotRange -> All]}

满足递归方程 ：

Wolfram Language code: ϕ = WaveletPhi[BattleLemarieWavelet[3]];
Wolfram Language code: b = WaveletFilterCoefficients[BattleLemarieWavelet[3], "PrimalHighpass"];

绘制分量以及递归和：

Wolfram Language code: wavelet[x_, ϕ_, b_] := 2Table[b[[i, 2]]ϕ[2x - b[[i, 1]]], {i, Length[b]}]
Wolfram Language code: {Plot[Evaluate@wavelet[x, ϕ, b], {x, -8, 8}, PlotRange -> All], Plot[Total@wavelet[x, ϕ, b], {x, -8, 8}, PlotRange -> All]}

的频率响应由 给出：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]

该滤波器是一个低通滤波器：

Wolfram Language code: Plot[Evaluate[Abs[h[BattleLemarieWavelet[3, 20], ω]]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]

的频率响应由 给出：

Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-I b[[i, 1]]ω], {i, Length[b]}] ]

该滤波器是一个高通滤波器：

Wolfram Language code: Plot[Evaluate[Abs[g[BattleLemarieWavelet[3, 20], ω]]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]

的傅立叶变换由 给出：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: fh[wav_, ω_, j_] := Abs[Product[h[wav, (ω/2^i)], {i, j}]]
Wolfram Language code: Plot[Evaluate[fh[BattleLemarieWavelet[3, 20], ω, 10]], {ω, -2Pi, 2Pi}, PlotRange -> All, Ticks -> {Range[-2Pi, 2Pi, 2Pi / 3], {1}}, AxesLabel -> {ω, Abs[ Overscript[ϕ, ^ ][ω]]}]

的傅立叶变换由 给出：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-I b[[i, 1]]ω], {i, Length[b]}] ]
Wolfram Language code: fg[wav_, ω_, j_] := Abs[g[wav, (ω/2)]Product[h[wav, (ω/2^i)], {i, 2, j}]]
Wolfram Language code: Plot[Evaluate[fg[BattleLemarieWavelet[3, 20], ω, 10]], {ω, -10, 10}, PlotRange -> All, AxesLabel -> {ω, Abs[ Overscript[ψ, ^ ][ω]]}]

可能存在的问题  (1)

BattleLemarieWavelet 仅限于小于15的 n：

Wolfram Language code: WaveletPhi[BattleLemarieWavelet[16]]

当 n 不是一个正机器整数，BattleLemarieWavelet 未定义：

Wolfram Language code: WaveletPhi[BattleLemarieWavelet[2 + I]]

巧妙范例  (2)

绘制尺度函数的平移和伸缩：

Wolfram Language code: ϕ[x_, j_, k_] := 2^j / 2WaveletPhi[BattleLemarieWavelet[3], 2^jx - k]
Wolfram Language code: Plot[Evaluate@Table[ϕ[x, j, 0], {j, 0, 2}], {x, -1, 1}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: Plot[Evaluate@Table[ϕ[x, 2, k], {k, 0, 2^2 - 1}], {x, -1, 2}, Filling -> Axis, PlotRange -> All]

绘制小波函数的平移和伸缩：

Wolfram Language code: ψ[x_, j_, k_] := 2^j / 2WaveletPsi[BattleLemarieWavelet[3], 2^jx - k]
Wolfram Language code: Plot[Evaluate@Table[ψ[x, j, 0], {j, 0, 2}], {x, -0.5, 1}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: Plot[Evaluate@Table[ψ[x, 2, k], {k, 0, 2^2 - 1}], {x, -0.5, 1.5}, Filling -> Axis, PlotRange -> All]
Wolfram Research (2010)，BattleLemarieWavelet，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BattleLemarieWavelet.html.

文本

Wolfram Research (2010)，BattleLemarieWavelet，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BattleLemarieWavelet.html.

CMS

Wolfram 语言. 2010. "BattleLemarieWavelet." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BattleLemarieWavelet.html.

APA

Wolfram 语言. (2010). BattleLemarieWavelet. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BattleLemarieWavelet.html 年

BibTeX

@misc{reference.wolfram_2026_battlelemariewavelet, author="Wolfram Research", title="{BattleLemarieWavelet}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/BattleLemarieWavelet.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_battlelemariewavelet, organization={Wolfram Research}, title={BattleLemarieWavelet}, year={2010}, url={https://reference.wolfram.com/language/ref/BattleLemarieWavelet.html}, note=[Accessed: 13-September-2026]}