WOLFRAM

Wolfram 语言与系统参考资料中心

Circumsphere[{p1,…,pn+1}]

给出 中的点 pi 的外接球.

Circumsphere[poly]

给出多面体或多边形 poly 的外接球.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
图形  
规范  
样式化  
区域  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

Circumsphere

Circumsphere[{p1,…,pn+1}]

给出 中的点 pi 的外接球.

Circumsphere[poly]

给出多面体或多边形 poly 的外接球.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (2)

在二维中的外接圆：

Wolfram Language code: Graphics[Circumsphere[{{0, 0}, {1, 0}, {0, 1}}]]

在三维中：

Wolfram Language code: Graphics3D[Circumsphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]]

正八面体的外接球：

Wolfram Language code: ℛ = Circumsphere[Octahedron[]]
Wolfram Language code: Graphics3D[{Opacity[0.6], Octahedron[], ℛ}]

表面积：

Wolfram Language code: Area[ℛ]

范围  (17)

图形  (6)

规范  (2)

在不同的维度的外接球：

Wolfram Language code: Graphics[Circumsphere[{{0, 0}, {1, 0}, {0, 1}}]]
Wolfram Language code: Graphics3D[Circumsphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]]

Circumsphere 计算为 Sphere：

Wolfram Language code: Circumsphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]

得到中心和半径：

Wolfram Language code: {First@%, Last@%}

样式化  (4)

彩色外接球：

Wolfram Language code: ℛ = Circumsphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Table[Graphics3D[{c, ℛ}], {c, {Red, Green, Blue, Yellow}}]

可以使用 FaceForm 指定面前方和后方的不同属性：

Wolfram Language code: ℛ = Circumsphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Graphics3D[{FaceForm[Yellow, Blue], ℛ}, PlotRange -> {{-0.8, 0.8}, {-0.8, 0.8}, {-0.8, 0.8}}]

不同镜面指数的外接球：

Wolfram Language code: ℛ = Circumsphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Table[Graphics3D[{Orange, Specularity[White, n], ℛ}], {n, {5, 20, 100}}]

发红光的黑色外接球：

Wolfram Language code: Graphics3D[{Glow[Red], Black, ℛ}]

Opacity 指定面的不透明度：

Wolfram Language code: ℛ = Circumsphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Table[Graphics3D[{Opacity[o], ℛ}], {o, {0.3, 0.5, 0.9}}]

区域  (11)

Circumsphere 适用于任意维数：

Wolfram Language code: Circumsphere[{{0, 0, 0, 0, 0}, {1, 0, 0, 0, 0}, {0, 1, 0, 0, 0}, {0, 0, 1, 0, 0}, {0, 0, 0, 1, 0}, {0, 0, 0, 0, 1}}]

获取外接圆圆心与半径：

Wolfram Language code: {First[%], Last[%]}

嵌入维是球所在空间的维度：

Wolfram Language code: ℛ = Circumsphere[{{0, 0}, {1, 0}, {1, 1}}];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

几何维度是形状本身的尺寸：

Wolfram Language code: RegionDimension[ℛ]

成员测试：

Wolfram Language code: ℛ = Circumsphere[{{1, 0, 0}, {0, 1, 0}, {0, 0, 1}, {-1, 0, 0}}];
Wolfram Language code: {RegionMember[ℛ, {1, 0, 0}], RegionMember[ℛ, {1, 2, 3}]}

得到成员的条件：

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

面积：

Wolfram Language code: ℛ = Circumsphere[{{1, 0, 0}, {0, 1, 0}, {0, 0, 1}, {-1, 0, 0}}];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

质心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

到一个点的距离：

Wolfram Language code: ℛ = Circumsphere[{{1, 0}, {0, 1}, {-1, 0}}];
Wolfram Language code: RegionDistance[ℛ, {1, 2}]

绘图：

Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

到一个点的带有正符号的距离：

Wolfram Language code: ℛ = Circumsphere[{{1, 0}, {0, 1}, {-1, 0}}];
Wolfram Language code: {SignedRegionDistance[ℛ, {2, 0}], SignedRegionDistance[ℛ, {1 / 4, 1 / 3}]}

绘图：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1]

区域上的最近点：

Wolfram Language code: ℛ = Circumsphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: {RegionNearest[ℛ, {2, 2, 2}], RegionNearest[ℛ, {(1/2), (1/2), (1/2)}]}

到一个封闭球体的最近点：

Wolfram Language code: spherePoints[{n_, m_}, c_, r_] := Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];
Wolfram Language code: pl = spherePoints[{8, 8}, RegionCentroid[ℛ], 3 / 2]; npl = Table[RegionNearest[ℛ, p], {p, pl}];
Wolfram Language code: Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

球是有界的：

Wolfram Language code: ℛ = Circumsphere[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: BoundedRegionQ[ℛ]

求它的范围：

Wolfram Language code: r = RegionBounds[ℛ]
Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[r]}, ℛ}, Boxed -> False]

在 Circumsphere 上进行 Integrate：

Wolfram Language code: ℛ = Circumsphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Integrate[1, {x, y, z}∈ℛ]
Wolfram Language code: Integrate[x^2y^2z^2, {x, y, z}∈ℛ]

在外接球上最优化：

Wolfram Language code: ℛ = Circumsphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Maximize[{x^2 + 2y^2 + 3z^2, {x, y, z}∈ℛ}, {x, y, z}]

求解 Circumsphere 上的方程：

Wolfram Language code: ℛ = Circumsphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: Reduce[x^2 == y^2 == z^2 && {x, y, z}∈ℛ, {x, y, z}]//LogicalExpand

应用  (7)

求 Line 和 Circumsphere 的交点：

Wolfram Language code: Subscript[ℛ, 1] = Line[{{-2, -1, 1}, {2, 1, -1}}]; Subscript[ℛ, 2] = Circumsphere[{{-1, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: pts = Solve[{x, y, z}∈Subscript[ℛ, 1] && {x, y, z}∈Subscript[ℛ, 2], {x, y, z}]
Wolfram Language code: Graphics3D[{Subscript[ℛ, 1], {Opacity[0.35], Subscript[ℛ, 2]}, {Red, PointSize[Medium], Point[{x, y, z} /. pts]}}, PlotRange -> 1]

求两个外接球的交点：

Wolfram Language code: Subscript[ℛ, 1] = Circumsphere[{{-1, 0}, {1, 0}, {0, 1}}]; Subscript[ℛ, 2] = Circumsphere[{{0, 0}, {2, 0}, {1, 1}}];
Wolfram Language code: pts = Solve[{x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2], {x, y}]
Wolfram Language code: Graphics[{Subscript[ℛ, 1], Subscript[ℛ, 2], {Red, PointSize[Medium], Point[{x, y} /. pts]}}]

求一个三角形的垂直平分线：

Wolfram Language code: pts = {a, b, c} = {{1, 2}, {0, 0}, {3, 0}};
Wolfram Language code: circumCenter = RegionCentroid[Circumsphere[pts]];
Wolfram Language code: bisector = Line[{circumCenter, RegionCentroid[Line[{a, b}]]}];

用红色标出外心和平分线：

Wolfram Language code: Graphics[{{LightGray, Circumsphere[pts]}, {LightBlue, Triangle[pts]}, {Dashed, Red, bisector}, {Blue, Point[pts]}, {Red, PointSize[Large], Point[circumCenter]}}]

DelaunayMesh 的定义属性是网格中任意 Triangle 的外接圆中不包含输入点：

Wolfram Language code: SeedRandom[12345]; pts = RandomReal[{0, 1}, {6, 2}]; ℛ = DelaunayMesh[pts]; tris = First /@ MeshPrimitives[ℛ, 2]; circs = Circumsphere /@ tris;
Wolfram Language code: Show[HighlightMesh[ℛ, Style[{0, All}, Directive[Red, PointSize[Medium]]]], Graphics[{Gray, circs}], PlotRange -> {{0, 1}, {0, 1}}]

使用 Circumsphere 近似​​函数的曲率半径：

Wolfram Language code: y[x_] := Sin[x ^ 2]; r[x_] := ((1 + y'[x] ^ 2) ^ (3 / 2)) / Abs[y''[x]]; c[x_] := With[{ϵ = 0.0001}, Circumsphere[{{x - ϵ, y[x - ϵ]}, {x, y[x]}, {x + ϵ, y[x + ϵ]}}]];

将曲率的精确半径与外接圆近似得到的半径比较：

Wolfram Language code: {N@r[1], Last[c[1]]}

绘图：

Wolfram Language code: Show[{Plot[y[x], {x, -2, 2}], Graphics[{c[-1.2], c[0], c[1.4], Red, PointSize[Medium], Point[{-1.2, y[-1.2]}], Point[{0, y[0]}], Point[{1.4, y[1.4]}]}]}, AspectRatio -> Automatic]

使用带有符号输入的外接球推导出曲率半径公式：

Wolfram Language code: circ = Circumsphere[{{x - ϵ, y[x - ϵ]}, {x, y[x]}, {x + ϵ, y[x + ϵ]}}];
Wolfram Language code: Limit[Last@circ, ϵ -> 0, Assumptions -> x∈Reals]

结果与半径公式相同：

Wolfram Language code: r[x]

使用 Circumsphere 求覆盖三角化后任意区域的圆. 首先对区域三角化：

Wolfram Language code: ℛ = TriangulateMesh@DiscretizeGraphics[Graphics[CountryData["UnitedStates", {"Shape", "Mercator"}]]]

使用 Circumsphere 计算各个三角的外接圆：

Wolfram Language code: circles = Circumsphere[First[#]]& /@ MeshPrimitives[ℛ, 2];
Wolfram Language code: Graphics[{Opacity[0.5], Map[{RandomColor[], #}&, circles]}]

计算其效率：

Wolfram Language code: coverArea = Total@Map[Area[Disk@@#]&, circles]
Wolfram Language code: regionArea = Area[ℛ]
Wolfram Language code: regionArea / coverArea

使用 Circumsphere 生成一个覆盖三角化区域的球. 首先对该区域进行离散和三角化：

Wolfram Language code: ℛ = TriangulateMesh[[image], MeshQualityGoal -> "Minimal"]

使用 Circumsphere 计算各个四面体的球：

Wolfram Language code: spheres = Circumsphere[First[#]]& /@ MeshPrimitives[ℛ, 3];
Wolfram Language code: Graphics3D[{Opacity[0.5], Map[{RandomColor[], #}&, spheres]}]

计算填充密度：

Wolfram Language code: coverVolume = Total@Map[Volume[Ball@@#]&, spheres]
Wolfram Language code: regionVolume = Volume[ℛ]
Wolfram Language code: regionVolume / coverVolume

属性和关系  (1)

Circumsphere 可以表示任意 Sphere，通过在二维中选取球上的3个点：

Wolfram Language code: points = {{x + r, y}, {x - r, y}, {x, y + r}};
Wolfram Language code: Simplify[RegionMember[Sphere[{x, y}, r], points], {x, y, r}∈Reals && r > 0]
Wolfram Language code: Simplify[Circumsphere[points], r > 0]

在三维中选取球上的4个点，等：

Wolfram Language code: points = {{x + r, y, z}, {x - r, y, z}, {x, y + r, z}, {x, y, z + r}};
Wolfram Language code: Simplify[RegionMember[Sphere[{x, y, z}, r], points], {x, y, z, r}∈Reals && r > 0]
Wolfram Language code: Simplify[Circumsphere[points], r > 0]
Wolfram Research (2014)，Circumsphere，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Circumsphere.html （更新于 2019 年）.

文本

Wolfram Research (2014)，Circumsphere，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Circumsphere.html （更新于 2019 年）.

CMS

Wolfram 语言. 2014. "Circumsphere." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2019. https://reference.wolfram.com/language/ref/Circumsphere.html.

APA

Wolfram 语言. (2014). Circumsphere. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Circumsphere.html 年

BibTeX

@misc{reference.wolfram_2026_circumsphere, author="Wolfram Research", title="{Circumsphere}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Circumsphere.html}", note=[Accessed: 01-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_circumsphere, organization={Wolfram Research}, title={Circumsphere}, year={2019}, url={https://reference.wolfram.com/language/ref/Circumsphere.html}, note=[Accessed: 01-August-2026]}