WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BlomqvistBeta[v1,v2]

ベクトル v1と v2についてBlomqvistの中間相関係数 β を与える．

BlomqvistBeta[m]

行列 m についてBlomqvistの中間相関係数 β を与える．

BlomqvistBeta[m1,m2]

行列 m1と m2についてBlomqvistの中間相関係数 β を与える．

BlomqvistBeta[dist]

多変量記号分布 dist について中間相関係数行列を与える．

BlomqvistBeta[dist,i,j]

多変量記号分布 dist の第(i,j)中間相関係数を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
データ  
分布と過程  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BlomqvistBeta

BlomqvistBeta[v1,v2]

ベクトル v1と v2についてBlomqvistの中間相関係数 β を与える．

BlomqvistBeta[m]

行列 m についてBlomqvistの中間相関係数 β を与える．

BlomqvistBeta[m1,m2]

行列 m1と m2についてBlomqvistの中間相関係数 β を与える．

BlomqvistBeta[dist]

多変量記号分布 dist について中間相関係数行列を与える．

BlomqvistBeta[dist,i,j]

多変量記号分布 dist の第(i,j)中間相関係数を与える．

詳細

  • BlomqvistBeta[v1,v2]は，v1と v2の間のBlomqvistの中間相関係数 β を与える．
  • ベクトル x とベクトル y との間のBlomqvistの中間相関係数 β はCorrelation[Sign[x-μx],Sign[y-μy]]で与えられる．ただし，μxと μyはそれぞれ x と y の中央値である．
  • 引数 v1と v2 は，同じ長さの任意の実ベクトルでよい．
  • 列数が の行列 m について，BlomqvistBeta[m]は m の列間にある β の × 行列である．
  • × 行列 m1と × 行列 m2について，BlomqvistBeta[m1,m2]は m1の列と m2の列の間にある β の × 行列である．
  • BlomqvistBeta[dist,i,j]は Probability[(x-μx)(y-μy)>0,{x,y}disti,j]-Probability[(x-μx)(y-μy)<0,{x,y}disti,j]である．この場合，disti,jは dist の番目の周辺分布である．
  • BlomqvistBetaは，離散分布については，あるいはタイがある場合は不明確である．
  • BlomqvistBeta[dist]は番目の項目がBlomqvistBeta[dist,i,j]で与えられる行列 β を与える．

例題

すべて開く すべて閉じる

例  (4)

2つのベクトルについてのBlomqvistの β：

Wolfram Language code: v1 = {3, -4, 1, 4, 22, 17, -2, 2, 13, -11}; v2 = {-20, -24, 0, 4, 24, 36, -12, -12, 56, -14};
Wolfram Language code: BlomqvistBeta[v1, v2]

行列についてのBlomqvistの β：

Wolfram Language code: m = RandomVariate[BinormalDistribution[.6], 10^3];
Wolfram Language code: BlomqvistBeta[m]//MatrixForm

2つの行列についてのBlomqvistの β：

Wolfram Language code: m1 = RandomReal[1, {10^3, 4}];
Wolfram Language code: m2 = RandomReal[1, {10^3, 3}];
Wolfram Language code: BlomqvistBeta[m1, m2]//MatrixForm

二変量分布についてBlomqvistの β 行列を計算する：

Wolfram Language code: 𝒟 = BinormalDistribution[.5];
Wolfram Language code: BlomqvistBeta[𝒟]//MatrixForm

シミュレーションによる値と比較する：

Wolfram Language code: BlomqvistBeta[RandomVariate[𝒟, 10^6]]//MatrixForm

スコープ  (7)

データ  (4)

厳密な入力は厳密な出力を与える：

Wolfram Language code: BlomqvistBeta[{-20, -21, 1, 7, 24, 36, -10, -12, 56, -14}, {3, -4, 1, 4, 22, 17, -2, 2, 13, -11}]

近似入力は近似出力を与える：

Wolfram Language code: BlomqvistBeta[{1.5, 3, 5, 10}, {2, 1.25, 15, 8}]
Wolfram Language code: BlomqvistBeta[N[{1, 3, 5, 6, 9}, 30], N[{2, -1, 3, 11, 4}, 30]]

大規模配列に使うことができる：

Wolfram Language code: BlomqvistBeta[RandomReal[1, 10 ^ 5], RandomReal[1, 10 ^ 5]]

SparseArrayデータを使うことができる：

Wolfram Language code: BlomqvistBeta[SparseArray[{{2, 2} -> 1, {5, 3} -> 2, {10, 1} -> 3}]]//MatrixForm

分布と過程  (3)

多変量連続分布についてのBlomqvistの β 行列：

Wolfram Language code: BlomqvistBeta[BinormalDistribution[ρ]]//Simplify//MatrixForm
Wolfram Language code: BlomqvistBeta[BinormalDistribution[ρ], 2, 1]//Simplify

派生分布についてのBlomqvistの β 行列：

Wolfram Language code: BlomqvistBeta[ProductDistribution[ExponentialDistribution[1], NormalDistribution[3, 5]]]//MatrixForm
Wolfram Language code: 𝒟 = CopulaDistribution[{"FGM", 2 / 3}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}];
Wolfram Language code: BlomqvistBeta[𝒟]//MatrixForm

データ分布について：

Wolfram Language code: 𝒟 = HistogramDistribution[RandomVariate[BinormalDistribution[.75], 10 ^ 4]];
Wolfram Language code: BlomqvistBeta[𝒟]//MatrixForm
Wolfram Language code: BlomqvistBeta[BinormalDistribution[.75]]//MatrixForm

時点およびにおける，ランダム過程についてのBlomqvistの β 行列：

Wolfram Language code: BlomqvistBeta[WienerProcess[][{0.2, 0.3}]]//MatrixForm

アプリケーション  (3)

Blomqvistの β は，一般に，2つのベクトル間の線形従属性の検出に使われる：

Wolfram Language code: {v11, v21} = Transpose[RandomVariate[BinormalDistribution[.99], 1000]]; {v12, v22} = Transpose[RandomVariate[BinormalDistribution[0], 1000]];

β の絶対的な大きさは，線形従属性が強い場合は，1に近くなる：

Wolfram Language code: BlomqvistBeta[v11, v21]

この値は，線形独立ベクトルについては0に近くなる：

Wolfram Language code: BlomqvistBeta[v12, v22]

Blomqvistの β を使って線形関係を測ることができる：

Wolfram Language code: data = BlockRandom[SeedRandom[1];Table[RandomVariate[BinormalDistribution[i], 1000], {i, {-.99, -.75, -.25, -.5, 0., .25, .5, .75, .99}}]];
Wolfram Language code: Grid[Partition[Table[ListPlot[i, PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None, Frame -> True, Axes -> None, PlotLabel -> Row[{"β : ", BlomqvistBeta[i][[1, 2]]}]], {i, data}], 3]]

Blomqvistの β は，単調依存構造しか検出しない：

Wolfram Language code: uni = RandomReal[{-3, 3}, 1000];
Wolfram Language code: f[x_] := {{x, -Sqrt[Abs[x]] + RandomReal[.5]}, {x, .25x^2 + RandomReal[.5]}, {x, -Sinc[x] + RandomReal[.5]}, {Cos[x], Sin[x] + RandomReal[.5]}}
Wolfram Language code: data = f /@ uni;
Wolfram Language code: Table[ListPlot[data[[All, i]], Frame -> True, Axes -> None, PlotLabel -> Row[{"β : ", BlomqvistBeta[data[[All, i]]][[1, 2]]}], PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None], {i, 4}]

HoeffdingDは他のさまざまな依存構造に使うことができる：

Wolfram Language code: Table[HoeffdingD[data[[All, i]]][[1, 2]], {i, 4}]

特性と関係  (7)

Blomqvistの β の範囲は，高い否定的関係を示すから高い関係性を示すまでである：

Wolfram Language code: d = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: BlomqvistBeta[d, d]
Wolfram Language code: BlomqvistBeta[d, -d]

Blomqvistの β 行列は対称行列である：

Wolfram Language code: blb = BlomqvistBeta[RandomVariate[BinormalDistribution[1 / 3], 10 ^ 3]];
Wolfram Language code: SymmetricMatrixQ[blb]

Blomqvistの β 行列の対角要素は1である：

Wolfram Language code: data = RandomInteger[{-3, 3}, {100, 15}];
Wolfram Language code: Diagonal[BlomqvistBeta[data]]

偶数のサンプルサイズについてのBlomqvistの ：

Wolfram Language code: d = RandomVariate[BinormalDistribution[.5], 100];
Wolfram Language code: med = Median[d]

中央値に集中しているデータ：

Wolfram Language code: medCentered = Transpose[Transpose[d] - med];
Wolfram Language code: ListPlot[medCentered, Frame -> True, AspectRatio -> 1, PlotRange -> {{-3, 3}, {-3, 3}}]

各象限の点の数を数える：

Wolfram Language code: q1 = Count[medCentered, {x_, y_} /; x > 0 && y > 0]; q2 = Count[medCentered, {x_, y_} /; x <= 0 && y > 0]; q3 = Count[medCentered, {x_, y_} /; x <= 0 && y <= 0]; q4 = Count[medCentered, {x_, y_} /; x > 0 && y <= 0];
Wolfram Language code: n1 = q1 + q3
Wolfram Language code: n2 = q2 + q4

Blomqvistの β：

Wolfram Language code: (n1 - n2/n1 + n2)//N
Wolfram Language code: BlomqvistBeta[d[[All, 1]], d[[All, 2]]]//N

Blomqvistの β は完全な単調関係がある場合はあるいはを返す：

Wolfram Language code: x = Sort@RandomReal[10, 50]; y = If[# > 5, 5#, #]& /@ x;
Wolfram Language code: ListPlot[{Transpose[{x, y}], Transpose[{x, -y}]}, Frame -> True]
Wolfram Language code: BlomqvistBeta[x, y]
Wolfram Language code: BlomqvistBeta[x, -y]

これは線形関係の程度を測るCorrelationとは対照的である：

Wolfram Language code: Correlation[x, y]
Wolfram Language code: Correlation[x, -y]

BlomqvistBetaTestを使って β の値の検定ができる：

Wolfram Language code: data = RandomVariate[BinormalDistribution[-.65], 100];
Wolfram Language code: BlomqvistBeta[data[[All, 1]], data[[All, 2]]]
Wolfram Language code: BlomqvistBetaTest[data[[All, 1]], data[[All, 2]], "TestDataTable"]

IndependenceTestを使って適切な検定を自動的に選ぶことができる：

Wolfram Language code: IndependenceTest[data[[All, 1]], data[[All, 2]], "TestDataTable"]

二変量分布についてのBlomqvistの β：

Wolfram Language code: 𝒟 = CopulaDistribution[{"AMH", 1}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}];
Wolfram Language code: BlomqvistBeta[𝒟, 1, 2]
Wolfram Language code: {μx, μy} = Table[Mean[MarginalDistribution[𝒟, i]], {i, 2}]
Wolfram Language code: βExpected = Probability[(x - μx)(y - μy) > 0, {x, y}𝒟] - Probability[(x - μx)(y - μy) < 0, {x, y}𝒟]
Wolfram Language code: data = RandomVariate[𝒟, 10 ^ 6];
Wolfram Language code: BlomqvistBeta[data][[1, 2]] - βExpected//N
Wolfram Research (2012), BlomqvistBeta, Wolfram言語関数， https://reference.wolfram.com/language/ref/BlomqvistBeta.html.

テキスト

Wolfram Research (2012), BlomqvistBeta, Wolfram言語関数， https://reference.wolfram.com/language/ref/BlomqvistBeta.html.

CMS

Wolfram Language. 2012. "BlomqvistBeta." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BlomqvistBeta.html.

APA

Wolfram Language. (2012). BlomqvistBeta. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BlomqvistBeta.html

BibTeX

@misc{reference.wolfram_2026_blomqvistbeta, author="Wolfram Research", title="{BlomqvistBeta}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BlomqvistBeta.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_blomqvistbeta, organization={Wolfram Research}, title={BlomqvistBeta}, year={2012}, url={https://reference.wolfram.com/language/ref/BlomqvistBeta.html}, note=[Accessed: 14-August-2026]}