WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BiorthogonalSplineWavelet[]

次数4，二重次数2の双直交スプラインウェーブレットを表す．

BiorthogonalSplineWavelet[n,m]

次数 n，二重次数 m の双直交スプラインウェーブレットを表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
ウェーブレット変換  
より高い次元  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

BiorthogonalSplineWavelet

BiorthogonalSplineWavelet[]

次数4，二重次数2の双直交スプラインウェーブレットを表す．

BiorthogonalSplineWavelet[n,m]

次数 n，二重次数 m の双直交スプラインウェーブレットを表す．

詳細

例題

すべて開く すべて閉じる

例  (6)

主スケーリング関数：

Wolfram Language code: Plot[WaveletPhi[BiorthogonalSplineWavelet[2, 4], x], {x, -4, 4}, PlotRange -> All]

主ウェーブレット関数：

Wolfram Language code: Plot[WaveletPsi[BiorthogonalSplineWavelet[2, 4], x], {x, -2, 3}, PlotRange -> All]

双対スケーリング関数：

Wolfram Language code: Plot[WaveletPhi[BiorthogonalSplineWavelet[2, 4], x, "Dual"], {x, -2, 2}, PlotRange -> All]

双対ウェーブレット関数：

Wolfram Language code: Plot[WaveletPsi[BiorthogonalSplineWavelet[2, 4], x, "Dual"], {x, -2, 3}, PlotRange -> All]

主フィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[BiorthogonalSplineWavelet[2, 4], {"PrimalLowpass", "PrimalHighpass"}, WorkingPrecision -> ∞]

双対フィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[BiorthogonalSplineWavelet[2, 4], {"DualLowpass", "DualHighpass"}, WorkingPrecision -> ∞]

スコープ  (17)

基本的な用法  (10)

主ローパスフィルタ係数を計算する：

Wolfram Language code: WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "PrimalLowpass"]

双対ローパスフィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "DualLowpass"]

主ハイパスフィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "PrimalHighpass"]

双対ハイパスフィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "DualHighpass"]

リフティングフィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "LiftingFilter", WorkingPrecision -> ∞]
Wolfram Language code: %[{"LiftingMatrixForm", z}]

関数を生成してリフティングウェーブレット変換を計算する：

Wolfram Language code: lf = WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "LiftingFilter", WorkingPrecision -> ∞]
Wolfram Language code: lf["ForwardLiftingFunction"][Range[8]]
Wolfram Language code: lf["InverseLiftingFunction"][%]

主スケーリング関数：

Wolfram Language code: Plot[WaveletPhi[BiorthogonalSplineWavelet[2, 6], x], {x, -6, 6}, PlotRange -> All]

双対スケーリング関数：

Wolfram Language code: Plot[WaveletPhi[BiorthogonalSplineWavelet[2, 6], x, "Dual"], {x, -1, 1}, PlotRange -> All]

異なる再帰レベルを使ってスケーリング関数をプロットする：

Wolfram Language code: Table[Plot[WaveletPhi[BiorthogonalSplineWavelet[2, 6], x, MaxRecursion -> i], {x, -4, 4}, PlotLabel -> i, PlotRange -> All], {i, 1, 8, 2}]

主ウェーブレット関数：

Wolfram Language code: Plot[WaveletPsi[BiorthogonalSplineWavelet[2, 6], x], {x, -3, 4}, PlotRange -> All]

双対ウェーブレット関数：

Wolfram Language code: Plot[WaveletPsi[BiorthogonalSplineWavelet[2, 6], x, "Dual"], {x, -3, 4}, PlotRange -> All]

異なる再帰レベルを使ってスケーリング関数をプロットする：

Wolfram Language code: Table[Plot[WaveletPsi[BiorthogonalSplineWavelet[2, 6], x, MaxRecursion -> i], {x, -3, 4}, PlotLabel -> i, PlotRange -> All], {i, 1, 8, 2}]

ウェーブレット変換  (5)

DiscreteWaveletTransformを計算する：

Wolfram Language code: data = Table[Sign[Cos[t^2]], {t, -2π, 2π, (4π/1023)}];
Wolfram Language code: ListLinePlot[data, PlotRange -> All]
Wolfram Language code: dwt = DiscreteWaveletTransform[data, BiorthogonalSplineWavelet[4, 4], 2]

ウェーブレット係数の木を見る：

Wolfram Language code: dwt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: dwt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[dwt, PlotLayout -> "CommonXAxis"]

DiscreteWaveletPacketTransformを計算する：

Wolfram Language code: data = Table[Sign[Cos[t^2]], {t, -2π, 2π, (4π/1023)}];
Wolfram Language code: dwpt = DiscreteWaveletPacketTransform[data, BiorthogonalSplineWavelet[4, 4], 2]

ウェーブレット係数の木を見る：

Wolfram Language code: dwpt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: dwpt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[dwpt, PlotLayout -> "CommonXAxis"]

StationaryWaveletTransformを計算する：

Wolfram Language code: data = Table[Sign[Cos[t^2]], {t, -2π, 2π, (4π/1023)}];
Wolfram Language code: swt = StationaryWaveletTransform[data, BiorthogonalSplineWavelet[4, 4], 2];

ウェーブレット係数の木を見る：

Wolfram Language code: swt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: swt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[swt, PlotLayout -> "CommonXAxis"]

StationaryWaveletPacketTransformを計算する：

Wolfram Language code: data = Table[Sign[Cos[t^2]], {t, -2π, 2π, (4π/1023)}];
Wolfram Language code: swpt = StationaryWaveletPacketTransform[data, BiorthogonalSplineWavelet[4, 4], 2];

ウェーブレット係数の木を見る：

Wolfram Language code: swpt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: swpt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[swpt, PlotLayout -> "CommonXAxis"]

LiftingWaveletTransformを計算する：

Wolfram Language code: data = Table[Sign[Cos[t^2]], {t, -2π, 2π, (4π/1023)}];
Wolfram Language code: lwt = LiftingWaveletTransform[data, BiorthogonalSplineWavelet[4, 4], 2];

ウェーブレット係数の木を見る：

Wolfram Language code: lwt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: lwt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[lwt, PlotLayout -> "CommonXAxis"]

より高い次元  (2)

多変量スケーリング関数と多変量ウェーブレット関数はそれぞれの一変量関数の積である：

Wolfram Language code: ϕ = WaveletPhi[BiorthogonalSplineWavelet[2, 6]]; ψ = WaveletPsi[BiorthogonalSplineWavelet[2, 6]];
Wolfram Language code: Plot3D[Evaluate[ϕ[x]ϕ[y]], {x, -6, 6}, {y, -6, 6}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ϕ[x]ψ[y]], {x, -6, 6}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x]ϕ[y]], {x, -3, 4}, {y, -6, 6}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x]ψ[y]], {x, -3, 4}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]

多変量双対スケーリング関数および多変量双対ウェーブレット関数はそれぞれの一変量関数の積である：

Wolfram Language code: Overscript[ϕ, ~] = Evaluate[WaveletPhi[BiorthogonalSplineWavelet[2, 6], #, "Dual"]]&; Overscript[ψ, ~] = Evaluate[WaveletPsi[BiorthogonalSplineWavelet[2, 6], #, "Dual"]]&;
Wolfram Language code: Plot3D[Evaluate[Overscript[ϕ, ~][x]Overscript[ϕ, ~][y]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All, ColorFunction -> "RustTones", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[Overscript[ϕ, ~][x]Overscript[ψ, ~][y]], {x, -1, 1}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "RustTones", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[Overscript[ψ, ~][x]Overscript[ϕ, ~][y]], {x, -3, 4}, {y, -1, 1}, PlotRange -> All, ColorFunction -> "RustTones", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[Overscript[ψ, ~][x]Overscript[ψ, ~][y]], {x, -3, 4}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "RustTones", Mesh -> None, Axes -> None]

特性と関係  (18)

BiorthogonalSplineWavelet[1,1]はHaarWaveletに等しい：

Wolfram Language code: WaveletFilterCoefficients[HaarWavelet[]] == WaveletFilterCoefficients[BiorthogonalSplineWavelet[1, 1]]
Wolfram Language code: WaveletFilterCoefficients[HaarWavelet[]] == WaveletFilterCoefficients[BiorthogonalSplineWavelet[1, 1], "DualLowpass"]

ローパスフィルタ係数の総和は単位元である．：

Wolfram Language code: Total@WaveletFilterCoefficients[BiorthogonalSplineWavelet[4, 2]][[All, 2]]

ハイパスフィルタ係数の総和は0である．：

Wolfram Language code: Total@WaveletFilterCoefficients[BiorthogonalSplineWavelet[4, 2], "PrimalHighpass"][[All, 2]]

双対ローパスフィルタ係数の総和は単位元である．：

Wolfram Language code: Total@WaveletFilterCoefficients[BiorthogonalSplineWavelet[4, 2], "DualLowpass"][[All, 2]]

双対ハイパスフィルタ係数の総和は0である．：

Wolfram Language code: Total@WaveletFilterCoefficients[BiorthogonalSplineWavelet[4, 2], "DualHighpass"][[All, 2]]

スケーリング関数を積分すると単位元になる．：

Wolfram Language code: Integrate[WaveletPhi[BiorthogonalSplineWavelet[2, 2], x], {x, -∞, ∞}]

双対スケーリング関数を積分すると単位元になる．：

Wolfram Language code: Integrate[WaveletPhi[BiorthogonalSplineWavelet[2, 2], x, "Dual"], {x, -∞, ∞}]

ウェーブレット関数を積分すると0になる．：

Wolfram Language code: Integrate[WaveletPsi[BiorthogonalSplineWavelet[2, 2], x], {x, -∞, ∞}]

双対ウェーブレット関数を積分すると0になる．：

Wolfram Language code: Integrate[WaveletPsi[BiorthogonalSplineWavelet[2, 2], x, "Dual"], {x, -∞, ∞}]

スケーリング関数 はコンパクトサポート{n1,n2}を持つ：

Wolfram Language code: ϕ = WaveletPhi[BiorthogonalSplineWavelet[3, 3], x]
Wolfram Language code: {n1, n2} = {-3, 4};

双対スケーリング関数 はコンパクトサポート{nd1,nd2}を持つ：

Wolfram Language code: Overscript[ϕ, ~] = WaveletPhi[BiorthogonalSplineWavelet[3, 3], x, "Dual"]
Wolfram Language code: {nd1, nd2} = {-1, 2};

対応するウェーブレット関数 はサポート({n1-nd2+1)/2,(n2-nd1+1)/2}を持つ：

Wolfram Language code: ψ = WaveletPsi[BiorthogonalSplineWavelet[3, 3], x]
Wolfram Language code: {(n1 - nd2 + 1/2), (n2 - nd1 + 1/2)}

双対ウェーブレット関数 はサポート({nd1-n2+1)/2,(nd2-n1+1)/2}を持つ：

Wolfram Language code: Overscript[ψ, ~] = WaveletPsi[BiorthogonalSplineWavelet[3, 3], x, "Dual"]
Wolfram Language code: {(nd1 - n2 + 1/2), (nd2 - n1 + 1/2)}

は再帰方程式 を満足する：

Wolfram Language code: ϕ = WaveletPhi[BiorthogonalSplineWavelet[1, 3]];
Wolfram Language code: a = WaveletFilterCoefficients[BiorthogonalSplineWavelet[1, 3], "PrimalLowpass"];

構成要素と再帰の総和をプロットする：

Wolfram Language code: scalet[x_, ϕ_, a_] := 2Table[a[[i, 2]]ϕ[2x - a[[i, 1]]], {i, Length[a]}]
Wolfram Language code: {Plot[Evaluate@scalet[x, ϕ, a], {x, -3, 4}, PlotRange -> All], Plot[Total@scalet[x, ϕ, a], {x, -3, 4}, PlotRange -> All]}

は再帰方程式 を満足する：

Wolfram Language code: ϕ = WaveletPhi[BiorthogonalSplineWavelet[1, 3]];
Wolfram Language code: b = WaveletFilterCoefficients[BiorthogonalSplineWavelet[1, 3], "PrimalHighpass"];

構成要素と再帰の総和をプロットする：

Wolfram Language code: wavelet[x_, ϕ_, b_] := 2Table[b[[i, 2]]ϕ[2x - b[[i, 1]]], {i, Length[b]}]
Wolfram Language code: {Plot[Evaluate@wavelet[x, ϕ, b], {x, -1, 2}, PlotRange -> All], Plot[Total@wavelet[x, ϕ, b], {x, -1, 2}, PlotRange -> All]}

は再帰方程式 を満足する：

Wolfram Language code: Overscript[ϕ, ~] = (Evaluate[WaveletPhi[BiorthogonalSplineWavelet[3, 5], #, "Dual"]]&);
Wolfram Language code: Overscript[a, ~] = WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 5], "DualLowpass"];

構成要素と再帰の総和をプロットする：

Wolfram Language code: scalet[x_, ϕ_, a_] := 2Table[a[[i, 2]]ϕ[2x - a[[i, 1]]], {i, Length[a]}]
Wolfram Language code: {Plot[Evaluate@scalet[x, Overscript[ϕ, ~], Overscript[a, ~]], {x, -1, 2}, PlotRange -> All], Plot[Total@scalet[x, Overscript[ϕ, ~], Overscript[a, ~]], {x, -1, 2}, PlotRange -> All]}

は再帰方程式 を満足する：

Wolfram Language code: Overscript[ϕ, ~] = (Evaluate[WaveletPhi[BiorthogonalSplineWavelet[3, 5], #, "Dual"]]&);
Wolfram Language code: Overscript[b, ~] = WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 5], "DualHighpass"];

構成要素と再帰の総和をプロットする：

Wolfram Language code: wavelet[x_, ϕ_, b_] := 2Table[b[[i, 2]]ϕ[2x - b[[i, 1]]], {i, Length[b]}]
Wolfram Language code: {Plot[Evaluate@wavelet[x, Overscript[ϕ, ~], Overscript[b, ~]], {x, -3, 4}, PlotRange -> All], Plot[Total@wavelet[x, Overscript[ϕ, ~], Overscript[b, ~]], {x, -3, 4}, PlotRange -> All]}

に対する周波数応答はで与えられる：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-Ia[[i, 1]]ω], {i, Length[a]}]]

フィルタはローパスフィルタである：

Wolfram Language code: Plot[Abs[h[BiorthogonalSplineWavelet[2, 2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]

のフーリエ(Fourier)変換はで与えられる：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-Ia[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: fh[wav_, ω_, j_] := Abs[Product[h[wav, (ω/2^i)], {i, j}]]
Wolfram Language code: Plot[fh[BiorthogonalSplineWavelet[2, 2], ω, 10], {ω, -10Pi, 10Pi}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[ϕ, ^ ][ω]]}]

に対する周波数応答はで与えられる：

Wolfram Language code: Overscript[h, ~][wav_, ω_] := With[{a = WaveletFilterCoefficients[wav, "DualLowpass"]}, Sum[a[[i, 2]]Exp[-Ia[[i, 1]]ω], {i, Length[a]}]]

フィルタは双対ローパスフィルタである：

Wolfram Language code: Plot[Abs[Overscript[h, ~][BiorthogonalSplineWavelet[2, 2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[Overscript[H, ~][ω]]}]

のフーリエ変換はで与えられる：

Wolfram Language code: Overscript[h, ~][wav_, ω_] := With[{a = WaveletFilterCoefficients[wav, "DualLowpass"]}, Sum[a[[i, 2]]Exp[-Ia[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: fh[wav_, ω_, j_] := Abs[Product[Overscript[h, ~][wav, (ω/2^i)], {i, j}]]
Wolfram Language code: Plot[fh[BiorthogonalSplineWavelet[2, 2], ω, 10], {ω, -10Pi, 10Pi}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[Overscript[ϕ, ~], ^ ][ω]]}]

に対する周波数応答はで与えられる：

Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-Ib[[i, 1]]ω], {i, Length[b]}] ]

フィルタはローパスフィルタである：

Wolfram Language code: Plot[Abs[g[BiorthogonalSplineWavelet[2, 2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]

のフーリエ変換は で与えられる：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-Ib[[i, 1]]ω], {i, Length[b]}]]
Wolfram Language code: fg[wav_, ω_, j_] := Abs[g[wav, (ω/2)]Product[h[wav, (ω/2^i)], {i, 2, j}]]
Wolfram Language code: Plot[fg[BiorthogonalSplineWavelet[2, 2], ω, 10], {ω, -10Pi, 10Pi}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[ψ, ^ ][ω]]}]

に対する周波数応答はで与えられる：

Wolfram Language code: Overscript[g, ~][wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "DualHighpass"]}, Sum[b[[i, 2]]Exp[-Ib[[i, 1]]ω], {i, Length[b]}]]

フィルタはローパスフィルタである：

Wolfram Language code: Plot[Abs[Overscript[g, ~][BiorthogonalSplineWavelet[2, 2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[Overscript[G, ~][ω]]}]

のフーリエ変換は で与えられる：

Wolfram Language code: Overscript[h, ~][wav_, ω_] := With[{a = WaveletFilterCoefficients[wav, "DualLowpass"]}, Sum[a[[i, 2]]Exp[-Ia[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: Overscript[g, ~][wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "DualHighpass"]}, Sum[b[[i, 2]]Exp[-Ib[[i, 1]]ω], {i, Length[b]}]]
Wolfram Language code: Overscript[fg, ~][wav_, ω_, j_] := Abs[Overscript[g, ~][wav, (ω/2)]Product[Overscript[h, ~][wav, (ω/2^i)], {i, 2, j}]]
Wolfram Language code: Plot[Overscript[fg, ~][BiorthogonalSplineWavelet[2, 2], ω, 10], {ω, -10Pi, 10Pi}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[Overscript[ψ, ~], ^ ][ω]]}]

おもしろい例題  (2)

スケーリング関数の平行移動と膨張をプロットする：

Wolfram Language code: ϕ[x_, j_, k_] := 2^j / 2WaveletPhi[BiorthogonalSplineWavelet[1, 3], 2^jx - k]
Wolfram Language code: Plot[Evaluate@Table[ϕ[x, j, 0], {j, 0, 4}], {x, -1, 2}, Filling -> Axis, PlotRange -> All, Axes -> {True, False}]
Wolfram Language code: Plot[Evaluate@Table[ϕ[x, 2, k], {k, 0, 2^2 - 1}], {x, -0.5, 2}, Filling -> Axis, PlotRange -> All]

ウェーブレット関数の平行移動と膨張をプロットする：

Wolfram Language code: ψ[x_, j_, k_] := 2^j / 2WaveletPsi[BiorthogonalSplineWavelet[1, 3], 2^jx - k]
Wolfram Language code: Plot[Evaluate@Table[ψ[x, j, 0], {j, 0, 4}], {x, -0.5, 1}, Filling -> Axis, PlotRange -> All, Axes -> {True, False}]
Wolfram Language code: Plot[Evaluate@Table[ψ[x, 2, k], {k, 0, 2^2 - 1}], {x, -0.5, 1.5}, Filling -> Axis, PlotRange -> All]
Wolfram Research (2010), BiorthogonalSplineWavelet, Wolfram言語関数， https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html.

テキスト

Wolfram Research (2010), BiorthogonalSplineWavelet, Wolfram言語関数， https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html.

CMS

Wolfram Language. 2010. "BiorthogonalSplineWavelet." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html.

APA

Wolfram Language. (2010). BiorthogonalSplineWavelet. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html

BibTeX

@misc{reference.wolfram_2026_biorthogonalsplinewavelet, author="Wolfram Research", title="{BiorthogonalSplineWavelet}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_biorthogonalsplinewavelet, organization={Wolfram Research}, title={BiorthogonalSplineWavelet}, year={2010}, url={https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html}, note=[Accessed: 16-August-2026]}