WOLFRAM

Wolfram 语言与系统参考资料中心

CauchyMatrix[x,y]

表示由生成向量 x 和 y 作为结构化数组给出的柯西矩阵.

CauchyMatrix[x]

等价于 CauchyMatrix[x,x].

CauchyMatrix[cmat]

将柯西矩阵 cmat 转换为结构化数组.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
TargetStructure  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

CauchyMatrix

CauchyMatrix[x,y]

表示由生成向量 x 和 y 作为结构化数组给出的柯西矩阵.

CauchyMatrix[x]

等价于 CauchyMatrix[x,x].

CauchyMatrix[cmat]

将柯西矩阵 cmat 转换为结构化数组.

更多信息和选项

  • 当表示为结构化数组时，柯西矩阵可进行更高效的存储和更高效的运算，包括 Det、Inverse 和 LinearSolve.
  • 柯西矩阵出现在与有理插值、保形映射、n-体仿真和奇异核积分方程离散化相关的计算中.
  • 给定生成向量 x 和 y，所得的柯西矩阵 中的元素由 给出.
  • CauchyMatrix 可以加快运算速度的计算包括：
  • Det用时
    Inverse用时
    LinearSolve用时
  • 对于 CauchyMatrix sa，可通过 sa["prop"] 访问以下属性 "prop"：
  • "XVector"生成向量 x
    "YVector"生成向量 y
    "Properties"支持的属性的列表
    "Structure"结构化数组的类型
    "StructuredData"结构化数组存储的内部数据
    "StructuredAlgorithms"可对结构化数组使用特殊方法的函数的列表
    "Summary"汇总信息，用 Dataset 表示
  • Normal[CauchyMatrix[x]] 以普通矩阵的方式给出柯西矩阵.
  • CauchyMatrix[…,TargetStructure->struct] 以 struct 指定的格式返回柯西矩阵. 可能的设置包括：
  • Automatic自动选择返回的表示
    "Dense"以稠密矩阵的形式表示矩阵
    "Structured"以结构化数组的形式表示矩阵
    "Symmetric"将矩阵表示为对称矩阵
  • CauchyMatrix[…,TargetStructureAutomatic] 等价于 CauchyMatrix[…,TargetStructure"Structured"].

范例

打开所有单元 关闭所有单元

基本范例  (2)

构建柯西矩阵：

Wolfram Language code: cm = CauchyMatrix[{1, 2, 3}, {1, 5, 6}]

显示元素：

Wolfram Language code: MatrixForm[cm]

Normal 可将 CauchyMatrix 转换成普通形式的矩阵：

Wolfram Language code: Normal[cm]

构建含有符号元素的柯西矩阵：

Wolfram Language code: cm = CauchyMatrix[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, {Subscript[y, 1], Subscript[y, 2], Subscript[y, 3]}]

显示元素：

Wolfram Language code: MatrixForm[cm]

获取行列式：

Wolfram Language code: Det[cm]

范围  (6)

生成一个对称的柯西矩阵：

Wolfram Language code: cm = CauchyMatrix[Array[, 3]]

显示元素：

Wolfram Language code: MatrixForm[cm]

获取普通形式的矩阵：

Wolfram Language code: Normal[cm]

生成矩形柯西矩阵：

Wolfram Language code: cm = CauchyMatrix[Range[5], Range[3]]

显示元素：

Wolfram Language code: MatrixForm[cm]

显示元素：

Wolfram Language code: Normal[cm]

以结构化数组的形式表示稠密柯西矩阵：

Wolfram Language code: cm = CauchyMatrix[(⁠| | | | | | | | | ------ | ------ | ------ | ------ | ------ | ------ | ------- | | (1/13) | (1/11) | (1/9) | (1/7) | (1/5) | (1/3) | 1 | | (1/11) | (1/9) | (1/7) | (1/5) | (1/3) | 1 | -1 | | (1/9) | (1/7) | (1/5) | (1/3) | 1 | -1 | -(1/3) | | (1/7) | (1/5) | (1/3) | 1 | -1 | -(1/3) | -(1/5) | | (1/5) | (1/3) | 1 | -1 | -(1/3) | -(1/5) | -(1/7) | | (1/3) | 1 | -1 | -(1/3) | -(1/5) | -(1/7) | -(1/9) | | 1 | -1 | -(1/3) | -(1/5) | -(1/7) | -(1/9) | -(1/11) |⁠)]

显示元素：

Wolfram Language code: MatrixForm[cm]

结构化表示通常使用更少的内存：

Wolfram Language code: ByteCount[cm = CauchyMatrix[N[Range[30]], 0.5 - N[Range[30]]]]
Wolfram Language code: ByteCount[Normal[cm]]

CauchyMatrix 对象含有可给出有关数组信息的属性：

Wolfram Language code: cm = CauchyMatrix[Subdivide[-1, 1, 5], Subdivide[-2, 2, 5]]
Wolfram Language code: cm["Properties"]

"XVector" 和 "YVector" 属性给出了柯西矩阵的生成向量：

Wolfram Language code: cm["XVector"]
Wolfram Language code: cm["YVector"]

"Summary" 属性给出了有关数组的信息的简明摘要：

Wolfram Language code: cm["Summary"]

"StructuredAlgorithms" 属性列出了含有结构化算法的函数：

Wolfram Language code: cm["StructuredAlgorithms"]

合适的情况下，结构化算法会返回另一个 CauchyMatrix 对象：

Wolfram Language code: cm = CauchyMatrix[Range[5], Range[3]]

转置也是一个 CauchyMatrix：

Wolfram Language code: Transpose[cm]

柯西矩阵及其转置的乘积不再是柯西矩阵：

Wolfram Language code: Transpose[cm].cm

选项  (1)

TargetStructure  (1)

以稠密矩阵的形式返回柯西矩阵：

Wolfram Language code: CauchyMatrix[{1, 5, 6}, TargetStructure -> "Dense"]

以结构化数组的形式返回柯西矩阵：

Wolfram Language code: CauchyMatrix[{1, 5, 6}, TargetStructure -> "Structured"]

将柯西矩阵返回为对称矩阵：

Wolfram Language code: CauchyMatrix[{1, 5, 6}, TargetStructure -> "Symmetric"]

应用  (3)

将 Hilbert 矩阵表示为 CauchyMatrix：

Wolfram Language code: hilbert[n_] := CauchyMatrix[Range[n], Range[0, n - 1]]

与 HilbertMatrix 比较：

Wolfram Language code: Table[hilbert[n] == HilbertMatrix[n], {n, 2, 5}]

用数值法计算大型希尔伯特矩阵的逆：

Wolfram Language code: {AbsoluteTiming[i1 = Inverse[N[hilbert[19]]];], AbsoluteTiming[i2 = Inverse[N[HilbertMatrix[19]]];]}

用结构化版本得到结果更准确：

Wolfram Language code: exact = Inverse[HilbertMatrix[19]]; {Norm[i1 - exact, ∞], Norm[i2 - exact, ∞]} / Norm[exact, ∞]

用 CauchyMatrix 计算具有固定极点的插值有理函数的系数：

Wolfram Language code: poles = N[Exp[2π I Range[0, 4] / 5]]; pts = {{-1, 0}, {-I, (1/2) - (I/2)}, {0, 1}, {I, (1/2) + (I/2)}, {2, -1}};coef = LinearSolve[CauchyMatrix[pts[[All, 1]], -poles], pts[[All, 2]]]

构建有理函数：

Wolfram Language code: ratInt[z_] = Total[coef / (z - poles)]

可视化复平面中的插值：

Wolfram Language code: ComplexPlot3D[ratInt[z], {z, -2 - 2I, 2 + 2I}, ColorFunction -> {Automatic, None}]

检查有理插值是否经过所有给定点：

Wolfram Language code: (ratInt /@ pts[[All, 1]]) - pts[[All, 2]]//Chop

用 CauchyMatrix 定义 Parter 矩阵：

Wolfram Language code: parter[n_] := CauchyMatrix[Range[n], 1 / 2 - Range[n]]

Parter 矩阵既是 Cauchy 矩阵，也是 Toeplitz 矩阵：

Wolfram Language code: MatrixForm[parter[5]]
Wolfram Language code: With[{n = 5}, ToeplitzMatrix[1 / (Range[n] - 1 / 2), 1 / (3 / 2 - Range[n])]]//MatrixForm

Parter matrix 矩阵的主奇异值聚集在 周围：

Wolfram Language code: SingularValueList[N[parter[20]]]
Wolfram Language code: % - π

属性和关系  (2)

将柯西矩阵表示为对角矩阵、范德蒙矩阵及其逆矩阵的乘积：

Wolfram Language code: xl = {x1, x2, x3, x4, x5}; yl = {y1, y2, y3, y4, y5}; CauchyMatrix[xl, yl] == DiagonalMatrix[1 / (Times@@@Outer[Plus, xl, yl])].VandermondeMatrix[xl].Inverse[VandermondeMatrix[-yl]].DiagonalMatrix[Table[Apply[Times, Delete[yl, k] - yl[[k]]], {k, Length[yl]}]]//Simplify

将柯西矩阵表示为对角矩阵、范德蒙德矩阵和汉克尔矩阵的乘积：

Wolfram Language code: xl = {x1, x2, x3, x4, x5}; yl = {y1, y2, y3, y4, y5}; CauchyMatrix[xl, yl] == DiagonalMatrix[1 / (Times@@@Outer[Plus, xl, yl])].VandermondeMatrix[xl].HankelMatrix[Rest[CoefficientList[Apply[Times, y + yl], y]]].Transpose[VandermondeMatrix[-yl]]//Simplify

可能存在的问题  (3)

文献有时使用柯西矩阵的不同定义，其中第二个生成向量被取负：

Wolfram Language code: CauchyMatrix[Array[Subscript[, #]&, 5], -Array[Subscript[, #]&, 5]]//MatrixForm

如果任一生成向量含有重复元素，则无法构建柯西矩阵：

Wolfram Language code: CauchyMatrix[{1, 1, 3}, {2, 1, 4}]

如果任一生成向量的分量是另一个生成向量的分量的负值，则无法构建柯西矩阵：

Wolfram Language code: CauchyMatrix[{1, 2, 3}, {2, -1, 4}]
Wolfram Research (2022)，CauchyMatrix，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CauchyMatrix.html （更新于 2024 年）.

文本

Wolfram Research (2022)，CauchyMatrix，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CauchyMatrix.html （更新于 2024 年）.

CMS

Wolfram 语言. 2022. "CauchyMatrix." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2024. https://reference.wolfram.com/language/ref/CauchyMatrix.html.

APA

Wolfram 语言. (2022). CauchyMatrix. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CauchyMatrix.html 年

BibTeX

@misc{reference.wolfram_2026_cauchymatrix, author="Wolfram Research", title="{CauchyMatrix}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/CauchyMatrix.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cauchymatrix, organization={Wolfram Research}, title={CauchyMatrix}, year={2024}, url={https://reference.wolfram.com/language/ref/CauchyMatrix.html}, note=[Accessed: 11-September-2026]}