WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Colorize[m]

正の整数には色を正ではない整数には黒を使って，整数行列 m から画像を生成する．

Colorize[image]

image の強度の値を擬似カラーの値で置換する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
2D  
3D  
オプション  
ColorFunction  
ColorRules  
ImageSize  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

Colorize

Colorize[m]

正の整数には色を正ではない整数には黒を使って，整数行列 m から画像を生成する．

Colorize[image]

image の強度の値を擬似カラーの値で置換する．

詳細とオプション

  • Colorizeは，画像の詳細をよりよく可視化するために，2Dあるいは3Dの画像の疑似または偽の色付けを生成する．また，しばしば分割とクラスタリングによって生成される整数配列も彩色することができる．
  • Colorizeは，2Dおよび3Dの画像と整数配列に使うことができる．
  • Colorizeは8ビットのRGB画像を生成する．
  • Colorizeで使用可能なオプション
  • ColorFunction Automatic各画素をどのように色付けするか
    ColorFunctionScaling TrueColorFunctionの引数をスケールするかどうか
    ColorRules Automatic行列と画素値から色を決定するための規則
    ImageSize Automatic画像のデフォルトの表示サイズ
  • デフォルトで，"DarkRainbow"が使われる．0未満および1を越える強度値は切り取られる．
  • 整数配列の場合，0および負の整数値は黒で示される．性の整数値は連続する整数に別個の色を使って彩色される．
  • ColorFunctionfunc を使って異なる色関数を指定する．関数 func は，0から1にスケールされた値を色の値にマッピングする．
  • ColorFunctionScalingFalseを使って，スケールされていない入力値についての色関数を指定する．
  • 次は，サポートされるColorFunctionの設定である．
  • GrayLevelグレーレベルの色空間を適用する
    HueHSB色空間を適用する
    ColorData["scheme"]指定されたColorData関数を適用する
    "scheme"ColorData["scheme"]と同等
    "GrayLevelOpacity"OpacityがあるGrayLevelを適用する．0に近い黒の値は透明になり，1に近い白の値は不透明になる
    "HueOpacity"OpacityのあるHue を適用する
    "schemeOpacity"OpacityのあるColorData["scheme"]を適用する
    "XRay"X線効果を近似する
    "WhiteBlackOpacity"不透明度のある白から黒の色成分を適用する
  • ColorRulesを使って色置換のリストを指定する．配列の場合は，色の規則が整数値を置換する．画像の場合は，色規則がグレースケールの値に適用される．
  • Colorizeは"Byte"型のRGB画像を生成する．入力画像，色関数，色規則によっては，画像にアルファチャンネルが含まれることがある．

例題

すべて開く すべて閉じる

例  (2)

グレースケール画像に色付けする：

Wolfram Language code: Colorize[[image]]

分割によって返されたラベル行列に色付けする：

Wolfram Language code: labels = MorphologicalComponents[[image]]; Short[labels, 3]
Wolfram Language code: Colorize[labels]

スコープ  (5)

2D  (3)

整数配列に彩色する：

Wolfram Language code: (arr = MorphologicalComponents[[image]])//Short[#, 3]&
Wolfram Language code: Colorize[arr]

整数値の疎な配列に彩色する：

Wolfram Language code: arr = SparseArray@MorphologicalComponents[[image]]
Wolfram Language code: Colorize[arr]

グレースケールの画像に彩色する：

Wolfram Language code: Colorize[[image]]

3D  (2)

3Dラベル行列に彩色する：

Wolfram Language code: MorphologicalComponents[[image]]//Colorize

3Dのグレースケール画像に彩色する：

Wolfram Language code: ExampleData[{"TestImage3D", "CTengine"}]
Wolfram Language code: Colorize[%, ColorFunction -> "DarkRainbowOpacity"]

オプション  (10)

ColorFunction  (4)

地図にカラースキームを適用する：

Wolfram Language code: Colorize[MorphologicalComponents[[image]], ColorFunction -> "ThermometerColors"]

グレースケールの画像に彩色する：

Wolfram Language code: Colorize[[image], ColorFunction -> "RoseColors"]

ColorRulesを使って背景を黒く保つ：

Wolfram Language code: Colorize[[image], ColorFunction -> "RoseColors", ColorRules -> {0 -> Black}]

色関数として純関数を使う：

Wolfram Language code: Colorize[[image], ColorFunction -> (Blend[{White, Purple}, #]&)]

透明度がある色関数は チャンネルがある画像を返す：

Wolfram Language code: Colorize[[image], ColorFunction -> "WhiteBlackOpacity" ]
Wolfram Language code: Information[%, "Transparency"]

ColorRules  (5)

黒以外の背景色を指定する：

Wolfram Language code: Colorize[ MorphologicalComponents[[image]], ColorFunction -> "Rainbow", ColorRules -> {0 -> White} ]

画像中の透明色の結果を チャンネルで置換する：

Wolfram Language code: Colorize[ MorphologicalComponents[[image]], ColorFunction -> "Rainbow", ColorRules -> {0 -> GrayLevel[0.8, 0.5]} ]
Wolfram Language code: Information[%, "Transparency"]

すべての行列値に対する色置換規則を指定する：

Wolfram Language code: Colorize[ MorphologicalComponents[[image]], ColorRules -> {0 -> White, 10 -> Red, _ -> Blue} ]

最大成分の色を指定する：

Wolfram Language code: c = MorphologicalComponents[[image]]; label = Max[SelectComponents[c, "Count", -1]]
Wolfram Language code: Colorize[c, ColorFunction -> "ThermometerColors", ColorRules -> {13 -> Green}]

暗色の背景を透明にする：

Wolfram Language code: Colorize[[image], ColorRules -> {_ ? (# < 0.1&) -> Transparent} ]

ImageSize  (1)

デフォルトで，ImageSize->Automaticが使われる：

Wolfram Language code: Colorize[MorphologicalComponents[[image]]]

画像の大きさを指定する：

Wolfram Language code: Colorize[MorphologicalComponents[[image]], ImageSize -> 150]

アプリケーション  (5)

分割結果を彩色する：

Wolfram Language code: ImageSegmentationComponents[[image]]//Colorize

高度地図の擬似彩色：

Wolfram Language code: data = GeoElevationData[Entity["City", {"Tokyo", "Tokyo", "Japan"}], GeoRange -> Quantity[120, "Kilometers"], GeoProjection -> Automatic]
Wolfram Language code: Colorize[ data, ColorFunction -> "AlpineColors", ColorRules -> {0 -> RGBColor[0.06666666666666668, 0.13333333333333336, 0.4]}, ImageSize -> 320 ]

CTスキャンに彩色して異なる組織タイプを強調する：

Wolfram Language code: CT = [image];

Hounsfield単位 (-1000 ↔ air, 0 ↔ water, ...)に基づく自然の彩色スキーム：

Wolfram Language code: naturalCT = Blend[{{-1000, RGBColor[0, 0, 0]}, {-600, RGBColor[{194/255, 7/17, 82/255}]}, {-400, RGBColor[{194/255, 7/17, 82/255}]}, {-100, RGBColor[{194/255, 166/255, 23/51}]}, {-60, RGBColor[{194/255, 166/255, 23/51}]}, {40, RGBColor[{2/5, 0, 0}]}, {80, RGBColor[{3/5, 0, 0}]}, {400, RGBColor[1, 1, 1]}, {1000, RGBColor[1, 1, 1]}}, #]&;

CTデータをHounsfield単位に再スケールして彩色する：

Wolfram Language code: Colorize[CT, ColorFunction -> (naturalCT[Rescale[#, {0, 1}, {-1000, 1200}]]&)]

地図のランダムな色付け：

Wolfram Language code: MorphologicalComponents[[image]]//Colorize

分割された国々に，その面積によって色付けする：

Wolfram Language code: m = MorphologicalComponents[[image]]; area = SortBy[ComponentMeasurements[m, "Count"], Last]; Colorize[m /. area, ColorFunction -> "RedGreenSplit"]

特性と関係  (1)

Wolfram Neural Net Repositoryからのニューラルネットワークを使ってグレースケールの画像に色付けする：

Wolfram Language code: net = NetModel["ColorNet Image Colorization Trained on Places Data"];

ネットの評価関数を構築する：

Wolfram Language code: netevaluation[img_Image] := Image[Prepend[ArrayResample[net[img], Prepend[Reverse@ImageDimensions@img, 2]], ImageData[ColorSeparate[img, "L"]]], Interleaving -> False, ColorSpace -> "LAB"]

グレースケールの画像に色付けする：

Wolfram Language code: netevaluation[[image]]

考えられる問題  (1)

バイナリ画像では前景画素がすべて同色で彩色される：

Wolfram Language code: Colorize[[image]]

異なる色で成分をハイライトしたい場合は最初に連結成分を計算する：

Wolfram Language code: Colorize[MorphologicalComponents[[image]]]

おもしろい例題  (2)

セルオートマトンの連結成分に適用されたランダムな色：

Wolfram Language code: Colorize[MorphologicalComponents[CellularAutomaton[30, {{1}, 0}, 101], CornerNeighbors -> False]]//Magnify

セルオートマトンのより多くのステップ数を実行する：

Wolfram Language code: Colorize[MorphologicalComponents[CellularAutomaton[30, {{1}, 0}, 10 ^ 3], CornerNeighbors -> False]]

3Dセルオートマトンの成分に彩色する：

Wolfram Language code: Colorize[MorphologicalComponents[CellularAutomaton[{10, {2, 1}, {1, 1}}, {{{1}}, 0}, 70], CornerNeighbors -> False], ColorFunction -> "Rainbow"]
Wolfram Research (2010), Colorize, Wolfram言語関数， https://reference.wolfram.com/language/ref/Colorize.html （2012年に更新）.

テキスト

Wolfram Research (2010), Colorize, Wolfram言語関数， https://reference.wolfram.com/language/ref/Colorize.html （2012年に更新）.

CMS

Wolfram Language. 2010. "Colorize." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2012. https://reference.wolfram.com/language/ref/Colorize.html.

APA

Wolfram Language. (2010). Colorize. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Colorize.html

BibTeX

@misc{reference.wolfram_2026_colorize, author="Wolfram Research", title="{Colorize}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/Colorize.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_colorize, organization={Wolfram Research}, title={Colorize}, year={2012}, url={https://reference.wolfram.com/language/ref/Colorize.html}, note=[Accessed: 07-September-2026]}