Wolfram 语言与系统参考资料中心

Clear

Clear[s₁,s₂,…]

清除关于 s_i 的值和定义.

Clear[patt₁,patt₂,…]

清除所有符号的值和定义，这些符号的名称在文字上与任意的字符串模式相匹配 patt_i.

Clear[{spec₁,spec₂,…}]

清除任何等于或其名称与任何一个 spec_i 相匹配的符号的值和定义.

范例

打开所有单元关闭所有单元

基本范例 (2)

清除一个变量：

Wolfram Language code: x = 5;

Wolfram Language code: Clear[x]

该变量不再有值：

Wolfram Language code: x

定义一个符号的值：

Wolfram Language code: f[x_] := x ^ 2

Wolfram Language code: Definition[f]

清除值：

Wolfram Language code: Clear[f]

Wolfram Language code: Definition[f]

范围 (12)

符号输入 (7)

清除所有变量的值 (ownvalues)：

Wolfram Language code: x = 5;

Wolfram Language code: x

Wolfram Language code: Clear[x]

Wolfram Language code: x

清除函数（下值（downvalue）集）：

Wolfram Language code:

fact[1] = 1;
fact[n_] := n fact[n - 1]

Wolfram Language code: fact[3]

Wolfram Language code: Clear[fact]

Wolfram Language code: fact[3]

清除上值：

Wolfram Language code: h/:f[h[x_]] := hf[x]

Wolfram Language code: f[h[x]]

Wolfram Language code: Clear[h]

Wolfram Language code: f[h[x]]

清除子值：

Wolfram Language code: f[x_][y_] := h[x, y]

Wolfram Language code: f[x][y]

Wolfram Language code: Clear[f]

Wolfram Language code: f[x][y]

清除格式：

Wolfram Language code: Format[kappa] := κ

Wolfram Language code: kappa

Wolfram Language code: Clear[kappa]

Wolfram Language code: kappa

清除若干符号：

Wolfram Language code:

a = 5;
f[x_] := x ^ 3

Wolfram Language code: f[a]

Wolfram Language code: Clear[a, f]

Wolfram Language code: f[a]

使用符号和符号名称的组合：

Wolfram Language code: x1 = 1;x2 = 3;x3 = 5;

Wolfram Language code: Clear[{x1, "x2"}]

仅剩 x3 还有定义：

Wolfram Language code: {x1, x2, x3}

使用模式 (5)

将要清除的符号指定为字符串模式：

Wolfram Language code: x1 = 1;x2 = 3;y = 5;

Wolfram Language code: Clear["x*"]

Wolfram Language code: {x1, x2, y}

清除当前上下文中的所有符号：

Wolfram Language code: x1 = 1;x2 = 3;y = 5;

Wolfram Language code: Clear["`*"]

Wolfram Language code: {x1, x2, y}

清除给定上下文中的所有符号：

Wolfram Language code: abc`x1 = 1;abc`x2 = 3;abc`y = 5;

Wolfram Language code: Clear["abc`*"]

Wolfram Language code: {abc`x1, abc`x2, abc`y}

使用 StringExpression 清除当前上下文中的所有 2 个字符的符号：

Wolfram Language code: x1 = 1;x2 = 3;y = 5;

Wolfram Language code: Clear["`" ~~ _ ~~ _]

符号 x1 和 x2 已清除，但 y 不受影响：

Wolfram Language code: {x1, x2, y}

使用 RegularExpression 清除当前上下文中的所有 3 个字符的符号

Wolfram Language code: x = 1;yy = 3;zzz = 5;

Wolfram Language code: Clear[RegularExpression["`..."]]

Wolfram Language code: {x, yy, zzz}

应用 (2)

在生成一个新定义前，清除以前的任何定义：

Wolfram Language code: Clear[fib]

Wolfram Language code:

fib[1] = fib[2] = 1;
fib[n_] := fib[n] = fib[n - 1] + fib[n - 2]

Wolfram Language code: fib[5]

解除保护并清除程序包中的所有符号，以使其能够被读取两次：

Wolfram Language code: Begin["`Private`"];

Wolfram Language code:

Unprotect["`*"];
Clear["`*"];

Wolfram Language code: f[x_] := x ^ 2

Wolfram Language code: Protect[f];

Wolfram Language code: End[];

属性和关系 (6)

Clear[pattern] 与 Clear/@Names[pattern] 可清除相同的符号：

Wolfram Language code:

x = 1;y = 2; xy = 3;
Clear["x*"];
{x, y, xy}

Wolfram Language code:

x = 1;y = 2; xy = 3;
Clear /@ Names["x*"];
{x, y, xy}

使用 Unset (=.) 来清除具有特定左侧的定义：

Wolfram Language code:

fact[0] = 1;
fact[n_Integer] /; n > 0 := n fact[n - 1]
fact[n_Integer] /; n < 0 := -∞

Wolfram Language code: fact[0]=.

Wolfram Language code: Definition[fact]

清除所有定义：

Wolfram Language code: Clear[fact]

Wolfram Language code: Definition[fact]

Clear 并不删除属性、默认值或选项：

Wolfram Language code:

SetAttributes[f, Listable];
Default[f] = 0;
Options[f] = {opt1 -> def1, opt2 -> def2};
f[x_.] := x ^ 2

Wolfram Language code: Clear[f]

Wolfram Language code: Definition[f]

使用 ClearAll 清除所有：

Wolfram Language code: ClearAll[f]

Wolfram Language code: Definition[f]

Clear 并不清除消息：

Wolfram Language code: f::usage = "f[x] gives (x - 1)(x + 1)";

Wolfram Language code: Clear[f]

Wolfram Language code: Message[f::usage]

使用 ClearAll 可清除消息：

Wolfram Language code: ClearAll[f]

Wolfram Language code: Message[f::usage]

Clear 清除所有定义，但保留符号：

Wolfram Language code: f[x_] := x ^ 2

Wolfram Language code: Clear[f]

Wolfram Language code: ? f

Remove 彻底去除该符号：

Wolfram Language code: Remove[f]

Wolfram Language code: ? f

Clear 拥有属性 HoldAll：

Wolfram Language code: Definition[Clear]

这会清除 symbol 本身：

Wolfram Language code: symbol = {"x", "y", "z"};x = 1;y = 3;z = 5;

Wolfram Language code: Clear[symbol]

Wolfram Language code: {symbol, x, y, z}

以下运算仅清除值：

Wolfram Language code: symbol = {"x", "y", "z"};

Wolfram Language code: Clear[Evaluate[symbol]]

Wolfram Language code: {symbol, x, y, z}

可能存在的问题 (2)

受保护的符号不能被清除：

Wolfram Language code:

x = 5;
Protect[x];

Wolfram Language code: Clear[x]

利用 Unprotect 清除受保护符号的定义：

Wolfram Language code:

Unprotect[x];
Clear[x]

当使用没有上下文标记的模式时，$ContextPath 上的所有匹配符号被清除：

Wolfram Language code:

x = 1;y = 2;xy = 3;
Clear[_ ~~ _]

符号 xy 被清除了，同时还试图清除几个系统符号：

Wolfram Language code: xy

使用带有明确上下文标记的模式，以避免可能匹配来自系统或其他上下文的符号：

Wolfram Language code: Clear["`" ~~ _]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Clear

更多信息

范例

基本范例 (2)

范围 (12)

符号输入 (7)

使用模式 (5)

应用 (2)

属性和关系 (6)

可能存在的问题 (2)

文本

CMS

APA

BibTeX

BibLaTeX

	*	零或更多的字符
	@	一个或更多的字符，排除大写字母

Clear

更多信息

范例

基本范例 (2)

范围 (12)

符号输入 (7)

使用模式 (5)

应用 (2)

属性和关系 (6)

可能存在的问题 (2)

参见

技术笔记

相关指南

相关的工作流程

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX