Wolfram 语言与系统参考资料中心

CompoundPoissonProcess

CompoundPoissonProcess[λ,jdist]

表示复合泊松过程，其中比率参数为 λ，跳跃尺寸分布为 jdist.

范例

打开所有单元关闭所有单元

基本范例 (2)

模拟一个指数型跳跃尺寸分布的复合泊松过程：

Wolfram Language code: 𝒫 = CompoundPoissonProcess[.8, ExponentialDistribution[2]];

Wolfram Language code: data = RandomFunction[𝒫, {20}]

Wolfram Language code: ListStepPlot[data, Filling -> Axis]

均值和方差函数：

Wolfram Language code: 𝒫 = CompoundPoissonProcess[λ, ExponentialDistribution[μ]];

Wolfram Language code: Mean[𝒫[t]]

Wolfram Language code: Variance[𝒫[t]]

范围 (8)

基本用法 (4)

模拟具有离散跳跃的复合泊松过程：

Wolfram Language code: 𝒫 = CompoundPoissonProcess[1.3, GeometricDistribution[.4]];

Wolfram Language code: data = RandomFunction[𝒫, {30}, 3]

Wolfram Language code: ListStepPlot[data, Filling -> Axis]

模拟具有连续跳跃的复合泊松过程：

Wolfram Language code: 𝒫 = CompoundPoissonProcess[2, NormalDistribution[0, 2]];

Wolfram Language code: data = RandomFunction[𝒫, {30}, 3]

Wolfram Language code: ListStepPlot[data, Filling -> Axis]

比较不同更新率时的复合泊松过程：

Wolfram Language code: proc[λ_] := CompoundPoissonProcess[λ, WeibullDistribution[.2, .3]];

Wolfram Language code: data = Table[RandomFunction[proc[λ], {300}], {λ, pars = {.7, 1, 2}}];

Wolfram Language code: ListStepPlot[data, PlotLegends -> (StringJoin["λ = ", ToString[#]]& /@ pars)]

过程参数估计：

Wolfram Language code: sample = RandomFunction[CompoundPoissonProcess[3, GammaDistribution[2, 5]], {1, 10 ^ 3}];

从样本数据估计分布参数：

Wolfram Language code: EstimatedProcess[sample, CompoundPoissonProcess[m, GammaDistribution[a, b]]]

过程切片性质 (4)

切片分布是一种 CompoundPoissonDistribution：

Wolfram Language code: CompoundPoissonProcess[λ, WeibullDistribution[a, b]][t]

Wolfram Language code: CompoundPoissonProcess[λ, ZipfDistribution[a, b]][t]

模拟切片分布：

Wolfram Language code: 𝒫 = CompoundPoissonProcess[2, WeibullDistribution[2, 3]];

Wolfram Language code: data = RandomVariate[SliceDistribution[𝒫, 7], 10 ^ 3];

Wolfram Language code: Histogram[data, 20, "PDF"]

切片分布的矩：

Wolfram Language code: 𝒫 = CompoundPoissonProcess[2, WeibullDistribution[2, 3]];

均值函数：

Wolfram Language code: Plot[Mean[𝒫[t]], {t, 0, 10}]

Wolfram Language code: Mean[𝒫[t]]

方差函数：

Wolfram Language code: Plot[Variance[𝒫[t]], {t, 0, 10}]

Wolfram Language code: Variance[𝒫[t]]

偏度：

Wolfram Language code: Skewness[𝒫[t]]

峰度：

Wolfram Language code: Kurtosis[𝒫[t]]

切片分布的矩和母函数：

Wolfram Language code: 𝒫 = CompoundPoissonProcess[m, BinomialDistribution[n, p]];

矩：

Wolfram Language code: Moment[𝒫[t], 3]

矩母函数：

Wolfram Language code: MomentGeneratingFunction[𝒫[t], x]

累积量：

Wolfram Language code: Cumulant[𝒫[t], 4]

累积量母函数：

Wolfram Language code: CumulantGeneratingFunction[𝒫[t], x]

应用 (2)

一家新装修好的商店举行酬宾活动，给每一位顾客都赠送一个礼品. 购物者光顾这家商店的过程是泊松过程，速率为每小时20个顾客. 礼品价值服从 WeibullDistribution，其中形状参数为10，尺度参数为3. 模拟在该商店开业当天12小时内所赠送礼物的成本，并求总成本的期望值：

Wolfram Language code: giftProcess = CompoundPoissonProcess[20, WeibullDistribution[10, 3]];

模拟该过程12个小时：

Wolfram Language code: data = RandomFunction[giftProcess, {12}, 3];

Wolfram Language code: ListStepPlot[data]

开业当天赠出礼品的期望总成本：

Wolfram Language code: Mean[giftProcess[12]]//N

模拟礼品成本分布：

Wolfram Language code: data1 = RandomVariate[giftProcess[12], 10 ^ 4];

成本分布的概率密度：

Wolfram Language code: Histogram[data1, 50, "PDF"]

这家商店的礼物花费在$500到$800之间的经验概率：

Wolfram Language code: NProbability[500 < p < 800, pdata1]

一种风险的索赔总额服从泊松参数为200的复合泊松过程，索赔额分布服从帕累托分布，其中最小值参数为300，形状参数为3，位置参数为0. 保险公司具有保留额度为300的超额赔款再保险. 模拟四年的索赔过程：

Wolfram Language code:

claimsProcess = CompoundPoissonProcess[200, TransformedDistribution[Max[0, x - 300], xParetoDistribution[300, 3, 0]]];

Wolfram Language code: ListStepPlot[RandomFunction[claimsProcess, {4}, 4]]

前四年的切片分布：

Wolfram Language code:

Histogram[Table[RandomVariate[claimsProcess[t], 5 10 ^ 3], {t, 4}], 150, "PDF", ChartLegends -> (StringJoin["t = ", ToString[#]]& /@ Range[4])]

再保险公司在前四年索赔总额的均值和方差：

Wolfram Language code: Table[Mean[claimsProcess[t]], {t, 4}]

Wolfram Language code: Table[Variance[claimsProcess[t]], {t, 4}]

属性和关系 (6)

CompoundPoissonProcess 是一个跳跃过程：

Wolfram Language code:

path = RandomFunction[CompoundPoissonProcess[2, StudentTDistribution[5]], {0, 10}];
f = path["PathFunction"];
jumps = path["PathTimes", 1];

Wolfram Language code: Plot[f[t], {t, 0, 10}, Exclusions -> jumps, ExclusionsStyle -> Red]

续约率 λ 控制着跳跃的频率：

Wolfram Language code: 𝒫[λ_] = CompoundPoissonProcess[λ, NormalDistribution[]];

Wolfram Language code:

pars = {.1, .5, 3};
data  = TemporalData@ Table[RandomFunction[𝒫[λ], {1, 100}], {λ, pars}];

Wolfram Language code: ListStepPlot[data, PlotLegends -> (StringJoin["λ = ", ToString[#]]& /@ pars)]

复合泊松过程不是弱平稳过程：

Wolfram Language code: WeakStationarity[CompoundPoissonProcess[4, PascalDistribution[3, .4]]]

复合泊松分布的任何切片均为 CompoundPoissonDistribution：

Wolfram Language code: CompoundPoissonProcess[λ, WeibullDistribution[a, b]][t]

BernoulliDistribution 的复合泊松分布的切片遵循 PoissonDistribution：

Wolfram Language code: CompoundPoissonProcess[μ, BernoulliDistribution[p]][t]

特殊 BorelTannerDistribution 的复合泊松分布的切片遵循 PoissonConsulDistribution：

Wolfram Language code: slice = CompoundPoissonProcess[μ, BorelTannerDistribution[α, 1]][t];

Borel-Tanner 分布变量的总和遵循 Borel-Tanner 分布，因此切片分布等于参数混合分布：

Wolfram Language code:

pdm = ParameterMixtureDistribution[BorelTannerDistribution[α, n], 
    n  PoissonDistribution[μ * t]]

比较特征函数：

Wolfram Language code: CharacteristicFunction[slice, x] / CharacteristicFunction[pdm, x]//Simplify

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

CompoundPoissonProcess

更多信息

范例

基本范例 (2)

范围 (8)

基本用法 (4)

过程切片性质 (4)

应用 (2)

属性和关系 (6)

文本

CMS

APA

BibTeX

BibLaTeX

CompoundPoissonProcess

更多信息

范例

基本范例 (2)

范围 (8)

基本用法 (4)

过程切片性质 (4)

应用 (2)

属性和关系 (6)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX