WOLFRAM

Wolfram 语言与系统参考资料中心

BiorthogonalSplineWavelet[]

表示阶数为 4 和对偶阶数为 2 的双正交样条小波.

BiorthogonalSplineWavelet[n,m]

表示阶数为 n 和对偶阶数为 m 的双正交样条小波.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
小波变换  
高维度  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

BiorthogonalSplineWavelet

BiorthogonalSplineWavelet[]

表示阶数为 4 和对偶阶数为 2 的双正交样条小波.

BiorthogonalSplineWavelet[n,m]

表示阶数为 n 和对偶阶数为 m 的双正交样条小波.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (6)

原尺度函数：

Wolfram Language code: Plot[WaveletPhi[BiorthogonalSplineWavelet[2, 4], x], {x, -4, 4}, PlotRange -> All]

原小波函数：

Wolfram Language code: Plot[WaveletPsi[BiorthogonalSplineWavelet[2, 4], x], {x, -2, 3}, PlotRange -> All]

对偶尺度函数：

Wolfram Language code: Plot[WaveletPhi[BiorthogonalSplineWavelet[2, 4], x, "Dual"], {x, -2, 2}, PlotRange -> All]

对偶小波函数：

Wolfram Language code: Plot[WaveletPsi[BiorthogonalSplineWavelet[2, 4], x, "Dual"], {x, -2, 3}, PlotRange -> All]

原滤波器系数：

Wolfram Language code: WaveletFilterCoefficients[BiorthogonalSplineWavelet[2, 4], {"PrimalLowpass", "PrimalHighpass"}, WorkingPrecision -> ∞]

对偶滤波器系数：

Wolfram Language code: WaveletFilterCoefficients[BiorthogonalSplineWavelet[2, 4], {"DualLowpass", "DualHighpass"}, WorkingPrecision -> ∞]

范围  (17)

基本用法  (10)

计算原低通滤波器系数：

Wolfram Language code: WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "PrimalLowpass"]

对偶低通滤波器系数：

Wolfram Language code: WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "DualLowpass"]

原高通滤波器系数：

Wolfram Language code: WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "PrimalHighpass"]

对偶高通滤波器系数：

Wolfram Language code: WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "DualHighpass"]

提示滤波系数：

Wolfram Language code: WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "LiftingFilter", WorkingPrecision -> ∞]
Wolfram Language code: %[{"LiftingMatrixForm", z}]

生成一个函数计算提升小波变换：

Wolfram Language code: lf = WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 3], "LiftingFilter", WorkingPrecision -> ∞]
Wolfram Language code: lf["ForwardLiftingFunction"][Range[8]]
Wolfram Language code: lf["InverseLiftingFunction"][%]

原尺度函数：

Wolfram Language code: Plot[WaveletPhi[BiorthogonalSplineWavelet[2, 6], x], {x, -6, 6}, PlotRange -> All]

对偶尺度函数：

Wolfram Language code: Plot[WaveletPhi[BiorthogonalSplineWavelet[2, 6], x, "Dual"], {x, -1, 1}, PlotRange -> All]

使用不同递归层绘制尺度函数：

Wolfram Language code: Table[Plot[WaveletPhi[BiorthogonalSplineWavelet[2, 6], x, MaxRecursion -> i], {x, -4, 4}, PlotLabel -> i, PlotRange -> All], {i, 1, 8, 2}]

原小波函数：

Wolfram Language code: Plot[WaveletPsi[BiorthogonalSplineWavelet[2, 6], x], {x, -3, 4}, PlotRange -> All]

对偶小波函数：

Wolfram Language code: Plot[WaveletPsi[BiorthogonalSplineWavelet[2, 6], x, "Dual"], {x, -3, 4}, PlotRange -> All]

使用不同递归层绘制尺度函数：

Wolfram Language code: Table[Plot[WaveletPsi[BiorthogonalSplineWavelet[2, 6], x, MaxRecursion -> i], {x, -3, 4}, PlotLabel -> i, PlotRange -> All], {i, 1, 8, 2}]

小波变换  (5)

计算一个 DiscreteWaveletTransform：

Wolfram Language code: data = Table[Sign[Cos[t^2]], {t, -2π, 2π, (4π/1023)}];
Wolfram Language code: ListLinePlot[data, PlotRange -> All]
Wolfram Language code: dwt = DiscreteWaveletTransform[data, BiorthogonalSplineWavelet[4, 4], 2]

查看小波系数组成的树：

Wolfram Language code: dwt["TreeView"]

获取小波系数的维度：

Wolfram Language code: dwt["Dimensions"]

绘制小波系数：

Wolfram Language code: WaveletListPlot[dwt, PlotLayout -> "CommonXAxis"]

计算一个 DiscreteWaveletPacketTransform：

Wolfram Language code: data = Table[Sign[Cos[t^2]], {t, -2π, 2π, (4π/1023)}];
Wolfram Language code: dwpt = DiscreteWaveletPacketTransform[data, BiorthogonalSplineWavelet[4, 4], 2]

查看小波系数组成的树：

Wolfram Language code: dwpt["TreeView"]

获取小波系数的维度：

Wolfram Language code: dwpt["Dimensions"]

绘制小波系数：

Wolfram Language code: WaveletListPlot[dwpt, PlotLayout -> "CommonXAxis"]

计算一个 StationaryWaveletTransform：

Wolfram Language code: data = Table[Sign[Cos[t^2]], {t, -2π, 2π, (4π/1023)}];
Wolfram Language code: swt = StationaryWaveletTransform[data, BiorthogonalSplineWavelet[4, 4], 2];

查看小波系数组成的树：

Wolfram Language code: swt["TreeView"]

获取小波系数的维度：

Wolfram Language code: swt["Dimensions"]

绘制小波系数：

Wolfram Language code: WaveletListPlot[swt, PlotLayout -> "CommonXAxis"]

计算一个 StationaryWaveletPacketTransform：

Wolfram Language code: data = Table[Sign[Cos[t^2]], {t, -2π, 2π, (4π/1023)}];
Wolfram Language code: swpt = StationaryWaveletPacketTransform[data, BiorthogonalSplineWavelet[4, 4], 2];

查看小波系数组成的树：

Wolfram Language code: swpt["TreeView"]

获取小波系数的维度：

Wolfram Language code: swpt["Dimensions"]

绘制小波系数：

Wolfram Language code: WaveletListPlot[swpt, PlotLayout -> "CommonXAxis"]

计算一个 LiftingWaveletTransform：

Wolfram Language code: data = Table[Sign[Cos[t^2]], {t, -2π, 2π, (4π/1023)}];
Wolfram Language code: lwt = LiftingWaveletTransform[data, BiorthogonalSplineWavelet[4, 4], 2];

查看小波系数组成的树：

Wolfram Language code: lwt["TreeView"]

获取小波系数的维度：

Wolfram Language code: lwt["Dimensions"]

绘制小波系数：

Wolfram Language code: WaveletListPlot[lwt, PlotLayout -> "CommonXAxis"]

高维度  (2)

多变量尺度函数和小波函数是单变量函数的乘积：

Wolfram Language code: ϕ = WaveletPhi[BiorthogonalSplineWavelet[2, 6]]; ψ = WaveletPsi[BiorthogonalSplineWavelet[2, 6]];
Wolfram Language code: Plot3D[Evaluate[ϕ[x]ϕ[y]], {x, -6, 6}, {y, -6, 6}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ϕ[x]ψ[y]], {x, -6, 6}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x]ϕ[y]], {x, -3, 4}, {y, -6, 6}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x]ψ[y]], {x, -3, 4}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]

多变量对偶尺度函数和小波函数是单变量函数的乘积：

Wolfram Language code: Overscript[ϕ, ~] = Evaluate[WaveletPhi[BiorthogonalSplineWavelet[2, 6], #, "Dual"]]&; Overscript[ψ, ~] = Evaluate[WaveletPsi[BiorthogonalSplineWavelet[2, 6], #, "Dual"]]&;
Wolfram Language code: Plot3D[Evaluate[Overscript[ϕ, ~][x]Overscript[ϕ, ~][y]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All, ColorFunction -> "RustTones", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[Overscript[ϕ, ~][x]Overscript[ψ, ~][y]], {x, -1, 1}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "RustTones", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[Overscript[ψ, ~][x]Overscript[ϕ, ~][y]], {x, -3, 4}, {y, -1, 1}, PlotRange -> All, ColorFunction -> "RustTones", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[Overscript[ψ, ~][x]Overscript[ψ, ~][y]], {x, -3, 4}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "RustTones", Mesh -> None, Axes -> None]

属性和关系  (18)

BiorthogonalSplineWavelet[1,1] 等价于 HaarWavelet：

Wolfram Language code: WaveletFilterCoefficients[HaarWavelet[]] == WaveletFilterCoefficients[BiorthogonalSplineWavelet[1, 1]]
Wolfram Language code: WaveletFilterCoefficients[HaarWavelet[]] == WaveletFilterCoefficients[BiorthogonalSplineWavelet[1, 1], "DualLowpass"]

低通滤波器系数的和为1；：

Wolfram Language code: Total@WaveletFilterCoefficients[BiorthogonalSplineWavelet[4, 2]][[All, 2]]

高通滤波器系数的和为0；：

Wolfram Language code: Total@WaveletFilterCoefficients[BiorthogonalSplineWavelet[4, 2], "PrimalHighpass"][[All, 2]]

对偶低通滤波器系数的和为1；：

Wolfram Language code: Total@WaveletFilterCoefficients[BiorthogonalSplineWavelet[4, 2], "DualLowpass"][[All, 2]]

对偶高通滤波器系数的和为0；：

Wolfram Language code: Total@WaveletFilterCoefficients[BiorthogonalSplineWavelet[4, 2], "DualHighpass"][[All, 2]]

尺度函数的积分为1；：

Wolfram Language code: Integrate[WaveletPhi[BiorthogonalSplineWavelet[2, 2], x], {x, -∞, ∞}]

对偶尺度函数的积分为1；：

Wolfram Language code: Integrate[WaveletPhi[BiorthogonalSplineWavelet[2, 2], x, "Dual"], {x, -∞, ∞}]

小波函数的积分为0；：

Wolfram Language code: Integrate[WaveletPsi[BiorthogonalSplineWavelet[2, 2], x], {x, -∞, ∞}]

对偶小波函数的积分为0；：

Wolfram Language code: Integrate[WaveletPsi[BiorthogonalSplineWavelet[2, 2], x, "Dual"], {x, -∞, ∞}]

尺度函数 具有紧支集 {n1,n2}：

Wolfram Language code: ϕ = WaveletPhi[BiorthogonalSplineWavelet[3, 3], x]
Wolfram Language code: {n1, n2} = {-3, 4};

对偶尺度函数 具有紧支集 {nd1,nd2}：

Wolfram Language code: Overscript[ϕ, ~] = WaveletPhi[BiorthogonalSplineWavelet[3, 3], x, "Dual"]
Wolfram Language code: {nd1, nd2} = {-1, 2};

相应的小波函数 具有紧支集 ({n1-nd2+1)/2,(n2-nd1+1)/2}:

Wolfram Language code: ψ = WaveletPsi[BiorthogonalSplineWavelet[3, 3], x]
Wolfram Language code: {(n1 - nd2 + 1/2), (n2 - nd1 + 1/2)}

对偶小波函数 具有紧支集 ({nd1-n2+1)/2,(nd2-n1+1)/2}：

Wolfram Language code: Overscript[ψ, ~] = WaveletPsi[BiorthogonalSplineWavelet[3, 3], x, "Dual"]
Wolfram Language code: {(nd1 - n2 + 1/2), (nd2 - n1 + 1/2)}

满足递归方程 ：

Wolfram Language code: ϕ = WaveletPhi[BiorthogonalSplineWavelet[1, 3]];
Wolfram Language code: a = WaveletFilterCoefficients[BiorthogonalSplineWavelet[1, 3], "PrimalLowpass"];

绘制分量以及递归和：

Wolfram Language code: scalet[x_, ϕ_, a_] := 2Table[a[[i, 2]]ϕ[2x - a[[i, 1]]], {i, Length[a]}]
Wolfram Language code: {Plot[Evaluate@scalet[x, ϕ, a], {x, -3, 4}, PlotRange -> All], Plot[Total@scalet[x, ϕ, a], {x, -3, 4}, PlotRange -> All]}

满足递归方程 ：

Wolfram Language code: ϕ = WaveletPhi[BiorthogonalSplineWavelet[1, 3]];
Wolfram Language code: b = WaveletFilterCoefficients[BiorthogonalSplineWavelet[1, 3], "PrimalHighpass"];

绘制分量以及递归和：

Wolfram Language code: wavelet[x_, ϕ_, b_] := 2Table[b[[i, 2]]ϕ[2x - b[[i, 1]]], {i, Length[b]}]
Wolfram Language code: {Plot[Evaluate@wavelet[x, ϕ, b], {x, -1, 2}, PlotRange -> All], Plot[Total@wavelet[x, ϕ, b], {x, -1, 2}, PlotRange -> All]}

满足递归方程 ：

Wolfram Language code: Overscript[ϕ, ~] = (Evaluate[WaveletPhi[BiorthogonalSplineWavelet[3, 5], #, "Dual"]]&);
Wolfram Language code: Overscript[a, ~] = WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 5], "DualLowpass"];

绘制分量以及递归和：

Wolfram Language code: scalet[x_, ϕ_, a_] := 2Table[a[[i, 2]]ϕ[2x - a[[i, 1]]], {i, Length[a]}]
Wolfram Language code: {Plot[Evaluate@scalet[x, Overscript[ϕ, ~], Overscript[a, ~]], {x, -1, 2}, PlotRange -> All], Plot[Total@scalet[x, Overscript[ϕ, ~], Overscript[a, ~]], {x, -1, 2}, PlotRange -> All]}

满足递归方程 ：

Wolfram Language code: Overscript[ϕ, ~] = (Evaluate[WaveletPhi[BiorthogonalSplineWavelet[3, 5], #, "Dual"]]&);
Wolfram Language code: Overscript[b, ~] = WaveletFilterCoefficients[BiorthogonalSplineWavelet[3, 5], "DualHighpass"];

绘制分量以及递归和：

Wolfram Language code: wavelet[x_, ϕ_, b_] := 2Table[b[[i, 2]]ϕ[2x - b[[i, 1]]], {i, Length[b]}]
Wolfram Language code: {Plot[Evaluate@wavelet[x, Overscript[ϕ, ~], Overscript[b, ~]], {x, -3, 4}, PlotRange -> All], Plot[Total@wavelet[x, Overscript[ϕ, ~], Overscript[b, ~]], {x, -3, 4}, PlotRange -> All]}

的频率响应由 给出：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-Ia[[i, 1]]ω], {i, Length[a]}]]

该滤波器是一个低通滤波器：

Wolfram Language code: Plot[Abs[h[BiorthogonalSplineWavelet[2, 2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]

的傅立叶变换由 给出：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-Ia[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: fh[wav_, ω_, j_] := Abs[Product[h[wav, (ω/2^i)], {i, j}]]
Wolfram Language code: Plot[fh[BiorthogonalSplineWavelet[2, 2], ω, 10], {ω, -10Pi, 10Pi}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[ϕ, ^ ][ω]]}]

的频率响应由 给出：

Wolfram Language code: Overscript[h, ~][wav_, ω_] := With[{a = WaveletFilterCoefficients[wav, "DualLowpass"]}, Sum[a[[i, 2]]Exp[-Ia[[i, 1]]ω], {i, Length[a]}]]

该滤波器是一个对偶低通滤波器：

Wolfram Language code: Plot[Abs[Overscript[h, ~][BiorthogonalSplineWavelet[2, 2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[Overscript[H, ~][ω]]}]

的傅立叶变换由 给出：

Wolfram Language code: Overscript[h, ~][wav_, ω_] := With[{a = WaveletFilterCoefficients[wav, "DualLowpass"]}, Sum[a[[i, 2]]Exp[-Ia[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: fh[wav_, ω_, j_] := Abs[Product[Overscript[h, ~][wav, (ω/2^i)], {i, j}]]
Wolfram Language code: Plot[fh[BiorthogonalSplineWavelet[2, 2], ω, 10], {ω, -10Pi, 10Pi}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[Overscript[ϕ, ~], ^ ][ω]]}]

的频率响应由 给出：

Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-Ib[[i, 1]]ω], {i, Length[b]}] ]

该滤波器是一个低通滤波器：

Wolfram Language code: Plot[Abs[g[BiorthogonalSplineWavelet[2, 2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]

的傅立叶变换由 给出：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-Ib[[i, 1]]ω], {i, Length[b]}]]
Wolfram Language code: fg[wav_, ω_, j_] := Abs[g[wav, (ω/2)]Product[h[wav, (ω/2^i)], {i, 2, j}]]
Wolfram Language code: Plot[fg[BiorthogonalSplineWavelet[2, 2], ω, 10], {ω, -10Pi, 10Pi}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[ψ, ^ ][ω]]}]

的频率响应由 给出：

Wolfram Language code: Overscript[g, ~][wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "DualHighpass"]}, Sum[b[[i, 2]]Exp[-Ib[[i, 1]]ω], {i, Length[b]}]]

该滤波器是一个低通滤波器：

Wolfram Language code: Plot[Abs[Overscript[g, ~][BiorthogonalSplineWavelet[2, 2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[Overscript[G, ~][ω]]}]

的傅立叶变换由 给出：

Wolfram Language code: Overscript[h, ~][wav_, ω_] := With[{a = WaveletFilterCoefficients[wav, "DualLowpass"]}, Sum[a[[i, 2]]Exp[-Ia[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: Overscript[g, ~][wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "DualHighpass"]}, Sum[b[[i, 2]]Exp[-Ib[[i, 1]]ω], {i, Length[b]}]]
Wolfram Language code: Overscript[fg, ~][wav_, ω_, j_] := Abs[Overscript[g, ~][wav, (ω/2)]Product[Overscript[h, ~][wav, (ω/2^i)], {i, 2, j}]]
Wolfram Language code: Plot[Overscript[fg, ~][BiorthogonalSplineWavelet[2, 2], ω, 10], {ω, -10Pi, 10Pi}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[Overscript[ψ, ~], ^ ][ω]]}]

巧妙范例  (2)

绘制尺度函数的平移和伸缩：

Wolfram Language code: ϕ[x_, j_, k_] := 2^j / 2WaveletPhi[BiorthogonalSplineWavelet[1, 3], 2^jx - k]
Wolfram Language code: Plot[Evaluate@Table[ϕ[x, j, 0], {j, 0, 4}], {x, -1, 2}, Filling -> Axis, PlotRange -> All, Axes -> {True, False}]
Wolfram Language code: Plot[Evaluate@Table[ϕ[x, 2, k], {k, 0, 2^2 - 1}], {x, -0.5, 2}, Filling -> Axis, PlotRange -> All]

绘制小波函数的平移和伸缩：

Wolfram Language code: ψ[x_, j_, k_] := 2^j / 2WaveletPsi[BiorthogonalSplineWavelet[1, 3], 2^jx - k]
Wolfram Language code: Plot[Evaluate@Table[ψ[x, j, 0], {j, 0, 4}], {x, -0.5, 1}, Filling -> Axis, PlotRange -> All, Axes -> {True, False}]
Wolfram Language code: Plot[Evaluate@Table[ψ[x, 2, k], {k, 0, 2^2 - 1}], {x, -0.5, 1.5}, Filling -> Axis, PlotRange -> All]
Wolfram Research (2010)，BiorthogonalSplineWavelet，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html.

文本

Wolfram Research (2010)，BiorthogonalSplineWavelet，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html.

CMS

Wolfram 语言. 2010. "BiorthogonalSplineWavelet." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html.

APA

Wolfram 语言. (2010). BiorthogonalSplineWavelet. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html 年

BibTeX

@misc{reference.wolfram_2026_biorthogonalsplinewavelet, author="Wolfram Research", title="{BiorthogonalSplineWavelet}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html}", note=[Accessed: 19-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_biorthogonalsplinewavelet, organization={Wolfram Research}, title={BiorthogonalSplineWavelet}, year={2010}, url={https://reference.wolfram.com/language/ref/BiorthogonalSplineWavelet.html}, note=[Accessed: 19-August-2026]}