WOLFRAM

Wolfram 语言与系统参考资料中心

BooleanMinterms[k,n]

表示第 k 个 n 元极小项.

BooleanMinterms[{k1,k2,…},n]

表示极小项 ki 的析取.

BooleanMinterms[{{u1,…,un},{v1,…},…}]

表示由指数向量 ui，vi，… 给出的极小项析取.

BooleanMinterms[spec,{a1,a2,…}]

给出关于变量 ai 的布尔表达式，相应 spec 指定的极小项函数.

BooleanMinterms[spec,{a1,a2,…},form]

给出由 form 指定形式的布尔表达式.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
参见
相关指南
历史
按以下格式引用：

BooleanMinterms

BooleanMinterms[k,n]

表示第 k 个 n 元极小项.

BooleanMinterms[{k1,k2,…},n]

表示极小项 ki 的析取.

BooleanMinterms[{{u1,…,un},{v1,…},…}]

表示由指数向量 ui，vi，… 给出的极小项析取.

BooleanMinterms[spec,{a1,a2,…}]

给出关于变量 ai 的布尔表达式，相应 spec 指定的极小项函数.

BooleanMinterms[spec,{a1,a2,…},form]

给出由 form 指定形式的布尔表达式.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (4)

指定相同极小项的等价方式：

Wolfram Language code: BooleanMinterms[{{True, False, True}}, {a, b, c}]
Wolfram Language code: BooleanMinterms[{{1, 0, 1}}, {a, b, c}]
Wolfram Language code: BooleanMinterms[{5}, {a, b, c}]

指定极小项的析取：

Wolfram Language code: BooleanMinterms[{1, 3, 5}, {a, b, c}]

指定极小项析取的等价方式：

Wolfram Language code: Or@@Table[BooleanMinterms[{i}, {a, b, c}], {i, {1, 3, 5}}]
Wolfram Language code: TautologyQ[Equivalent[%%, %]]

返回一个 BooleanFunction 对象，表示极小项的析取：

Wolfram Language code: BooleanMinterms[{1, 3, 5}, 3]@@{a, b, c}
Wolfram Language code: BooleanMinterms[{1, 3, 5}, {a, b, c}]
Wolfram Language code: TautologyQ[Equivalent[%%, %]]

列举三个变量的所有极小项：

Wolfram Language code: Table[BooleanMinterms[{i}, {a, b, c}], {i, 0, 2 ^ 3 - 1}]

范围  (2)

指定结果的不同形式：

Wolfram Language code: BooleanMinterms[{1, 3, 5}, {a, b, c}, "DNF"]
Wolfram Language code: BooleanMinterms[{1, 3, 5}, {a, b, c}, "CNF"]
Wolfram Language code: BooleanMinterms[{1, 3, 5}, {a, b, c}, "ANF"]

用指数向量指定极小项的合取：

Wolfram Language code: BooleanMinterms[{{0, 1, 1}, {1, 0, 1}, {1, 1, 0}}]
Wolfram Language code: BooleanConvert[%[a, b, c], "DNF"]

属性和关系  (4)

相应 True 坐标的指针，在 BooleanTable 的缺省顺序中给出：

Wolfram Language code: BooleanTable[BooleanMinterms[{0, 3, 7}, {a, b, c}], {a, b, c}]
Wolfram Language code: Length[%] - Position[%, True]

BooleanMinterms 可以表示任何 BooleanFunction：

Wolfram Language code: f = BooleanMinterms[{1, 5, 7}, 3]
Wolfram Language code: g = BooleanFunction[FromDigits[{1, 0, 1, 0, 0, 0, 1, 0}, 2], 3]
Wolfram Language code: f === g

从极小项到指针的映射：

Wolfram Language code: mindex[l_, k_] := FromDigits[Table[If[MemberQ[l, i], 1, 0], {i, 2 ^ k - 1, 0, -1}], 2]
Wolfram Language code: mindex[{1, 5, 7}, 3]

从指针到极小项的映射：

Wolfram Language code: indmin[m_, k_] := Flatten@Position[Reverse[IntegerDigits[m, 2, 2 ^ k]], 1] - 1
Wolfram Language code: indmin[162, 3]

用位向量：

Wolfram Language code: With[{m = 123, k = 4}, BooleanMinterms[Select[Range[0, 2^k - 1], BitAnd[2^#, m] ≠ 0&], k] === BooleanFunction[m, k]]

用 Subsets 列举出 BooleanMinterms 的所有可能的函数：

Wolfram Language code: BooleanMinterms[#, {a, b}]& /@ Subsets[Range[0, 2 ^ 2 - 1]]

BooleanMaxterms 与 BooleanMinterms 相关：

Wolfram Language code: f = BooleanMaxterms[{1, 3, 5}, 3]
Wolfram Language code: g = BooleanMinterms[{1, 3, 5}, 3]
Wolfram Language code: TautologyQ[Equivalent[f[a, b, c], ¬g[¬a, ¬b, ¬c]]]
Wolfram Research (2008)，BooleanMinterms，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BooleanMinterms.html.

文本

Wolfram Research (2008)，BooleanMinterms，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BooleanMinterms.html.

CMS

Wolfram 语言. 2008. "BooleanMinterms." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BooleanMinterms.html.

APA

Wolfram 语言. (2008). BooleanMinterms. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BooleanMinterms.html 年

BibTeX

@misc{reference.wolfram_2026_booleanminterms, author="Wolfram Research", title="{BooleanMinterms}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/BooleanMinterms.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_booleanminterms, organization={Wolfram Research}, title={BooleanMinterms}, year={2008}, url={https://reference.wolfram.com/language/ref/BooleanMinterms.html}, note=[Accessed: 09-August-2026]}