WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CenteredInterval[x,dx]

実数 x および dx に対して実数区間{a in TemplateBox[{}, Reals]|x-dx<=a<=x+dx}を含む中心がある区間を与える．

CenteredInterval[x+ y,dx+ dy]

複素長方形{a+ⅈ b in TemplateBox[{}, Complexes]|x-dx<=a<=x+dx∧y-dy<=b<=y+dy}を含む中心がある区間を与える．

CenteredInterval[c]

近似数 c に対して c の誤差境界内のすべての値を含む中心がある区間を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
中心・半径区間を構築する  
区間演算  
区間特性  
線形代数  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

CenteredInterval

CenteredInterval[x,dx]

実数 x および dx に対して実数区間{a in TemplateBox[{}, Reals]|x-dx<=a<=x+dx}を含む中心がある区間を与える．

CenteredInterval[x+ y,dx+ dy]

複素長方形{a+ⅈ b in TemplateBox[{}, Complexes]|x-dx<=a<=x+dx∧y-dy<=b<=y+dy}を含む中心がある区間を与える．

CenteredInterval[c]

近似数 c に対して c の誤差境界内のすべての値を含む中心がある区間を与える．

詳細

  • 中心がある区間は中心半径区間あるいは中半径区間としても知られている．
  • CenteredIntervalは，通常，数値計算で累積された誤差の検証済み境界を得るために使われる．中心がある区間の計算は，関数の全引数の誤差境界が与えられると関数値の誤差の信頼できる境界を与える．
  • CenteredInterval[…]は中心がある区間オブジェクトΔを，中心 ，半径 で与える． と は2つの分母をベキ乗したガウスの有理数である． と が実数ならΔは実区間を表し，それ以外の場合はΔは複素長方形を表す．
  • 中心がある区間引数は算術演算および多くの数学関数で使うことができる．f[Δ1,…,Δn]は中心がある区間オブジェクトΔを与える．これには任意の ai∈Δiについての f[a1,…,an]が含まれる．
  • IntervalMemberQは区間への帰属や区間間の包含関係の決定に使うことができる．
  • EqualやLess等の有理演算子は，互いに素な区間を与えられると常に明示的なTrueまたはFalseの結果を与える．
  • StandardFormおよび関連する形式では，CenteredIntervalオブジェクトは中心と半径の近似値しか表示されない省略形で出力される．
  • NormalはCenteredIntervalオブジェクトを確度が半径に対応する任意精度数に変換する．
  • Information[CenteredInterval[…], prop]は中心半径区間の特性 prop を与える．以下は指定可能な特性である．
  • "Center"区間の中心
    "Radius"区間の半径
    "Bounds"区間内の値の境界
  • Det，Inverse，LinearSolve，Eigensystem等の線形代数の演算は，CenteredInterval成分を持つ行列に使うことができる．

例題

すべて開く すべて閉じる

例  (3)

実区間を構築する：

Wolfram Language code: CenteredInterval[2, 10 ^ -10]

この区間で関数を評価する：

Wolfram Language code: % Log[%] + Sin[% ^ 2 + 1]

結果を任精度数に変換する：

Wolfram Language code: Normal[%]

複素区間を構築する：

Wolfram Language code: CenteredInterval[2 + 3I, 10 ^ -10 + 5 10 ^ -9 I]

この区間で関数を評価する：

Wolfram Language code: E ^ Gamma[%]

中心と半径の厳密値を抽出する：

Wolfram Language code: Information[%, {"Center", "Radius"}]

矩形上での値の境界を計算する：

Wolfram Language code: bds = Information[Exp[CenteredInterval[0, 1 + I]], "Bounds"]

矩形上での値の集合を近似する：

Wolfram Language code: reg = Region[Style[TransformedRegion[Rectangle[{-1, -1}, {1, 1}], Function[{a, b}, {E^a Cos[b], E^a Sin[b]}]], Red]];

計算された領域は境界内にある：

Wolfram Language code: Show[{Graphics[{Yellow, Rectangle@@(ReIm /@ bds)}], reg}]

スコープ  (27)

中心・半径区間を構築する  (7)

中心と半径を指定して実区間を構築する：

Wolfram Language code: CenteredInterval[2 / 3, 10 ^ -10]

中心と半径を指定して複素区間を構築する：

Wolfram Language code: CenteredInterval[2 + 3I, 1 + I]

任意精度数を指定して中心がある区間を構築する：

Wolfram Language code: CenteredInterval[1.23`20]
Wolfram Language code: CenteredInterval[1.23`20 + 4.56`30 I]
Wolfram Language code: CenteredInterval[0``7]

有界のIntervalオブジェクトを中心がある区間に変換する：

Wolfram Language code: CenteredInterval[Interval[{1, 2}]]

2進ガウス有理数は半径0の区間として厳密に表現できる：

Wolfram Language code: CenteredInterval[123 / 2 ^ 12]
Wolfram Language code: CenteredInterval[1 / 2 + 3 / 4I]

他の厳密数は非零の半径を持つ区間に変換される：

Wolfram Language code: CenteredInterval[1 / 3]
Wolfram Language code: CenteredInterval[E + I Pi]

非零の機械精度数は$MachinePrecision精度数として扱われる：

Wolfram Language code: CenteredInterval[9.87]

機械精度の0を中心・半径区間に変換する：

Wolfram Language code: CenteredInterval[0.]

区間演算  (5)

中心がある区間引数で演算操作を使う：

Wolfram Language code: {a, b} = {CenteredInterval[2, 1 / 100], CenteredInterval[3 + I / 4, (1 + I) / 20]};
Wolfram Language code: {a + b, a b, a ^ b}

中心がある区間を数学関数の引数として使う：

Wolfram Language code: Sin[CenteredInterval[1.23`4]]
Wolfram Language code: BesselJ[CenteredInterval[1, 1 / 1000], CenteredInterval[2, 1 / 1000]]

中心がある区間と数値引数の演算は中心がある区間を返す：

Wolfram Language code: a = CenteredInterval[1.234`10];
Wolfram Language code: a + Pi
Wolfram Language code: Beta[2`15, a] + 3 / 4

返された区間には入力区間内の関数のすべての値が含まれる：

Wolfram Language code: Log[#]Sin[#]&[CenteredInterval[20, 10]]
Wolfram Language code: Plot[Log[x]Sin[x], {x, 10, 30}, Epilog -> {Green, Opacity[0.25], Rectangle[{10, -#}, {30, #}]&[Information[%, "Radius"]]}]

値の集合が非有界のときは，区間演算操作はIndeterminateを返す：

Wolfram Language code: 1 / CenteredInterval[0, 1]

区間特性  (5)

実区間の特性を抽出する：

Wolfram Language code: int = CenteredInterval[1.23`20]

中心と半径は2進有理数である：

Wolfram Language code: Information[int, {"Center", "Radius"}]

区間の要素の有理境界を求める：

Wolfram Language code: Information[int, "Bounds"]
Wolfram Language code: N[%, 21]

区間を任意精度数に変換する：

Wolfram Language code: Normal[int]

複素区間の中心と半径を抽出する：

Wolfram Language code: int = CenteredInterval[N[ArcSin[2], 10]]

中心と半径は2進ガウス有理数である：

Wolfram Language code: Information[int, {"Center", "Radius"}]

区間の要素のガウス有理境界を求める：

Wolfram Language code: Information[int, "Bounds"]
Wolfram Language code: N[%, 11]

区間を任意精度数に変換する：

Wolfram Language code: Normal[int]

区間に属すかどうかをテストする：

Wolfram Language code: int = CenteredInterval[2, 1 / 2]
Wolfram Language code: IntervalMemberQ[int, 9 / 4]
Wolfram Language code: IntervalMemberQ[int, 5 / 4]

区間に含まれるかどうかをテストする：

Wolfram Language code: int1 = CenteredInterval[0, 1 + I]
Wolfram Language code: int2 = CenteredInterval[1 / 3, 1 / 3 + 1 / 3I]
Wolfram Language code: IntervalMemberQ[int1, int2]
Wolfram Language code: IntervalMemberQ[int2, int1]

区間を可視化する：

Wolfram Language code: Graphics[{{Red, Rectangle@@ReIm[Information[int1, "Bounds"]]}, {Yellow, Rectangle@@ReIm[Information[int2, "Bounds"]]}}]

実区間を比較する：

Wolfram Language code: int1 = CenteredInterval[1, 3 / 4]; int2 = CenteredInterval[2, 3 / 4]; int3 = CenteredInterval[3, 3 / 4];
Wolfram Language code: int1 < int3

区間が交差する場合は比較はできない：

Wolfram Language code: int1 < int2

IntervalIntersectionを使って交点を計算する：

Wolfram Language code: IntervalIntersection[int1, int2]

空区間はInterval[]として表される：

Wolfram Language code: IntervalIntersection[int1, int3]

線形代数  (10)

CenteredInterval行列の積：

Wolfram Language code: m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}]; n = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 2}, WorkingPrecision -> 10], {2}]; (mn = m.n)//MatrixForm

m と n のランダムな代表の mrep と nrep を求める：

Wolfram Language code: ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"] (mrep = Map[ranrep, m, {2}])//MatrixForm
Wolfram Language code: (nrep = Map[ranrep, n, {2}])//MatrixForm

mn が mrep と nrep の積を含むことを確認する：

Wolfram Language code: MapThread[IntervalMemberQ, {mn, mrep.nrep}, 2]//MatrixForm

CenteredInterval行列を整数乗する：

Wolfram Language code: (m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}])//MatrixForm
Wolfram Language code: (mpow = MatrixPower[m, 17])//MatrixForm

m のランダムな代表の mrep を求める：

Wolfram Language code: ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"] (mrep = Map[ranrep, m, {2}])//MatrixForm

mpow がMatrixPower[mrep,17]を含むことを確認する：

Wolfram Language code: MapThread[IntervalMemberQ, {mpow, MatrixPower[mrep, 17]}, 2]//MatrixForm

CenteredInterval行列の指数行列：

Wolfram Language code: (m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}])//MatrixForm
Wolfram Language code: (mexp = MatrixExp[m])//MatrixForm

m のランダムな代表の mrep を求める：

Wolfram Language code: ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"] (mrep = Map[ranrep, m, {2}])//MatrixForm

mexp が mrep の指数行列を含むことを確認する：

Wolfram Language code: MapThread[IntervalMemberQ, {mexp, MatrixExp[mrep]}, 2]//MatrixForm

CenteredInterval行列の行列式：

Wolfram Language code: (m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}])//MatrixForm
Wolfram Language code: mdet = Det[m]

m のランダムな代表 mrep を求める：

Wolfram Language code: ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"] (mrep = Map[ranrep, m, {2}])//MatrixForm

mdet が mrep の行列式を含むことを確認する：

Wolfram Language code: IntervalMemberQ[mdet, Det[mrep]]

CenteredInterval行列の逆行列：

Wolfram Language code: (m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}])//MatrixForm
Wolfram Language code: (minv = Inverse[m])//MatrixForm

m のランダムな代表の mrep を求める：

Wolfram Language code: ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"] (mrep = Map[ranrep, m, {2}])//MatrixForm

minv が mrep の逆行列を含むことを確認する：

Wolfram Language code: MapThread[IntervalMemberQ, {minv, Inverse[mrep]}, 2]//MatrixForm

CenteredInterval行列について を解く：

Wolfram Language code: m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}]; b = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 2}, WorkingPrecision -> 10], {2}]; (sol = LinearSolve[m, b])//MatrixForm

m と b のランダムな代表の mrep と brep を求める：

Wolfram Language code: ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"] (mrep = Map[ranrep, m, {2}])//MatrixForm
Wolfram Language code: (brep = Map[ranrep, b, {2}])//MatrixForm

sol がLinearSolve[mrep,brep]を含むことを確認する：

Wolfram Language code: MapThread[IntervalMemberQ, {sol, LinearSolve[mrep, brep]}, 2]//MatrixForm

CenteredInterval行列の固有系：

Wolfram Language code: SeedRandom[777];(m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}])//MatrixForm
Wolfram Language code: {vals, vecs} = Eigensystem[m]

m のランダムな代表 mrep の固有系を求める：

Wolfram Language code: ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"] (mrep = Map[ranrep, m, {2}])//MatrixForm
Wolfram Language code: {rvals, rvecs} = Eigensystem[mrep]

ベクトルを並べ替えてスケーリングし直した後で，vals が rvals，vecs が rvecs を含むことを確認する：

Wolfram Language code: MapThread[IntervalMemberQ, {vals, rvals[[{3, 1, 2}]]}]
Wolfram Language code: MapThread[IntervalMemberQ, {vecs, rvecs[[{3, 1, 2}]] * (Last[#]["Center"]& /@ vecs)}, 2]

CenteredInterval行列のLU分解：

Wolfram Language code: (m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}])//MatrixForm
Wolfram Language code: MatrixForm /@ ({l, u, p, c} = LUDecomposition[m])

分解を検証する：

Wolfram Language code: MapThread[IntervalMemberQ, {l.u, p.m}, 2]//MatrixForm

実対称正定値CenteredInterval行列のコレスキー(Cholesky)分解：

Wolfram Language code: rm = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}]; (m = rm.Transpose[rm])//MatrixForm
Wolfram Language code: (q = CholeskyDecomposition[m])//MatrixForm
Wolfram Language code: MapThread[IntervalMemberQ, {Transpose[q].q, m}, 2]//MatrixForm

CenteredInterval行列の固有多項式：

Wolfram Language code: (m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}])//MatrixForm
Wolfram Language code: p = CharacteristicPolynomial[m, x]

m のランダムな代表 mrep を求める：

Wolfram Language code: ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"] (mrep = Map[ranrep, m, {2}])//MatrixForm

p の係数が mrep の固有多項式の係数を含むことを確認する：

Wolfram Language code: MapThread[IntervalMemberQ, {CoefficientList[p, x], CoefficientList[CharacteristicPolynomial[mrep, x], x]}]

特性と関係  (2)

区間演算は計算誤差の検証された境界を与える：

Wolfram Language code: a = CenteredInterval[1, 1 / 10];

なので，についての誤差はで有界である：

Wolfram Language code: a ^ 2

任意精度数演算は線形項に基づいて誤差を推定してを得る：

Wolfram Language code: CenteredInterval[Normal[a] ^ 2]

Intervalは端点を指定することで与えられた実区間を表す：

Wolfram Language code: Interval[{1, 2}]

区間をCenteredInterval表現に変換する：

Wolfram Language code: CenteredInterval[%]

変換し直す：

Wolfram Language code: Interval[Information[%, "Bounds"]]

区間の端点が2進有理数ではないときは，変換によって区間が大きくなる：

Wolfram Language code: Interval[{0, 1 / 3}]
Wolfram Language code: CenteredInterval[%]
Wolfram Language code: Interval[Information[%, "Bounds"]]
Wolfram Language code: N[%[[1]] - %%%[[1]]]

考えられる問題  (1)

CenteredIntervalは有界の区間しか表せない：

Wolfram Language code: Tan[CenteredInterval[N[Pi / 2, 20]]]

Interval表現には非有界区間も使うことができる：

Wolfram Language code: Tan[Interval[N[Pi / 2, 20]]]
Wolfram Research (2021), CenteredInterval, Wolfram言語関数， https://reference.wolfram.com/language/ref/CenteredInterval.html.

テキスト

Wolfram Research (2021), CenteredInterval, Wolfram言語関数， https://reference.wolfram.com/language/ref/CenteredInterval.html.

CMS

Wolfram Language. 2021. "CenteredInterval." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CenteredInterval.html.

APA

Wolfram Language. (2021). CenteredInterval. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CenteredInterval.html

BibTeX

@misc{reference.wolfram_2026_centeredinterval, author="Wolfram Research", title="{CenteredInterval}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/CenteredInterval.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_centeredinterval, organization={Wolfram Research}, title={CenteredInterval}, year={2021}, url={https://reference.wolfram.com/language/ref/CenteredInterval.html}, note=[Accessed: 14-August-2026]}