WOLFRAM

Wolfram 语言与系统参考资料中心

Blend[{col1,col2},x]

给出混合的颜色，其中 col1 颜色占分数比例为 ，col2 颜色占分数比例为 .

Blend[{col1,col2,col3,…},x]

在颜色 coli 间应用线性插值，其中 x 从 0 到 1 变化.

Blend[{{x1,col1},{x2,col2},…},x]

当 x=xi 时，对 coli 应用插值.

Blend[{col1,col2,…},{u1,u2,…}]

coli 颜色使用分数比例 ui，混合所有 coli.

Blend[{image1,image2,…},…]

混合二维或三维图像 imagei 的像素值.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
颜色  
图像  
应用  
属性和关系  
可能存在的问题  
互动范例  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

Blend

Blend[{col1,col2},x]

给出混合的颜色，其中 col1 颜色占分数比例为 ，col2 颜色占分数比例为 .

Blend[{col1,col2,col3,…},x]

在颜色 coli 间应用线性插值，其中 x 从 0 到 1 变化.

Blend[{{x1,col1},{x2,col2},…},x]

当 x=xi 时，对 coli 应用插值.

Blend[{col1,col2,…},{u1,u2,…}]

coli 颜色使用分数比例 ui，混合所有 coli.

Blend[{image1,image2,…},…]

混合二维或三维图像 imagei 的像素值.

更多信息

  • Blend 进行迭加颜色混合，作为相适宜的彩色光源或发光显示.
  • 在 Blend[{col1,…,coln},{u1,…,un}] 中，ui 被标准化，使得和为1. »
  • Blend[{col1,col2,…}] 混合所有 coli 的相等分数.
  • 在 Blend[{image1,image2},x] 中，如果 image1 和 image2 为不同维度，则使用维度的线性内插值.
  • Blend[{image,col},x] 将 image 的每个像素与颜色 col 混合.
  • 在 Blend[{image1,col1,…,coln,image2},x] 中，coli 被解释为一个图像，其尺寸是取自 image1 和image2 维度之间的线性内插值.

范例

打开所有单元 关闭所有单元

基本范例  (4)

按比例混合两种颜色：

Wolfram Language code: Blend[{Red, Blue}, 1 / 3]

生成从红到蓝的混合颜色的阵列：

Wolfram Language code: Graphics[Table[{Blend[{Red, Blue}, x], Disk[{8x, 0}]}, {x, 0, 1, 1 / 8}]]

从黄色到紫色混合，表示高度变化：

Wolfram Language code: Plot3D[Sin[x + y ^ 2], {x, -3, 3}, {y, -2, 2}, ColorFunction -> (Blend[{Yellow, Purple}, #3]&)]

将图像的像素与颜色混合：

Wolfram Language code: Blend[{[image], Magenta}]

范围  (12)

颜色  (6)

两种颜色等分：

Wolfram Language code: Blend[{Red, Green}]

为图形着色：

Wolfram Language code: Graphics[{Blend[{Red, Green}], Disk[]}]

两种颜色的线性内插值：

Wolfram Language code: Graphics[Table[{Blend[{Red, Green}, x], Disk[{8x, 0}]}, {x, 0, 1, 1 / 8}]]

使用颜色和不透明度的线性插值：

Wolfram Language code: Blend[{RGBColor[1, 0, 0, 1], RGBColor[0, 1, 0, 0]}]
Wolfram Language code: Graphics[Table[{Blend[{RGBColor[1, 0, 0, 1], RGBColor[0, 1, 0, 0]}, x], Disk[{8x, 0}]}, {x, 0, 1, 1 / 8}]]

在多种一致颜色间线性插值：

Wolfram Language code: Graphics[Table[{Blend[{Red, Yellow, Green}, x], Disk[{8x, 0}]}, {x, 0, 1, 1 / 8}]]

在指定值处对颜色进行线性插值：

Wolfram Language code: Graphics[Table[{Blend[{{1, Red}, {3, Yellow}, {10, Green}}, x], Disk[{x, 0}]}, {x, 1, 10}]]

等比例的混合：

Wolfram Language code: Blend[{RGBColor[1, 0, 0], RGBColor[0, 1, 0], RGBColor[0, 0, 1]}]

指定比例的混合：

Wolfram Language code: Blend[{RGBColor[1, 0, 0], RGBColor[0, 1, 0], RGBColor[0, 0, 1]}, {1 / 8, 1 / 2, 3 / 8}]
Wolfram Language code: ParametricPlot[{x, y}, {x, 0, 1}, {y, 0, 1 - x}, ColorFunction -> Function[{x, y}, Blend[{Red, Green, Blue}, {x, y, 1 - x - y}]]]

图像  (6)

图像像素与一种颜色的线性插值：

Wolfram Language code: Blend[{[image], Yellow}]

图像和颜色在一个特定值处的线性插值：

Wolfram Language code: Blend[{[image], Yellow}, .2]

两个图像的线性插值：

Wolfram Language code: Blend[{[image], [image]}]

两幅大小不同的图像的线性插值：

Wolfram Language code: Blend[{[image], [image]}]

混合图像和它们的阿尔法通道：

Wolfram Language code: Blend[{[image], [image]}]

三维图像的混合：

Wolfram Language code: Blend[{\!\(\*Graphics3DBox[«8»]\), \!\(\*Graphics3DBox[«8»]\)}]

应用  (2)

用 Blend，从基本色中构造一个 ColorFunction：

Wolfram Language code: Plot[1 / x Sin[x ^ 2], {x, 0, 6}, ColorFunction -> (Blend[{LightBlue, Blue}, #2]&), PlotStyle -> Thick]
Wolfram Language code: Plot3D[ x y / (x ^ 2 + y ^ 2), {x, -2, 2}, {y, -2, 2}, RegionFunction -> Function[{x, y, z}, x^2 + y^2 > 0.1], ColorFunction -> (Blend[{Lighter[Yellow, .8], Orange, Red}, #3]&), Mesh -> None]
Wolfram Language code: ContourPlot3D[x ^ 2 + y ^ 2 - z ^ 4 + z ^ 5 == 0, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, ColorFunction -> (Blend[{Cyan, Magenta, Yellow}, {#1, #2, #3}]&), Mesh -> None, ContourStyle -> Opacity[0.7]]

将多幅曝光度不同的图像合并为一幅图像：

Wolfram Language code: Blend[{[image], [image], [image], [image], [image]}]

属性和关系  (7)

权重总会正规化，以使比例总和为1：

Wolfram Language code: Blend[{Red, Green, Blue}, {1, 2, 3}]
Wolfram Language code: %//InputForm

坐标值总是排序：

Wolfram Language code: Graphics[Raster[{Range[100] / 100}, ColorFunction -> (Blend[{{0, Red}, {1, Green}, {2 / 3, Yellow}, {1 / 3, Blue}}, #]&)], AspectRatio -> .3]

当颜色指定使用相同的色彩空间时，则用该空间进行插值：

Wolfram Language code: Column[Labeled[ArrayPlot[{Table[Blend[ColorConvert[{Blue, Red}, #], n], {n, 0, 1, .01}]}, AspectRatio -> .25], #]& /@ {RGBColor, Hue, XYZColor, LCHColor}]

当颜色指定使用不同颜色空间时，则在 RGB 空间应用插值：

Wolfram Language code: ArrayPlot[{Table[Blend[{Red, Hue[2 / 3]}, n], {n, 0, 1, .01}]}, AspectRatio -> .25]

Lighter 是 Blend 的一个特例：

Wolfram Language code: {Lighter[Blue, 1 / 3], Blend[{Blue, White}, 1 / 3]}

Darker 是 Blend 的一个特例：

Wolfram Language code: {Darker[Blue, 1 / 3], Blend[{Blue, Black}, 1 / 3]}

ColorData 包含大量称为 "Gradients" 的预定义 Blend 色.

Wolfram Language code: ColorData["Gradients"]//Short
Wolfram Language code: ColorData["TemperatureMap", "Image"]
Wolfram Language code: DensityPlot[x, {x, 0, 1}, {y, 0, 1}, ColorFunction -> (ColorData["SunsetColors"][#]&)]

梯度只能通过它们的名称调用：

Wolfram Language code: DensityPlot[x, {x, 0, 1}, {y, 0, 1}, ColorFunction -> "SunsetColors"]

Polygon 支持等比例的 VertexColors 混合：

Wolfram Language code: Graphics[Polygon[{{0, 0}, {1, 0}, {0, 1}}, VertexColors -> {Blue, Red, Green}]]
Wolfram Language code: ParametricPlot[{x, y}, {x, 0, 1}, {y, 0, 1 - x}, ColorFunction -> Function[{x, y}, Blend[{Red, Green, Blue}, {x, y, 1 - x - y}]], Frame -> False, Axes -> False]

可能存在的问题  (2)

在 0，1 范围外的值将被舍去：

Wolfram Language code: Graphics[Table[{Blend[{Red, Green}, i], EdgeForm[Gray], Rectangle[{4i, 0}]}, {i, 0 - 1 / 4, 1 + 1 / 4, 1 / 4}]]

在绘图函数中，用 ColorFunctionScaling 控制变量的整体比例：

Wolfram Language code: Table[DensityPlot[x, {x, -2, 3}, {y, 0, 1}, FrameTicks -> None, ColorFunction -> (Blend[{Red, Green}, #]&), ColorFunctionScaling -> t], {t, {False, True}}]

在单个位置上设定不同的颜色，会产生不连贯：

Wolfram Language code: Graphics[Raster[{Range[100] / 100}, ColorFunction -> (Blend[{{0, Red}, {1 / 2, Yellow}, {1 / 2, Green}, {1, Blue}}, #]&)], AspectRatio -> .3]

互动范例  (4)

两个图像之间连续混合：

Wolfram Language code: Manipulate[Blend[{[image], [image]}, a], {a, 0, 1}]

具有不同尺寸的两个图像的线性插值：

Wolfram Language code: Manipulate[Blend[{[image], [image]}, a], {a, 0, 1}]

多个图像的混合，同时要通过每两个图像之间的白色背景：

Wolfram Language code: Manipulate[Blend[Riffle[{[image], [image], [image]}, RGBColor[1, 1, 1]], a], {a, 0, 1}]

多种颜色的线性插值的互动表示：

Wolfram Language code: Manipulate[Show[{ParametricPlot3D[List@@f[x], {x, 0, 1}, AxesLabel -> (Style[#, ToExpression@#]& /@ {"Red", "Green", "Blue"}), ColorFunction -> (RGBColor[#1, #2, #3]&), PlotStyle -> AbsoluteThickness[5]], Graphics3D[{f[u], AbsolutePointSize[20], Point[List@@f[u]]}]}], {u, 0, 1, Appearance -> "Labeled"}, Initialization :> (f[x_ ? NumericQ] := Blend[{Red, Blue, Yellow, Green}, x])]

巧妙范例  (2)

在图中使用 Blend 得到复合纹理：

Wolfram Language code: ArrayPlot[Table[Evaluate[Sum[Sin[RandomReal[5, 2].{x, y}], {10}]], {x, 0, 10, .05}, {y, 0, 10, .05}], ColorFunction -> (Blend[{Black, Red, Yellow, Black}, #]&)]
Wolfram Language code: ReliefPlot[Table[Evaluate[Sum[Sin[RandomReal[5, 2].{x, y}], {10}]], {x, 0, 10, .05}, {y, 0, 10, .05}], ColorFunction -> (Blend[{Darker[Green, .8], Lighter[Brown, .2], White}, #]&)]

模拟星星的颜色：

Wolfram Language code: Graphics3D[Table[{Specularity[White, 100], Blend[{Red, Orange, Lighter[Gray, 1 / 3], Lighter[Blue, 2 / 3]}, i / 15], Sphere[{i Sin[2Pi i / 15], i Cos[2Pi i / 15], i}, i / 6]}, {i, 15}], Lighting -> "Neutral", ViewPoint -> Top, Boxed -> False, Background -> GrayLevel[.15]]
Wolfram Research (2007)，Blend，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Blend.html （更新于 2014 年）.

文本

Wolfram Research (2007)，Blend，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Blend.html （更新于 2014 年）.

CMS

Wolfram 语言. 2007. "Blend." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/Blend.html.

APA

Wolfram 语言. (2007). Blend. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Blend.html 年

BibTeX

@misc{reference.wolfram_2026_blend, author="Wolfram Research", title="{Blend}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Blend.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_blend, organization={Wolfram Research}, title={Blend}, year={2014}, url={https://reference.wolfram.com/language/ref/Blend.html}, note=[Accessed: 15-September-2026]}