WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BooleanConvert[expr]

ブール式 expr を選言標準形に変換する．

BooleanConvert[expr,form]

ブール式 expr を指定形式に変換する．

BooleanConvert[expr,form,cond]

cond が真であるときに expr と等価である式を指定形式で求める．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

BooleanConvert

BooleanConvert[expr]

ブール式 expr を選言標準形に変換する．

BooleanConvert[expr,form]

ブール式 expr を指定形式に変換する．

BooleanConvert[expr,form,cond]

cond が真であるときに expr と等価である式を指定形式で求める．

詳細とオプション

  • BooleanConvert[expr,form] は expr と等価である式を生成する．
  • 使用可能な形式
  • "DNF","SOP"選言標準形，積の総和
    "CNF","POS"連言標準形，総和の積
    "ESOP"排他的積和
    "ANF"代数標準形
    "NOR"2レベルのNorとNot
    "NAND"2レベルのNandとNot
    "BinaryNOR", "NOR2"2引数のNor
    "BinaryNAND", "NAND2"2引数のNand
    "AND"2レベルのAndとNot
    "OR"2レベルのOrとNot
    "IMPLIES"ImpliesとNot
    "ITE","IF"Ifおよび定数
    "BFF"BooleanFunction形式
    "BDT"ブール決定木
  • 式 expr は，BooleanFunction，BooleanCountingFunction等を含む任意のブール関数および論理関数を含むことができる．
  • BooleanConvert[bf,form]は純BooleanFunctionオブジェクトの内部形式を変換することができる．
  • BooleanConvertは使用するメソッドの詳細を指定するMethodオプションをサポートする．

例題

すべて開く すべて閉じる

例  (3)

ブール式を選言標準形に変換する：

Wolfram Language code: BooleanConvert[Equivalent[x, y, z]]

x⊻y をいくつかの一般的な形式に変換する：

Wolfram Language code: Table[BooleanConvert[Xor[x, y], fm], {fm, {"DNF", "CNF", "NAND", "NOR"}}]

x∧(y∨z)が真であるという条件を使ってを使って x⊻y⊻z を変換する：

Wolfram Language code: BooleanConvert[Xor[x, y, z], "DNF", x∧(y∨z)]

x∧(y∨z)のとき，出力が入力と等しいことを示す：

Wolfram Language code: TautologyQ[Implies[x∧(y∨z), Equivalent[Xor[x, y, z], %]]]

スコープ  (2)

ブール式を別の形式に変換する：

Wolfram Language code: expr = BooleanCountingFunction[{2, 3}, 4][a, b, c, d]

選言標準形：

Wolfram Language code: e1 = BooleanConvert[expr]

連言標準形：

Wolfram Language code: e2 = BooleanConvert[expr, "CNF"]

排他的積和：

Wolfram Language code: e3 = BooleanConvert[expr, "ESOP"]

代数標準形：

Wolfram Language code: e4 = BooleanConvert[expr, "ANF"]

2レベルのNandとNot：

Wolfram Language code: e5 = BooleanConvert[expr, "NAND"]

2レベルのNorとNot：

Wolfram Language code: e6 = BooleanConvert[expr, "NOR"]

2引数のNand：

Wolfram Language code: e7 = BooleanConvert[expr, "BinaryNAND"]

2引数のNor：

Wolfram Language code: e8 = BooleanConvert[expr, "BinaryNOR"]

2レベルのAndとNot：

Wolfram Language code: e9 = BooleanConvert[expr, "AND"]

2レベルのOrとNot：

Wolfram Language code: e10 = BooleanConvert[expr, "OR"]

ImpliesとNot：

Wolfram Language code: e11 = BooleanConvert[expr, "IMPLIES"]

Ifおよび定数：

Wolfram Language code: e12 = BooleanConvert[expr, "ITE"]

ブール関数形式：

Wolfram Language code: e13 = BooleanConvert[expr, "BFF"]

ブールの決定木：

Wolfram Language code: e14 = BooleanConvert[expr, "BDT"]

これらがすべて等しいことを示す：

Wolfram Language code: TautologyQ[Equivalent[expr, e1, e2, e3, e4, e5, e6, e7, e8, e9, e10, e11, e12, e13, e14]]

「care set」すなわち条件を用いてブール関数を変換する：

Wolfram Language code: f = BooleanCountingFunction[{2, 3}, 4][a, b, c, d]
Wolfram Language code: cond = Xor[a, b, c, d]
Wolfram Language code: g = BooleanConvert[f, cond]
Wolfram Language code: h = BooleanConvert[f, "CNF", cond]

結果の形式は cond が真である場合に等しい：

Wolfram Language code: TautologyQ[Implies[cond, Equivalent[f, g, h]]]

両者は条件なしでは等しくない：

Wolfram Language code: TautologyQ[Equivalent[f, g, h]]

一般に，条件がない方が形は長くなる：

Wolfram Language code: BooleanConvert[f]
Wolfram Language code: BooleanConvert[f, "CNF"]

特性と関係  (3)

BooleanConvertの出力は入力に等しい：

Wolfram Language code: f = BooleanFunction[228, 3][a, b, c]
Wolfram Language code: g = BooleanConvert[f]
Wolfram Language code: TautologyQ[Equivalent[f, g]]

条件付きのBooleanConvertの出力はその入力と条件付きで等しい：

Wolfram Language code: f = BooleanFunction[158, {a, b, c}]
Wolfram Language code: cond = a || b || c;
Wolfram Language code: g = BooleanConvert[f, "DNF", cond]

形式 f と g は cond が真である場合は等しい：

Wolfram Language code: TautologyQ[Implies[cond, Equivalent[f, g]]]

両者はそれらだけでは等しくない：

Wolfram Language code: TautologyQ[Equivalent[f, g]]

BooleanMinimizeを使って最短形を求める：

Wolfram Language code: f = BooleanConvert[BooleanCountingFunction[{1, 2}, 3][a, b, c]]
Wolfram Language code: g = BooleanMinimize[f]

2つの形は等しい：

Wolfram Language code: TautologyQ[Equivalent[f, g]]

おもしろい例題  (1)

色付き円板のブール結合を変換する：

Wolfram Language code: {a, b, c, d} = Table[Graphics[{col, Disk[]}, ImageSize -> 25], {col, {Red, Green, Blue, Yellow}}]
Wolfram Language code: BooleanConvert[Xor[a, b, c, d]]
Wolfram Research (2008), BooleanConvert, Wolfram言語関数， https://reference.wolfram.com/language/ref/BooleanConvert.html （2024年に更新）.

テキスト

Wolfram Research (2008), BooleanConvert, Wolfram言語関数， https://reference.wolfram.com/language/ref/BooleanConvert.html （2024年に更新）.

CMS

Wolfram Language. 2008. "BooleanConvert." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/BooleanConvert.html.

APA

Wolfram Language. (2008). BooleanConvert. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BooleanConvert.html

BibTeX

@misc{reference.wolfram_2026_booleanconvert, author="Wolfram Research", title="{BooleanConvert}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/BooleanConvert.html}", note=[Accessed: 08-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_booleanconvert, organization={Wolfram Research}, title={BooleanConvert}, year={2024}, url={https://reference.wolfram.com/language/ref/BooleanConvert.html}, note=[Accessed: 08-August-2026]}