WOLFRAM

Wolfram 语言与系统参考资料中心

Colorize[m]

从整数矩阵 m 生成一个图像，对正整数使用彩色，对非正整数使用黑色.

Colorize[image]

把 image 中的亮度值用伪彩色值代替.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
二维  
三维  
选项  
ColorFunction  
ColorRules  
ImageSize  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

Colorize

Colorize[m]

从整数矩阵 m 生成一个图像，对正整数使用彩色，对非正整数使用黑色.

Colorize[image]

把 image 中的亮度值用伪彩色值代替.

更多信息和选项

  • Colorize 对二维和三维图像进行伪着色或假着色，以更好地显示图像中的细节. 它还能对整数数组进行着色，通常由分割和聚类生成.
  • Colorize 可处理二维、三维图像和整数数组.
  • Colorize 生成一个 8 位 RGB 图像.
  • Colorize 采用下列选项：
  • ColorFunction Automatic应该如何对每个像素着色
    ColorFunctionScaling True是否对 ColorFunction 的变量进行缩放
    ColorRules Automatic从矩阵和像素值判断颜色的规则
    ImageSize Automatic图像的默认显示尺寸
  • 默认情况下，图像使用 "DarkRainbow". 强度值低于 0 和高于 1 时会被裁剪.
  • 对于整数数组，0 和负整数值用黑色显示. 正整数用不同的颜色表示连续的整数.
  • 使用 ColorFunctionfunc 可指定不同的颜色函数. 函数 func 将 0 和 1 之间的缩放值映射为颜色值.
  • 使用 ColorFunctionScalingFalse 可在未缩放的输入值上指定颜色函数.
  • 支持的 ColorFunction 设置包括：
  • GrayLevel应用灰度色彩空间
    Hue应用 HSB 色彩空间
    ColorData["scheme"]应用指定的 ColorData 函数
    "scheme"等价于 ColorData["scheme"]
    "GrayLevelOpacity"应用带有 Opacity 的 GrayLevel；接近 0 的黑色值是透明的，而接近 1 的白色色调是不透明的
    "HueOpacity"通过 Opacity 应用 Hue
    "schemeOpacity"通过 Opacity 应用 ColorData["scheme"]
    "XRay"近似 X 射线效应
    "WhiteBlackOpacity"应用具有不透明度的白-黑颜色分量
  • 使用 ColorRules 指定颜色替换列表. 对于数组，颜色规则会替换整数值. 对于图像，颜色规则适用于灰度值.
  • Colorize 生成 "Byte" 类型的 RGB 图像. 根据输入图像、色彩函数和色彩规则的不同，图像可能会有一个 alpha 通道.

范例

打开所有单元 关闭所有单元

基本范例  (2)

对灰度图像着色：

Wolfram Language code: Colorize[[image]]

对来自分割的标签矩阵进行着色：

Wolfram Language code: labels = MorphologicalComponents[[image]]; Short[labels, 3]
Wolfram Language code: Colorize[labels]

范围  (5)

二维  (3)

为整数数组着色：

Wolfram Language code: (arr = MorphologicalComponents[[image]])//Short[#, 3]&
Wolfram Language code: Colorize[arr]

为整数值稀疏数组着色：

Wolfram Language code: arr = SparseArray@MorphologicalComponents[[image]]
Wolfram Language code: Colorize[arr]

为灰度图像着色：

Wolfram Language code: Colorize[[image]]

三维  (2)

对三维标签矩阵进行着色：

Wolfram Language code: MorphologicalComponents[[image]]//Colorize

为三维灰度图像着色：

Wolfram Language code: ExampleData[{"TestImage3D", "CTengine"}]
Wolfram Language code: Colorize[%, ColorFunction -> "DarkRainbowOpacity"]

选项  (10)

ColorFunction  (4)

对一幅地图应用彩色方案：

Wolfram Language code: Colorize[MorphologicalComponents[[image]], ColorFunction -> "ThermometerColors"]

对灰度图像进行着色：

Wolfram Language code: Colorize[[image], ColorFunction -> "RoseColors"]

使用 ColorRules 使得背景保持为黑色：

Wolfram Language code: Colorize[[image], ColorFunction -> "RoseColors", ColorRules -> {0 -> Black}]

将纯函数作为颜色函数使用：

Wolfram Language code: Colorize[[image], ColorFunction -> (Blend[{White, Purple}, #]&)]

带有不透明度的颜色函数会返回带有 通道的图像：

Wolfram Language code: Colorize[[image], ColorFunction -> "WhiteBlackOpacity" ]
Wolfram Language code: Information[%, "Transparency"]

ColorRules  (5)

指定不同于黑色的背景颜色：

Wolfram Language code: Colorize[ MorphologicalComponents[[image]], ColorFunction -> "Rainbow", ColorRules -> {0 -> White} ]

替换透明色后，会得到带有一个 通道的图像：

Wolfram Language code: Colorize[ MorphologicalComponents[[image]], ColorFunction -> "Rainbow", ColorRules -> {0 -> GrayLevel[0.8, 0.5]} ]
Wolfram Language code: Information[%, "Transparency"]

指定所有矩阵数值的颜色替换规则：

Wolfram Language code: Colorize[ MorphologicalComponents[[image]], ColorRules -> {0 -> White, 10 -> Red, _ -> Blue} ]

指定最大分量的颜色：

Wolfram Language code: c = MorphologicalComponents[[image]]; label = Max[SelectComponents[c, "Count", -1]]
Wolfram Language code: Colorize[c, ColorFunction -> "ThermometerColors", ColorRules -> {13 -> Green}]

使深色背景透明：

Wolfram Language code: Colorize[[image], ColorRules -> {_ ? (# < 0.1&) -> Transparent} ]

ImageSize  (1)

默认情况下，使用 ImageSize->Automatic：

Wolfram Language code: Colorize[MorphologicalComponents[[image]]]

指定图像大小：

Wolfram Language code: Colorize[MorphologicalComponents[[image]], ImageSize -> 150]

应用  (5)

为分割结果着色：

Wolfram Language code: ImageSegmentationComponents[[image]]//Colorize

海拔图的伪着色：

Wolfram Language code: data = GeoElevationData[Entity["City", {"Tokyo", "Tokyo", "Japan"}], GeoRange -> Quantity[120, "Kilometers"], GeoProjection -> Automatic]
Wolfram Language code: Colorize[ data, ColorFunction -> "AlpineColors", ColorRules -> {0 -> RGBColor[0.06666666666666668, 0.13333333333333336, 0.4]}, ImageSize -> 320 ]

为 CT 扫描着色，以突出不同的组织类型：

Wolfram Language code: CT = [image];

基于亨氏单位的自然着色方案（-1000 ↔ 空气，0 ↔ 水，......）：

Wolfram Language code: naturalCT = Blend[{{-1000, RGBColor[0, 0, 0]}, {-600, RGBColor[{194/255, 7/17, 82/255}]}, {-400, RGBColor[{194/255, 7/17, 82/255}]}, {-100, RGBColor[{194/255, 166/255, 23/51}]}, {-60, RGBColor[{194/255, 166/255, 23/51}]}, {40, RGBColor[{2/5, 0, 0}]}, {80, RGBColor[{3/5, 0, 0}]}, {400, RGBColor[1, 1, 1]}, {1000, RGBColor[1, 1, 1]}}, #]&;

将 CT 数据重新缩放为亨氏单位并着色：

Wolfram Language code: Colorize[CT, ColorFunction -> (naturalCT[Rescale[#, {0, 1}, {-1000, 1200}]]&)]

地图的随机着色：

Wolfram Language code: MorphologicalComponents[[image]]//Colorize

根据面积对分割后的国家进行着色：

Wolfram Language code: m = MorphologicalComponents[[image]]; area = SortBy[ComponentMeasurements[m, "Count"], Last]; Colorize[m /. area, ColorFunction -> "RedGreenSplit"]

属性和关系  (1)

使用 Wolfram 神经网络库中的神经网络为灰度图像着色.

Wolfram Language code: net = NetModel["ColorNet Image Colorization Trained on Places Data"];

构建净评估函数：

Wolfram Language code: netevaluation[img_Image] := Image[Prepend[ArrayResample[net[img], Prepend[Reverse@ImageDimensions@img, 2]], ImageData[ColorSeparate[img, "L"]]], Interleaving -> False, ColorSpace -> "LAB"]

为灰度图像着色：

Wolfram Language code: netevaluation[[image]]

可能存在的问题  (1)

在一个二值图像中，所有的前景像素使用相同的颜色：

Wolfram Language code: Colorize[[image]]

为了使用不同的颜色强调各个分量，首先计算连通分量：

Wolfram Language code: Colorize[MorphologicalComponents[[image]]]

巧妙范例  (2)

对一个元胞自动机应用随机着色：

Wolfram Language code: Colorize[MorphologicalComponents[CellularAutomaton[30, {{1}, 0}, 101], CornerNeighbors -> False]]//Magnify

运行元胞自动机的更多步骤：

Wolfram Language code: Colorize[MorphologicalComponents[CellularAutomaton[30, {{1}, 0}, 10 ^ 3], CornerNeighbors -> False]]

对三维细胞自动机的组件着色：

Wolfram Language code: Colorize[MorphologicalComponents[CellularAutomaton[{10, {2, 1}, {1, 1}}, {{{1}}, 0}, 70], CornerNeighbors -> False], ColorFunction -> "Rainbow"]
Wolfram Research (2010)，Colorize，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Colorize.html （更新于 2012 年）.

文本

Wolfram Research (2010)，Colorize，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Colorize.html （更新于 2012 年）.

CMS

Wolfram 语言. 2010. "Colorize." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2012. https://reference.wolfram.com/language/ref/Colorize.html.

APA

Wolfram 语言. (2010). Colorize. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Colorize.html 年

BibTeX

@misc{reference.wolfram_2026_colorize, author="Wolfram Research", title="{Colorize}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/Colorize.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_colorize, organization={Wolfram Research}, title={Colorize}, year={2012}, url={https://reference.wolfram.com/language/ref/Colorize.html}, note=[Accessed: 10-September-2026]}