WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BellB[n]

ベル数 TemplateBox[{n}, BellB]を与える．

BellB[n,x]

ベル多項式 TemplateBox[{n, x}, BellB2]を与える．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

BellB

BellB[n]

ベル数 TemplateBox[{n}, BellB]を与える．

BellB[n,x]

ベル多項式 TemplateBox[{n, x}, BellB2]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • ベル多項式は母関数の関係式 e^((e^t-1)x)=sum_(n=0)^(infty)(TemplateBox[{n, x}, BellB2]t^n)/(n!)を満たす．
  • ベル数は TemplateBox[{n}, BellB]=TemplateBox[{n, 1}, BellB2]で与えられる．
  • 特別な引数の場合，BellBは，自動的に厳密値を計算する．
  • BellBは任意の数値精度で評価できる．
  • BellBは自動的にリストに縫い込まれる．

予備知識

  • BellBは，ベル数またはベル多項式返す数学関数である．中でも，BellB[n,x]は 番目のベル多項式 を返し，BellB[n]は 番目のベル数 TemplateBox[{n}, BellB]=TemplateBox[{n, 1}, BellB2]を返す．ベル多項式は指数母関数で決定することができる．ベル数は漸化式 B_(n+1)=sum_(k=0)^nTemplateBox[{n, k}, Binomial]B_kを満足する．最初の数個のベル多項式 は で，最初の数個のベル数 はである．
  • ベル多項式は，指数多項式，あるいはより明示的に，「完全指数ベル多項式」と呼ばれることがあり，と表示されることがある．ベル多項式は，数学者で数学の解説者でもあり，1934年にこの多項式についての論文を発表したEric Temple Bellに因んで名付けられた．
  • 多項式 は， を 個の部分に分割する方法が 通りあるなら であると解釈される．さらに， を分割する方法が全部で 通りなら である．例えば，元の数が の集合 をの部分に分割する方法は通り，つの部分に分割する方法は通り ()，つの部分に分割する方法は通り（, と ），つの部分に分割する方法は通り()で，となる． を分割する方法は全部で5通りなので，である．
  • ベル多項式とベル数は，BellY関数の特殊ケース（TemplateBox[{n, x}, BellB2]=sum_(k=0)^nY_(n,k)(x,...,x)および）である．TemplateBox[{n, k}, StirlingS2]でStirlingS2が返す第2種スターリング数を表すとすると，B_n=B_n(1)=sum_(k=0)^nTemplateBox[{n, k}, StirlingS2]となる．

例題

すべて開く すべて閉じる

例  (2)

10番目のベル数：

Wolfram Language code: BellB[10]

5番目のベル多項式：

Wolfram Language code: BellB[5, x]

スコープ  (5)

数値的に評価する：

Wolfram Language code: BellB[1000, 0.5]

出力精度は入力精度に従う：

Wolfram Language code: BellB[1000, 0.500000000000000000000000]

BellBは要素単位でリストに並列的な関数の適用を行う：

Wolfram Language code: BellB[{1, 2, 3, 4, 5, 6}]

BellBは，ベキ級数に適用することができる：

Wolfram Language code: BellB[n, Sin[x] + O[x] ^ 3]

TraditionalFormによる表示：

Wolfram Language code: BellB[n]//TraditionalForm
Wolfram Language code: BellB[n, x]//TraditionalForm

アプリケーション  (4)

BellB数とその漸近線との対比：

Wolfram Language code: Show[ListPlot[Table[(Log[BellB[n]]/n), {n, 50}]], Plot[Log[n] + (Log[Log[n]] + 1) ((1/Log[n]) - 1) + (1/2) ((Log[Log[n]]/Log[n]))^2, {n, 5, 50}]]

最初の10個のcomplementary Bell numbersを計算する：

Wolfram Language code: Table[BellB[n, -1], {n, 10}]

第2種スターリング数による式と比較する：

Wolfram Language code: Table[Underoverscript[∑, k = 0, n](-1)^kStirlingS2[n, k], {n, 10}]

ヘッセンベルグ行列式によるベル数についての式の最初の数例を検証する：

Wolfram Language code: Table[BellB[n + 1] == Det[SparseArray[{Band[{2, 1}] -> 1, Band[{1, 1}] -> 2, {j_, k_} /; j < k :> (-1)^j + kBinomial[k - 1, j - 1]}, {n, n}]], {n, 2, 9}]

ベル数BellB[n]は，これから作られた2つのハンケル行列式がどちらもBarnesG[n+2]と等しい一意的な集合であるという事実で特徴付けられる．最初のいくつかの例についてこれを検証する：

Wolfram Language code: Table[BarnesG[n + 2] == Det[HankelMatrix[BellB[Range[0, n]], BellB[Range[n, 2n]]]] == Det[HankelMatrix[BellB[Range[n + 1]], BellB[Range[n + 1, 2n + 1]]]], {n, 9}]

特性と関係  (7)

BellBの指数型母関数：

Wolfram Language code: ExponentialGeneratingFunction[BellB[n], n, x]

明示的な総和の式と比較する：

Wolfram Language code: Sum[BellB[n]x^n / n!, {n, 0, Infinity}]

SumはBellBを含む結果を与えることがある：

Wolfram Language code: Sum[k^n / k!, {k, 0, Infinity}, Assumptions -> n∈Integers && n ≥ 0]
Wolfram Language code: Sum[StirlingS2[n, k], {k, 0, n}]

PoissonDistributionの 番目のモーメントは平均 の 番目のBellB多項式で与えられる：

Wolfram Language code: Moment[PoissonDistribution[μ], n]

FullSimplifyを使ってBellBを含む式を簡約する：

Wolfram Language code: FullSimplify[Mod[BellB[k + p] + BellB[k] - BellB[k + 1], p], p ∈ Primes]

分割集合 からベル数を直接計算する：

Wolfram Language code: Table[Sum[(n!/Underoverscript[∏, k = 1, n]k!^Subscript[m, k]Subscript[m, k]!)Boole[Subsuperscript[∑, k = 0, n]k Subscript[m, k] == n∧Subsuperscript[∑, k = 1, n]Subscript[m, k] == Subscript[m, 0]], Evaluate[Array[{Subscript[m, #], 0, n}&, n + 1, 0, Sequence]]], {n, 1, 5}]

IntegerPartitionsを使って指標についての条件を満足する項の総和を直接計算する：

Wolfram Language code: Table[Sum[(Multinomial@@p) / Product[k!, {k, Length /@ Split[p]}], {p, IntegerPartitions[n]}], {n, 10}]

BellBの結果と比較する：

Wolfram Language code: Table[BellB[k], {k, 1, 10}]

一般化されたベル多項式を使ってベル数を計算する：

Wolfram Language code: Table[BellY[ConstantArray[1, {n, 2}]], {n, 10}]
Wolfram Language code: Table[BellB[n], {n, 10}]

一般化されたベル多項式を使ってベル多項式を計算する：

Wolfram Language code: Table[BellY[ConstantArray[{1, x}, n]], {n, 5}]
Wolfram Language code: Table[BellB[n, x], {n, 5}]

FindSequenceFunctionはBellBを認識する：

Wolfram Language code: Table[BellB[n], {n, 10}]
Wolfram Language code: FindSequenceFunction[%, n]

考えられる問題  (1)

BellBの第1引数は非負の整数でなければならない：

Wolfram Language code: BellB[1 / 2, x]

おもしろい例題  (1)

チェザロ(Cesàro)によるベル数の積分表示：

Wolfram Language code: Im[Table[(2/π E)n! NIntegrate[E^E^E^I t Sin[n t], {t, 0, Pi}], {n, 10}]]
Wolfram Language code: BellB[Range[10]]
Wolfram Research (2007), BellB, Wolfram言語関数， https://reference.wolfram.com/language/ref/BellB.html.

テキスト

Wolfram Research (2007), BellB, Wolfram言語関数， https://reference.wolfram.com/language/ref/BellB.html.

CMS

Wolfram Language. 2007. "BellB." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BellB.html.

APA

Wolfram Language. (2007). BellB. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BellB.html

BibTeX

@misc{reference.wolfram_2026_bellb, author="Wolfram Research", title="{BellB}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/BellB.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_bellb, organization={Wolfram Research}, title={BellB}, year={2007}, url={https://reference.wolfram.com/language/ref/BellB.html}, note=[Accessed: 15-August-2026]}