WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Circumsphere[{p1,…,pn+1}]

内の点 piに外接する球を返す．

Circumsphere[poly]

多面体あるいは多角形 poly の外接球を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
グラフィックス  
指定  
スタイリング  
領域  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

Circumsphere

Circumsphere[{p1,…,pn+1}]

内の点 piに外接する球を返す．

Circumsphere[poly]

多面体あるいは多角形 poly の外接球を与える．

詳細

例題

すべて開く すべて閉じる

例  (2)

2Dにおける外接球：

Wolfram Language code: Graphics[Circumsphere[{{0, 0}, {1, 0}, {0, 1}}]]

3Dにおける外接球：

Wolfram Language code: Graphics3D[Circumsphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]]

正八面体の外接球：

Wolfram Language code: ℛ = Circumsphere[Octahedron[]]
Wolfram Language code: Graphics3D[{Opacity[0.6], Octahedron[], ℛ}]

その表面積：

Wolfram Language code: Area[ℛ]

スコープ  (17)

グラフィックス  (6)

指定  (2)

さまざまな次元の外接球：

Wolfram Language code: Graphics[Circumsphere[{{0, 0}, {1, 0}, {0, 1}}]]
Wolfram Language code: Graphics3D[Circumsphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]]

Circumsphereを評価するとSphereになる：

Wolfram Language code: Circumsphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]

中心と半径を得る：

Wolfram Language code: {First@%, Last@%}

スタイリング  (4)

彩色された外接球：

Wolfram Language code: ℛ = Circumsphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Table[Graphics3D[{c, ℛ}], {c, {Red, Green, Blue, Yellow}}]

FaceFormを使って表と裏の面に異なる特性を指定することができる：

Wolfram Language code: ℛ = Circumsphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Graphics3D[{FaceForm[Yellow, Blue], ℛ}, PlotRange -> {{-0.8, 0.8}, {-0.8, 0.8}, {-0.8, 0.8}}]

さまざまな鏡面反射指数の外接球：

Wolfram Language code: ℛ = Circumsphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Table[Graphics3D[{Orange, Specularity[White, n], ℛ}], {n, {5, 20, 100}}]

赤く輝く黒い外接球：

Wolfram Language code: Graphics3D[{Glow[Red], Black, ℛ}]

Opacityは表面の不透明度を指定する：

Wolfram Language code: ℛ = Circumsphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Table[Graphics3D[{Opacity[o], ℛ}], {o, {0.3, 0.5, 0.9}}]

領域  (11)

Circumsphereは任意数の次元で使うことができる：

Wolfram Language code: Circumsphere[{{0, 0, 0, 0, 0}, {1, 0, 0, 0, 0}, {0, 1, 0, 0, 0}, {0, 0, 1, 0, 0}, {0, 0, 0, 1, 0}, {0, 0, 0, 0, 1}}]

外心と外接半径を得る：

Wolfram Language code: {First[%], Last[%]}

埋込み次元は球がある空間の次元である：

Wolfram Language code: ℛ = Circumsphere[{{0, 0}, {1, 0}, {1, 1}}];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

幾何次元は形それ自体の次元である：

Wolfram Language code: RegionDimension[ℛ]

帰属判定：

Wolfram Language code: ℛ = Circumsphere[{{1, 0, 0}, {0, 1, 0}, {0, 0, 1}, {-1, 0, 0}}];
Wolfram Language code: {RegionMember[ℛ, {1, 0, 0}], RegionMember[ℛ, {1, 2, 3}]}

帰属条件を得る：

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

面積：

Wolfram Language code: ℛ = Circumsphere[{{1, 0, 0}, {0, 1, 0}, {0, 0, 1}, {-1, 0, 0}}];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

重心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

点からの距離：

Wolfram Language code: ℛ = Circumsphere[{{1, 0}, {0, 1}, {-1, 0}}];
Wolfram Language code: RegionDistance[ℛ, {1, 2}]

これをプロットする：

Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

点からの符号付き距離：

Wolfram Language code: ℛ = Circumsphere[{{1, 0}, {0, 1}, {-1, 0}}];
Wolfram Language code: {SignedRegionDistance[ℛ, {2, 0}], SignedRegionDistance[ℛ, {1 / 4, 1 / 3}]}

これをプロットする：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1]

領域内の最近点：

Wolfram Language code: ℛ = Circumsphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: {RegionNearest[ℛ, {2, 2, 2}], RegionNearest[ℛ, {(1/2), (1/2), (1/2)}]}

包み込んでいる球までの最近点：

Wolfram Language code: spherePoints[{n_, m_}, c_, r_] := Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];
Wolfram Language code: pl = spherePoints[{8, 8}, RegionCentroid[ℛ], 3 / 2]; npl = Table[RegionNearest[ℛ, p], {p, pl}];
Wolfram Language code: Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

球は有界である：

Wolfram Language code: ℛ = Circumsphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: BoundedRegionQ[ℛ]

その範囲を求める：

Wolfram Language code: r = RegionBounds[ℛ]
Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[r]}, ℛ}, Boxed -> False]

Circumsphere上でIntegrateする：

Wolfram Language code: ℛ = Circumsphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Integrate[1, {x, y, z}∈ℛ]
Wolfram Language code: Integrate[x^2y^2z^2, {x, y, z}∈ℛ]

その上で最適化する：

Wolfram Language code: ℛ = Circumsphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Maximize[{x^2 + 2y^2 + 3z^2, {x, y, z}∈ℛ}, {x, y, z}]

Circumsphere上で方程式を解く：

Wolfram Language code: ℛ = Circumsphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Reduce[x^2 == y^2 == z^2 && {x, y, z}∈ℛ, {x, y, z}]//LogicalExpand

アプリケーション  (7)

LineとCircumsphereの交点を求める：

Wolfram Language code: Subscript[ℛ, 1] = Line[{{-2, -1, 1}, {2, 1, -1}}]; Subscript[ℛ, 2] = Circumsphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: pts = Solve[{x, y, z}∈Subscript[ℛ, 1] && {x, y, z}∈Subscript[ℛ, 2], {x, y, z}]
Wolfram Language code: Graphics3D[{Subscript[ℛ, 1], {Opacity[0.35], Subscript[ℛ, 2]}, {Red, PointSize[Medium], Point[{x, y, z} /. pts]}}, PlotRange -> 1]

2つの外接球の交点を求める：

Wolfram Language code: Subscript[ℛ, 1] = Circumsphere[{{-1, 0}, {1, 0}, {0, 1}}]; Subscript[ℛ, 2] = Circumsphere[{{0, 0}, {2, 0}, {1, 1}}];
Wolfram Language code: pts = Solve[{x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2], {x, y}]
Wolfram Language code: Graphics[{Subscript[ℛ, 1], Subscript[ℛ, 2], {Red, PointSize[Medium], Point[{x, y} /. pts]}}]

三角形の垂直二等分線を求める：

Wolfram Language code: pts = {a, b, c} = {{1, 2}, {0, 0}, {3, 0}};
Wolfram Language code: circumCenter = RegionCentroid[Circumsphere[pts]];
Wolfram Language code: bisector = Line[{circumCenter, RegionCentroid[Line[{a, b}]]}];

外心と二等分線を赤で可視化する：

Wolfram Language code: Graphics[{{LightGray, Circumsphere[pts]}, {LightBlue, Triangle[pts]}, {Dashed, Red, bisector}, {Blue, Point[pts]}, {Red, PointSize[Large], Point[circumCenter]}}]

DelaunayMeshの定義特性は，いかなる入力点もメッシュ中の任意のTriangleの外接円中に含まれない，というものである：

Wolfram Language code: SeedRandom[12345]; pts = RandomReal[{0, 1}, {6, 2}]; ℛ = DelaunayMesh[pts]; tris = First /@ MeshPrimitives[ℛ, 2]; circs = Circumsphere /@ tris;
Wolfram Language code: Show[HighlightMesh[ℛ, Style[{0, All}, Directive[Red, PointSize[Medium]]]], Graphics[{Gray, circs}], PlotRange -> {{0, 1}, {0, 1}}]

Circumsphereを使って関数の曲率の半径を近似する：

Wolfram Language code: y[x_] := Sin[x ^ 2]; r[x_] := ((1 + y'[x] ^ 2) ^ (3 / 2)) / Abs[y''[x]]; c[x_] := With[{ϵ = 0.0001}, Circumsphere[{{x - ϵ, y[x - ϵ]}, {x, y[x]}, {x + ϵ, y[x + ϵ]}}]];

曲率の厳密な半径を外接円の近似から得た半径と比較する：

Wolfram Language code: {N@r[1], Last[c[1]]}

これをプロットする：

Wolfram Language code: Show[{Plot[y[x], {x, -2, 2}], Graphics[{c[-1.2], c[0], c[1.4], Red, PointSize[Medium], Point[{-1.2, y[-1.2]}], Point[{0, y[0]}], Point[{1.4, y[1.4]}]}]}, AspectRatio -> Automatic]

記号入力の外接球を使って曲率の半径を求める式を導く：

Wolfram Language code: circ = Circumsphere[{{x - ϵ, y[x - ϵ]}, {x, y[x]}, {x + ϵ, y[x + ϵ]}}];
Wolfram Language code: Limit[Last@circ, ϵ -> 0, Assumptions -> x∈Reals]

結果は半径の公式と一致する：

Wolfram Language code: r[x]

Circumsphereを使って，三角形分割されている任意の領域を被覆する円板を求める．まず，領域を三角形分割する：

Wolfram Language code: ℛ = TriangulateMesh@DiscretizeGraphics[Graphics[CountryData["UnitedStates", {"Shape", "Mercator"}]]]

Circumsphereを使って各三角形についての円を計算する：

Wolfram Language code: circles = Circumsphere[First[#]]& /@ MeshPrimitives[ℛ, 2];
Wolfram Language code: Graphics[{Opacity[0.5], Map[{RandomColor[], #}&, circles]}]

その効率を計算する：

Wolfram Language code: coverArea = Total@Map[Area[Disk@@#]&, circles]
Wolfram Language code: regionArea = Area[ℛ]
Wolfram Language code: regionArea / coverArea

Circumsphereを使って，三角形分割された領域を被覆する球体を生成する．まず，領域を離散化し，三角形分割する：

Wolfram Language code: ℛ = TriangulateMesh[[image], MeshQualityGoal -> "Minimal"]

Circumsphereを使って各四面体についての球を計算する：

Wolfram Language code: spheres = Circumsphere[First[#]]& /@ MeshPrimitives[ℛ, 3];
Wolfram Language code: Graphics3D[{Opacity[0.5], Map[{RandomColor[], #}&, spheres]}]

記録密度を計算する：

Wolfram Language code: coverVolume = Total@Map[Volume[Ball@@#]&, spheres]
Wolfram Language code: regionVolume = Volume[ℛ]
Wolfram Language code: regionVolume / coverVolume

特性と関係  (1)

Circumsphereは，2Dにおける球面上の3点を拾うことで，任意のSphereを表すことができる：

Wolfram Language code: points = {{x + r, y}, {x - r, y}, {x, y + r}};
Wolfram Language code: Simplify[RegionMember[Sphere[{x, y}, r], points], {x, y, r}∈Reals && r > 0]
Wolfram Language code: Simplify[Circumsphere[points], r > 0]

3Dの球面上で4点を拾う等：

Wolfram Language code: points = {{x + r, y, z}, {x - r, y, z}, {x, y + r, z}, {x, y, z + r}};
Wolfram Language code: Simplify[RegionMember[Sphere[{x, y, z}, r], points], {x, y, z, r}∈Reals && r > 0]
Wolfram Language code: Simplify[Circumsphere[points], r > 0]
Wolfram Research (2014), Circumsphere, Wolfram言語関数， https://reference.wolfram.com/language/ref/Circumsphere.html （2019年に更新）.

テキスト

Wolfram Research (2014), Circumsphere, Wolfram言語関数， https://reference.wolfram.com/language/ref/Circumsphere.html （2019年に更新）.

CMS

Wolfram Language. 2014. "Circumsphere." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/Circumsphere.html.

APA

Wolfram Language. (2014). Circumsphere. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Circumsphere.html

BibTeX

@misc{reference.wolfram_2026_circumsphere, author="Wolfram Research", title="{Circumsphere}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Circumsphere.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_circumsphere, organization={Wolfram Research}, title={Circumsphere}, year={2019}, url={https://reference.wolfram.com/language/ref/Circumsphere.html}, note=[Accessed: 16-September-2026]}