WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Clear[s1,s2,…]

siに与えられている値や定義をクリアする．

Clear[patt1,patt2,…]

文字列パターン pattiのいずれかに名前がテキスト的にマッチするすべてのシンボルの値や定義をクリアする．

Clear[{spec1,spec2,…}]

名前が speciのいずれかと等しいあるいはいずれかにマッチする任意のシンボルの値や定義をクリアする．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
シンボルの入力  
パターンを使う  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連するワークフロー
関連リンク
履歴
引用書式

Clear

Clear[s1,s2,…]

siに与えられている値や定義をクリアする．

Clear[patt1,patt2,…]

文字列パターン pattiのいずれかに名前がテキスト的にマッチするすべてのシンボルの値や定義をクリアする．

Clear[{spec1,spec2,…}]

名前が speciのいずれかと等しいあるいはいずれかにマッチする任意のシンボルの値や定義をクリアする．

詳細

  • Clearは，シンボルに関連付けられている属性，デフォルト，オプション，メッセージをクリアすることはない． »
  • パターン patt は，メタ文字を含む文字列，StringExpression[…]，あるいはRegularExpression["regex"]として与えることができる． »
  • Clearは，次のメタ文字を含む省略された文字列パターンを許容する．
  • *0個以上の文字
    @大文字を除く1個以上の文字
  • Clear["context`*"]は，特定のコンテキストに置かれているすべてのシンボルをクリアする． »
  • Clear["`*"]は現行コンテキストのすべてのシンボルをクリアする． »
  • Clearは，属性としてProtectedが与えられているシンボルに影響を与えることはない． »
  • Clearは属性HoldAllを有する． »

例題

すべて開く すべて閉じる

例  (2)

変数をクリアする：

Wolfram Language code: x = 5;
Wolfram Language code: Clear[x]

この変数の値はなくなった：

Wolfram Language code: x

シンボルの値を定義する：

Wolfram Language code: f[x_] := x ^ 2
Wolfram Language code: Definition[f]

値をクリアする：

Wolfram Language code: Clear[f]
Wolfram Language code: Definition[f]

スコープ  (12)

シンボルの入力  (7)

変数の値（それ自身の値）をクリアする：

Wolfram Language code: x = 5;
Wolfram Language code: x
Wolfram Language code: Clear[x]
Wolfram Language code: x

関数（下向きの値）をクリアする：

Wolfram Language code: fact[1] = 1; fact[n_] := n fact[n - 1]
Wolfram Language code: fact[3]
Wolfram Language code: Clear[fact]
Wolfram Language code: fact[3]

上向きの値をクリアする：

Wolfram Language code: h/:f[h[x_]] := hf[x]
Wolfram Language code: f[h[x]]
Wolfram Language code: Clear[h]
Wolfram Language code: f[h[x]]

部分的な値をクリアする：

Wolfram Language code: f[x_][y_] := h[x, y]
Wolfram Language code: f[x][y]
Wolfram Language code: Clear[f]
Wolfram Language code: f[x][y]

書式をクリアする：

Wolfram Language code: Format[kappa] := κ
Wolfram Language code: kappa
Wolfram Language code: Clear[kappa]
Wolfram Language code: kappa

複数のシンボルをクリアする：

Wolfram Language code: a = 5; f[x_] := x ^ 3
Wolfram Language code: f[a]
Wolfram Language code: Clear[a, f]
Wolfram Language code: f[a]

シンボルとシンボル名の組合せを使う：

Wolfram Language code: x1 = 1;x2 = 3;x3 = 5;
Wolfram Language code: Clear[{x1, "x2"}]

x3だけが定義されたままである：

Wolfram Language code: {x1, x2, x3}

パターンを使う  (5)

クリアするシンボルを文字列パターンとして指定する：

Wolfram Language code: x1 = 1;x2 = 3;y = 5;
Wolfram Language code: Clear["x*"]
Wolfram Language code: {x1, x2, y}

現行コンテキストのすべてのシンボルをクリアする：

Wolfram Language code: x1 = 1;x2 = 3;y = 5;
Wolfram Language code: Clear["`*"]
Wolfram Language code: {x1, x2, y}

指定されたコンテキストのすべてのシンボルをクリアする：

Wolfram Language code: abc`x1 = 1;abc`x2 = 3;abc`y = 5;
Wolfram Language code: Clear["abc`*"]
Wolfram Language code: {abc`x1, abc`x2, abc`y}

StringExpressionを使って現行コンテキストにある2文字のシンボルをすべてクリアする：

Wolfram Language code: x1 = 1;x2 = 3;y = 5;
Wolfram Language code: Clear["`" ~~ _ ~~ _]

シンボルx1とx2はクリアされたがyはそのまま残っている：

Wolfram Language code: {x1, x2, y}

RegularExpressionを使って現行コンテキストにある3文字のシンボルをすべてクリアする：

Wolfram Language code: x = 1;yy = 3;zzz = 5;
Wolfram Language code: Clear[RegularExpression["`..."]]
Wolfram Language code: {x, yy, zzz}

アプリケーション  (2)

新しい定義をする前に古い定義をクリアする：

Wolfram Language code: Clear[fib]
Wolfram Language code: fib[1] = fib[2] = 1; fib[n_] := fib[n] = fib[n - 1] + fib[n - 2]
Wolfram Language code: fib[5]

2回読み込むことを可能にするために，パッケージのすべてのシンボルのプロテクトを外してクリアする：

Wolfram Language code: Begin["`Private`"];
Wolfram Language code: Unprotect["`*"]; Clear["`*"];
Wolfram Language code: f[x_] := x ^ 2
Wolfram Language code: Protect[f];
Wolfram Language code: End[];

特性と関係  (6)

Clear[pattern]はClear/@Names[pattern]と同じシンボルをクリアする：

Wolfram Language code: x = 1;y = 2; xy = 3; Clear["x*"]; {x, y, xy}
Wolfram Language code: x = 1;y = 2; xy = 3; Clear /@ Names["x*"]; {x, y, xy}

Unset (=.)を使って特定の左辺を持つ定義をクリアする：

Wolfram Language code: fact[0] = 1; fact[n_Integer] /; n > 0 := n fact[n - 1] fact[n_Integer] /; n < 0 := -∞
Wolfram Language code: fact[0]=.
Wolfram Language code: Definition[fact]

すべての定義をクリアする：

Wolfram Language code: Clear[fact]
Wolfram Language code: Definition[fact]

Clearは属性，デフォルト値，オプションは除かない：

Wolfram Language code: SetAttributes[f, Listable]; Default[f] = 0; Options[f] = {opt1 -> def1, opt2 -> def2}; f[x_.] := x ^ 2
Wolfram Language code: Clear[f]
Wolfram Language code: Definition[f]

ClearAllを使ってすべてをクリアする：

Wolfram Language code: ClearAll[f]
Wolfram Language code: Definition[f]

Clearはメッセージは除去しない：

Wolfram Language code: f::usage = "f[x] gives (x - 1)(x + 1)";
Wolfram Language code: Clear[f]
Wolfram Language code: Message[f::usage]

ClearAllを使ってメッセージを除去する：

Wolfram Language code: ClearAll[f]
Wolfram Language code: Message[f::usage]

Clearはすべての定義を除去するがシンボルはそのまま残す：

Wolfram Language code: f[x_] := x ^ 2
Wolfram Language code: Clear[f]
Wolfram Language code: ? f

Removeはシンボルを完全に除去する：

Wolfram Language code: Remove[f]
Wolfram Language code: ? f

Clearは属性HoldAllを有する：

Wolfram Language code: Definition[Clear]

次はsymbolそれ自身をクリアする：

Wolfram Language code: symbol = {"x", "y", "z"};x = 1;y = 3;z = 5;
Wolfram Language code: Clear[symbol]
Wolfram Language code: {symbol, x, y, z}

次はその値をクリアする：

Wolfram Language code: symbol = {"x", "y", "z"};
Wolfram Language code: Clear[Evaluate[symbol]]
Wolfram Language code: {symbol, x, y, z}

考えられる問題  (2)

プロテクトされたシンボルはクリアできない：

Wolfram Language code: x = 5; Protect[x];
Wolfram Language code: Clear[x]

Unprotectを使ってプロテクトされたシンボルの定義をクリアする：

Wolfram Language code: Unprotect[x]; Clear[x]

パターンをコンテキストマークなしで使うと，$ContextPath上のパターンにマッチするすべてのシンボルがクリアされる：

Wolfram Language code: x = 1;y = 2;xy = 3; Clear[_ ~~ _]

シンボル xy はクリアされ，いくつかのシステムシンボルのクリアも試みられた：

Wolfram Language code: xy

パターンを明示的なコンテキストマークを付けて使うと，システムあるいはその他のコンテキストにあるパターンとマッチするシンボルがクリアされるのを防ぐことができる：

Wolfram Language code: Clear["`" ~~ _]
Wolfram Research (1988), Clear, Wolfram言語関数， https://reference.wolfram.com/language/ref/Clear.html （2022年に更新）.

テキスト

Wolfram Research (1988), Clear, Wolfram言語関数， https://reference.wolfram.com/language/ref/Clear.html （2022年に更新）.

CMS

Wolfram Language. 1988. "Clear." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/Clear.html.

APA

Wolfram Language. (1988). Clear. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Clear.html

BibTeX

@misc{reference.wolfram_2026_clear, author="Wolfram Research", title="{Clear}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/Clear.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_clear, organization={Wolfram Research}, title={Clear}, year={2022}, url={https://reference.wolfram.com/language/ref/Clear.html}, note=[Accessed: 06-September-2026]}