WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CepstrumArray[data]

data のパワーケプストラムを計算する．

CepstrumArray[data,type]

data のケプストラムの指定された type を計算する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
関連項目
関連するガイド
履歴
引用書式

CepstrumArray

CepstrumArray[data]

data のパワーケプストラムを計算する．

CepstrumArray[data,type]

data のケプストラムの指定された type を計算する．

詳細とオプション

  • ケプストラム解析は，信号処理におけるエコーの特徴付け，たたみ込まれた信号の分離，ピッチ抽出アプリケーションに使われてきた．
  • 実ケプストラムは，対数振幅フーリエ(Fourier)スペクトルの逆フーリエ変換として計算される．
  • data は次の任意のものでよい．
  • list任意階数の数値配列またはQuantity配列
    audioAudioオブジェクトまたはSoundオブジェクト
    image任意のImageオブジェクトまたはImage3Dオブジェクト
    videoVideoオブジェクト
  • type 指定は次のどちらでもよい．
  • "Power"|F^(-1)log(TemplateBox[{{F, (, data, )}}, Abs]^2)|^2
    "Real"TemplateBox[{Re, paclet:ref/Re}, RefLink, BaseStyle -> {2ColumnTableMod}](F^(-1)log(TemplateBox[{{F, (, data, )}}, Abs]))
  • 多チャンネル画像および音声信号については，CepstrumArrayは各チャンネルについて別々に返される．
  • CepstrumArrayはFourierParametersオプションを取る．デフォルト設定はFourierParameters->{1,-1}である．

例題

すべて開く すべて閉じる

例  (2)

リストのケプストラム：

Wolfram Language code: CepstrumArray[{1, 1, 2, 2, 1, 1, 0, 0}]

Audioオブジェクトのケプストラム：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];
Wolfram Language code: CepstrumArray[a]

パワーケプストラムをプロットする：

Wolfram Language code: ListLinePlot[Take[%, {20, 500}]]

スコープ  (7)

リストの実ケプストラム：

Wolfram Language code: CepstrumArray[{1, 1, 2, 2, 1, 1, 0, 0}, "Real"]

2Dリストのケプストラム：

Wolfram Language code: a = RandomComplex[1 + I, {3, 3}]; a//MatrixForm
Wolfram Language code: CepstrumArray[a]//MatrixForm

Soundのケプストラムを計算する：

Wolfram Language code: a = ExampleData[{"Sound", "Apollo11ReturnSafely"}]
Wolfram Language code: CepstrumArray[a]
Wolfram Language code: ListLinePlot[Take[%, {20, 500}], PlotRange -> All]

多チャンネルAudioオブジェクトのケプストラム：

Wolfram Language code: a = ExampleData[{"Audio", "Bee"}];
Wolfram Language code: CepstrumArray[a, "Real"]

ケプストラムは各チャンネルについて別々に計算される：

Wolfram Language code: ListLinePlot[Take[%, All, {20, 500}], PlotRange -> All]

動画オブジェクトの音声トラックのケプストラムを計算する：

Wolfram Language code: CepstrumArray[\!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-2sfji)"]\)]
Wolfram Language code: ListLinePlot[Take[%[[1]], {20, 500}], PlotRange -> All]

Imageオブジェクトのケプストラム：

Wolfram Language code: a = [image];
Wolfram Language code: CepstrumArray[a]

パワーケプストラムのプロット：

Wolfram Language code: MatrixPlot[RotateLeft[Log@%, {150, 150}], PlotTheme -> "Minimal"]

多チャンネル画像のケプストラム：

Wolfram Language code: a = [image];
Wolfram Language code: c = CepstrumArray[a];

ケプストラムは各チャンネルについて別々に計算される：

Wolfram Language code: Dimensions@c
Wolfram Language code: Table[MatrixPlot[RotateLeft[Log[cc], Round[Dimensions[cc] / 2]], PlotTheme -> "Minimal"], {cc, c}]

アプリケーション  (3)

信号に対する櫛形フィルタの影響を検知する：

Wolfram Language code: data = Table[2 Sin[0.05π n ] + Sin[0.154 π n] + RandomReal[{-1, 1}] / 10., {n, 0, 1023}];

この信号には2つの正弦波成分しかない：

Wolfram Language code: dtf = TransferFunctionModel[(1/1 - 0.8 z^-31), z, SamplingPeriod -> 1]

31サンプルの遅延がある櫛形フィルタを適用する：

Wolfram Language code: y = RecurrenceFilter[dtf, data];

従来のスペクトル分析を使って櫛形フィルタの周期性を識別するのは簡単ではない：

Wolfram Language code: Periodogram[{data, y}]

収束のケプストラムは2つの成分のケプストラの合計なので，櫛形フィルタによるピークの識別が簡単である：

Wolfram Language code: ListLinePlot[{CepstrumArray[data][[ ;; 100]], CepstrumArray[y][[ ;; 100]]}, PlotRange -> .2]

エコーの時間定数を測定する：

Wolfram Language code: a = AudioDelay[Import["ExampleData/rule30.wav"], Quantity[0.6, "Seconds"], .6, PaddingSize -> 4]

ケプストラムの対数を計算し，後ろ半分を削除する（実ケプストラムは対称である）：

Wolfram Language code: cepstrum = CepstrumArray[a]; cepstrum = Log[cepstrum[[ ;; Length[cepstrum] / 2]]];

峰を求める：

Wolfram Language code: peaks = FindPeaks[cepstrum, 1, 2, -2]

結果をプロットする：

Wolfram Language code: ListLinePlot[cepstrum, PlotRange -> All, Epilog -> {Red, Point[peaks]}]

最大の峰の位置を選ぶ：

Wolfram Language code: quefrency = MaximalBy[peaks, Last][[1, 1]] - 1

ケフレンシをサンプルレートで割って周期を計算する：

Wolfram Language code: UnitConvert[N@quefrency / AudioSampleRate[a], "s"]

録音のピッチを検知する：

Wolfram Language code: a = ExampleData[{"Sound", "Oboe"}, "Audio"]

倍音では，ピッチはスペクトルの最大の峰には対応しない：

Wolfram Language code: Periodogram[a, 4000]

ケプストラムを計算し，対称部分を削除する：

Wolfram Language code: cepstrum = CepstrumArray[a]; cepstrum = cepstrum[[ ;; Length[cepstrum] / 2]];

峰を求め結果を表示する：

Wolfram Language code: peaks = FindPeaks[cepstrum, 1, .1]
Wolfram Language code: ListLinePlot[cepstrum[[ ;; 1000]], PlotRange -> {0, 1}, Epilog -> {Red, Point[peaks]}]

ゼロケフレンシに対応する峰は削除され，最大の峰が選ばれる：

Wolfram Language code: quefrency = MaximalBy[Select[peaks, #[[1]] > 1&], Last][[1, 1]] - 1

サンプルレートをケフレンシで割って基本周波数を計算する：

Wolfram Language code: ff = AudioSampleRate[a] / quefrency

結果を確認する：

Wolfram Language code: AudioGenerator[{"Sin", ff}]
Wolfram Research (2017), CepstrumArray, Wolfram言語関数， https://reference.wolfram.com/language/ref/CepstrumArray.html （2024年に更新）.

テキスト

Wolfram Research (2017), CepstrumArray, Wolfram言語関数， https://reference.wolfram.com/language/ref/CepstrumArray.html （2024年に更新）.

CMS

Wolfram Language. 2017. "CepstrumArray." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/CepstrumArray.html.

APA

Wolfram Language. (2017). CepstrumArray. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CepstrumArray.html

BibTeX

@misc{reference.wolfram_2026_cepstrumarray, author="Wolfram Research", title="{CepstrumArray}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/CepstrumArray.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_cepstrumarray, organization={Wolfram Research}, title={CepstrumArray}, year={2024}, url={https://reference.wolfram.com/language/ref/CepstrumArray.html}, note=[Accessed: 18-August-2026]}