---
title: "Circle"
language: "en"
type: "Symbol"
summary: "Circle[{x, y}, r] represents a circle of radius r centered at {x, y}. Circle[{x, y}] gives a circle of radius 1. Circle[{x, y}, {rx, ry}] gives an axis-aligned ellipse with semiaxes lengths rx and ry. Circle[{x, y}, ..., {\\[Theta]1, \\[Theta]2}] gives a circular or ellipse arc from angle \\[Theta]1 to \\[Theta]2."
keywords: 
- arc of circle
- circle
- circular arc
- ellipse
- elliptical arc
- oval
- ellipse
canonical_url: "https://reference.wolfram.com/language/ref/Circle.html"
source: "Wolfram Language Documentation"
related_guides: 
  - 
    title: "Graphics Objects"
    link: "https://reference.wolfram.com/language/guide/GraphicsObjects.en.md"
  - 
    title: "Basic Geometric Regions"
    link: "https://reference.wolfram.com/language/guide/GeometricSpecialRegions.en.md"
  - 
    title: "Maps & Cartography"
    link: "https://reference.wolfram.com/language/guide/MapsAndCartography.en.md"
  - 
    title: "Precollege Education"
    link: "https://reference.wolfram.com/language/guide/PrecollegeEducation.en.md"
  - 
    title: "Symbolic Graphics Language"
    link: "https://reference.wolfram.com/language/guide/SymbolicGraphicsLanguage.en.md"
  - 
    title: "Synthetic Geometry"
    link: "https://reference.wolfram.com/language/guide/SyntheticGeometry.en.md"
  - 
    title: "Solid Geometry"
    link: "https://reference.wolfram.com/language/guide/SolidGeometry.en.md"
  - 
    title: "Plane Geometry"
    link: "https://reference.wolfram.com/language/guide/PlaneGeometry.en.md"
related_functions: 
  - 
    title: "Disk"
    link: "https://reference.wolfram.com/language/ref/Disk.en.md"
  - 
    title: "CircleThrough"
    link: "https://reference.wolfram.com/language/ref/CircleThrough.en.md"
  - 
    title: "RoundingRadius"
    link: "https://reference.wolfram.com/language/ref/RoundingRadius.en.md"
  - 
    title: "Rotate"
    link: "https://reference.wolfram.com/language/ref/Rotate.en.md"
  - 
    title: "Cylinder"
    link: "https://reference.wolfram.com/language/ref/Cylinder.en.md"
  - 
    title: "Sphere"
    link: "https://reference.wolfram.com/language/ref/Sphere.en.md"
  - 
    title: "CirclePoints"
    link: "https://reference.wolfram.com/language/ref/CirclePoints.en.md"
  - 
    title: "GeometricScene"
    link: "https://reference.wolfram.com/language/ref/GeometricScene.en.md"
---
# Circle

Circle[{x, y}, r] represents a circle of radius r centered at {x, y}.

Circle[{x, y}] gives a circle of radius 1. 

Circle[{x, y}, {rx, ry}] gives an axis-aligned ellipse with semiaxes lengths rx and ry.

Circle[{x, y}, …, {θ1, θ2}] gives a circular or ellipse arc from angle θ1 to θ2.

## Details

* ``Circle`` with its different parameter settings is also known as arc, circular arc, semicircle, and ellipse.

* ``Circle`` can be used as a geometric region and a graphics primitive.

* ``Circle[]`` is equivalent to ``Circle[{0, 0}]``. »

[image]

* ``Circle`` represents the curve $\left\{\left\{x+r_x \cos (\theta ),y+r_y \sin (\theta )\right\}|\theta _1\leq \theta \leq \theta _2\right\}$.

* Angles are measured in radians counterclockwise from the positive ``x`` direction.

* ``Circle`` can be used in ``Graphics``.

* In graphics, the point ``{x, y}`` and radii ``r`` and ``{rx, ry}`` can be ``Scaled``, ``Offset``, ``ImageScaled``, and ``Dynamic`` expressions.

* Graphics rendering is affected by directives such as ``Thickness``, ``Dashing``, and color.

* ``Circle`` can be used with symbolic points and quantities in ``GeometricScene``.

---

## Background & Context

``Circle`` is a graphics and geometry primitive that represents a circle, ellipse, or circular/elliptical arc in the plane. In particular, ``Circle[{x, y}, r]`` represents the circle of radius ``r`` in $\mathbb{R}^2$ centered at ``{x, y}``, ``Circle[{x, y}, {rx, ry}]`` represents the axis-aligned filled ellipse in $\mathbb{R}^2$ with center ``{x, y}`` and semiaxis lengths ``rx`` and ``ry``, and ``Circle[{x, y}, …, {θ1, θ2}]`` represents the (potentially elliptical) arc centered at ``{x, y}`` ranging between angles ``θ1`` and ``θ2`` measured in radians counterclockwise from the positive $x$ axis. The shorthand form ``Circle[{x, y}]`` is equivalent to ``Circle[{x, y}, 1]``, while ``Circle[]`` autoevaluates to ``Circle[{0, 0}, 1]``.

``Circle`` objects can be formatted by placing them inside a ``Graphics`` expression. Note that while abstract circles have dimension 1 and zero thickness, for convenience, formatted ``Circle`` objects are rendered by default with finite thickness. The appearance of ``Circle`` objects in graphics can be modified by specifying thickness directives such as ``Thickness``, ``AbsoluteThickness``, ``Thick`` and ``Thin``; dashing directives such as ``Dashing``, ``AbsoluteDashing``, ``Dashed``, ``Dotted`` and ``DotDashed``; color directives such as ``Red``; the transparency directive ``Opacity``; and the style option ``Antialiasing``.

``Circle`` may also serve as a region specification over which a computation should be performed. For example, ``Integrate[1, {x, y}∈Circle[{0, 0}, r]]`` and ``ArcLength[Circle[{x, y}, r]]`` both return the perimeter $2 \pi  r$.

``CirclePoints`` may be used to give the positions of equally spaced points around a circle.

``Circle`` is related to a number of other symbols. ``Circle`` represents the boundary of a disk, as can be computed using ``RegionBoundary[Disk[{x, y}, r]]``. ``Cylinder`` and ``Sphere`` may be thought of as higher-dimensional analogs of circles. ``Circle[{x, y}, r]`` may be alternately represented using ``Sphere[{x, y}, r]``, ``ImplicitRegion[(x - u)^2 + (y - v)^2=r^2, {u, v}]`` or ``ParametricRegion[{x + r Cos[t], y + r Sin[t]}, {t, 0, 2π}]``. Precomputed properties of the circle and its variants in standard position are available using ``PlaneCurveData["entity", "property"]`` or ``EntityValue[Entity["PlaneCurve", "entity"], "property"]``, where ``"entity"`` is one of ``"Circle"``, ``"CircularArc"``, ``"Ellipse"``, ``"Semicircle"``, etc.

---

## Examples (52)

### Basic Examples (5)

A unit circle:

```wl
In[1]:= Graphics[Circle[]]

Out[1]= [image]
```

---

A circular arc:

```wl
In[1]:= Graphics[Circle[{0, 0}, 1, {Pi / 6, 3Pi / 4}]]

Out[1]= [image]
```

---

An ellipse:

```wl
In[1]:= Graphics[Circle[{0, 0}, {3, 4}]]

Out[1]= [image]
```

---

Differently styled circles:

```wl
In[1]:= {Graphics[{Red, Circle[]}], Graphics[{Thick, Circle[]}], Graphics[{Dashed, Circle[]}], Graphics[{Red, Thick, Dashed, Circle[]}]}

Out[1]= {[image], [image], [image], [image]}
```

---

``ArcLength`` of a circle:

```wl
In[1]:= ArcLength[Circle[]]

Out[1]= 2 π
```

Length or circular arc:

```wl
In[2]:= ArcLength[Circle[{0, 0}, 1, {Pi / 6, 3Pi / 4}]]

Out[2]= (7 π/12)
```

### Scope (23)

#### Graphics (13)

##### Specification (6)

Specify radii:

```wl
In[2]:= Graphics[{Circle[{0, 0}, 1], Circle[{0, 0}, 3], Circle[{0, 0}, 5]}]

Out[2]= [image]
```

---

Specify centers:

```wl
In[1]:= Graphics[{Circle[{0, 0}, 1], Circle[{1, 1}, 1], Circle[{2, 2}, 1]}]

Out[1]= [image]
```

---

A circular arc:

```wl
In[1]:= Graphics[Circle[{0, 0}, 1, {0, 4Pi / 3}]]

Out[1]= [image]

In[2]:= Graphics[Circle[{0, 0}, 1, {4Pi / 3, 2Pi}]]

Out[2]= [image]
```

---

An ellipse:

```wl
In[1]:= Graphics[Circle[{0, 0}, {3, 2}]]

Out[1]= [image]
```

---

An elliptical arc:

```wl
In[1]:= Graphics[Circle[{0, 0}, {3, 2}, {0, 4Pi / 3}]]

Out[1]= [image]
```

---

Short form for a unit circle at the origin:

```wl
In[1]:= Graphics[Circle[], Axes -> True]

Out[1]= [image]
```

##### Styling (3)

Circles with different thicknesses:

```wl
In[1]:= Table[Graphics[{Thickness[i], Circle[]}], {i, {Tiny, Small, Medium, Large}}]

Out[1]= {[image], [image], [image], [image]}
```

Thickness in scaled size:

```wl
In[1]:= Table[Graphics[{Thickness[i], Circle[]}], {i, {.05, .1, .2}}]

Out[1]= {[image], [image], [image]}
```

Thickness in printer's points:

```wl
In[2]:= Table[Graphics[{AbsoluteThickness[i], Circle[]}], {i, {1, 5, 10}}]

Out[2]= {[image], [image], [image]}
```

---

Dashed circles:

```wl
In[1]:= {Graphics[{Dashed, Circle[]}], Graphics[{Dotted, Circle[]}], Graphics[{DotDashed, Circle[]}]}

Out[1]= {[image], [image], [image]}
```

---

Colored circles:

```wl
In[1]:= Table[Graphics[{c, Circle[]}], {c, {Red, Green, Blue, Yellow}}]

Out[1]= {[image], [image], [image], [image]}
```

##### Coordinates (4)

Using ``Scaled`` coordinates and radii:

```wl
In[1]:= Graphics[Circle[Scaled[{.2, .2}], .2], Frame -> True]

Out[1]= [image]

In[2]:= Graphics[Circle[{0, 0}, Scaled[.25]], Frame -> True]

Out[2]= [image]

In[3]:= Graphics[Circle[{0, 0}, Scaled[{.5, .25}]], Frame -> True]

Out[3]= [image]
```

---

Use ``ImageScaled`` coordinates and radii:

```wl
In[1]:= Graphics[Circle[ImageScaled[{.2, .2}], .2], Frame -> True]

Out[1]= [image]

In[2]:= Graphics[Circle[{0, 0}, ImageScaled[{.5, .25}]], Frame -> True]

Out[2]= [image]
```

---

Use ``Offset`` coordinates:

```wl
In[1]:= Graphics[Circle[Offset[{10, 10}, {0, 0}], .5], Frame -> True]

Out[1]= [image]
```

---

Use ``Offset`` to specify the radii in printer's points:

```wl
In[1]:= Graphics[Circle[{0, 0}, Offset[{10, 40}]], Frame -> True]

Out[1]= [image]
```

#### Regions (10)

Embedding dimension:

```wl
In[1]:= RegionEmbeddingDimension[Circle[{Subscript[c, 1], Subscript[c, 2]}, r]]

Out[1]= 2
```

Geometric dimension:

```wl
In[2]:= RegionDimension[Circle[{Subscript[c, 1], Subscript[c, 2]}, r]]

Out[2]= 1
```

---

Point membership test:

```wl
In[1]:= {RegionMember[Circle[], {0, 1}], RegionMember[Circle[], {0, 0}]}

Out[1]= {True, False}
```

Get conditions for point membership:

```wl
In[2]:= RegionMember[Circle[{Subscript[c, 1], Subscript[c, 2]}, {Subscript[r, 1], Subscript[r, 2]}], {x, y}]

Out[2]= (x | y)∈ℝ && Subscript[r, 1] > 0 && Subscript[r, 2] > 0 && ((x - Subscript[c, 1])^2/Subsuperscript[r, 1, 2]) + ((y - Subscript[c, 2])^2/Subsuperscript[r, 2, 2]) == 1
```

---

Arc length:

```wl
In[1]:= ℛ = Circle[];

In[2]:= {ArcLength[ℛ], RegionMeasure[ℛ]}

Out[2]= {2 π, 2 π}
```

Centroid:

```wl
In[3]:= c = RegionCentroid[ℛ]

Out[3]= {0, 0}

In[4]:= Graphics[{{Gray, ℛ}, {Red, Point[c]}}]

Out[4]= [image]
```

---

Distance from a point:

```wl
In[1]:= ℛ = Circle[];

In[2]:= {RegionDistance[ℛ, {1, 1}], RegionDistance[ℛ, {1, 0}]}

Out[2]= {-1 + Sqrt[2], 0}
```

The distance to the nearest point for the unit circle:

```wl
In[3]:= {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

Out[3]= {[image], [image]}
```

---

Signed distance from a point:

```wl
In[1]:= ℛ = Circle[];

In[2]:= {SignedRegionDistance[ℛ, {1, 1}], SignedRegionDistance[ℛ, {1, 0}]}

Out[2]= {-1 + Sqrt[2], 0}
```

Signed distance to the unit circle:

```wl
In[3]:= Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, Exclusions -> Norm[{x, y}] == 1, Mesh -> None]

Out[3]= [image]
```

---

Nearest point in the region:

```wl
In[1]:= ℛ = Circle[{0, 0}, {3, 2}];

In[2]:= {RegionNearest[ℛ, {0, 3}], RegionNearest[ℛ, {3, 0}]}

Out[2]= {{0, 2}, {3, 0}}
```

Nearest points:

```wl
In[3]:=
pts = Join[Table[4{Cos[k 2 π / 10], Sin[k 2π / 10]}, {k, 0., 9}], 
	Table[{k, 0}, {k, -3., 3, 0.6}]];
nst = RegionNearest[ℛ, #]& /@ pts;

In[4]:= Legended[Graphics[{ℛ, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

Out[4]= [image]
```

---

A circle is bounded:

```wl
In[1]:= ℛ = Circle[];

In[2]:= BoundedRegionQ[ℛ]

Out[2]= True
```

Get its range:

```wl
In[3]:= rr = RegionBounds[ℛ]

Out[3]= {{-1, 1}, {-1, 1}}

In[4]:= Graphics[{{EdgeForm[Directive[Dashed, Red]], Opacity[0.1], Yellow, Rectangle@@Transpose[rr]}, ℛ}]

Out[4]= [image]
```

---

``Integrate`` over a circle:

```wl
In[1]:= ℛ = Circle[{Subscript[c, 1], Subscript[c, 2]}, r];

In[2]:= Integrate[x y, {x, y}∈ℛ]

Out[2]=
ConditionalExpression[2*Pi*r*Subscript[c, 1]*Subscript[c, 2], 
 Element[Subscript[c, 1] | Subscript[c, 2], Reals] && r > 0]
```

---

Optimize over a circle:

```wl
In[1]:= ℛ = Circle[{1, 2}, 3];

In[2]:= Minimize[{x y - x, {x, y}∈ℛ}, {x, y}]//Simplify

Out[2]= {-4, {x -> (1/2) (1 + Sqrt[17]), y -> (1/2) (3 - Sqrt[17])}}
```

---

Solve equations in a circle:

```wl
In[1]:= ℛ = Circle[{1, 2}, 3];

In[2]:= Solve[y == 2x + 1 && {x, y}∈Circle[], {x, y}]

Out[2]= {{x -> -(4/5), y -> -(3/5)}, {x -> 0, y -> 1}}

In[3]:= Graphics[{{Black, Circle[]}, {Gray, InfiniteLine[{0, 1}, {1, 2}]}, {Red, PointSize[Medium], Point[{x, y} /. %]}}, Frame -> True]

Out[3]= [image]
```

### Applications (8)

The square packing of circles:

```wl
In[1]:= Graphics[Table[Circle[{i, j}, 1 / 2], {i, 7}, {j, 5}]]

Out[1]= [image]
```

The hexagonal packing of circles:

```wl
In[2]:= Graphics[Table[Circle[{i + ((-1) ^ j + 1) / 4, Sqrt[3] / 2j}, 1 / 2], {i, 7}, {j, 5}]]

Out[2]= [image]
```

---

Simulation of elliptical gears:

```wl
In[1]:= Animate[Module[{a = 4, b = 3, f, r}, f = Sqrt[a ^ 2 - b ^ 2];r = b ^ 2 / (a + f Cos[θ]);Graphics[{Point[{{0, 0}, {2a, 0}}], Rotate[Circle[{-f, 0}, {a, b}], θ, {0, 0}], Translate[Rotate[Circle[{-f, 0}, {a, b}], -ArcTan[ 2 f + r Cos[θ], r Sin[θ]], {0, 0}], {2a, 0}]}, PlotRange -> {{-2a, 4a}, {-2a, 2a}}, ImageSize -> 250]], {θ, 0, 2Pi}, AnimationRunning -> False]

Out[1]= DynamicModule[«8»]
```

---

Find the intersections of a ``Line`` and a ``Circle`` :

```wl
In[1]:=
Subscript[ℛ, 1] = Line[{{-2, -1}, {5, 6}}];
Subscript[ℛ, 2] = Circle[{1, 2}, 3];

In[2]:= pts = Solve[{x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2], {x, y}]

Out[2]= {{x -> (1/2) (2 - 3 Sqrt[2]), y -> 1 + (1/2) (2 - 3 Sqrt[2])}, {x -> (1/2) (2 + 3 Sqrt[2]), y -> 1 + (1/2) (2 + 3 Sqrt[2])}}

In[3]:= Graphics[{Subscript[ℛ, 1], Subscript[ℛ, 2], {Red, PointSize[Medium], Point[{x, y} /. pts]}}]

Out[3]= [image]
```

---

Find the intersections of two circles:

```wl
In[1]:=
Subscript[ℛ, 1] = Circle[{-1, 0}, 3];
Subscript[ℛ, 2] = Circle[{1, 0}, 3];

In[2]:= pts = Solve[{x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2], {x, y}]

Out[2]= {{x -> 0, y -> -2 Sqrt[2]}, {x -> 0, y -> 2 Sqrt[2]}}

In[3]:= Graphics[{Subscript[ℛ, 1], Subscript[ℛ, 2], {Red, PointSize[Medium], Point[{x, y} /. pts]}}]

Out[3]= [image]
```

---

Illustrate a function's radius of curvature:

```wl
In[1]:=
y[x_] := Sin[x ^ 2];
r[x_] := ((1 + y'[x] ^ 2) ^ (3 / 2)) / y''[x];
c[x_] := Circle[{x, y[x]} + r[x]Normalize[{-y'[x], 1}], Abs[r[x]]];

In[2]:= Show[{Plot[y[x], {x, -2, 2}], Graphics[{c[-1.2], c[0], c[1.4], Red, PointSize[Medium], Point[{-1.2, y[-1.2]}], Point[{0, y[0]}], Point[{1.4, y[1.4]}]}]}, AspectRatio -> Automatic]

Out[2]= [image]
```

---

A circumcircle is a circle in the plane defined by three noncollinear points:

```wl
In[1]:=
pts = {{0, 1}, {-2 / 3, -1 / 3}, {3 / 4, 0}};
circ = Circumsphere[pts];

In[2]:= Graphics[{circ, LightBlue, Triangle[pts]}]

Out[2]= [image]
```

The radius and circumcenter can be extracted from the ``Circumsphere`` :

```wl
In[3]:= {c, r} = {First[circ], Last[circ]}

Out[3]= {{-(1/24), (3/16)}, (5 Sqrt[61]/48)}

In[4]:= Graphics[{circ, LightBlue, Triangle[pts], Red, Point[c], Dashed, Line[{c, c + r * Normalize[{1, 1}]}]}]

Out[4]= [image]
```

---

The defining property of a ``DelaunayMesh`` is that no input point is contained in the circumcircle of any ``Triangle`` in the mesh:

```wl
In[1]:=
SeedRandom[1234];
ℛ = DelaunayMesh[RandomReal[1, {8, 2}]];
circles = Circumsphere@@@Normal@GraphicsComplex[MeshCoordinates[ℛ], MeshCells[ℛ, 2]];

In[2]:= Show[HighlightMesh[ℛ, Style[{0, All}, Directive[Red, PointSize[Medium]]]], Graphics[{Gray, circles}], PlotRange -> {{0, 1}, {0, 1}}]

Out[2]= [image]
```

---

Given electric charge density along a circular wire, use ``Integrate`` to find the total charge:

```wl
In[1]:= charge[x_, y_] := x ^ 4 + y ^ 2;

In[2]:= ParametricPlot3D[{Cos[θ], Sin[θ], charge[Cos[θ], Sin[θ]]z}, {θ, 0, 2π}, {z, 0, 1}, Mesh -> None]

Out[2]= [image]

In[3]:= Integrate[charge[x, y], {x, y}∈Circle[]]

Out[3]= (7 π/4)
```

### Properties & Relations (10)

Use ``Rotate`` to get all possible ellipses:

```wl
In[1]:= Graphics[Rotate[Circle[{0, 0}, {4, 2}], Pi / 6], Axes -> True]

Out[1]= [image]
```

---

To create a filled circle, use ``Disk`` :

```wl
In[1]:= Graphics[{Pink, Disk[]}]

Out[1]= [image]
```

---

The 3D generalization is ``Sphere``:

```wl
In[1]:= Graphics3D[Sphere[]]

Out[1]= [image]
```

---

An implicit specification of a circle can be generated by ``ContourPlot`` :

```wl
In[1]:= ContourPlot[x ^ 2 + y ^ 2 == 1, {x, -1, 1}, {y, -1, 1}]

Out[1]= [image]
```

---

A parametric specification of a circle can be generated by ``ParametricPlot`` :

```wl
In[1]:= ParametricPlot[{Cos[θ], Sin[θ]}, {θ, 0, 2π}]

Out[1]= [image]
```

---

``Sphere`` can represent any ``Circle`` :

```wl
In[1]:=
Subscript[ℛ, 1] = Sphere[{x, y}, r];
Subscript[ℛ, 2] = Circle[{x, y}, r];

In[2]:= RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Out[2]= True
```

---

``Circumsphere`` can represent any ``Circle`` :

```wl
In[1]:=
Subscript[ℛ, 1] = Circumsphere[{{1, 0}, {0, 1}, {-1, 0}}];
Subscript[ℛ, 2] = Circle[{0, 0}, 1];

In[2]:= RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Out[2]= True
```

---

``ParametricRegion`` can represent any ``Circle``:

```wl
In[1]:=
Subscript[ℛ, 1] = ParametricRegion[{{1 + 3Cos[t], 2 + 4 Sin[t]}, 0 ≤ t ≤ 2π}, {t}];
Subscript[ℛ, 2] = Circle[{1, 2}, {3, 4}];

In[2]:= RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Out[2]= True
```

---

``ImplicitRegion`` can represent any ``Circle`` :

```wl
In[1]:=
Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 == 1, {x, y}];
Subscript[ℛ, 2] = Circle[{0, 0}, 1];

In[2]:= RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Out[2]= True
```

---

``Circle`` is a norm circle for the Euclidean norm:

```wl
In[1]:= ℛ = Circle[{0, 0}, 1];

In[2]:= Reduce[{x, y}∈ℛ⧦Norm[{x, y}] == 1, {x, y}, Reals]

Out[2]= True
```

### Possible Issues (2)

Using ``Scaled`` radii will depend on the ``PlotRange`` :

```wl
In[1]:= Table[Graphics[Circle[{0, 0}, Scaled[.25]], PlotRange -> {{-n, n}, {-1, 1}}, Frame -> True, FrameTicks -> {{{-1, 1}, None}, {{-n, n}, None}}], {n, {1, 2, 3}}]

Out[1]= {[image], [image], [image]}
```

---

Using ``ImageScaled`` sizes will depend on the ``ImageSize`` and ``AspectRatio`` :

```wl
In[1]:= Table[Graphics[Circle[ImageScaled[{.5, .5}], ImageScaled[{.25, .25}]], Frame -> True, FrameTicks -> {{{-1, 1}, None}, {{-1, 1}, None}}, ImageSize -> n], {n, {50, 70, 100}}]

Out[1]= {[image], [image], [image]}

In[2]:= Table[Graphics[Circle[ImageScaled[{.5, .5}], ImageScaled[{.25, .25}]], Frame -> True, FrameTicks -> {{{-1, 1}, None}, {{-1, 1}, None}}, ImageSize -> 100, AspectRatio -> n], {n, {1, 1 / 2, 1 / 3}}]

Out[2]= {[image], [image], [image]}
```

### Neat Examples (4)

Random circles:

```wl
In[1]:= Graphics[Table[{Hue[RandomReal[]], Circle[RandomReal[4, {2}], RandomReal[1]]}, {40}]]

Out[1]= [image]
```

---

The seed of life:

```wl
In[1]:= Graphics[{Thick, Orange, Circle[], Table[Circle[{Cos[2 Pi i / 6], Sin[2Pi i / 6]}, 1], {i, 6}]}]

Out[1]= [image]
```

---

A family of circles:

```wl
In[1]:= Graphics[Table[{Hue[t / 20], Circle[{Cos[2Pi t / 20], Sin[2Pi t / 20]}, 1]}, {t, 20}]]

Out[1]= [image]
```

---

Yin and yang:

```wl
In[1]:= Animate[Graphics[{Thick, Circle[{0, 0}, 2, {0, Pi}], Circle[{0, 0}, 2, {Pi, 2Pi}], Circle[{-1, 0}, 1, {Pi, 2Pi}], Circle[{1, 0}, 1, {0, Pi}]}, PlotRange -> 2.1, ImageSize -> 150] /. Circle[x__] :> Rotate[Circle[x], d Degree, {0, 0}], {d, 0, 360}, AnimationRunning -> False]

Out[1]= DynamicModule[«7»]
```

## See Also

* [`Disk`](https://reference.wolfram.com/language/ref/Disk.en.md)
* [`CircleThrough`](https://reference.wolfram.com/language/ref/CircleThrough.en.md)
* [`RoundingRadius`](https://reference.wolfram.com/language/ref/RoundingRadius.en.md)
* [`Rotate`](https://reference.wolfram.com/language/ref/Rotate.en.md)
* [`Cylinder`](https://reference.wolfram.com/language/ref/Cylinder.en.md)
* [`Sphere`](https://reference.wolfram.com/language/ref/Sphere.en.md)
* [`CirclePoints`](https://reference.wolfram.com/language/ref/CirclePoints.en.md)
* [`GeometricScene`](https://reference.wolfram.com/language/ref/GeometricScene.en.md)

## Related Guides

* [Graphics Objects](https://reference.wolfram.com/language/guide/GraphicsObjects.en.md)
* [Basic Geometric Regions](https://reference.wolfram.com/language/guide/GeometricSpecialRegions.en.md)
* [Maps & Cartography](https://reference.wolfram.com/language/guide/MapsAndCartography.en.md)
* [Precollege Education](https://reference.wolfram.com/language/guide/PrecollegeEducation.en.md)
* [Symbolic Graphics Language](https://reference.wolfram.com/language/guide/SymbolicGraphicsLanguage.en.md)
* [Synthetic Geometry](https://reference.wolfram.com/language/guide/SyntheticGeometry.en.md)
* [Solid Geometry](https://reference.wolfram.com/language/guide/SolidGeometry.en.md)
* [Plane Geometry](https://reference.wolfram.com/language/guide/PlaneGeometry.en.md)

## Related Links

* [An Elementary Introduction to the Wolfram Language: Basic Graphics Objects](https://www.wolfram.com/language/elementary-introduction/08-basic-graphics-objects.html)
* [An Elementary Introduction to the Wolfram Language: Coordinates and Graphics](https://www.wolfram.com/language/elementary-introduction/14-coordinates-and-graphics.html)
* [An Elementary Introduction to the Wolfram Language: Options](https://www.wolfram.com/language/elementary-introduction/20-options.html)
* [An Elementary Introduction to the Wolfram Language: Pure Anonymous Functions](https://www.wolfram.com/language/elementary-introduction/26-pure-anonymous-functions.html)

## History

* Introduced in 1991 (2.0) \| Updated in 1996 (3.0) ▪ [2014 (10.0)](https://reference.wolfram.com/language/guide/SummaryOfNewFeaturesIn100.en.md)