WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CategoricalDistribution[{c1,c2,…}]

クラス c1，c2等で一様カテゴリ分布を表す．

CategoricalDistribution[{c1,c2,…},{w1,w2,…}]

クラス ciで重みが wiのカテゴリ分布を表す．

CategoricalDistribution[{{a1,a2,…},{b1,b2,…},…}]

領域 {a1,a2,…}×{b1,b2,…}×…上で多変量一様カテゴリ分布を表す．

CategoricalDistribution[domain,weights]

配列の weights を使って領域の各要素の確率を定義する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
一変量の定義  
多変量の定義  
情報  
記号による重み  
領域外の動作  
確率と推定  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CategoricalDistribution

CategoricalDistribution[{c1,c2,…}]

クラス c1，c2等で一様カテゴリ分布を表す．

CategoricalDistribution[{c1,c2,…},{w1,w2,…}]

クラス ciで重みが wiのカテゴリ分布を表す．

CategoricalDistribution[{{a1,a2,…},{b1,b2,…},…}]

領域 {a1,a2,…}×{b1,b2,…}×…上で多変量一様カテゴリ分布を表す．

CategoricalDistribution[domain,weights]

配列の weights を使って領域の各要素の確率を定義する．

詳細とオプション

  • CategoricalDistributionは，順序を持たないクラスから構成される領域を有する離散分布であり，通常，有限集合に確率測度を与えるために用いられる．
  • カテゴリ分布は1つあるいは複数の変数を持つことができる．各領域要素についての確率は分割表で可視化できる．
  • CategoricalDistribution[…]は，RandomVariate，PDF，Probability，Expectation等の関数で使うことができる．
  • CategoricalDistributionは非数値的分布で，MeanやCDF等の関数と一緒に使うことはできない．
  • CategoricalDistribution[domain,weights]の配列次元の weights は domain で定義された各変数のクラス数と一致しなければならない．
  • 配列の weights はSparseArray[…]形式で与えることができる．
  • 重みは，定義されると確率になるように正規化される．
  • CategoricalDistribution[{c1w1,c2w2,…}]を使ってクラス ciと重み wiを定義することができる．
  • CategoricalDistribution[{{c11,c12,…}w1,elem2w2,…}]を使って多変量領域の要素 elemi（クラスのリスト）とその重み wiが定義できる．省略された要素にはデフォルトで重み0が与えられる．
  • CategoricalDistribution[{elem1w1,elem2w2,…, _val}]における欠略された要素には重み val が与えられる．
  • CategoricalDistribution[domain,{elem1w1,elem2w2,…}]を使って分布領域といくつかの分布要素の確率の両方が指定できる．
  • Information[CategoricalDistribution[…]]は分布についてのレポートを与える．
  • CategoricalDistributionについてのInformationには以下の特性が含まれる．
  • "Categories"分布クラスのリスト
    "Dimension"変数の数
    "DomainElements"領域内の全要素
    "DomainSize"領域内の要素数
    "Entropy"厳密なエントロピー
    "NEntropy"近似エントロピー
    "Probabilities"確率の連想
    "ProbabilityArray"確率配列
    "ProbabilityPlot"確率関数の可視化
    "ProbabilityTable"Datasetにおける確率
    "Properties"使用可能な全特性
    "TopProbabilities"最高確率の要素のリスト
    "TopProbabilities"n確率が高いものから n 個の要素

例題

すべて開く すべて閉じる

例  (2)

一変量で一様なカテゴリ分布を作る：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}]

この分布からランダムなサンプルを生成する：

Wolfram Language code: RandomVariate[cd]

クラスの確率質量を計算する：

Wolfram Language code: PDF[cd, "A"]

重み付きの一変量カテゴリ分布を作成する：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}, {1, 2, 3}]

分布からランダムなサンプルを生成する：

Wolfram Language code: RandomVariate[cd, 20]

クラスの確率質量を計算する：

Wolfram Language code: PDF[cd, {"A", "B", "C"}]

確率をプロットで可視化する：

Wolfram Language code: Information[cd, "ProbabilityPlot"]

スコープ  (16)

一変量の定義  (4)

シンボルがクラスの一変量カテゴリ分布を定義する：

Wolfram Language code: cd = CategoricalDistribution[{True, False, x, y}]

この分布からサンプルを生成する：

Wolfram Language code: RandomVariate[cd, 20]

規則を使って一変量カテゴリ分布を定義する：

Wolfram Language code: cd = CategoricalDistribution[{"A" -> 1, "B" -> 2, "C" -> 3}]

分布の情報を可視化する：

Wolfram Language code: Information[cd]

領域と規則を使って一変量カテゴリ分布を定義する：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}, {"A" -> 1}]

分布についての情報を可視化する：

Wolfram Language code: Information[cd]

未定義要素のデフォルトの重みを指定する：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}, {"A" -> 1, _ -> 0.1}]

分布についての情報を可視化する：

Wolfram Language code: Information[cd]

繰返し要素でカテゴリ分布を定義する：

Wolfram Language code: cd = CategoricalDistribution[{"A", "A", "B", "A", "B", "C", "A"}]

確率は繰返し要素の数に比例する：

Wolfram Language code: Information[cd, "ProbabilityTable"]

多変量の定義  (5)

一様な多変量カテゴリ分布を作成する：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"1st", "2nd"}}]

分布からランダムなサンプルを生成する：

Wolfram Language code: RandomVariate[cd, 6]

要素の確率質量を計算する：

Wolfram Language code: PDF[cd, {"A", "2nd"}]

分布の分割表を可視化する：

Wolfram Language code: Information[cd, "ProbabilityTable"]

各要素の重みを指定して，多変量のカテゴリ分布を作成する：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}}, {{1, 2}, {3, 4}, {5, 6}}]

分布からランダムなサンプルを生成する：

Wolfram Language code: RandomVariate[cd, 20]

要素の確率質量を計算する：

Wolfram Language code: PDF[cd, {"A", "E"}]

分布の分割表を可視化する：

Wolfram Language code: Information[cd, "ProbabilityTable"]

周辺分布を第1変数について計算する：

Wolfram Language code: cd1 = MarginalDistribution[cd, 1]

周辺分布の分割表を可視化する：

Wolfram Language code: Information[cd1, "ProbabilityTable"]

疎な配列を使って多変量カテゴリ分布を定義する：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}}, SparseArray[{{1, 1} -> 1, {3, 2} -> 1, _ -> 0}]]

その確率表を可視化する：

Wolfram Language code: Information[cd, "ProbabilityTable"]

領域と規則を定義することで多変量カテゴリ分布を定義する：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}}, {{"A", "D"} -> 1, {"C", "E"} -> 1}]

その確率表を可視化する：

Wolfram Language code: Information[cd, "ProbabilityTable"]

未定義の要素が与えられた重みを持つように指定する：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}}, {{"A", "D"} -> 1, {"C", "E"} -> 1, _ -> 0.1}]

確率表を可視化する：

Wolfram Language code: Information[cd, "ProbabilityTable"]

たくさんの変数を持つカテゴリ分布を作成する：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}, {"F", "G"}, {"H", "I"}}, RandomInteger[3, {3, 2, 2, 2}]]

その確率表を可視化する：

Wolfram Language code: Information[cd, "ProbabilityTable"]

情報  (2)

一変量分布を作成する：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}, {1, 2, 3}]

この分布についての情報のレポートを取得する：

Wolfram Language code: Information[cd]

使用可能な情報特性のリストを得る：

Wolfram Language code: Information[cd, "Properties"]

クラスのリストを得る：

Wolfram Language code: Information[cd, "Categories"]

全クラスの確率を得る：

Wolfram Language code: Information[cd, "Probabilities"]

確率を可視化する：

Wolfram Language code: Information[cd, "ProbabilityPlot"]

分布の厳密なエントロピーを得る：

Wolfram Language code: Information[cd, "Entropy"]

多変量分布を作成する：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}}, {{1, 2}, {3, 4}, {5, 6}}]

この分布についての情報のレポートを得る：

Wolfram Language code: Information[cd]

使用可能な情報特性のリストを得る：

Wolfram Language code: Information[cd, "Properties"]

各変数についての可能なクラスを得る：

Wolfram Language code: Information[cd, "Categories"]

使用可能な全領域要素を得る：

Wolfram Language code: Information[cd, "DomainElements"]

すべての領域要素についての確率を得る：

Wolfram Language code: Information[cd, "Probabilities"]

最高確率の要素を2つ得る：

Wolfram Language code: Information[cd, "TopProbabilities" -> 2]

確率を可視化する：

Wolfram Language code: Information[cd, "ProbabilityPlot"]

この分布の厳密なエントロピーを得る：

Wolfram Language code: Information[cd, "Entropy"]

記号による重み  (2)

記号（非数値）パラメータでカテゴリ分布を定義する：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}, {a, 2, 3}]

確率表を可視化する：

Wolfram Language code: Information[cd, "ProbabilityTable"]

パラメータ a を数値で置換する：

Wolfram Language code: cd2 = cd /. a -> 1

確率表を可視化する：

Wolfram Language code: Information[cd2, "ProbabilityTable"]

記号パラメータでカテゴリ分布を定義する：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}, {a, 2, 3}]

RandomVariateは評価されない：

Wolfram Language code: RandomVariate[cd]

記号パラメータを数値で置換する：

Wolfram Language code: RandomVariate[cd] /. a -> 1

領域外の動作  (1)

カテゴリ分布を定義する：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}]

「領域外」クラスの確率質量は定義されていないので，PDFは評価されない：

Wolfram Language code: pdf = PDF[cd, x]

領域外のクラスを領域クラスで置換する：

Wolfram Language code: ReplaceAll[pdf, x -> "A"]

確率と推定  (2)

多変量分布を作成する：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}}, RandomInteger[{1, 4}, {3, 2}]]
Wolfram Language code: Information[cd, "ProbabilityTable"]

第1変数が"A"である確率を計算する：

Wolfram Language code: Probability[x == "A", {x, y}cd]

MarginalDistributionで計算された同じ確率と比較する：

Wolfram Language code: PDF[MarginalDistribution[cd, 1], "A"]

多変量分布を作成する：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}}, RandomInteger[{1, 4}, {3, 2}]]

Expectationを使ってそのエントロピーを計算する：

Wolfram Language code: Expectation[-Log[PDF[cd, {x, y}]], {x, y}cd]

Informationで与えられるようなエントロピーと比較する：

Wolfram Language code: Information[cd, "Entropy"]

NExpectationを使ってエントロピーを計算する：

Wolfram Language code: NExpectation[-Log[PDF[cd, {x, y}]], {x, y}cd]

"MonteCarlo"メソッドを使うように指定する：

Wolfram Language code: NExpectation[-Log[PDF[cd, {x, y}]], {x, y}cd, Method -> "MonteCarlo"]

使用するサンプル数を指定する：

Wolfram Language code: NExpectation[-Log[PDF[cd, {x, y}]], {x, y}cd, Method -> {"MonteCarlo", "SamplingIncrement" -> 10000}]

アプリケーション  (2)

分類器を訓練する：

Wolfram Language code: c = Classify[{1 -> "A", 2 -> "A", 3 -> "B", 4 -> "B"}]

与えられた入力に対して予測された分布を返す：

Wolfram Language code: dist = c[1.8, "Distribution"]

予測された分布からランダムなサンプルを生成する：

Wolfram Language code: RandomVariate[dist, 100]

タイタニック号の乗客のデータ集合をロードする：

Wolfram Language code: data = ResourceData["Sample Data: Titanic Survival"]

3つのカテゴリ変数を抽出し，それらを合わせた出現回数を数える：

Wolfram Language code: counts = Counts[Normal@Values[data[All, {"Class", "Sex", "SurvivalStatus"}]]]

これらの回数からカテゴリ分布を作成する：

Wolfram Language code: cd = CategoricalDistribution[counts]

この分布の確率表を可視化する：

Wolfram Language code: Information[cd, "ProbabilityTable"]

乗客の生存確率を計算する：

Wolfram Language code: NProbability[z == "survived", {x, y, z}cd]

女性の乗客の生存確率を計算する：

Wolfram Language code: p1 = NProbability[z == "died" && y == "female", {x, y, z}cd]; p2 = NProbability[z == "survived" && y == "female", {x, y, z}cd]; p2 / (p1 + p2)

特性と関係  (1)

カテゴリ分布を作成する：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}, {"F", "G"}, {"H", "I"}}, RandomInteger[3, {3, 2, 2, 2}]]

領域の各要素についての確率を得る：

Wolfram Language code: proba = Information[cd, "Probabilities"]

確率が負になることはない：

Wolfram Language code: AllTrue[proba, NonNegative]

確率を合計すると常に1になる：

Wolfram Language code: Total[proba]
Wolfram Research (2020), CategoricalDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/CategoricalDistribution.html.

テキスト

Wolfram Research (2020), CategoricalDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/CategoricalDistribution.html.

CMS

Wolfram Language. 2020. "CategoricalDistribution." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CategoricalDistribution.html.

APA

Wolfram Language. (2020). CategoricalDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CategoricalDistribution.html

BibTeX

@misc{reference.wolfram_2026_categoricaldistribution, author="Wolfram Research", title="{CategoricalDistribution}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/CategoricalDistribution.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_categoricaldistribution, organization={Wolfram Research}, title={CategoricalDistribution}, year={2020}, url={https://reference.wolfram.com/language/ref/CategoricalDistribution.html}, note=[Accessed: 17-August-2026]}