WOLFRAM

Wolfram 语言与系统参考资料中心

BlomqvistBeta[v1,v2]

对向量 v1 和 v2，给出 Blomqvist 的中间相关系数 β.

BlomqvistBeta[m]

对于矩阵 m，给出 Blomqvist 的中间相关系数 β.

BlomqvistBeta[m1,m2]

对于矩阵 m1 和 m2，给出 Blomqvist 的中间相关系数 β.

BlomqvistBeta[dist] 对于多变量符号式分布 dist，给出中间相关系数矩阵.

BlomqvistBeta[dist,i,j]

对于多变量符号式分布 dist，给出第 (i,j) 中间相关系数.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数据  
分布和过程  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

BlomqvistBeta

BlomqvistBeta[v1,v2]

对向量 v1 和 v2，给出 Blomqvist 的中间相关系数 β.

BlomqvistBeta[m]

对于矩阵 m，给出 Blomqvist 的中间相关系数 β.

BlomqvistBeta[m1,m2]

对于矩阵 m1 和 m2，给出 Blomqvist 的中间相关系数 β.

BlomqvistBeta[dist] 对于多变量符号式分布 dist，给出中间相关系数矩阵.

BlomqvistBeta[dist,i,j]

对于多变量符号式分布 dist，给出第 (i,j) 中间相关系数.

更多信息

  • BlomqvistBeta[v1,v2] 给出位于 v1 和 v2 之间的 Blomqvist 的中间相关系数 β.
  • 向量 x 和 y 之间的 Blomqvist 的 β 由 Correlation[Sign[x-μx],Sign[y-μy]] 给出，其中 μx 和 μy 分别是 x 和 y 的中位数.
  • 参数 v1 和 v2 可以是相等长度的任意实值向量.
  • 对于具有 个列的矩阵 m，BlomqvistBeta[m] 是 m 的 β 列间组成的 × 矩阵.
  • 对于 × 矩阵 m1 和 × 矩阵 m2，BlomqvistBeta[m1,m2] 是 × 矩阵，由 m1 和 m2 的 β 列间组成.
  • BlomqvistBeta[dist,i,j] 是 Probability[(x-μx)(y-μy)>0,{x,y}disti,j]-Probability[(x-μx)(y-μy)<0,{x,y}disti,j]，其中 disti,j 是 dist 的第 边缘分布.
  • BlomqvistBeta 对于离散分布或者出现等值情况时定义不明确.
  • BlomqvistBeta[dist] 给出矩阵 β，其中第 元素是由 BlomqvistBeta[dist,i,j] 给出.

范例

打开所有单元 关闭所有单元

基本范例  (4)

两个向量的 Blomqvist β：

Wolfram Language code: v1 = {3, -4, 1, 4, 22, 17, -2, 2, 13, -11}; v2 = {-20, -24, 0, 4, 24, 36, -12, -12, 56, -14};
Wolfram Language code: BlomqvistBeta[v1, v2]

矩阵的 Blomqvist β：

Wolfram Language code: m = RandomVariate[BinormalDistribution[.6], 10^3];
Wolfram Language code: BlomqvistBeta[m]//MatrixForm

两个矩阵的 Blomqvist β：

Wolfram Language code: m1 = RandomReal[1, {10^3, 4}];
Wolfram Language code: m2 = RandomReal[1, {10^3, 3}];
Wolfram Language code: BlomqvistBeta[m1, m2]//MatrixForm

计算双变量分布的 Blomqvist β 矩阵：

Wolfram Language code: 𝒟 = BinormalDistribution[.5];
Wolfram Language code: BlomqvistBeta[𝒟]//MatrixForm

与模拟数值比较：

Wolfram Language code: BlomqvistBeta[RandomVariate[𝒟, 10^6]]//MatrixForm

范围  (7)

数据  (4)

精确的输入产生精确的输出：

Wolfram Language code: BlomqvistBeta[{-20, -21, 1, 7, 24, 36, -10, -12, 56, -14}, {3, -4, 1, 4, 22, 17, -2, 2, 13, -11}]

精确的输入产生近似的输出：

Wolfram Language code: BlomqvistBeta[{1.5, 3, 5, 10}, {2, 1.25, 15, 8}]
Wolfram Language code: BlomqvistBeta[N[{1, 3, 5, 6, 9}, 30], N[{2, -1, 3, 11, 4}, 30]]

适用于大型数组：

Wolfram Language code: BlomqvistBeta[RandomReal[1, 10 ^ 5], RandomReal[1, 10 ^ 5]]

可以使用 SparseArray：

Wolfram Language code: BlomqvistBeta[SparseArray[{{2, 2} -> 1, {5, 3} -> 2, {10, 1} -> 3}]]//MatrixForm

分布和过程  (3)

连续多变量分布的 Blomqvist β 矩阵：

Wolfram Language code: BlomqvistBeta[BinormalDistribution[ρ]]//Simplify//MatrixForm
Wolfram Language code: BlomqvistBeta[BinormalDistribution[ρ], 2, 1]//Simplify

导出分布的 Blomqvist β 矩阵：

Wolfram Language code: BlomqvistBeta[ProductDistribution[ExponentialDistribution[1], NormalDistribution[3, 5]]]//MatrixForm
Wolfram Language code: 𝒟 = CopulaDistribution[{"FGM", 2 / 3}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}];
Wolfram Language code: BlomqvistBeta[𝒟]//MatrixForm

数据分布：

Wolfram Language code: 𝒟 = HistogramDistribution[RandomVariate[BinormalDistribution[.75], 10 ^ 4]];
Wolfram Language code: BlomqvistBeta[𝒟]//MatrixForm
Wolfram Language code: BlomqvistBeta[BinormalDistribution[.75]]//MatrixForm

随机过程在时刻 和 的 Blomqvist β 矩阵：

Wolfram Language code: BlomqvistBeta[WienerProcess[][{0.2, 0.3}]]//MatrixForm

应用  (3)

Blomqvist β 通常用于检测两个向量之间的线性关系：

Wolfram Language code: {v11, v21} = Transpose[RandomVariate[BinormalDistribution[.99], 1000]]; {v12, v22} = Transpose[RandomVariate[BinormalDistribution[0], 1000]];

在给出强烈的线性关系时，β 的绝对幅度趋于1：

Wolfram Language code: BlomqvistBeta[v11, v21]

对于线性无关的向量，该值趋向于0：

Wolfram Language code: BlomqvistBeta[v12, v22]

Blomqvist β 可用于测量线性相关：

Wolfram Language code: data = BlockRandom[SeedRandom[1];Table[RandomVariate[BinormalDistribution[i], 1000], {i, {-.99, -.75, -.25, -.5, 0., .25, .5, .75, .99}}]];
Wolfram Language code: Grid[Partition[Table[ListPlot[i, PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None, Frame -> True, Axes -> None, PlotLabel -> Row[{"β : ", BlomqvistBeta[i][[1, 2]]}]], {i, data}], 3]]

Blomqvist β 仅检测单调的依赖结构：

Wolfram Language code: uni = RandomReal[{-3, 3}, 1000];
Wolfram Language code: f[x_] := {{x, -Sqrt[Abs[x]] + RandomReal[.5]}, {x, .25x^2 + RandomReal[.5]}, {x, -Sinc[x] + RandomReal[.5]}, {Cos[x], Sin[x] + RandomReal[.5]}}
Wolfram Language code: data = f /@ uni;
Wolfram Language code: Table[ListPlot[data[[All, i]], Frame -> True, Axes -> None, PlotLabel -> Row[{"β : ", BlomqvistBeta[data[[All, i]]][[1, 2]]}], PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None], {i, 4}]

HoeffdingD 可用于各种其它的依赖结构：

Wolfram Language code: Table[HoeffdingD[data[[All, i]]][[1, 2]], {i, 4}]

属性和关系  (7)

Blomqvist β 对于高负相关和高正相关范围分别从 到 ：

Wolfram Language code: d = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: BlomqvistBeta[d, d]
Wolfram Language code: BlomqvistBeta[d, -d]

Blomqvist β 矩阵是对称的：

Wolfram Language code: blb = BlomqvistBeta[RandomVariate[BinormalDistribution[1 / 3], 10 ^ 3]];
Wolfram Language code: SymmetricMatrixQ[blb]

Blomqvist β 矩阵的对角线元素是 1：

Wolfram Language code: data = RandomInteger[{-3, 3}, {100, 15}];
Wolfram Language code: Diagonal[BlomqvistBeta[data]]

对于偶数样本大小的 Blomqvist ：

Wolfram Language code: d = RandomVariate[BinormalDistribution[.5], 100];
Wolfram Language code: med = Median[d]

中位数为中心的数据：

Wolfram Language code: medCentered = Transpose[Transpose[d] - med];
Wolfram Language code: ListPlot[medCentered, Frame -> True, AspectRatio -> 1, PlotRange -> {{-3, 3}, {-3, 3}}]

计算每个象限中的点数：

Wolfram Language code: q1 = Count[medCentered, {x_, y_} /; x > 0 && y > 0]; q2 = Count[medCentered, {x_, y_} /; x <= 0 && y > 0]; q3 = Count[medCentered, {x_, y_} /; x <= 0 && y <= 0]; q4 = Count[medCentered, {x_, y_} /; x > 0 && y <= 0];
Wolfram Language code: n1 = q1 + q3
Wolfram Language code: n2 = q2 + q4

Blomqvist β:

Wolfram Language code: (n1 - n2/n1 + n2)//N
Wolfram Language code: BlomqvistBeta[d[[All, 1]], d[[All, 2]]]//N

Blomqvist β 将产生 或者 如果存在完美的单调的相关：

Wolfram Language code: x = Sort@RandomReal[10, 50]; y = If[# > 5, 5#, #]& /@ x;
Wolfram Language code: ListPlot[{Transpose[{x, y}], Transpose[{x, -y}]}, Frame -> True]
Wolfram Language code: BlomqvistBeta[x, y]
Wolfram Language code: BlomqvistBeta[x, -y]

这与 Correlation 相反，它测量线性相关度：

Wolfram Language code: Correlation[x, y]
Wolfram Language code: Correlation[x, -y]

BlomqvistBetaTest 可用于检验 β 的数值：

Wolfram Language code: data = RandomVariate[BinormalDistribution[-.65], 100];
Wolfram Language code: BlomqvistBeta[data[[All, 1]], data[[All, 2]]]
Wolfram Language code: BlomqvistBetaTest[data[[All, 1]], data[[All, 2]], "TestDataTable"]

IndependenceTest 可用于自动选择合适的检验：

Wolfram Language code: IndependenceTest[data[[All, 1]], data[[All, 2]], "TestDataTable"]

双变量分布的 Blomqvist β：

Wolfram Language code: 𝒟 = CopulaDistribution[{"AMH", 1}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}];
Wolfram Language code: BlomqvistBeta[𝒟, 1, 2]
Wolfram Language code: {μx, μy} = Table[Mean[MarginalDistribution[𝒟, i]], {i, 2}]
Wolfram Language code: βExpected = Probability[(x - μx)(y - μy) > 0, {x, y}𝒟] - Probability[(x - μx)(y - μy) < 0, {x, y}𝒟]
Wolfram Language code: data = RandomVariate[𝒟, 10 ^ 6];
Wolfram Language code: BlomqvistBeta[data][[1, 2]] - βExpected//N
Wolfram Research (2012)，BlomqvistBeta，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BlomqvistBeta.html.

文本

Wolfram Research (2012)，BlomqvistBeta，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BlomqvistBeta.html.

CMS

Wolfram 语言. 2012. "BlomqvistBeta." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BlomqvistBeta.html.

APA

Wolfram 语言. (2012). BlomqvistBeta. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BlomqvistBeta.html 年

BibTeX

@misc{reference.wolfram_2026_blomqvistbeta, author="Wolfram Research", title="{BlomqvistBeta}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BlomqvistBeta.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_blomqvistbeta, organization={Wolfram Research}, title={BlomqvistBeta}, year={2012}, url={https://reference.wolfram.com/language/ref/BlomqvistBeta.html}, note=[Accessed: 16-August-2026]}