WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Blend[{col1,col2},x]

色 col1を，色 col2を の割合で合成して得られる色を与える．

Blend[{col1,col2,col3,…},x]

x が0から1に変化するのにつれて，色 coliを線形に補間する．

Blend[{{x1,col1},{x2,col2},…},x]

x=xiのとき，補間して色 coliを与える．

Blend[{col1,col2,…},{u1,u2,…}]

すべての coliを，色 coliの割合を uiとして合成する．

Blend[{image1,image2,…},…]

2Dあるいは3Dの画像 imageiの画素値を合成する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
色  
画像  
アプリケーション  
特性と関係  
考えられる問題  
インタラクティブな例題  
おもしろい例題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

Blend

Blend[{col1,col2},x]

色 col1を，色 col2を の割合で合成して得られる色を与える．

Blend[{col1,col2,col3,…},x]

x が0から1に変化するのにつれて，色 coliを線形に補間する．

Blend[{{x1,col1},{x2,col2},…},x]

x=xiのとき，補間して色 coliを与える．

Blend[{col1,col2,…},{u1,u2,…}]

すべての coliを，色 coliの割合を uiとして合成する．

Blend[{image1,image2,…},…]

2Dあるいは3Dの画像 imageiの画素値を合成する．

詳細

  • Blendは，色付きの光源あるいは発色表示に適する加法混色を実装する．
  • Blend[{col1,…,coln},{u1,…,un}]では，ui は合計が1になるように正規化される． »
  • Blend[{col1,col2,…}]は，すべての coliを同じ割合で合成する．
  • Blend[{image1,image2},x]では，image1 と image2 の次元が異なる場合は，次元の線形補間が使われる．
  • Blend[{image,col},x]は，image のすべての画素を色 col と合成する．
  • Blend[{image1,col1,…,coln,image2},x]では，coli は，次元が image1の次元と image2の次元の線形補間による画像であると解釈される．

例題

すべて開く すべて閉じる

例  (4)

2つの色を割合に応じて合成する：

Wolfram Language code: Blend[{Red, Blue}, 1 / 3]

赤から青への混色の配列を生成する：

Wolfram Language code: Graphics[Table[{Blend[{Red, Blue}, x], Disk[{8x, 0}]}, {x, 0, 1, 1 / 8}]]

高さを黄色から紫の混合で表す：

Wolfram Language code: Plot3D[Sin[x + y ^ 2], {x, -3, 3}, {y, -2, 2}, ColorFunction -> (Blend[{Yellow, Purple}, #3]&)]

画像の画素と色を合成する：

Wolfram Language code: Blend[{[image], Magenta}]

スコープ  (12)

色  (6)

2つの色を均等に平均化する：

Wolfram Language code: Blend[{Red, Green}]

グラフィックスに彩色する：

Wolfram Language code: Graphics[{Blend[{Red, Green}], Disk[]}]

2つの色の間の線形補間：

Wolfram Language code: Graphics[Table[{Blend[{Red, Green}, x], Disk[{8x, 0}]}, {x, 0, 1, 1 / 8}]]

色と不透明度の線形補間：

Wolfram Language code: Blend[{RGBColor[1, 0, 0, 1], RGBColor[0, 1, 0, 0]}]
Wolfram Language code: Graphics[Table[{Blend[{RGBColor[1, 0, 0, 1], RGBColor[0, 1, 0, 0]}, x], Disk[{8x, 0}]}, {x, 0, 1, 1 / 8}]]

複数の色の均等な線形補間：

Wolfram Language code: Graphics[Table[{Blend[{Red, Yellow, Green}, x], Disk[{8x, 0}]}, {x, 0, 1, 1 / 8}]]

特定の値における色の間の線形補間：

Wolfram Language code: Graphics[Table[{Blend[{{1, Red}, {3, Yellow}, {10, Green}}, x], Disk[{x, 0}]}, {x, 1, 10}]]

等しい重みで色を合成する：

Wolfram Language code: Blend[{RGBColor[1, 0, 0], RGBColor[0, 1, 0], RGBColor[0, 0, 1]}]

指定の重みで色を合成する：

Wolfram Language code: Blend[{RGBColor[1, 0, 0], RGBColor[0, 1, 0], RGBColor[0, 0, 1]}, {1 / 8, 1 / 2, 3 / 8}]
Wolfram Language code: ParametricPlot[{x, y}, {x, 0, 1}, {y, 0, 1 - x}, ColorFunction -> Function[{x, y}, Blend[{Red, Green, Blue}, {x, y, 1 - x - y}]]]

画像  (6)

画像の画素と色の間の線形補間：

Wolfram Language code: Blend[{[image], Yellow}]

特定の値における画像と色の線形補間：

Wolfram Language code: Blend[{[image], Yellow}, .2]

2つの画像の線形補間：

Wolfram Language code: Blend[{[image], [image]}]

次元が異なる2つの画像の線形補間：

Wolfram Language code: Blend[{[image], [image]}]

画像とそのアルファチャンネルを合成する：

Wolfram Language code: Blend[{[image], [image]}]

3D画像の混色：

Wolfram Language code: Blend[{\!\(\*Graphics3DBox[«8»]\), \!\(\*Graphics3DBox[«8»]\)}]

アプリケーション  (2)

Blendを使って基調色からColorFunctionを構成する：

Wolfram Language code: Plot[1 / x Sin[x ^ 2], {x, 0, 6}, ColorFunction -> (Blend[{LightBlue, Blue}, #2]&), PlotStyle -> Thick]
Wolfram Language code: Plot3D[ x y / (x ^ 2 + y ^ 2), {x, -2, 2}, {y, -2, 2}, RegionFunction -> Function[{x, y, z}, x^2 + y^2 > 0.1], ColorFunction -> (Blend[{Lighter[Yellow, .8], Orange, Red}, #3]&), Mesh -> None]
Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 4 + z ^ 5 == 0, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, ColorFunction -> (Blend[{Cyan, Magenta, Yellow}, {#1, #2, #3}]&), Mesh -> None, ContourStyle -> Opacity[0.7]]

露出が異なる複数の画像を組み合せて1つの画像にする：

Wolfram Language code: Blend[{[image], [image], [image], [image], [image]}]

特性と関係  (7)

重みは，総和が1になるように常に正規化される：

Wolfram Language code: Blend[{Red, Green, Blue}, {1, 2, 3}]
Wolfram Language code: %//InputForm

位置の値は常に整理される：

Wolfram Language code: Graphics[Raster[{Range[100] / 100}, ColorFunction -> (Blend[{{0, Red}, {1, Green}, {2 / 3, Yellow}, {1 / 3, Blue}}, #]&)], AspectRatio -> .3]

色が同じ色空間を使って指定された場合，その空間は補間に用いられる：

Wolfram Language code: Column[Labeled[ArrayPlot[{Table[Blend[ColorConvert[{Blue, Red}, #], n], {n, 0, 1, .01}]}, AspectRatio -> .25], #]& /@ {RGBColor, Hue, XYZColor, LCHColor}]

色が異なる色空間で指定された場合，補間はRGB空間で行われる：

Wolfram Language code: ArrayPlot[{Table[Blend[{Red, Hue[2 / 3]}, n], {n, 0, 1, .01}]}, AspectRatio -> .25]

LighterはBlendの特殊ケースである：

Wolfram Language code: {Lighter[Blue, 1 / 3], Blend[{Blue, White}, 1 / 3]}

DarkerはBlendの特殊ケースである：

Wolfram Language code: {Darker[Blue, 1 / 3], Blend[{Blue, Black}, 1 / 3]}

ColorDataは"Gradients"と呼ばれる多くの予め定義されたBlendされた（混合）色を含んでいる：

Wolfram Language code: ColorData["Gradients"]//Short
Wolfram Language code: ColorData["TemperatureMap", "Image"]
Wolfram Language code: DensityPlot[x, {x, 0, 1}, {y, 0, 1}, ColorFunction -> (ColorData["SunsetColors"][#]&)]

階調度はその名前のみで指定される：

Wolfram Language code: DensityPlot[x, {x, 0, 1}, {y, 0, 1}, ColorFunction -> "SunsetColors"]

PolygonはVertexColorsを同じ重みで合成することをサポートする：

Wolfram Language code: Graphics[Polygon[{{0, 0}, {1, 0}, {0, 1}}, VertexColors -> {Blue, Red, Green}]]
Wolfram Language code: ParametricPlot[{x, y}, {x, 0, 1}, {y, 0, 1 - x}, ColorFunction -> Function[{x, y}, Blend[{Red, Green, Blue}, {x, y, 1 - x - y}]], Frame -> False, Axes -> False]

考えられる問題  (2)

0, 1範囲外の値は切り取られる：

Wolfram Language code: Graphics[Table[{Blend[{Red, Green}, i], EdgeForm[Gray], Rectangle[{4i, 0}]}, {i, 0 - 1 / 4, 1 + 1 / 4, 1 / 4}]]

プロット関数では，ColorFunctionScalingを使って変数の大域的スケーリングを制御する：

Wolfram Language code: Table[DensityPlot[x, {x, -2, 3}, {y, 0, 1}, FrameTicks -> None, ColorFunction -> (Blend[{Red, Green}, #]&), ColorFunctionScaling -> t], {t, {False, True}}]

1つの位置に異なる色を与えることで不連続性を生成する：

Wolfram Language code: Graphics[Raster[{Range[100] / 100}, ColorFunction -> (Blend[{{0, Red}, {1 / 2, Yellow}, {1 / 2, Green}, {1, Blue}}, #]&)], AspectRatio -> .3]

インタラクティブな例題  (4)

2つの画像を連続的に合成する：

Wolfram Language code: Manipulate[Blend[{[image], [image]}, a], {a, 0, 1}]

次元が異なる2つの画像の線形補間：

Wolfram Language code: Manipulate[Blend[{[image], [image]}, a], {a, 0, 1}]

各2画像間の背景を白くしながら複数の画像を合成する：

Wolfram Language code: Manipulate[Blend[Riffle[{[image], [image], [image]}, RGBColor[1, 1, 1]], a], {a, 0, 1}]

複数の色の線形補間のインタラクティブな表現：

Wolfram Language code: Manipulate[Show[{ParametricPlot3D[List@@f[x], {x, 0, 1}, AxesLabel -> (Style[#, ToExpression@#]& /@ {"Red", "Green", "Blue"}), ColorFunction -> (RGBColor[#1, #2, #3]&), PlotStyle -> AbsoluteThickness[5]], Graphics3D[{f[u], AbsolutePointSize[20], Point[List@@f[u]]}]}], {u, 0, 1, Appearance -> "Labeled"}, Initialization :> (f[x_ ? NumericQ] := Blend[{Red, Blue, Yellow, Green}, x])]

おもしろい例題  (2)

Blendをプロットとともに使って合成した質感を生成する：

Wolfram Language code: ArrayPlot[Table[Evaluate[Sum[Sin[RandomReal[5, 2].{x, y}], {10}]], {x, 0, 10, .05}, {y, 0, 10, .05}], ColorFunction -> (Blend[{Black, Red, Yellow, Black}, #]&)]
Wolfram Language code: ReliefPlot[Table[Evaluate[Sum[Sin[RandomReal[5, 2].{x, y}], {10}]], {x, 0, 10, .05}, {y, 0, 10, .05}], ColorFunction -> (Blend[{Darker[Green, .8], Lighter[Brown, .2], White}, #]&)]

星の擬似色：

Wolfram Language code: Graphics3D[Table[{Specularity[White, 100], Blend[{Red, Orange, Lighter[Gray, 1 / 3], Lighter[Blue, 2 / 3]}, i / 15], Sphere[{i Sin[2Pi i / 15], i Cos[2Pi i / 15], i}, i / 6]}, {i, 15}], Lighting -> "Neutral", ViewPoint -> Top, Boxed -> False, Background -> GrayLevel[.15]]
Wolfram Research (2007), Blend, Wolfram言語関数， https://reference.wolfram.com/language/ref/Blend.html （2014年に更新）.

テキスト

Wolfram Research (2007), Blend, Wolfram言語関数， https://reference.wolfram.com/language/ref/Blend.html （2014年に更新）.

CMS

Wolfram Language. 2007. "Blend." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/Blend.html.

APA

Wolfram Language. (2007). Blend. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Blend.html

BibTeX

@misc{reference.wolfram_2026_blend, author="Wolfram Research", title="{Blend}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Blend.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_blend, organization={Wolfram Research}, title={Blend}, year={2014}, url={https://reference.wolfram.com/language/ref/Blend.html}, note=[Accessed: 17-August-2026]}