WOLFRAM

Wolfram 语言与系统参考资料中心

CauchyPointProcess[μ,λ,b,d]

表示 中的一个柯西聚点过程，其密度为 μ，聚类平均值为 λ，缩放参数为 b.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
参见
相关指南
历史
按以下格式引用：

CauchyPointProcess

CauchyPointProcess[μ,λ,b,d]

表示 中的一个柯西聚点过程，其密度为 μ，聚类平均值为 λ，缩放参数为 b.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

单位圆盘上柯西点过程的抽样：

Wolfram Language code: pts = RandomPointConfiguration[CauchyPointProcess[10, 20, .01, 2], Disk[]]
Wolfram Language code: Show[RegionPlot[pts["ObservationRegion"]], ListPlot[pts]]

单位圆球上柯西点过程的抽样：

Wolfram Language code: pts = RandomPointConfiguration[CauchyPointProcess[30, 20, .01, 3], Ball[]]
Wolfram Language code: Show[RegionPlot3D[pts["ObservationRegion"], PlotStyle -> Opacity[.2], Boxed -> False], ListPointPlot3D[pts]]

地理区域上柯西点过程的抽样：

Wolfram Language code: proc = CauchyPointProcess[.006, .3, .1, 2];
Wolfram Language code: pts = RandomPointConfiguration[proc, Entity["Country", "Poland"]]
Wolfram Language code: GeoListPlot[pts]

范围  (3)

一个维数等于其嵌入维数的可行域中的抽样：

Wolfram Language code: ℛ = ImplicitRegion[x ^ 2 - 2y ^ 2 <= 1, {{x, -3, 3}, {y, -4, 4}}];
Wolfram Language code: {RegionQ[ℛ], RegionEmbeddingDimension[ℛ] == RegionDimension[ℛ]}

区域中柯西点过程的抽样并可视化这些点：

Wolfram Language code: pts = RandomPointConfiguration[CauchyPointProcess[4, 15, 0.05, 2], ℛ]
Wolfram Language code: Show[RegionPlot[pts["ObservationRegion"]], ListPlot[pts]]

模拟并计算：

Wolfram Language code: proc = CauchyPointProcess[20, 30, 1, 2]; points = RandomPointConfiguration[proc, Rectangle[]];
Wolfram Language code: PointValuePlot[points]

使用 "FindClusters" 方法计算点过程模型：

Wolfram Language code: est = EstimatedPointProcess[points, CauchyPointProcess[a, b, c, d], PointProcessEstimator -> "FindClusters"]

比较原始过程和计算出的模型之间的 Ripley 作为度量标准：

Wolfram Language code: DiscretePlot[{RipleyK[proc, r], RipleyK[est, r]}, {r, 0.1, .5, .005}, PlotLegends -> {"original process", "estimated model"}]

柯西点过程的对关联函数：

Wolfram Language code: pcf = PairCorrelationG[CauchyPointProcess[μ, λ, b, 3], r]

用给定参数值可视化该函数：

Wolfram Language code: Plot[pcf /. {μ -> 3, λ -> 2, b -> 1}, {r, 0, 3}]

属性和关系  (6)

已知 PointCountDistribution：

Wolfram Language code: proc = CauchyPointProcess[4, 15, .1, 2];
Wolfram Language code: dist = PointCountDistribution[proc, Disk[]]

平均值和方差：

Wolfram Language code: {Mean[dist], Variance[dist]}

绘制概率密度函数：

Wolfram Language code: DiscretePlot[PDF[dist, x], {x, 50, 400, 5}]

模拟该分布：

Wolfram Language code: sample = RandomVariate[dist, 10 ^ 4];

概率密度直方图：

Wolfram Language code: Histogram[sample, 30, "PDF"]

二维空间中柯西点过程的 Ripley's 和 Besag's ：

Wolfram Language code: proc = CauchyPointProcess[μ, λ, b, 2];
Wolfram Language code: f1 = RipleyK[proc, r]
Wolfram Language code: f2 = BesagL[proc, r]
Wolfram Language code: Block[{μ = 20, λ = 10, b = .5}, Plot[{f1, f2}, {r, 0, 1}, PlotLegends -> {"Ripley's K", "Besag's L"}]]

柯西点过程的 Ripley's 比泊松点过程的更大：

Wolfram Language code: cproc = CauchyPointProcess[μ, λ, b, d];
Wolfram Language code: RipleyK[cproc][r]

与泊松点过程比较：

Wolfram Language code: pproc = PoissonPointProcess[μ, d];
Wolfram Language code: RipleyK[pproc][r]

柯西点过程的 Besag's 比泊松点过程的更大：

Wolfram Language code: cproc = CauchyPointProcess[μ, λ, b, d];
Wolfram Language code: BesagL[cproc][r]//Together

与泊松点过程对比：

Wolfram Language code: pproc = PoissonPointProcess[μ, d];
Wolfram Language code: BesagL[pproc][r]

柯西点过程的对关联大于 1：

Wolfram Language code: PairCorrelationG[CauchyPointProcess[μ, λ, b, d], r]

与同类的泊松点过程进行比较：

Wolfram Language code: PairCorrelationG[PoissonPointProcess[μ, d], r]

三维空间中柯西点过程的空白空间函数：

Wolfram Language code: proc = CauchyPointProcess[4, 15, 0.05, 3];
Wolfram Language code: DiscretePlot[EmptySpaceF[proc, r], {r, 0.02, .5, 0.01}]
Wolfram Research (2020)，CauchyPointProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CauchyPointProcess.html.

文本

Wolfram Research (2020)，CauchyPointProcess，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CauchyPointProcess.html.

CMS

Wolfram 语言. 2020. "CauchyPointProcess." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CauchyPointProcess.html.

APA

Wolfram 语言. (2020). CauchyPointProcess. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CauchyPointProcess.html 年

BibTeX

@misc{reference.wolfram_2026_cauchypointprocess, author="Wolfram Research", title="{CauchyPointProcess}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/CauchyPointProcess.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_cauchypointprocess, organization={Wolfram Research}, title={CauchyPointProcess}, year={2020}, url={https://reference.wolfram.com/language/ref/CauchyPointProcess.html}, note=[Accessed: 09-August-2026]}