WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CompoundPoissonProcess[λ,jdist]

割合母数 λ でジャンプサイズ分布 jdist に従う複合ポアソン(Poisson)過程を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
過程スライス特性  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CompoundPoissonProcess

CompoundPoissonProcess[λ,jdist]

割合母数 λ でジャンプサイズ分布 jdist に従う複合ポアソン(Poisson)過程を表す．

詳細

  • CompoundPoissonProcessは，累積ポアソン過程あるいはポアソンクラスタ過程としても知られている．
  • CompoundPoissonProcessは連続時間で，jdist によって連続状態あるいは離散状態となるランダム過程である．
  • 時間 における状態は で与えられる．ただし，は jdist に従う独立同分布の確率変数であり， はPoissonProcess[λ]に従う．
  • 母数 λ は任意の正の実数でよく，jdist は任意の一変量分布でよい．
  • CompoundPoissonProcessは，Mean，Variance，RandomFunction等の関数で使うことができる．

例題

すべて開く すべて閉じる

例  (2)

指数ジャンプサイズ分布に従う複合ポアソン過程のシミュレーションを行う：

Wolfram Language code: 𝒫 = CompoundPoissonProcess[.8, ExponentialDistribution[2]];
Wolfram Language code: data = RandomFunction[𝒫, {20}]
Wolfram Language code: ListStepPlot[data, Filling -> Axis]

平均値関数と分散関数：

Wolfram Language code: 𝒫 = CompoundPoissonProcess[λ, ExponentialDistribution[μ]];
Wolfram Language code: Mean[𝒫[t]]
Wolfram Language code: Variance[𝒫[t]]

スコープ  (8)

基本的な用法  (4)

離散ジャンプがある複合ポアソン過程のシミュレーションを行う：

Wolfram Language code: 𝒫 = CompoundPoissonProcess[1.3, GeometricDistribution[.4]];
Wolfram Language code: data = RandomFunction[𝒫, {30}, 3]
Wolfram Language code: ListStepPlot[data, Filling -> Axis]

連続ジャンプがある複合ポアソン過程のシミュレーションを行う：

Wolfram Language code: 𝒫 = CompoundPoissonProcess[2, NormalDistribution[0, 2]];
Wolfram Language code: data = RandomFunction[𝒫, {30}, 3]
Wolfram Language code: ListStepPlot[data, Filling -> Axis]

さまざまな更新率の複合ポアソン過程を比較する：

Wolfram Language code: proc[λ_] := CompoundPoissonProcess[λ, WeibullDistribution[.2, .3]];
Wolfram Language code: data = Table[RandomFunction[proc[λ], {300}], {λ, pars = {.7, 1, 2}}];
Wolfram Language code: ListStepPlot[data, PlotLegends -> (StringJoin["λ = ", ToString[#]]& /@ pars)]

過程母数推定：

Wolfram Language code: sample = RandomFunction[CompoundPoissonProcess[3, GammaDistribution[2, 5]], {1, 10 ^ 3}];

サンプルデータから分布母数を推定する：

Wolfram Language code: EstimatedProcess[sample, CompoundPoissonProcess[m, GammaDistribution[a, b]]]

過程スライス特性  (4)

スライス分布はCompoundPoissonDistributionである：

Wolfram Language code: CompoundPoissonProcess[λ, WeibullDistribution[a, b]][t]
Wolfram Language code: CompoundPoissonProcess[λ, ZipfDistribution[a, b]][t]

スライス分布のシミュレーションを行う：

Wolfram Language code: 𝒫 = CompoundPoissonProcess[2, WeibullDistribution[2, 3]];
Wolfram Language code: data = RandomVariate[SliceDistribution[𝒫, 7], 10 ^ 3];
Wolfram Language code: Histogram[data, 20, "PDF"]

スライス分布モーメント：

Wolfram Language code: 𝒫 = CompoundPoissonProcess[2, WeibullDistribution[2, 3]];

平均値関数：

Wolfram Language code: Plot[Mean[𝒫[t]], {t, 0, 10}]
Wolfram Language code: Mean[𝒫[t]]

分散関数：

Wolfram Language code: Plot[Variance[𝒫[t]], {t, 0, 10}]
Wolfram Language code: Variance[𝒫[t]]

歪度：

Wolfram Language code: Skewness[𝒫[t]]

尖度：

Wolfram Language code: Kurtosis[𝒫[t]]

スライス分布モーメントと母関数：

Wolfram Language code: 𝒫 = CompoundPoissonProcess[m, BinomialDistribution[n, p]];

モーメント：

Wolfram Language code: Moment[𝒫[t], 3]

モーメント母関数：

Wolfram Language code: MomentGeneratingFunction[𝒫[t], x]

キュムラント：

Wolfram Language code: Cumulant[𝒫[t], 4]

キュムラント母関数：

Wolfram Language code: CumulantGeneratingFunction[𝒫[t], x]

アプリケーション  (2)

改装開店した商店に，ポアソン過程に従って1時間に20人の割合で顧客が来店する．この商店は，販売促進の一環として，来店客全員に粗品を贈呈している．粗品の値は，形状母数10，尺度母数3のWeibullDistributionに従う．改装開店初日の営業時間である12時間について，粗品にかかる費用の過程のシミュレーションを行い，費用総額の期待値を求める：

Wolfram Language code: giftProcess = CompoundPoissonProcess[20, WeibullDistribution[10, 3]];

過程のシミュレーションを12時間行う：

Wolfram Language code: data = RandomFunction[giftProcess, {12}, 3];
Wolfram Language code: ListStepPlot[data]

初日に贈られる粗品の費用総額の期待値：

Wolfram Language code: Mean[giftProcess[12]]//N

粗品費用の分布のシミュレーションを行う：

Wolfram Language code: data1 = RandomVariate[giftProcess[12], 10 ^ 4];

費用分布の確率密度関数：

Wolfram Language code: Histogram[data1, 50, "PDF"]

商店が500ドルから800ドルを粗品に費やす経験的確率：

Wolfram Language code: NProbability[500 < p < 800, pdata1]

リスクからの保険金請求総額は，ポアソン母数が200の複合ポアソン過程に従う．保険金請求額の分布は，最小値母数300，形状母数3，位置母数0のパレート(Pareto)分布に従う．保険業者は有効な保持レベル300の超過損害再保険に加入している．4年間の保険金請求の過程のシミュレーションを行う：

Wolfram Language code: claimsProcess = CompoundPoissonProcess[200, TransformedDistribution[Max[0, x - 300], xParetoDistribution[300, 3, 0]]];
Wolfram Language code: ListStepPlot[RandomFunction[claimsProcess, {4}, 4]]

最初の4年間のスライス分布：

Wolfram Language code: Histogram[Table[RandomVariate[claimsProcess[t], 5 10 ^ 3], {t, 4}], 150, "PDF", ChartLegends -> (StringJoin["t = ", ToString[#]]& /@ Range[4])]

最初の4年間の再保険業者の保険金請求総額の平均と分散：

Wolfram Language code: Table[Mean[claimsProcess[t]], {t, 4}]
Wolfram Language code: Table[Variance[claimsProcess[t]], {t, 4}]

特性と関係  (6)

CompoundPoissonProcessはジャンプ過程である：

Wolfram Language code: path = RandomFunction[CompoundPoissonProcess[2, StudentTDistribution[5]], {0, 10}]; f = path["PathFunction"]; jumps = path["PathTimes", 1];
Wolfram Language code: Plot[f[t], {t, 0, 10}, Exclusions -> jumps, ExclusionsStyle -> Red]

更新率 λ はジャンプの頻度を制御する：

Wolfram Language code: 𝒫[λ_] = CompoundPoissonProcess[λ, NormalDistribution[]];
Wolfram Language code: pars = {.1, .5, 3}; data = TemporalData@ Table[RandomFunction[𝒫[λ], {1, 100}], {λ, pars}];
Wolfram Language code: ListStepPlot[data, PlotLegends -> (StringJoin["λ = ", ToString[#]]& /@ pars)]

複合ポアソン過程は弱定常ではない：

Wolfram Language code: WeakStationarity[CompoundPoissonProcess[4, PascalDistribution[3, .4]]]

複合ポアソン過程の任意のスライス分布はCompoundPoissonDistributionである：

Wolfram Language code: CompoundPoissonProcess[λ, WeibullDistribution[a, b]][t]

BernoulliDistributionの複合ポアソン過程のスライスはPoissonDistributionに従う：

Wolfram Language code: CompoundPoissonProcess[μ, BernoulliDistribution[p]][t]

特殊BorelTannerDistributionの複合ポアソン過程のスライスはPoissonConsulDistributionに従う：

Wolfram Language code: slice = CompoundPoissonProcess[μ, BorelTannerDistribution[α, 1]][t];

Borel-Tanner分布に従う変数の和はBorel-Tanner分布に従うので，スライス分布はパラメータ混合分布と等しい：

Wolfram Language code: pdm = ParameterMixtureDistribution[BorelTannerDistribution[α, n], n  PoissonDistribution[μ * t]]

特性関数と比較する：

Wolfram Language code: CharacteristicFunction[slice, x] / CharacteristicFunction[pdm, x]//Simplify
Wolfram Research (2012), CompoundPoissonProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/CompoundPoissonProcess.html.

テキスト

Wolfram Research (2012), CompoundPoissonProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/CompoundPoissonProcess.html.

CMS

Wolfram Language. 2012. "CompoundPoissonProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CompoundPoissonProcess.html.

APA

Wolfram Language. (2012). CompoundPoissonProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CompoundPoissonProcess.html

BibTeX

@misc{reference.wolfram_2026_compoundpoissonprocess, author="Wolfram Research", title="{CompoundPoissonProcess}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CompoundPoissonProcess.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_compoundpoissonprocess, organization={Wolfram Research}, title={CompoundPoissonProcess}, year={2012}, url={https://reference.wolfram.com/language/ref/CompoundPoissonProcess.html}, note=[Accessed: 15-September-2026]}