WOLFRAM

Wolfram 语言与系统参考资料中心

Correlation[v,w]

给出向量 v 和 w 之间的相关.

Correlation[a,b]

给出矩阵 a 和 b 的交叉相关矩阵.

Correlation[a]

给出矩阵 a 中观测值的自相关矩阵.

Correlation[dist]

给出多变量符号分布 dist 的相关矩阵.

Correlation[dist,i,j]

给出多变量符号分布 dist 的第 (i,j) 个相关.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数据  
分布和过程  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

Correlation

Correlation[v,w]

给出向量 v 和 w 之间的相关.

Correlation[a,b]

给出矩阵 a 和 b 的交叉相关矩阵.

Correlation[a]

给出矩阵 a 中观测值的自相关矩阵.

Correlation[dist]

给出多变量符号分布 dist 的相关矩阵.

Correlation[dist,i,j]

给出多变量符号分布 dist 的第 (i,j) 个相关.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

两个向量之间的相关：

Wolfram Language code: Correlation[{a, b}, {x, y}]

实数值：

Wolfram Language code: Refine[%, {a, b, x, y}∈Reals]

矩阵的相关矩阵：

Wolfram Language code: Correlation[{{a, b}, {c, d}}]

实数值：

Wolfram Language code: Refine[%, {a, b, c, d}∈Reals]

两个矩阵的相关矩阵：

Wolfram Language code: Correlation[{{a, b}, {c, d}}, {{x}, {y}}]//MatrixForm

实数值：

Wolfram Language code: Refine[%, {a, b, c, d, x, y}∈Reals]

范围  (14)

数据  (8)

精确输入生成精确输出：

Wolfram Language code: Correlation[{5, 3 / 4, 1}, {2, 1 / 2, 1}]
Wolfram Language code: Correlation[{1, π, 2}, {2, 2, 1}]//Simplify

近似​​输入生成近似输出：

Wolfram Language code: Correlation[{1.5, 3, 5, 10}, {2, 1.25, 15, 8}]
Wolfram Language code: Correlation[N[{1, 2, 5, 6}, 20], N[{2, 3, 6, 8}, 20]]

复向量之间的相关：

Wolfram Language code: Correlation[{2 + I, 3 - 2I, 5 + 4I}, {I, 1 + 2I, 10 - 5I}]

适用于大型数组：

Wolfram Language code: Correlation[RandomReal[1, 10 ^ 7], RandomReal[1, 10 ^ 7]]

可以使用结构化数组（参见指南）：

Wolfram Language code: Correlation[SparseArray[{{1, 2} -> 1.2, {2, 2} -> 1, {3, 1} -> 2}]]//MatrixForm
Wolfram Language code: Correlation[IdentityMatrix[2]]//MatrixForm
Wolfram Language code: Correlation[ToeplitzMatrix[4]]//MatrixForm
Wolfram Language code: Correlation[QuantityArray[RandomReal[1, {20, 2}], "Meters"]]//MatrixForm

求出包含数量的数据之间的相关：

Wolfram Language code: v = Quantity[{2, 3.5, 4, 5}, "Meters"]; w = Quantity[{10, 32, 19, 24.2}, "Pounds"];
Wolfram Language code: Correlation[v, w]

日期列表间的相关：

Wolfram Language code: v = RandomDate[4]
Wolfram Language code: w = RandomDate[4]
Wolfram Language code: Correlation[v, w]

时间矩阵之间的相关：

Wolfram Language code: Correlation[RandomTime[{4, 2}], RandomTime[{4, 3}]]//MatrixForm

分布和过程  (6)

连续多元分布的相关：

Wolfram Language code: Correlation[BinormalDistribution[ρ]]//MatrixForm
Wolfram Language code: Correlation[BinormalDistribution[ρ], 2, 1]

离散多元分布的相关：

Wolfram Language code: Correlation[MultivariatePoissonDistribution[μ, {2, 3}]]//MatrixForm
Wolfram Language code: Correlation[MultivariatePoissonDistribution[μ, {2, 3}], 2, 1]

相关性控制着多元概率分布的方向和锐度：

Wolfram Language code: dists = { BinormalDistribution[-0.7], BinormalDistribution[0], BinormalDistribution[0.99] };
Wolfram Language code: colors = Table[ColorData[97, i], {i, 3}]; GraphicsRow[Table[ Plot3D[PDF[dists[[i]], {x, y}], {x, -3.5, 3.5}, {y, -3.5, 3.5}, PlotRange -> All, PlotStyle -> {colors[[i]]}, Ticks -> None, MeshStyle -> Opacity[.1], AxesLabel -> {"*x*", "*y*", None}, PlotLabel -> dists[[i]], ViewPoint -> {0, 2, 2} ] , {i, 3} ], ImageSize -> {500, 500 .3} ]

导出分布的相关：

Wolfram Language code: Correlation[ProductDistribution[ExponentialDistribution[1], NormalDistribution[3, 5]]]//MatrixForm
Wolfram Language code: 𝒟 = CopulaDistribution[{"Frank", 2}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}];
Wolfram Language code: Correlation[𝒟]//MatrixForm

数据分布：

Wolfram Language code: 𝒟 = HistogramDistribution[RandomVariate[BinormalDistribution[.75], 10 ^ 4]];
Wolfram Language code: Correlation[𝒟]//MatrixForm
Wolfram Language code: Correlation[BinormalDistribution[.75]]//MatrixForm

随机过程在时刻 s 和 t 的相关矩阵：

Wolfram Language code: Correlation[WienerProcess[][{s, t}]]//MatrixForm

TemporalData 在时刻 和 的相关矩阵：

Wolfram Language code: td = RandomFunction[WienerProcess[1, 1], {0, 10, 0.05}, 100]
Wolfram Language code: Correlation[td[{0.2, 0.3}]]//MatrixForm

应用  (3)

计算两个金融时间序列之间的相关性：

Wolfram Language code: gspc = TemporalData[TimeSeries, {{{2058.2, 2020.58, 2002.61, 2025.9, 2062.14, 2044.81, 2028.26, 2023.03, 2011.27, 1992.67, 2019.42, 2022.55, 2032.12, 2063.15, 2051.82, 2057.09, 2029.55, 2002.16, 2021.25, 1994.99, 2020.85, 2050.03, 2041.51, 2062. ... 3719174400, 3719260800, 3719520000, 3719606400, 3719692800}}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, DateFunction -> Automatic, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, True, 314.1];
Wolfram Language code: ndx = TemporalData[TimeSeries, {{{4230.2368, 4160.9644, 4110.8301, 4159.9995, 4240.5495, 4213.2758, 4169.9704, 4166.2025, 4145.8414, 4089.6482, 4142.1401, 4171.2143, 4192.0934, 4270.3628, 4278.1424, 4275.7154, 4165.5017, 4140.3756, 4181.3514, 4 ... 3719174400, 3719260800, 3719520000, 3719606400, 3719692800}}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, DateFunction -> Automatic, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, True, 314.1];
Wolfram Language code: Correlation[gspc["Values"], ndx["Values"]]

Correlation 可用于测量线性关联：

Wolfram Language code: data = BlockRandom[SeedRandom[1];Table[RandomVariate[BinormalDistribution[i], 3000], {i, {-.99, -.75, -.25, -.5, 0., .25, .5, .75, .99}}]];
Wolfram Language code: Grid[Partition[Table[ListPlot[i, PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None, Frame -> True, Axes -> None, PlotLabel -> Row[{"ρ : ", Correlation[i][[1, 2]]}]], {i, data}], 3]]

Correlation 只能检测单调关系：

Wolfram Language code: uni = RandomReal[{-3, 3}, 3000];
Wolfram Language code: f[x_] := {{x, -Sqrt[Abs[x]] + RandomReal[.5]}, {x, .25x^2 + RandomReal[.5]}, {x, -Sinc[x] + RandomReal[.5]}, {Cos[x], Sin[x] + RandomReal[.5]}}
Wolfram Language code: data = f /@ uni;
Wolfram Language code: Table[ListPlot[data[[All, i]], Frame -> True, Axes -> None, PlotLabel -> Row[{"ρ : ", Correlation[data[[All, i]]][[1, 2]]}], PlotStyle -> Directive[PointSize[Tiny]], FrameTicks -> None], {i, 4}]

HoeffdingD 可用于检测各种依赖结构：

Wolfram Language code: Table[HoeffdingD[data[[All, i]]][[1, 2]], {i, 4}]

属性和关系  (7)

相关矩阵是对称且半正定的：

Wolfram Language code: corr = Correlation[RandomVariate[BinormalDistribution[1 / 3], 10 ^ 3]];
Wolfram Language code: SymmetricMatrixQ[corr]
Wolfram Language code: PositiveSemidefiniteMatrixQ[corr]

相关矩阵按比例缩放几个标准差是协方差矩阵：

Wolfram Language code: data = RandomReal[5, {20, 5}];
Wolfram Language code: s = DiagonalMatrix[1 / StandardDeviation[data]];
Wolfram Language code: Correlation[data] == s.Covariance[data].s
Wolfram Language code: {a, b} = RandomReal[1, {2, 3, 2}];
Wolfram Language code: invS = TensorProduct@@((StandardDeviation /@ {a, b}) ^ -1);
Wolfram Language code: Covariance[a, b] invS == Correlation[a, b]

在均值为零且单位边际方差的情况下，Correlation 和 AbsoluteCorrelation 一致：

Wolfram Language code: 𝒟 = BinormalDistribution[ρ];
Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]
Wolfram Language code: Correlation[𝒟]
Wolfram Language code: AbsoluteCorrelation[𝒟]

SpearmanRho 是应用于秩的 Correlation：

Wolfram Language code: data = Transpose@RandomVariate[BinormalDistribution[.8], 100];
Wolfram Language code: SpearmanRho[data[[1]], data[[2]]]
Wolfram Language code: rnks = Ordering[Ordering[#]]& /@ data;
Wolfram Language code: Correlation[rnks[[1]], rnks[[2]]]//N

对于过程而言，CorrelationFunction 是相关矩阵的非对角线项：

Wolfram Language code: 𝒫 = WienerProcess[μ, σ];
Wolfram Language code: Correlation[𝒫[{s, t}], 1, 2]
Wolfram Language code: CorrelationFunction[𝒫, s, t]
Wolfram Language code: Simplify[%% - %, 0 < s < t]

对于标准化向量，Correlation 和 Covariance 相同：

Wolfram Language code: sample = RandomVariate[DiscreteUniformDistribution[{{2, 3}, {4, 5}}], 200];
Wolfram Language code: Covariance[sample] === Correlation[sample]
Wolfram Language code: Covariance[Standardize[sample]] === Correlation[sample]

相关矩阵的对角线元素等于1：

Wolfram Language code: Diagonal[Correlation[RandomReal[10, {100, 4}]]]
Wolfram Research (2007)，Correlation，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Correlation.html （更新于 2024 年）.

文本

Wolfram Research (2007)，Correlation，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Correlation.html （更新于 2024 年）.

CMS

Wolfram 语言. 2007. "Correlation." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2024. https://reference.wolfram.com/language/ref/Correlation.html.

APA

Wolfram 语言. (2007). Correlation. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Correlation.html 年

BibTeX

@misc{reference.wolfram_2026_correlation, author="Wolfram Research", title="{Correlation}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/Correlation.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_correlation, organization={Wolfram Research}, title={Correlation}, year={2024}, url={https://reference.wolfram.com/language/ref/Correlation.html}, note=[Accessed: 14-September-2026]}