WOLFRAM

Wolfram 语言与系统参考资料中心

CepstrumArray[data]

计算 data 的功率倒频谱.

CepstrumArray[data,type]

计算 type 的指定 data 的倒频谱.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
参见
相关指南
历史
按以下格式引用：

CepstrumArray

CepstrumArray[data]

计算 data 的功率倒频谱.

CepstrumArray[data,type]

计算 type 的指定 data 的倒频谱.

更多信息和选项

  • 在信号处理中，倒频谱分析被用于回声特性分析、卷积信号分离、音高检测.
  • 实数倒频谱的计算方法为：傅立叶频谱幅值的对数的逆傅立叶变换.
  • data 可为以下形式：
  • list任意维数的数值数组或 Quantity 数组
    audioAudio 或 Sound 对象
    image任意 Image 或 Image3D 对象
    videoVideo 对象
  • type 指定可为以下任意一个：
  • "Power"|F^(-1)log(TemplateBox[{{F, (, data, )}}, Abs]^2)|^2
    "Real"TemplateBox[{Re, paclet:ref/Re}, RefLink, BaseStyle -> {2ColumnTableMod}](F^(-1)log(TemplateBox[{{F, (, data, )}}, Abs]))
  • 对于多通道图像和音频对象，对每个通道分别计算 CepstrumArray.
  • CepstrumArray 接受 FourierParameters 选项. 默认设置为 FourierParameters->{1,-1}.

范例

打开所有单元 关闭所有单元

基本范例  (2)

列表的倒频谱：

Wolfram Language code: CepstrumArray[{1, 1, 2, 2, 1, 1, 0, 0}]

Audio 对象的倒频谱：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];
Wolfram Language code: CepstrumArray[a]

功率倒频谱图：

Wolfram Language code: ListLinePlot[Take[%, {20, 500}]]

范围  (7)

列表的实数倒频谱：

Wolfram Language code: CepstrumArray[{1, 1, 2, 2, 1, 1, 0, 0}, "Real"]

二维列表的倒频谱：

Wolfram Language code: a = RandomComplex[1 + I, {3, 3}]; a//MatrixForm
Wolfram Language code: CepstrumArray[a]//MatrixForm

计算 Sound 的倒频谱：

Wolfram Language code: a = ExampleData[{"Sound", "Apollo11ReturnSafely"}]
Wolfram Language code: CepstrumArray[a]
Wolfram Language code: ListLinePlot[Take[%, {20, 500}], PlotRange -> All]

多通道 Audio 对象的倒频谱：

Wolfram Language code: a = ExampleData[{"Audio", "Bee"}];
Wolfram Language code: CepstrumArray[a, "Real"]

分别计算每个通道的倒频谱：

Wolfram Language code: ListLinePlot[Take[%, All, {20, 500}], PlotRange -> All]

计算视频对象音轨的倒频谱：

Wolfram Language code: CepstrumArray[\!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-2sfji)"]\)]
Wolfram Language code: ListLinePlot[Take[%[[1]], {20, 500}], PlotRange -> All]

Image 的倒频谱：

Wolfram Language code: a = [image];
Wolfram Language code: CepstrumArray[a]

绘制功率倒频谱：

Wolfram Language code: MatrixPlot[RotateLeft[Log@%, {150, 150}], PlotTheme -> "Minimal"]

多通道图像的倒频谱：

Wolfram Language code: a = [image];
Wolfram Language code: c = CepstrumArray[a];

分别计算每个通道的倒频谱：

Wolfram Language code: Dimensions@c
Wolfram Language code: Table[MatrixPlot[RotateLeft[Log[cc], Round[Dimensions[cc] / 2]], PlotTheme -> "Minimal"], {cc, c}]

应用  (3)

检查梳状滤波器对信号的滤波效果：

Wolfram Language code: data = Table[2 Sin[0.05π n ] + Sin[0.154 π n] + RandomReal[{-1, 1}] / 10., {n, 0, 1023}];

信号只有两个正弦分量：

Wolfram Language code: dtf = TransferFunctionModel[(1/1 - 0.8 z^-31), z, SamplingPeriod -> 1]

应用延迟为 31 个样本的梳状滤波器：

Wolfram Language code: y = RecurrenceFilter[dtf, data];

用传统的频谱分析来识别梳状滤波器的周期性并不容易：

Wolfram Language code: Periodogram[{data, y}]

由于卷积的倒频谱是两个分量的倒频谱的和，因此更容易识别由梳状滤波器引起的峰值：

Wolfram Language code: ListLinePlot[{CepstrumArray[data][[ ;; 100]], CepstrumArray[y][[ ;; 100]]}, PlotRange -> .2]

测量回声的时间常数：

Wolfram Language code: a = AudioDelay[Import["ExampleData/rule30.wav"], Quantity[0.6, "Seconds"], .6, PaddingSize -> 4]

计算倒频谱的对数，丢弃后面一半数据（实数倒频谱是对称的）：

Wolfram Language code: cepstrum = CepstrumArray[a]; cepstrum = Log[cepstrum[[ ;; Length[cepstrum] / 2]]];

求峰值：

Wolfram Language code: peaks = FindPeaks[cepstrum, 1, 2, -2]

绘制结果：

Wolfram Language code: ListLinePlot[cepstrum, PlotRange -> All, Epilog -> {Red, Point[peaks]}]

选取最大峰值的位置：

Wolfram Language code: quefrency = MaximalBy[peaks, Last][[1, 1]] - 1

倒频除以采样率，算出周期：

Wolfram Language code: UnitConvert[N@quefrency / AudioSampleRate[a], "s"]

检测一段录音的音高：

Wolfram Language code: a = ExampleData[{"Sound", "Oboe"}, "Audio"]

在谐波组成的声音中，音高并不对应于频谱中最高的峰值：

Wolfram Language code: Periodogram[a, 4000]

计算倒频谱并丢弃对称部分：

Wolfram Language code: cepstrum = CepstrumArray[a]; cepstrum = cepstrum[[ ;; Length[cepstrum] / 2]];

求峰值并显示结果：

Wolfram Language code: peaks = FindPeaks[cepstrum, 1, .1]
Wolfram Language code: ListLinePlot[cepstrum[[ ;; 1000]], PlotRange -> {0, 1}, Epilog -> {Red, Point[peaks]}]

丢弃对应于零倒频的峰值，选取最大峰值：

Wolfram Language code: quefrency = MaximalBy[Select[peaks, #[[1]] > 1&], Last][[1, 1]] - 1

采样率除以倒频，算出基频：

Wolfram Language code: ff = AudioSampleRate[a] / quefrency

查看结果：

Wolfram Language code: AudioGenerator[{"Sin", ff}]
Wolfram Research (2017)，CepstrumArray，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CepstrumArray.html （更新于 2024 年）.

文本

Wolfram Research (2017)，CepstrumArray，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CepstrumArray.html （更新于 2024 年）.

CMS

Wolfram 语言. 2017. "CepstrumArray." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2024. https://reference.wolfram.com/language/ref/CepstrumArray.html.

APA

Wolfram 语言. (2017). CepstrumArray. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CepstrumArray.html 年

BibTeX

@misc{reference.wolfram_2026_cepstrumarray, author="Wolfram Research", title="{CepstrumArray}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/CepstrumArray.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_cepstrumarray, organization={Wolfram Research}, title={CepstrumArray}, year={2024}, url={https://reference.wolfram.com/language/ref/CepstrumArray.html}, note=[Accessed: 13-August-2026]}