Wolfram 语言与系统参考资料中心

Binomial

Binomial[n,m]

gives the binomial coefficient .

背景

Binomial 表示一个二项式系数函数，返回和的二项式系数 . 对于非负整数和，二项式系数为，其中是 Factorial 函数. 通过对称，. 二项式系数在概率论和组合学中很重要，有时被表示为
对于非负整数和，二项式系数给出包含在集合中长度为的子集数. 这也是从前个正整数选择个元素（没有替代和忽略排序）的不同方法数，因此，它常被称之为 " 选择 ".
二项式系数位于二项式公式的心脏，它表明对于任何非负整数， $(x+y)^n=sum_(k=0)^nTemplateBox[{n, k}, Binomial] x^(n-k)y^k$ . 这种二项式系数的诠释与概率论的二项分布相关，通过 BinomialDistribution 实现. 另一个重要应用是在称之为帕斯卡规则的组合恒等式中，它与根据带有移位参数的二项系数有关.
将阶乘表示为伽马函数将二项式系数用推广为复数和 . 对整数和以及复数使用对称公式 $(TemplateBox[{{s, -, a, +, 1}}, Gamma])/(TemplateBox[{{s, -, b, +, 1}}, Gamma])=(-1)^(b-a)( TemplateBox[{{b, -, s}}, Gamma])/(TemplateBox[{{a, -, s}}, Gamma])$ ，允许二项系数的定义延伸至负整数参数，使其对于所有整数参数以及复数参数是连续的，除了负整数和非整数（这种情况下是无穷）. 负数和整数的定义在时由 $(-1)^k TemplateBox[{{k, -, n, -, 1}, k}, Binomial]$ 给出，在时由 $(-1)^(n-k) TemplateBox[{{{-, k}, -, 1}, {n, -, k}}, Binomial]$ 给出，否则为 0，这与二项式定理和大多数组合恒等式一致（有一些特殊例外）.
二项式系数通过多项式系数来推广. Multinomial 返回给定数 n₁,…,n_k 加的多项式系数 (n;n₁,…,n_k)，其中 . 二项式系数是多项式系数 (n;k,n-k).

范例

打开所有单元关闭所有单元

基本范例 (5)

数值化计算：

Wolfram Language code: Binomial[10, 3]

使用符号运算：

Wolfram Language code: Binomial[n, n - 1]

构建帕斯卡三角形：

Wolfram Language code: Column[Table[Binomial[n, k], {n, 0, 5}, {k, 0, n}], Center]

作为第一个参数的函数在实数子集上绘图：

Wolfram Language code: Plot[Binomial[x, 3], {x, -2, 4}]

作为第二个参数的函数在实数子集上绘图：

Wolfram Language code: Plot[Binomial[3, x], {x, -2, 4}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[Binomial[z, 1 / 5], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

范围 (35)

数值运算 (7)

数值运算：

Wolfram Language code: Binomial[8, 4]

Wolfram Language code: Binomial[8.5, -4.2]

对半整数自变量求值：

Wolfram Language code: Binomial[9 / 2, 7 / 2]

高精度运算：

Wolfram Language code: N[Binomial[7 / 3, 1 / 5], 20]

输出的精度与输入的精度相符：

Wolfram Language code: Binomial[8.2211111111115000000, 4]

复数输入：

Wolfram Language code: Binomial[1 + I, 5]

Wolfram Language code: Binomial[2. + I, 7 - 3I]

高效地进行高精度运算：

Wolfram Language code: Binomial[17 / 2, -4.2`100]//Timing

Wolfram Language code: Binomial[-88889 + (1/2), 4.2`1000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: Binomial[1 / 2, Interval[{0.5, 0.6}]]

Wolfram Language code: Binomial[1, CenteredInterval[1 / 2, 1 / 100]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: Binomial[Around[2, 0.01], 2]

计算数组中每个元素的值：

Wolfram Language code: Binomial[ {{5π / 6, 0}, {3π / 2, -π / 2}}, 2]

或用 MatrixFunction 计算矩阵形式的 Binomial 函数：

Wolfram Language code: MatrixFunction[Binomial[#, 2]&, {{5π / 6, 0}, {3π / 2, -π / 2}}]

特殊值 (4)

Binomial 在特殊点的值：

Wolfram Language code: Table[Binomial[n, 2], {n, 1, 5}]

符号 n 的 Binomial 表达式：

Wolfram Language code: Binomial[n, 4]

零处的值：

Wolfram Language code: Binomial[n, 0]

Wolfram Language code: FunctionExpand[Binomial[0, m]]

请注意，除的情况外，对于所有整数，该值都为零：

Wolfram Language code: Simplify[%, m∈ℤ && m != 0]

求使得 Binomial[n,2]=15 成立的 n 值：

Wolfram Language code: nval = n /. FindRoot[Binomial[ n , 2] == 15, {n, 5}]

Wolfram Language code: Plot[Binomial[n, 2], {n, 0, 10}, Epilog -> Style[Point[{nval, Binomial[nval, 2]}], PointSize[Large], StandardMagenta]]

可视化 (3)

绘制作为参数 n 的函数的 Binomial：

Wolfram Language code: Plot[{Binomial[n, 1], Binomial[n, 2], Binomial[n, 3], Binomial[n, 4]}, {n, -2, 4}]

绘制作为参数的函数的 Binomial：

Wolfram Language code: Plot[{Binomial[1, m], Binomial[2, m], Binomial[3, m], Binomial[4, m]}, {m, -1, 5}]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[Binomial[z, 5]], {z, -4 - 4I, 8 + 4I}, Contours -> 24]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[Binomial[z, 5]], {z, -4 - 4I, 8 + 4I}, Contours -> 24]

函数属性 (12)

绘制作为参数 n 的函数的 Binomial 的实域：

Wolfram Language code: FunctionDomain[Binomial[n, 2], n]

绘制作为参数 m 的函数的 Binomial 的实域：

Wolfram Language code: FunctionDomain[Binomial[2, m], m]

复定义域：

Wolfram Language code: FunctionDomain[Binomial[z, 2], z, Complexes]

Wolfram Language code: FunctionDomain[Binomial[2, z], z, Complexes]

Binomial 的值域：

Wolfram Language code: FunctionRange[Binomial[x, 2], x, y]

Binomial 具有镜像属性：

Wolfram Language code: FullSimplify[Binomial[Conjugate[z], 2] == Conjugate[Binomial[z, 2]]]

计算涉及 Binomial 的和：

Wolfram Language code: Sum[Binomial[n, k], {k, 0, n}]

Wolfram Language code: Sum[Binomial[n, k] ^ 2, {k, 0, n}]

当为正时，是关于两个变量的解析函数：

Wolfram Language code: FunctionAnalytic[{Binomial[x, y], x > 0}, {x, y}]

当为负时，情况则不然：

Wolfram Language code: FunctionAnalytic[{Binomial[x, y], x < 0}, {x, y}]

既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[Binomial[x, 7], x]

不是单射函数：

Wolfram Language code: FunctionInjective[Binomial[x, 7], x]

Wolfram Language code: Plot[{Binomial[x, 7], 0.01}, {x, -1, 3}]

是满射函数：

Wolfram Language code: FunctionSurjective[Binomial[x, 7], x]

Wolfram Language code: Plot[{Binomial[x, 7], 750}, {x, -10, 15}]

Binomial 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[Binomial[x, 1], x]

Wolfram Language code: FunctionSign[Binomial[1, x], x]

为负整数时，有奇点和断点：

Wolfram Language code: FunctionSingularities[Binomial[x, y], x]

Wolfram Language code: FunctionDiscontinuities[Binomial[x, y], x]

既不凸，也不凹：

Wolfram Language code: FunctionConvexity[Binomial[x, 7], x]

TraditionalForm 格式输出：

Wolfram Language code: Binomial[n, k]//TraditionalForm

微分 (3)

关于的一阶导数：

Wolfram Language code: D[Binomial[n, m], m]

关于的高阶导数：

Wolfram Language code: Table[D[Binomial[n, m], {m, k}], {k, 1, 3}]//FullSimplify

，绘制关于的高阶导数：

Wolfram Language code: Plot[Evaluate[% /. n -> 2], {m, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

关于的一阶导数：

Wolfram Language code: D[Binomial[n, m], n]

级数展开式 (4)

用 Series 求泰勒展开式：

Wolfram Language code: Series[Binomial[n, x], {x, 0, 3}]//Normal//FullSimplify

绘制处的前三个近似式：

Wolfram Language code:

terms = Normal@Table[Series[Binomial[2, x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{Binomial[2, x], terms}, {x, -5, 5}]

求 Infinity 处的级数展开式：

Wolfram Language code: FullSimplify[Series[Binomial[n, x], {x, Infinity, 1}]//Normal, x > n]

求任意符号方向上的级数展开式：

Wolfram Language code: Series[Binomial[2, x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0 ]//Normal// FullSimplify

普通点上的泰勒展开式：

Wolfram Language code: Series[Binomial[n, x], {x, x0, 2}]// Normal//FullSimplify

函数恒等式和化简 (2)

函数恒等式：

Wolfram Language code: Binomial[n, k] == (k + 1/n - k) Binomial[n, k + 1]//FullSimplify

递归关系：

Wolfram Language code: Binomial[n, k] == (n/n - k) Binomial[n - 1, k]//FullSimplify

Wolfram Language code: Binomial[n, k] == (n - k + 1/n + 1) Binomial[n + 1, k]//FullSimplify

推广和延伸 (2)

无穷自变量得到符号解：

Wolfram Language code: Binomial[Infinity, 2]

Wolfram Language code: Binomial[-Infinity, -12]

Binomial 逐项作用于列表的各个元素：

Wolfram Language code: Binomial[{2, 3, 5, 7, 11}, 3]

应用 (11)

从个元素中无放回地选择个元素，有种方式：

Wolfram Language code: With[{n = 5, m = 2}, Binomial[n, m]]

用直接列举的方法进行检查：

Wolfram Language code: With[{n = 5, m = 2}, Subsets[Range[n], {m}]]

Wolfram Language code: Length[%]

从个元素中有放回地选择个元素，有种方式：

Wolfram Language code: With[{n = 5, m = 2}, Binomial[n + m - 1, m]]

用直接列举的方法进行检查：

Wolfram Language code: With[{n = 5, m = 2}, DeleteDuplicates[Sort /@ Tuples[Range[n], {m}]]]

Wolfram Language code: Length[%]

一组元素由两类对象组成，其中一类为个无区别的对象，另一类为个无区别的对象，对这组元素进行排列有种方法：

Wolfram Language code: With[{n = 5, m = 2}, Binomial[n + m, m]]

Wolfram Language code: With[{n = 5, m = 2}, Permutations[Join[ConstantArray[0, n], ConstantArray[1, m]]]]

Wolfram Language code: Length[%]

说明二项式定理：

Wolfram Language code: Sum[Binomial[n, k]x ^ k, {k, 0, n}]

Wolfram Language code: Expand[(1 + x) ^ 10]

分数二项式定理：

Wolfram Language code: Series[(1 + x) ^ (1 / 3), {x, 0, 5}]

Wolfram Language code: Sum[Binomial[1 / 3, k]x ^ k, {k, 0, 5}]

二项式系数模除 2：

Wolfram Language code: ArrayPlot[Table[Mod[Binomial[i, j], 2], {i, 50}, {j, i}], PlotTheme -> "Scientific"]

在自变量平面绘制 Binomial：

Wolfram Language code: Plot3D[Binomial[n, k], {n, -10, 10}, {k, -10, 10}]

绘制从个元素中选取出个元素的方法数的对数：

Wolfram Language code: Plot3D[Log[Binomial[n, k]], {n, 1, 12}, {k, 1, 12}, RegionFunction -> (#2 <= #1&)]

计算两个函数积的高阶导数：

Wolfram Language code: Sum[Binomial[4, k] D[f[z], {z, k}]D[g[z], {z, 4 - k}], {k, 0, 4}]

Wolfram Language code: D[f[z] g[z], {z, 4}]

二项式概率分布的 PDF：

Wolfram Language code: With[{n = 20, q = 0.3}, PDF[BinomialDistribution[n, q], k]]

Wolfram Language code: DiscretePlot[%, {k, 0, 20}]

用 Binomial 定义伯恩斯坦多项式：

Wolfram Language code: PiecewiseExpand[BernsteinBasis[n, k, x], 0 < x < 1 && n >= k > 0]

Wolfram Language code: Table[Plot[Evaluate[Table[BernsteinBasis[n, k, x], {k, 0, n}]], {x, 0, 1}, PlotLabel -> n], {n, 0, 3}]

属性和关系 (11)

整数情况下，Binomial[n,m] 等于：

Wolfram Language code:

And@@Flatten@Table[Binomial[n, m] == Underscript[, ϵUnderscript[ -> , ℂ]0](Gamma[n + ϵ + 1]/Gamma[m + ϵ + 1] Gamma[-m + n + ϵ + 1]), {n, -5, 5}, {m, -5, 5}]

对于可表示为 $(-1)^m TemplateBox[{{-, n}, m}, Pochhammer]/m!$ ，对于可表示为 $(-1)^(n-m) TemplateBox[{{-, n}, {n, -, m}}, Pochhammer]/(n-m)!$ ：

Wolfram Language code:

And@@Flatten@Table[Binomial[``n``, ``m``] == Piecewise[{{((-1)^m*Pochhammer[-n, m])/m!, m >= 0}, 
  {((-1)^(-m + n)*Pochhammer[-n, -m + n])/(-m + n)!, m <= n}}], {n, -5, 5}, {m, -5, 5}]

关于整数的另一个公式：

Wolfram Language code: Assuming[{n, m}∈ℤ, FullSimplify@FunctionExpand[Binomial[n, m]]]

帕斯卡恒等几乎无处不在：

Wolfram Language code: FullSimplify[Binomial[n, m] == Binomial[n - 1, m] + Binomial[n - 1, m - 1], n ≠ 0 && m ≠ 0]

但在原点处则不满足：

Wolfram Language code: FullSimplify[Binomial[n, m] == Binomial[n - 1, m] + Binomial[n - 1, m - 1], n == 0 && m == 0]

PascalBinomial 在包括原点在内的任何地方都满足恒等：

Wolfram Language code: FullSimplify[PascalBinomial[n, m] == PascalBinomial[n - 1, m] + PascalBinomial[n - 1, m - 1], n == 0 && m == 0]

对称法则对所有和值都成立：

Wolfram Language code: FullSimplify[Binomial[n, m] == Binomial[n, n - m]]

PascalBinomial 对符号参数进行简单的运算：

Wolfram Language code: Binomial[n + 2, n]

对于更复杂的表达式，则会避免自动展开：

Wolfram Language code: Binomial[n + 6, n]

使用带条件的 FunctionExpand 来实现适当的化简：

Wolfram Language code: FunctionExpand[Binomial[n + 6, n], n∈Integers]

用 FullSimplify 简化含有二项式系数的表达式：

Wolfram Language code: FullSimplify[Binomial[n + 1, k + 1] / Binomial[n, k]]

用 FunctionExpand 将二项式系数展开为 Gamma 函数：

Wolfram Language code: FunctionExpand[Binomial[n, k]]

含有 Binomial 的求和：

Wolfram Language code: Underoverscript[∑, k = 0, n](-1)^kBinomial[n, k]

Wolfram Language code: Underoverscript[∑, k = 0, ∞]Binomial[n, k] k

Wolfram Language code: Underoverscript[∑, j = k, n]Binomial[n, j] Binomial[j, k]

Wolfram Language code: Underoverscript[∑, k = 1, ∞](1/Binomial[2 k, k])

求母函数 Binomial：

Wolfram Language code: Underoverscript[∑, k = 0, ∞]Binomial[n, k] x ^ k

Binomial 可被表示为 DifferenceRoot：

Wolfram Language code: DifferenceRootReduce[Binomial[k, z], k]

Wolfram Language code: DifferenceRootReduce[Binomial[z, k], k]

Binomial 的母函数：

Wolfram Language code: GeneratingFunction[Binomial[k, n], n, x]

Binomial 的指数母函数：

Wolfram Language code: ExponentialGeneratingFunction[Binomial[k, n], n, x]

可能存在的问题 (3)

较大的自变量得到的解太大，以至于不能被明确地计算求出：

Wolfram Language code: Binomial[10. ^ 100, 10 ^ 99]

机器数的输入能得到高精度的解：

Wolfram Language code: Binomial[10. ^ 6, 10. ^ 5]

Wolfram Language code: MachineNumberQ[%]

作为一个二元函数，当两个变量都为负整数时，Binomial 不连续：

Wolfram Language code: With[{ϵ = 10 ^ -6.}, Table[Binomial[-3 - p ϵ, -5 - ϵ], {p, {-3, -2, -1, 1, 2, 3, 4}}]]

在负整数时的 Binomial 值由 Binomial[n,m]Binomial[n,n-m] 确定：

Wolfram Language code: Binomial[-3, -5]

Wolfram Language code: {Binomial[n, n - 2], Binomial[n, 2]}

Wolfram Language code: % /. n -> -3

巧妙范例 (7)

构建帕斯卡三角形（Pascal's triangle）的图形版本：

Wolfram Language code:

With[{n = 8}, 
Graph[Flatten[Table[{b[i, j] <-> b[i + 1, j], b[i, j] <-> b[i + 1, j + 1], b[i + 1, j] <-> b[i + 1, j + 1]}, {i, 0, n - 1}, {j, 0, i}]], VertexCoordinates -> {b[i_, j_] :> {(n + 1/2) - i / 2 + j, -i}}, VertexLabels -> {b[i_, j_] :> Placed[Binomial[i, j], Center]}, IconizedObject[«Style options»]]]

将三角形延展到负整数；未标记的点表示零值：

Wolfram Language code:

With[{n = 6}, Graph[Flatten[Table[{b[i, j] <-> b[i + 1, j], b[i, j] <-> b[i + 1, j + 1], b[i + 1, j] <-> b[i + 1, j + 1]}, {i, n - 1, -n - 1, -1}, {j, -n + i UnitStep[i] - UnitStep[-1 - i], n + i UnitStep[-i] + UnitStep[-1 - i]}]], VertexCoordinates -> {b[i_, j_] :> {(n + 1/2) - (i/2) + j, -i}}, IconizedObject[«Style options»]]]

相比之下，在输入均为负数的情况下，PascalBinomial 导致左上角的扇形区域为零：

Wolfram Language code:

With[{n = 6}, Graph[Flatten[Table[{b[i, j] <-> b[i + 1, j], b[i, j] <-> b[i + 1, j + 1], b[i + 1, j] <-> b[i + 1, j + 1]}, {i, n - 1, -n - 1, -1}, {j, -n + i UnitStep[i] - UnitStep[-1 - i], n + i UnitStep[-i] + UnitStep[-1 - i]}]], VertexCoordinates -> {b[i_, j_] :> {(n + 1/2) - (i/2) + j, -i}}, IconizedObject[«Style options»]]]

二项式系数模除：

Wolfram Language code: ArrayPlot[Table[Mod[Binomial[i, j], Pi], {i, 50}, {j, i}], PlotTheme -> "Scientific"]

希耳伯特矩阵的闭形逆：

Wolfram Language code:

Block[{n = 4}, Table[(-1) ^ (i + j)(i + j - 1)Binomial[n + i - 1, n - j]Binomial[n + j - 1, n - i]Binomial[i + j - 2, i - 1] ^ 2, {i, n}, {j, n}]]//MatrixForm

Wolfram Language code: Inverse[%]

复平面上的嵌套二项式：

Wolfram Language code:

DensityPlot[Arg[Nest[Binomial[#, # / 2]&, x + I y, 3]], {x, -1, -0.9}, {y, -0.06, 0.06}, Exclusions -> {}, MaxRecursion -> 4, PlotPoints -> 50]

绘制无穷处的 Binomial：

Wolfram Language code:

DensityPlot[Arg[Binomial[(x + I y), 1 / (x + I y)]], {x, -1 / 2, 1 / 2}, {y, -1 / 2, 1 / 2}, Exclusions -> {}, MaxRecursion -> 4, PlotPoints -> 50]

绘制自变量为复数的 Binomial ：

Wolfram Language code:

DensityPlot[Arg[Binomial[4.1 Exp[I ϕ1], 2.2 Exp[I ϕ2]]], {ϕ1, -Pi, Pi}, {ϕ2, -Pi, Pi}, Exclusions -> {}, MaxRecursion -> 4, PlotPoints -> 50]

绘制自变量为高斯整数的 Binomial：

Wolfram Language code:

Block[{$MaxExtraPrecision = 1000}, ArrayPlot[Table[Mod[Im@Round[Binomial[x  + I y, x ]], 2], {x, 0, 50}, {y, -25, 25}], PlotTheme -> "Scientific"]]

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Binomial

更多信息

背景

范例

基本范例 (5)

范围 (35)

数值运算 (7)

特殊值 (4)

可视化 (3)

函数属性 (12)

微分 (3)

级数展开式 (4)

函数恒等式和化简 (2)

推广和延伸 (2)

应用 (11)

属性和关系 (11)

可能存在的问题 (3)

巧妙范例 (7)

文本

CMS

APA

BibTeX

BibLaTeX

Binomial

更多信息

背景

范例

基本范例 (5)

范围 (35)

数值运算 (7)

特殊值 (4)

可视化 (3)

函数属性 (12)

微分 (3)

级数展开式 (4)

函数恒等式和化简 (2)

推广和延伸 (2)

应用 (11)

属性和关系 (11)

可能存在的问题 (3)

巧妙范例 (7)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX