WOLFRAM

Wolfram 语言与系统参考资料中心

CategoricalDistribution[{c1,c2,…}]

在 c1、c2 等类别上表现均匀范畴分布.

CategoricalDistribution[{c1,c2,…},{w1,w2,…}]

在权重为 wi 的类别 ci 上表现范畴分布.

CategoricalDistribution[{{a1,a2,…},{b1,b2,…},…}]

在域 {a1,a2,…}×{b1,b2,…}×… 上表现多变量均匀范畴分布.

CategoricalDistribution[domain,weights]

用数组 weights 定义域中每个元素的概率.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
单变量定义  
多变量定义  
信息  
符号权重  
域外行为  
概率和期望  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

CategoricalDistribution

CategoricalDistribution[{c1,c2,…}]

在 c1、c2 等类别上表现均匀范畴分布.

CategoricalDistribution[{c1,c2,…},{w1,w2,…}]

在权重为 wi 的类别 ci 上表现范畴分布.

CategoricalDistribution[{{a1,a2,…},{b1,b2,…},…}]

在域 {a1,a2,…}×{b1,b2,…}×… 上表现多变量均匀范畴分布.

CategoricalDistribution[domain,weights]

用数组 weights 定义域中每个元素的概率.

更多信息和选项

  • CategoricalDistribution 是一个离散分布，它的域由无序类别组成，通常用于对有限集合进行概率测度.
  • 范畴分布可以有一个或多个变量. 列联表显示了域中每个元素的概率：
  • CategoricalDistribution[…] 可用于诸如 RandomVariate、PDF、Probability 和 Expectation 之类的函数中.
  • CategoricalDistribution[…] 不是数字分布：不能对其使用诸如 Mean 或 CDF 之类的函数.
  • 在 CategoricalDistribution[domain,weights] 中，数组 weights 的维度必须与 domain 中定义的每个变量的类别数匹配.
  • 可用 SparseArray[…] 形式给出数组 weights.
  • 定义了权重的情况下，权重将被规范化为概率.
  • CategoricalDistribution[{c1w1,c2w2,…}] 可用于定义类别 ci 和权重 wi.
  • CategoricalDistribution[{{c11,c12,…}w1,elem2w2,…}] 可用于定义多元域元素 elemi（类的列表）及其权重 wi. 省略的元素默认权重为 0.
  • 在 CategoricalDistribution[{elem1w1,elem2w2,…, _val}] 中，省略元素的权重为 val.
  • CategoricalDistribution[domain,{elem1w1,elem2w2,…}] 可用于指定分布域和域中某些元素的概率.
  • Information[CategoricalDistribution[…]] 给出有关该分布的报告.
  • CategoricalDistribution 的 Information 包括以下属性：
  • "Categories"分布类别列表
    "Dimension"变量的个数
    "DomainElements"域中的所有元素
    "DomainSize"域中元素的个数
    "Entropy"精确熵
    "NEntropy"近似熵
    "Probabilities"概率关联
    "ProbabilityArray"概率数组
    "ProbabilityPlot"概率函数可视化
    "ProbabilityTable"Dataset 中的概率
    "Properties"所有可用属性
    "TopProbabilities"概率最高的元素的列表
    "TopProbabilities"n概率最高的 n 个元素

范例

打开所有单元 关闭所有单元

基本范例  (2)

创建一个单变量均匀范畴分布：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}]

根据分布生成随机样本：

Wolfram Language code: RandomVariate[cd]

计算一个类别的概率质量：

Wolfram Language code: PDF[cd, "A"]

创建加权单变量范畴分布：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}, {1, 2, 3}]

根据分布生成随机样本：

Wolfram Language code: RandomVariate[cd, 20]

计算类别的概率质量：

Wolfram Language code: PDF[cd, {"A", "B", "C"}]

可视化概率：

Wolfram Language code: Information[cd, "ProbabilityPlot"]

范围  (16)

单变量定义  (4)

定义一个以符号表示类别的单变量范畴分布：

Wolfram Language code: cd = CategoricalDistribution[{True, False, x, y}]

根据分布生成样本：

Wolfram Language code: RandomVariate[cd, 20]

用规则定义单变量范畴分布：

Wolfram Language code: cd = CategoricalDistribution[{"A" -> 1, "B" -> 2, "C" -> 3}]

可视化分布的信息：

Wolfram Language code: Information[cd]

用域和规则定义单变量范畴分布：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}, {"A" -> 1}]

可视化分布的信息：

Wolfram Language code: Information[cd]

指定未定义元素的默认权重：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}, {"A" -> 1, _ -> 0.1}]

可视化分布的信息：

Wolfram Language code: Information[cd]

定义包含重复元素的范畴分布：

Wolfram Language code: cd = CategoricalDistribution[{"A", "A", "B", "A", "B", "C", "A"}]

概率与重复元素的数量成正比：

Wolfram Language code: Information[cd, "ProbabilityTable"]

多变量定义  (5)

创建一个均匀的多元范畴分布：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"1st", "2nd"}}]

根据分布生成随机样本：

Wolfram Language code: RandomVariate[cd, 6]

计算某个元素的概率质量：

Wolfram Language code: PDF[cd, {"A", "2nd"}]

可视化分布的列联表：

Wolfram Language code: Information[cd, "ProbabilityTable"]

创建一个多元范畴分布，为每个元素指定权重：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}}, {{1, 2}, {3, 4}, {5, 6}}]

根据分布生成随机样本：

Wolfram Language code: RandomVariate[cd, 20]

计算一个元素的概率质量：

Wolfram Language code: PDF[cd, {"A", "E"}]

可视化分布的列联表：

Wolfram Language code: Information[cd, "ProbabilityTable"]

计算第一个变量的边际分布：

Wolfram Language code: cd1 = MarginalDistribution[cd, 1]

可视化边际分布的列联表：

Wolfram Language code: Information[cd1, "ProbabilityTable"]

用稀疏数组定义多变量范畴分布：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}}, SparseArray[{{1, 1} -> 1, {3, 2} -> 1, _ -> 0}]]

可视化概率表：

Wolfram Language code: Information[cd, "ProbabilityTable"]

通过定义域和规则来定义多变量范畴分布：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}}, {{"A", "D"} -> 1, {"C", "E"} -> 1}]

可视化概率表：

Wolfram Language code: Information[cd, "ProbabilityTable"]

指定未定义的元素应具有给定的权重：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}}, {{"A", "D"} -> 1, {"C", "E"} -> 1, _ -> 0.1}]

可视化概率表：

Wolfram Language code: Information[cd, "ProbabilityTable"]

创建具有许多变量的范畴分布：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}, {"F", "G"}, {"H", "I"}}, RandomInteger[3, {3, 2, 2, 2}]]

可视化概率表：

Wolfram Language code: Information[cd, "ProbabilityTable"]

信息  (2)

创建单变量分布：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}, {1, 2, 3}]

获取分布的信息报告：

Wolfram Language code: Information[cd]

获取可能的信息属性列表：

Wolfram Language code: Information[cd, "Properties"]

获取类别列表：

Wolfram Language code: Information[cd, "Categories"]

获取所有类别的概率：

Wolfram Language code: Information[cd, "Probabilities"]

可视化概率：

Wolfram Language code: Information[cd, "ProbabilityPlot"]

获取分布的精确熵：

Wolfram Language code: Information[cd, "Entropy"]

创建多变量分布：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}}, {{1, 2}, {3, 4}, {5, 6}}]

获取分布的信息报告：

Wolfram Language code: Information[cd]

获取可能的信息属性列表：

Wolfram Language code: Information[cd, "Properties"]

获取每个变量的可能的类别：

Wolfram Language code: Information[cd, "Categories"]

获取所有可能的域元素：

Wolfram Language code: Information[cd, "DomainElements"]

获得所有域元素的概率：

Wolfram Language code: Information[cd, "Probabilities"]

获得两个概率最高的元素：

Wolfram Language code: Information[cd, "TopProbabilities" -> 2]

可视化概率：

Wolfram Language code: Information[cd, "ProbabilityPlot"]

获取分布的精确熵：

Wolfram Language code: Information[cd, "Entropy"]

符号权重  (2)

用符号（非数字）参数定义范畴分布：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}, {a, 2, 3}]

可视化概率表：

Wolfram Language code: Information[cd, "ProbabilityTable"]

用数字替换参数 a：

Wolfram Language code: cd2 = cd /. a -> 1

可视化概率表：

Wolfram Language code: Information[cd2, "ProbabilityTable"]

用符号参数定义范畴分布：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}, {a, 2, 3}]

RandomVariate 不进行计算：

Wolfram Language code: RandomVariate[cd]

用数值替换符号参数：

Wolfram Language code: RandomVariate[cd] /. a -> 1

域外行为  (1)

定义一个范畴分布：

Wolfram Language code: cd = CategoricalDistribution[{"A", "B", "C"}]

没有定义 "out-of-domain" 类别的概率质量，因此 PDF 不进行计算：

Wolfram Language code: pdf = PDF[cd, x]

用域内类别替换域外类别：

Wolfram Language code: ReplaceAll[pdf, x -> "A"]

概率和期望  (2)

创建多变量分布：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}}, RandomInteger[{1, 4}, {3, 2}]]
Wolfram Language code: Information[cd, "ProbabilityTable"]

计算第一个变量为 "A" 的概率：

Wolfram Language code: Probability[x == "A", {x, y}cd]

与使用 MarginalDistribution 计算相同概率所得到的结果进行比较：

Wolfram Language code: PDF[MarginalDistribution[cd, 1], "A"]

创建多变量分布：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}}, RandomInteger[{1, 4}, {3, 2}]]

用 Expectation 计算熵：

Wolfram Language code: Expectation[-Log[PDF[cd, {x, y}]], {x, y}cd]

与 Information 给出的熵相比较：

Wolfram Language code: Information[cd, "Entropy"]

用 NExpectation 计算熵：

Wolfram Language code: NExpectation[-Log[PDF[cd, {x, y}]], {x, y}cd]

指定使用 "MonteCarlo" 方法：

Wolfram Language code: NExpectation[-Log[PDF[cd, {x, y}]], {x, y}cd, Method -> "MonteCarlo"]

指定应使用的样本数：

Wolfram Language code: NExpectation[-Log[PDF[cd, {x, y}]], {x, y}cd, Method -> {"MonteCarlo", "SamplingIncrement" -> 10000}]

应用  (2)

训练一个分类器：

Wolfram Language code: c = Classify[{1 -> "A", 2 -> "A", 3 -> "B", 4 -> "B"}]

返回给定输入的预测分布：

Wolfram Language code: dist = c[1.8, "Distribution"]

根据预测的分布生成随机样本：

Wolfram Language code: RandomVariate[dist, 100]

加载泰坦尼克号上乘客的数据集：

Wolfram Language code: data = ResourceData["Sample Data: Titanic Survival"]

提取三个类别变量，并计算它们的组合出现的次数：

Wolfram Language code: counts = Counts[Normal@Values[data[All, {"Class", "Sex", "SurvivalStatus"}]]]

根据这些计数创建范畴分布：

Wolfram Language code: cd = CategoricalDistribution[counts]

可视化分布的概率表：

Wolfram Language code: Information[cd, "ProbabilityTable"]

计算乘客幸存的可能性：

Wolfram Language code: NProbability[z == "survived", {x, y, z}cd]

计算女性乘客幸存的可能性：

Wolfram Language code: p1 = NProbability[z == "died" && y == "female", {x, y, z}cd]; p2 = NProbability[z == "survived" && y == "female", {x, y, z}cd]; p2 / (p1 + p2)

属性和关系  (1)

创建一个范畴分布：

Wolfram Language code: cd = CategoricalDistribution[{{"A", "B", "C"}, {"D", "E"}, {"F", "G"}, {"H", "I"}}, RandomInteger[3, {3, 2, 2, 2}]]

获取域中每个元素的概率：

Wolfram Language code: proba = Information[cd, "Probabilities"]

概率永远不会为负：

Wolfram Language code: AllTrue[proba, NonNegative]

概率的总和总是为一：

Wolfram Language code: Total[proba]
Wolfram Research (2020)，CategoricalDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CategoricalDistribution.html.

文本

Wolfram Research (2020)，CategoricalDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CategoricalDistribution.html.

CMS

Wolfram 语言. 2020. "CategoricalDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CategoricalDistribution.html.

APA

Wolfram 语言. (2020). CategoricalDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CategoricalDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_categoricaldistribution, author="Wolfram Research", title="{CategoricalDistribution}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/CategoricalDistribution.html}", note=[Accessed: 10-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_categoricaldistribution, organization={Wolfram Research}, title={CategoricalDistribution}, year={2020}, url={https://reference.wolfram.com/language/ref/CategoricalDistribution.html}, note=[Accessed: 10-July-2026]}