WOLFRAM

Wolfram 语言与系统参考资料中心

ColorDistance[c1,c2]

给出颜色指令 c1 和 c2 之间的近似感知距离.

ColorDistance[list,c]

给出 list 的元素与 c 之间的颜色距离.

ColorDistance[list1,list2]

给出 list1 和 list2 的对应元素之间的颜色距离.

ColorDistance[image,c]

给出一个图像，其像素值是 image 中像素和颜色 c 之间的颜色距离.

ColorDistance[image1,image2]

生成一个图像，按像素给出 image1 和image2 之间的颜色距离.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
DistanceFunction  
应用  
属性和关系  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

ColorDistance

ColorDistance[c1,c2]

给出颜色指令 c1 和 c2 之间的近似感知距离.

ColorDistance[list,c]

给出 list 的元素与 c 之间的颜色距离.

ColorDistance[list1,list2]

给出 list1 和 list2 的对应元素之间的颜色距离.

ColorDistance[image,c]

给出一个图像，其像素值是 image 中像素和颜色 c 之间的颜色距离.

ColorDistance[image1,image2]

生成一个图像，按像素给出 image1 和image2 之间的颜色距离.

更多信息和选项

  • 色距又称色差，是对视觉、知觉色彩差异的一种测量. 感知上相似的颜色色距较小.
  • ColorDistance 计算两种颜色之间的距离，即两种颜色向量在 LABColor 空间中的欧氏距离.
  • 在计算颜色距离时，阿尔法通道被忽略.
  • ColorDistance 适用于任意二维和三维图像.
  • 当 ColorDistance[image,…] 时，颜色距离以实型图像的形式返回，其维度与 image 相同.
  • 当 ColorDistance[image1,image2] 时，image1 和 image2 是中心对齐，且返回重叠像素的颜色距离图像.
  • ColorDistance 支持 DistanceFunction 选项. 有以下设置可用：
  • "CIE76"在 LABColor 中的欧几里得距离（默认设置）
    "CIE94"在 LCHColor 中定义的色差
    "CIE2000"带有修正的 CIE94
    {"CMC",{l,c}}颜色测量委员会（Color Measurement Committee）度量，参数为亮度 l 和色度 c
    "DeltaL"在 LCHColor 中的亮度差
    "DeltaC"在 LCHColor 中的色度差
    "DeltaH"在 LCHColor 中基于色调的差异
    f给出两个Lab值列表的函数 f
  • 在 "CMC" 度量下，常用的参数是感知度 和可接受度 . 如果未指定，则使用 .

范例

打开所有单元 关闭所有单元

基本范例  (2)

两种颜色之间的距离：

Wolfram Language code: ColorDistance[Red, Blue]

颜色与图像的每个像素之间的距离：

Wolfram Language code: ColorDistance[[image], Orange]

范围  (5)

在不同色彩空间定义的颜色的距离：

Wolfram Language code: ColorDistance[Gray, LABColor[.5, .5, 0]]

彩色阵列的各个元素与一个颜色之间的距离：

Wolfram Language code: ColorDistance[{RGBColor[0.18077129219442112, 0.15154331458502068, 0.7644876344337121], RGBColor[0.37570945003037726, 0.004125067713668384, 0.2969503457671252], RGBColor[0.45339135078104875, 0.17876965775449882, 0.5229579155791375], RGBColor[0.21616382900417186, 0.7084611599452941, 0.9442344792776058], RGBColor[0.27418805094023435, 0.6676801751797845, 0.7841343593807673]}, RGBColor[0.7691099329143689, 0.3894376342272303, 0.8087557327930035]]

彩色阵列之间的距离：

Wolfram Language code: ColorDistance[{RGBColor[0.18077129219442112, 0.15154331458502068, 0.7644876344337121], RGBColor[0.37570945003037726, 0.004125067713668384, 0.2969503457671252], RGBColor[0.45339135078104875, 0.17876965775449882, 0.5229579155791375], RGBColor[0.21616382900417186, 0.7084611599452941, 0.9442344792776058], RGBColor[0.27418805094023435, 0.6676801751797845, 0.7841343593807673]}, {RGBColor[0.7691099329143689, 0.3894376342272303, 0.8087557327930035], RGBColor[0.2850187923162437, 0.33077177352188514, 0.13868103167491896], RGBColor[0.4556483766455912, 0.5813490503852354, 0.2804828580204961], RGBColor[0.2899288571808647, 0.3138074861832185, 0.4691678374570174], RGBColor[0.48990820234332033, 0.15952412128896754, 0.0013851383895859826]}]

两个图像之间的颜色距离：

Wolfram Language code: ColorDistance[[image], [image]]

具有不同尺寸的图像的中央区域之间的颜色距离：

Wolfram Language code: ColorDistance[[image], [image]]

选项  (8)

DistanceFunction  (8)

默认情况下，使用 "CIE76"（也用 ΔEa*b* 表示）：

Wolfram Language code: ColorDistance[Red, Blue]

对于 LABColor 分量，这对应于 EuclideanDistance：

Wolfram Language code: {c1, c2} = ColorConvert[#, "LAB"]& /@ {Red, Blue};
Wolfram Language code: EuclideanDistance[List@@c1, List@@c2]

可视化 "LAB" 空间中的 "CIE76" 颜色距离：

使用 "CIE94" 度量计算颜色距离（也用 ΔE94 表示）：

Wolfram Language code: ColorDistance[Red, Blue, DistanceFunction -> "CIE94"]

注意，这个度量是不对称的：

Wolfram Language code: ColorDistance[Blue, Red, DistanceFunction -> "CIE94"]

使用 "CIE2000" 度量计算颜色距离（也用 "CIEDE2000" 或 ΔE00 表示）：

Wolfram Language code: ColorDistance[Red, Blue, DistanceFunction -> "CIE2000"]

注意，这个度量是对称的：

Wolfram Language code: ColorDistance[Blue, Red, DistanceFunction -> "CIE2000"]

使用 "CMC" 颜色距离：

Wolfram Language code: ColorDistance[Red, Blue, DistanceFunction -> "CMC"]

使用 "DeltaL" 颜色距离：

Wolfram Language code: ColorDistance[Red, Blue, DistanceFunction -> "DeltaL"]

在 "LAB" 空间中表示的 L* 通道之间的距离：

使用 "DeltaC" 颜色距离：

Wolfram Language code: ColorDistance[Red, Blue, DistanceFunction -> "DeltaC"]

两种颜色的色度之间的距离，每个色度用 Norm[{a^*,b^*}] 计算：

使用 "DeltaH" 颜色距离：

Wolfram Language code: ColorDistance[Red, Blue, DistanceFunction -> "DeltaH"]

使用仅根据亮度的自定义距离函数：

Wolfram Language code: ColorDistance[Red, Blue, DistanceFunction -> (Abs[#1[[1]] - #2[[1]]]&)]

应用  (6)

使用选择性去饱和突出图像的细节：

Wolfram Language code: img = [image];
Wolfram Language code: mask = ColorNegate@ImageAdjust@ColorDistance[Red, img]
Wolfram Language code: ImageCompose[ColorConvert[img, "Grayscale"], SetAlphaChannel[img, mask]]

图像中具体颜色的截面分量：

Wolfram Language code: δ = ColorDistance[[image], {RGBColor[239/255, 11/17, 3/17], RGBColor[32/85, 47/85, 58/255], RGBColor[62/85, 47/255, 43/255]}]; Binarize[ImageAdjust[#], {0, .2}]& /@ δ

通过比较两个图像检测运动：

Wolfram Language code: ColorDistance[[image], [image]]

此图像具有很强的红色色偏：

Wolfram Language code: i = [image];

默认距离考虑色调、亮度和色度的差异：

Wolfram Language code: ColorDistance[i, Red]

使用 DistanceFunction"DeltaH" 仅测量色调的差异：

Wolfram Language code: ColorDistance[i, Red, DistanceFunction -> "DeltaH"]

根据距离对一个颜色列表进行汇集：

Wolfram Language code: colors = DominantColors[[image], 50];
Wolfram Language code: FindClusters[colors, 4]//Column

根据到基准颜色的感知距离对一列颜色排序：

Wolfram Language code: ref = Blue; colors = RandomColor[20]
Wolfram Language code: colors[[Ordering[ColorDistance[colors, ref, DistanceFunction -> "CIE2000"]]]]

与基于 RGB 值的排序相比：

Wolfram Language code: Sort[colors]

属性和关系  (8)

ColorDistance 等价于 LABColor 空间中颜色的 EuclideanDistance：

Wolfram Language code: {c1, c2} = {RGBColor[1, 0, 0], RGBColor[0, 1, 0]};
Wolfram Language code: ColorDistance[c1, c2]
Wolfram Language code: {labc1, labc2} = List@@@(ColorConvert[#, LABColor]& /@ {c1, c2});
Wolfram Language code: EuclideanDistance[labc1, labc2]

颜色与其自身的距离总是零：

Wolfram Language code: color = RGBColor[1, 0, 0];
Wolfram Language code: ColorDistance[color, color]

在两个色彩空间表示的颜色距离为零：

Wolfram Language code: ColorDistance[color, ColorConvert[color, XYZColor]]

注意，如果颜色在新的色彩空间不可用，这个距离可以是非零的：

Wolfram Language code: lab = LABColor[0, 0.5, 1.5];
Wolfram Language code: ColorDistance[lab, ColorConvert[lab, CMYKColor]]

计算距离时，阿尔法通道没有被使用：

Wolfram Language code: ColorDistance[RGBColor[1, 0, 0, 1], RGBColor[1, 0, 0, .3]]

对于 RGB 颜色，每种方法的距离的一般范围如下：

使用 RGB 方块的边界来定义一个样本集合：

Wolfram Language code: colors = With[{δ = .2}, Flatten[Table[RGBColor[r, g, b], {r, 0, 1, δ}, {g, 0, 1, δ}, {b, 0, 1, δ}]]]; colors = Cases[colors, RGBColor[0. | 1., _, _] | RGBColor[_, 0. | 1., _] | RGBColor[_, _, 0. | 1.]]; pairs = Transpose@Flatten[Outer[List, colors, colors], 1];

在样本颜色之间计算每对之间的距离：

Wolfram Language code: distanceNames = {"CIE76", "CIE94", "CIE2000", "CMC", "DeltaL", "DeltaC", "DeltaH"}; computedDist = ColorDistance[Sequence@@pairs, DistanceFunction -> #]& /@ distanceNames;

计算范围：

Wolfram Language code: MapThread[Rule, {distanceNames, MinMax /@ computedDist}]//Column

不是所有的颜色距离都是数学意义上的度量：

"CIE76"
"CIE94"
"CIE2000"
"CMC"
"DeltaL"
"DeltaC"
"DeltaH"
"non-negativity"
✓✓✓✓✓✓✓
"coincidence axiom"
✓✓✓✓
"-"
"-"
"-"
"symmetry"
✓
"-"
✓
"-"
✓✓✓
"triangle inequality"
✓
"-"
"-"
"-"
✓✓
"-"

"CIE94" 和 "CMC" 不是对称的：

Wolfram Language code: ColorDistance[Red, Black, DistanceFunction -> #]& /@ {"CIE94", "CMC"} ColorDistance[Black, Red, DistanceFunction -> #]& /@ {"CIE94", "CMC"}

"CIE94"、"CIE2000"、"CMC" 和 "DeltaH" 并不总是满足三角不等式：

Wolfram Language code: {c1, c2, c3} = {LABColor[0.13746501016460688, -0.3385073806178629, -0.37154877167601175], LABColor[0.5569755775933762, -0.13467171094537056, 0.5119240857106018], LABColor[0.9568310647628457, 0.18081259166998453, 1.274230978258097]};
Wolfram Language code: Table[ ColorDistance[c1, c3, DistanceFunction -> d] ≤ ColorDistance[c1, c2, DistanceFunction -> d] + ColorDistance[c2, c3, DistanceFunction -> d], {d, {"CIE94", "CIE2000", "CMC", "DeltaH"}}]

满足三角不等式的模拟频率取决于指定的距离：

Wolfram Language code: colors = RandomColor[LABColor, {3, 20000}];
Wolfram Language code: simulateTriangularInequality[dist_] := Apply[Thread[ColorDistance[#, #3, DistanceFunction -> dist] ≤ ColorDistance[#, #2, DistanceFunction -> dist] + ColorDistance[#2, #3, DistanceFunction -> dist]]&, colors]//Tally//Sort;
Wolfram Language code: simulateTriangularInequality["CIE94"]
Wolfram Language code: simulateTriangularInequality["CIE2000"]
Wolfram Language code: simulateTriangularInequality["CMC"]
Wolfram Language code: simulateTriangularInequality["DeltaH"]

"CIE2000" 是最新的标准，引进了很多改进简单实验室距离（Lab distance）的规则. 感觉上会比 "CIE76" 和 "CIE94" 更精确：

显示在 平面上固定亮度的的固定距离曲线，:

然而，"CIE2000" 在计算上比以前的矩阵更复杂：

Wolfram Language code: image = RandomImage[1, {1500, 1500}]; color = RandomColor[];
Wolfram Language code: ColorDistance[image, color, DistanceFunction -> "CIE76"]//AbsoluteTiming//First
Wolfram Language code: ColorDistance[image, color, DistanceFunction -> "CIE94"]//AbsoluteTiming//First
Wolfram Language code: ColorDistance[image, color, DistanceFunction -> "CIE2000"]//AbsoluteTiming//First

ImageDistance 默认计算在 RGB 空间中的两个图像之间的欧几里德距离：

Wolfram Language code: images = {ConstantImage[Red], ConstantImage[LightRed]};
Wolfram Language code: ImageDistance@@images
Wolfram Language code: EuclideanDistance[Flatten@ImageData[#1], Flatten@ImageData[#2]]&@@ColorConvert[images, "RGB"]

ColorDistance 默认计算在 LAB 空间中的两个像素之间的欧几里得距离：

Wolfram Language code: Sqrt@Total[ImageData[ColorDistance@@images] ^ 2, 2]
Wolfram Language code: EuclideanDistance[Flatten@ImageData[#1], Flatten@ImageData[#2]]&@@ColorConvert[images, "LAB"]

ColorDistance 返回不同尺寸的图像的中央区域之间的距离

Wolfram Language code: ColorDistance[[image], [image]]

如果两个图像重叠的区域重合，则它们之间的距离可以是同为零：

Wolfram Language code: ColorDistance[[image], [image]]
Wolfram Language code: ImageMeasurements[%, "Max"]

巧妙范例  (1)

利用距离地图从三原色着色图像：

Wolfram Language code: ColorDistance[{Red, Green, Blue}, [image]]//ColorCombine//ImageAdjust//ColorNegate
Wolfram Research (2014)，ColorDistance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ColorDistance.html （更新于 2015 年）.

文本

Wolfram Research (2014)，ColorDistance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ColorDistance.html （更新于 2015 年）.

CMS

Wolfram 语言. 2014. "ColorDistance." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2015. https://reference.wolfram.com/language/ref/ColorDistance.html.

APA

Wolfram 语言. (2014). ColorDistance. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ColorDistance.html 年

BibTeX

@misc{reference.wolfram_2026_colordistance, author="Wolfram Research", title="{ColorDistance}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/ColorDistance.html}", note=[Accessed: 17-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_colordistance, organization={Wolfram Research}, title={ColorDistance}, year={2015}, url={https://reference.wolfram.com/language/ref/ColorDistance.html}, note=[Accessed: 17-July-2026]}