WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CauchyPointProcess[μ,λ,b,d]

における，密度 μ，クラスタ平均 λ，尺度パラメータ b のコーシー(Cauchy)クラスタ点過程を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CauchyPointProcess

CauchyPointProcess[μ,λ,b,d]

における，密度 μ，クラスタ平均 λ，尺度パラメータ b のコーシー(Cauchy)クラスタ点過程を表す．

詳細

  • CauchyPointProcessは，中心が空間内で一様に分布し，クラスタ点が裾が重い動径分布に従って等方的に分布するクラスタ点配置をモデル化する．
  • 主に林業等で，例えば種子がその発生源から遠く離れて分散することがあるダイオウマツ等の樹木の位置をモデル化するために使われる．
  • クラスタの中心は，密度が μ のPoissonPointProcessに従って分布する．
  • クラスタの点の数は，平均が λ のPoissonDistributionに従って分布する．
  • における各クラスタのクラスタ点はCauchyDistribution[0,b]に従って分布する．
  • におけるクラスタ点は，クラスタの中心を中心とするMultivariateTDistribution[DiagonalMatrix[{b2,b2,…}],1]に従って分布する．
  • CauchyPointProcessでは， μ，λ，b は任意の正の実数でよく，d は任意の正の整数でよい．
  • PointProcessEstimatorについてCauchyPointProcessを推定するために以下の設定を使うことができる．
  • "FindClusters"FindClusters関数を使う
    "MethodOfMoments"均一性尺度を使ってパラメータを推定する
  • CauchyPointProcessは，RipleyK，PointCountDistribution，RandomPointConfiguration等の関数と一緒に使うことができる．

例題

すべて開く すべて閉じる

例  (3)

単位円板上でコーシー点過程からサンプルを取る：

Wolfram Language code: pts = RandomPointConfiguration[CauchyPointProcess[10, 20, .01, 2], Disk[]]
Wolfram Language code: Show[RegionPlot[pts["ObservationRegion"]], ListPlot[pts]]

単位球上でコーシー点過程からサンプルを取る：

Wolfram Language code: pts = RandomPointConfiguration[CauchyPointProcess[30, 20, .01, 3], Ball[]]
Wolfram Language code: Show[RegionPlot3D[pts["ObservationRegion"], PlotStyle -> Opacity[.2], Boxed -> False], ListPointPlot3D[pts]]

地理領域上でコーシー点過程からサンプルを取る：

Wolfram Language code: proc = CauchyPointProcess[.006, .3, .1, 2];
Wolfram Language code: pts = RandomPointConfiguration[proc, Entity["Country", "Poland"]]
Wolfram Language code: GeoListPlot[pts]

スコープ  (3)

次元が埋込み次元と等しい有効な領域からサンプルを取る：

Wolfram Language code: ℛ = ImplicitRegion[x ^ 2 - 2y ^ 2 <= 1, {{x, -3, 3}, {y, -4, 4}}];
Wolfram Language code: {RegionQ[ℛ], RegionEmbeddingDimension[ℛ] == RegionDimension[ℛ]}

領域内のコーシー点過程からサンプルを取って点を可視化する：

Wolfram Language code: pts = RandomPointConfiguration[CauchyPointProcess[4, 15, 0.05, 2], ℛ]
Wolfram Language code: Show[RegionPlot[pts["ObservationRegion"]], ListPlot[pts]]

シミュレーションを行って推定する：

Wolfram Language code: proc = CauchyPointProcess[20, 30, 1, 2]; points = RandomPointConfiguration[proc, Rectangle[]];
Wolfram Language code: PointValuePlot[points]

"FindClusters"法を使って点過程モデルを推定する：

Wolfram Language code: est = EstimatedPointProcess[points, CauchyPointProcess[a, b, c, d], PointProcessEstimator -> "FindClusters"]

もとの過程と推定モデルのRipley 測度を比較する：

Wolfram Language code: DiscretePlot[{RipleyK[proc, r], RipleyK[est, r]}, {r, 0.1, .5, .005}, PlotLegends -> {"original process", "estimated model"}]

コーシー点過程の対相関関数：

Wolfram Language code: pcf = PairCorrelationG[CauchyPointProcess[μ, λ, b, 3], r]

与えられたパラメータ値で関数を可視化する：

Wolfram Language code: Plot[pcf /. {μ -> 3, λ -> 2, b -> 1}, {r, 0, 3}]

特性と関係  (6)

PointCountDistributionは既知である：

Wolfram Language code: proc = CauchyPointProcess[4, 15, .1, 2];
Wolfram Language code: dist = PointCountDistribution[proc, Disk[]]

平均と分散：

Wolfram Language code: {Mean[dist], Variance[dist]}

確率密度関数をプロットする：

Wolfram Language code: DiscretePlot[PDF[dist, x], {x, 50, 400, 5}]

分布のシミュレーションを行う：

Wolfram Language code: sample = RandomVariate[dist, 10 ^ 4];

確率密度ヒストグラム：

Wolfram Language code: Histogram[sample, 30, "PDF"]

2Dにおけるコーシー点過程についてのRipleyの 関数とBesagの 関数：

Wolfram Language code: proc = CauchyPointProcess[μ, λ, b, 2];
Wolfram Language code: f1 = RipleyK[proc, r]
Wolfram Language code: f2 = BesagL[proc, r]
Wolfram Language code: Block[{μ = 20, λ = 10, b = .5}, Plot[{f1, f2}, {r, 0, 1}, PlotLegends -> {"Ripley's K", "Besag's L"}]]

コーシー点過程のRipleyの 関数はポアソン(Poisson)点過程についてよりも大きい：

Wolfram Language code: cproc = CauchyPointProcess[μ, λ, b, d];
Wolfram Language code: RipleyK[cproc][r]

ポアソン点過程と比較する：

Wolfram Language code: pproc = PoissonPointProcess[μ, d];
Wolfram Language code: RipleyK[pproc][r]

コーシー点過程についてのBesagの 関数はポアソン点過程についてよりも大きい：

Wolfram Language code: cproc = CauchyPointProcess[μ, λ, b, d];
Wolfram Language code: BesagL[cproc][r]//Together

ポアソン点過程と比較する：

Wolfram Language code: pproc = PoissonPointProcess[μ, d];
Wolfram Language code: BesagL[pproc][r]

コーシー点過程の対相関は1より大きい：

Wolfram Language code: PairCorrelationG[CauchyPointProcess[μ, λ, b, d], r]

同次ポアソン点過程と比較する：

Wolfram Language code: PairCorrelationG[PoissonPointProcess[μ, d], r]

3Dにおけるコーシー点過程の空空間関数：

Wolfram Language code: proc = CauchyPointProcess[4, 15, 0.05, 3];
Wolfram Language code: DiscretePlot[EmptySpaceF[proc, r], {r, 0.02, .5, 0.01}]
Wolfram Research (2020), CauchyPointProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/CauchyPointProcess.html.

テキスト

Wolfram Research (2020), CauchyPointProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/CauchyPointProcess.html.

CMS

Wolfram Language. 2020. "CauchyPointProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CauchyPointProcess.html.

APA

Wolfram Language. (2020). CauchyPointProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CauchyPointProcess.html

BibTeX

@misc{reference.wolfram_2026_cauchypointprocess, author="Wolfram Research", title="{CauchyPointProcess}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/CauchyPointProcess.html}", note=[Accessed: 19-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_cauchypointprocess, organization={Wolfram Research}, title={CauchyPointProcess}, year={2020}, url={https://reference.wolfram.com/language/ref/CauchyPointProcess.html}, note=[Accessed: 19-August-2026]}