Cross

関連項目
- 関数
- Dot
- Signature
- Outer
- Curl
- TensorWedge
- LeviCivitaTensor
- HodgeDual
- KroneckerProduct
- Orthogonalize
- VectorAngle
- 文字
- \[Cross]
関連するガイド
テクニカルノート
- ベクトルと行列
- 演算子
- 関連項目
  - 関数
  - Dot
  - Signature
  - Outer
  - Curl
  - TensorWedge
  - LeviCivitaTensor
  - HodgeDual
  - KroneckerProduct
  - Orthogonalize
  - VectorAngle
  - 文字
  - \[Cross]
- 関連するガイド
- テクニカルノート
  - ベクトルと行列
  - 演算子

Cross

Cross[a,b]

ベクトル a と b の外積を与える．

詳細

a と b が長さ3のリストのときは（三次元ベクトルに相当），Cross[a,b]も長さ3のリストになる．
StandardFormおよびInputFormでは，Cross[a,b]を使う代りに ab，a cross b またはa\[Cross]b を使っても入力できる．\[Cross]と\[Times]の違いに注意すること．
Crossは非対称である．つまり，Cross[b,a] = -Cross[a,b]である． »
Cross[{x,y}]は垂直ベクトル{-y,x}を与える．
一般に，長さ n のベクトル積Cross[v₁,v₂,…,v_n-1]は完全に非対称な積になり，v_i すべてに直交した長さ n のベクトルを与える．
Cross[v₁,v₂,…]は，n 次元空間における単一形としてみたベクトル v_i の双対（ホッジ(Hodge)の星演算子）を与える．

例題

すべて開くすべて閉じる

例 (3)

三次元における2つのベクトルの外積：

Wolfram Language code:

u = {1, 2, -1};
v = {-1, 1, 0};

Wolfram Language code: w = Cross[u, v]

2つの初期ベクトル，それらが跨る平面，積を可視化する：

Wolfram Language code:

Graphics3D[{Black, Arrow[Tube[{{0, 0, 0}, u}]], Arrow[Tube[{{0, 0, 0}, v}]], StandardRed, Arrow[{{0, 0, 0}, w}], White, InfinitePlane[{0, 0, 0}, {u, v}]}, Axes -> True, PlotRangePadding -> 2]

二次元における単一のベクトルの外積：

Wolfram Language code: Cross[{1, Sqrt[3]}]

2つのベクトルを可視化する：

Wolfram Language code: Graphics[{Arrow[{{0, 0}, {1, Sqrt[3]}}], StandardRed, Arrow[{{0, 0}, {-Sqrt[3], 1}}]}, Axes -> True]

crossを使って入力する：

Wolfram Language code: {a, b, c}⨯{x, y, z}

スコープ (9)

機械精度のベクトルの外積を求める：

Wolfram Language code: Cross[{3.2, 4.2, 5.2}, {0.75, 0.09, 0.06}]

複素ベクトルの外積：

Wolfram Language code: Cross[{1.3 + I, 2, 3 - 2 I}, {6. + I, 4, 5 - 7 I}]

厳密ベクトルの外積：

Wolfram Language code: {1, 2, 3}⨯{1, 8, 9}

任意精度ベクトルの外積：

Wolfram Language code: {u, v} = RandomReal[4, {2, 3}, WorkingPrecision -> 20]

Wolfram Language code: u⨯v

記号ベクトルの外積：

Wolfram Language code: Cross[{x, 0, x}, {x, y, 2x}]

QuantityArrayベクトルの外積を計算する：

Wolfram Language code: e = QuantityArray[{1, 2, 3}, "Newtons" / "Coulombs"]

Wolfram Language code: b = QuantityArray[{4, 5, 6}, "Teslas"]

QuantityArrayの構造は保持されている：

Wolfram Language code: e⨯b

結果をフォーマットする：

Wolfram Language code: %//MatrixForm

二次元における1つのベクトルの外積：

Wolfram Language code: Cross[{x, y}]

結果はもとのベクトルに垂直である：

Wolfram Language code: {x, y}.%

三次元における2つのベクトルを定義する：

Wolfram Language code: a = {1, 2, 3};

Wolfram Language code: b = {4, 5, 6};

Crossが反対称であることを確認する：

Wolfram Language code: Cross[a, b] == -Cross[b, a]

四次元における3つのベクトルを定義する：

Wolfram Language code: {a, b, c} = {{1, 2, 3, 4}, {1, 4, 9, 16}, {1, 8, 27, 81}};

ベクトルの外積を計算する：

Wolfram Language code: d = a⨯b⨯c

積が3つすべてのベクトルと直交することを確認する：

Wolfram Language code: {d.a, d.b, d.c}

可能なすべての積順を計算する．2つのベクトルを入れ替えても符号が変わるだけである：

Wolfram Language code: Cross @@@ Permutations[{a, b, c}]

アプリケーション (10)

幾何学のアプリケーション (5)

2つのベクトルでスパンした平面までの法線を求める：

Wolfram Language code:

u = {1, 2, 3};
v = {1, 4, 9};

Wolfram Language code: w = Cross[u, v]

結果がどちらの入力に対しても垂直であることを確認する：

Wolfram Language code: {w.u, w.v}

平面の方程式：

Wolfram Language code: w.{x, y, z} == 0

平面上のベクトルに垂直なベクトルを求める：

Wolfram Language code: u = RandomReal[1, 2]

Wolfram Language code: v = Cross[u]

u と v が直交することを確認する：

Wolfram Language code: u.v

n 次元における n-1個のベクトルに直交するベクトルを求める：

Wolfram Language code:

n = 5;
uu = RandomReal[1, {n - 1, n}];
v = Apply[Cross, uu]

Wolfram Language code: Chop[uu.v]

2つのベクトルで定義された平行四辺形の面積を求める：

Wolfram Language code:

a = {1, 2, -2};
b = {1, -1, 2};
Norm[a⨯b]

Areaを使った直接計算と比較する：

Wolfram Language code: Area[Parallelepiped[{0, 0, 0}, {a, b}]]

これは，でも計算できる．はベクトル間の角度である：

Wolfram Language code: Norm[a]Norm[b]Sin[VectorAngle[a, b]]

平行四辺形を可視化する：

Wolfram Language code: Graphics3D[Parallelepiped[{0, 0, 0}, {a, b}]]

フレネ・セレ(Frenet–Serret)の系は全空間曲線の特性をベクトル基底とスカラー関数で符号化する．次の曲線について考える：

Wolfram Language code: c[t_] := {Cos[t], Sin[t], (t/2π)}

接線，法線，従法線の各ベクトルを最初の2つの導関数の外積によって定義する：

Wolfram Language code:

{Subscript[e, 1], Subscript[e, 2], Subscript[e, 3]} = Simplify[{Normalize[c'[t]], Normalize[c'[t]⨯(c''[t]⨯c'[t])], Normalize[c'[t]⨯c''[t]]}, t∈Reals]

こらら3つのベクトルは，についての右手系の直交基底を定義する：

Wolfram Language code: {Table[Subscript[e, i].Subscript[e, j], {i, 3}, {j, 3}], Subscript[e, 1]⨯Subscript[e, 2] == Subscript[e, 3]}//Simplify

曲線の曲り方を数量化する曲率とねじれを計算する：

Wolfram Language code:

{κ, τ} = Simplify[{(Norm[c''[t]⨯c'[t]]/Norm[c'[t]]^3), (c'[t].(c''[t]⨯c'''[t])/Norm[c'[t]⨯c''[t]]^2)}, t∈Reals]

FrenetSerretSystemを使って答を確認する：

Wolfram Language code: Simplify[{{κ, τ}, {Subscript[e, 1], Subscript[e, 2], Subscript[e, 3]}} == FrenetSerretSystem[c[t], t], t∈Reals]

曲線と関連するフレームとも呼ばれる移動基底を可視化する：

Wolfram Language code:

DynamicModule[{s}, Labeled[Show[ParametricPlot3D[c[t], {t, 0, 6π}, PlotRangePadding -> {.5, .5, .9}], Graphics3D[{AbsoluteThickness[2], StandardBlue, Arrow[{c[t], c[t] + Subscript[e, 1]}], StandardRed, Arrow[{c[t], c[t] + Subscript[e, 2]}], StandardPurple, Arrow[{c[t], c[t] + Subscript[e, 3]}]}] /. t -> Dynamic[s]], Animator[Dynamic[s], {0, 6π}], Top]]

物理のアプリケーション (5)

点に垂直に加えられたの力の原点に関するトルクを求める：

Wolfram Language code:

F = Quantity[{0, 0, -10}, "Newtons"];
r  = Quantity[{1.5, 3.2, 1.25}, "Meters"];

トルクは式で与えられる：

Wolfram Language code: r⨯F

質量，速度で位置が原点の周りの粒子の角運動量を求める：

Wolfram Language code:

m = Quantity[3, "Kilograms"];
v = Quantity[{1.5, 2.3, -3.4}, "Meters" / "Seconds"];
r = Quantity[{2.5, -3.3, 1.4}, "Meters"];

角運動量はで与えられる．線形運動量はに等しい：

Wolfram Language code: r⨯(m v)

電荷，速度での磁場を正の方向に移動する粒子の磁力を求める：

Wolfram Language code:

q = Quantity[2, "Coulombs"];
v = QuantityArray[{3, -4, 5}, "Meters" / "Seconds"];
B = QuantityArray[{0, 0, 0.075}, "Teslas"];

磁力はで与えられる：

Wolfram Language code: q v ⨯B

UnitSimplifyを使って期待される単位ニュートンを求め，MatrixFormを使ってベクトルをフォーマットする：

Wolfram Language code: UnitSimplify[%]//MatrixForm

軸から固定の距離で回転するように制約された粒子について考える：

Wolfram Language code: r[t_] := {0, Cos[t^2], Sin[t^2]}

角速度を外積によって定義する：

Wolfram Language code: ω = (r'[t]⨯r''[t]/r'[t].r'[t])//Simplify

多くの特性がによって表せる．線速度はに等しい：

Wolfram Language code: r'[t] == ω⨯r[t]

直角加速度あるいは求心加速度はに等しい：

Wolfram Language code: Subscript[a, perp] = ω⨯r'[t]

とは直交するので，直感的に $TemplateBox[{{a, _, {(, perp, )}}}, Norm]=TemplateBox[{omega}, Norm] TemplateBox[{{r, ^, {(, ', )}}}, Norm]$ である：

Wolfram Language code: Simplify[Norm[Subscript[a, perp]] == Norm[ω]Norm[r'[t]] == (r'[t].r'[t]/Norm[r[t]]), t∈Reals]

求心加速度のよく知られた公式 $TemplateBox[{{a, _, {(, perp, )}}}, Norm]=(TemplateBox[{{r, ^, {(, ', )}}}, Norm]^2)/(TemplateBox[{r}, Norm])=(TemplateBox[{v}, Norm]^2)/(TemplateBox[{r}, Norm])$ もまた成り立つ：

Wolfram Language code: Simplify[Norm[Subscript[a, perp]] == (r'[t].r'[t]/Norm[r[t]]), t∈Reals]

の導関数は角速度である：

Wolfram Language code: α = D[ω, t]

運動方向と平行の加速度はに等しい：

Wolfram Language code: Subscript[a, par] = α⨯r[t]

線加速度は和に等しい点に注意のこと：

Wolfram Language code: r''[t] == Subscript[a, par] + Subscript[a, perp]

固定の三次元ベクトルについての外積は行列の乗算で表すことができるが，これは回転運動を学ぶ際に役に立つ．線形演算子を表す反対称行列を構築する．は軸の周りの角速度である：

Wolfram Language code: Overscript[ω, ⇀] = {0, 0, 2};

Wolfram Language code: (Subscript[ℒ, L] = Map[Cross[#, Overscript[ω, ⇀]]&, IdentityMatrix[3]])//MatrixForm

の動作はとの外積を取ることと同じであることを確認する：

Wolfram Language code: Subscript[ℒ, L]. {x, y, z} == Overscript[ω, ⇀]⨯{x, y, z}

時点における回転行列は，前の行列を倍した行列指数である：

Wolfram Language code: (rot[t_] = MatrixExp[t Subscript[ℒ, L]])//MatrixForm

RotationMatrixを使ってを確認する：

Wolfram Language code: rot[t] == RotationMatrix[Norm[Overscript[ω, ⇀]]t, {0, 0, 1}]

時点0における点は，時点ではになる：

Wolfram Language code: Overscript[r, ⇀] = rot[t].{x, y, z}

の速度はで与えられる：

Wolfram Language code: Overscript[v, ⇀] = Overscript[ω, ⇀]⨯Overscript[r, ⇀]

回転軸からへの速度は $(v(t)xomega)/(TemplateBox[{omega}, Norm]^2)$ である：

Wolfram Language code: (Overscript[v, ⇀]⨯Overscript[ω, ⇀]/Overscript[ω, ⇀].Overscript[ω, ⇀])//Expand

動きと関連するベクトルを可視化する：

Wolfram Language code:

With[{w = Overscript[ω, ⇀], x = rot[s].{1, 1, 1}}, Animate[Legended[Graphics3D[{AbsoluteThickness[3], StandardRed, Arrow[{{0, 0, 0}, w}], StandardBlue, Arrow[{{0, 0, 0}, x}], StandardCyan, Arrow[{{0, 0, 1}, x}], StandardPurple, Translate[Arrow[{{0, 0, 0}, w⨯x}], x]}, PlotRange -> {{-3, 3}, {-3, 3}, {0, 2}}], SwatchLegend[{StandardRed, StandardBlue, StandardPurple, StandardCyan}, {ω, r[t], v[t] == ω⨯r[t], Subscript[r, "⟂"] == (v[t]⨯ω/ω.ω)}]], {{s, 0, t}, 0, 2π}]]

特性と関係 (10)

u と v が線形に非依存の場合，u×v は非零で u と v に直交する：

Wolfram Language code: {u, v} = RandomInteger[{-9, 9}, {2, 3}]

Wolfram Language code: w = Cross[u, v]

Wolfram Language code: {u.w, v.w}

u と v が線形に依存する場合，u×v は零である：

Wolfram Language code:

u = RandomReal[1, 3];
v = RandomReal[1] u;

Wolfram Language code: Chop[Cross[u, v]]

三次元ベクトル $TemplateBox[{{{u, _, 1}, x, {u, _, 2}}}, Norm]=TemplateBox[{{u, _, 1}}, Norm] TemplateBox[{{u, _, 2}}, Norm]sin(theta)$ を求める．ただし，はとの間の角度である：

Wolfram Language code:

{u1, u2} = RandomReal[1, {2, 3}];
Norm[u1⨯u2] == Norm[u1]Norm[u2]Sin[VectorAngle[u1, u2]]

Cross[u₁,…,u_k]のノルムは u_iが跨る k 次元平行六面体の測度値である：

Wolfram Language code:

{u1, u2} = {{5, -9, 6}, {-7, 5, 3}};
p  = Parallelepiped[{0, 0, 0}, {u1, u2}];
Norm[u1⨯u2] == Area[p] == RegionMeasure[p, 2]

Wolfram Language code:

{v1, v2, v3} = {{8, -5, 5, -1}, {6, 7, 8, -2}, {-7, 6, -3, 2}};
p  = Parallelepiped[{0, 0, 0, 0}, {v1, v2, v3}];
Norm[v1⨯v2⨯v3] == Volume[p] == RegionMeasure[p, 3]

Crossは反対称である：

Wolfram Language code: {u, v} = RandomReal[1, {2, 3}];

Wolfram Language code: Cross[u, v] == -Cross[v, u]

Crossは，各引数で線形である：

Wolfram Language code:

Subscript[u, 1] = {Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]};
Subscript[u, 2] = {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]};
Subscript[u, 3] = {Subscript[x, 3], Subscript[y, 3], Subscript[z, 3]};

Wolfram Language code:

Expand[Cross[a Subscript[u, 1] + Subscript[u, 3], Subscript[u, 2]] == a Cross[Subscript[u, 1], Subscript[u, 2]] + Cross[Subscript[u, 3], Subscript[u, 2]]]

Wolfram Language code:

Expand[Cross[Subscript[u, 1], b Subscript[u, 2] + Subscript[u, 3]] == b Cross[Subscript[u, 1], Subscript[u, 2]] + Cross[Subscript[u, 1], Subscript[u, 3]]]

Crossは線形なので，演算子は行列の乗算で表すことができる：

Wolfram Language code: Overscript[ω, ⇀] = {Subscript[ω, x], Subscript[ω, y], Subscript[ω, z]};

Wolfram Language code: (Subscript[ℒ, L] = Map[Cross[#, Overscript[ω, ⇀]]&, IdentityMatrix[3]])//MatrixForm

ベクトルに反対称行列を掛けることはと同じである：

Wolfram Language code: Subscript[ℒ, L].{a, b, c} == Overscript[ω, ⇀]⨯{a, b, c}

逆順で積を計算するための対応する演算子が存在する：

Wolfram Language code: (Subscript[ℒ, R] = Map[Cross[Overscript[ω, ⇀], #]&, IdentityMatrix[3]])//MatrixForm

Wolfram Language code: Subscript[ℒ, R].{a, b, c} == {a, b, c}⨯Overscript[ω, ⇀]

これら2つの行列は，転置，あるいは反対称性のために同等の，互いの否定である：

Wolfram Language code: Subscript[ℒ, R] == Transpose[Subscript[ℒ, L]] == -Subscript[ℒ, L]

次元のCrossはベクトルをレヴィ(Levi)-チヴィタ(Civita)テンソルに縮約したものである：

Wolfram Language code:

α = Array[a, {4}];
β = Array[b, {4}];
γ = Array[c, {4}];
Cross[α, β, γ] === TensorContract[αβγLeviCivitaTensor[4, List], {{1, 4}, {2, 5}, {3, 6}}]

次元のベクトルのCrossは，それらのテンソル積のホッジ(Hodge)双対の(倍である：

Wolfram Language code: {a, b, c, d}⨯{d, e, f, g}⨯{h, i, j, k}

Wolfram Language code: (4 - 1)!HodgeDual[{a, b, c, d}{d, e, f, g}{h, i, j, k}]

Wolfram Language code: % == %%

ベクトルのTensorWedgeのホッジ双対はそれらのベクトルのCrossと一致する：

Wolfram Language code:

v1 = {a, b, c};
v2 = {x, y, z};

Wolfram Language code: Normal@HodgeDual[v1v2] === Cross[v1, v2]

Wolfram Language code:

v1 = {a, b, c, d};
v2 = {x, y, z, t};
v3 = {p, q, r, s};

Wolfram Language code: Normal@HodgeDual[v1v2v3] === Cross[v1, v2, v3]

TensorWedgeは，より高階の形式を扱うことができる：

Wolfram Language code:

M = Array[m, {5, 5}];
Q = Array[q, {5, 5}];

Wolfram Language code: HodgeDual[MQ]

インタラクティブな例題 (1)

- 平面上のドラッグ可能な2つのベクトル，（軸と平行の）その外積，それらが跨る平行四辺形を可視化する：

Wolfram Language code:

Manipulate[
	DynamicModule[{vv, ww, angles, cros}, 
	vv = Normalize[v];ww = Normalize[w];
	cros = First[PadLeft[v, 3]⨯PadLeft[w, 3]];
	angles = Sort[N@{ArcTan@@vv, ArcTan@@ww}];Graphics[{IconizedObject[«x ticks»], {If[showPar, {If[cros > 0, RGBColor[1, 0.6, 0.7000000000000001, 0.5], RGBColor[0.6, 0.7000000000000001, 1, 0.5]], Polygon[{{0, 0}, v, v + w, w}]}]}, 
	{LightDarkSwitched[GrayLevel[0]], Arrow[{{0, 0}, v}]}, {LightDarkSwitched[GrayLevel[0]], Arrow[{{0, 0}, w}]}, AbsoluteThickness[3], {If[cros < 0, RGBColor[0.4, 0.6, 1], RGBColor[0.98, 0.56, 0.17]], Circle[{0, 0}, .3, If[-Subtract@@angles < π, angles, Reverse[angles] + {0, 2π}]]}, {If[cros > 0, RGBColor[0.98, 0.56, 0.17], RGBColor[0.4, 0.6, 1]], Arrow[{{0, 0}, cros{-1 / 2, -1 / 2}}]}, Text["OverscriptBox[v, ⇀]", v 3 / 4, {1, 1}], Text["OverscriptBox[w, ⇀]", 3w / 4, {1, 1}], Text["OverscriptBox[v, ⇀] ⨯ OverscriptBox[w, ⇀]", cros{-1 / 2, -1 / 2}, {1, 1}]}, Axes -> True, PlotRange -> 3, AxesLabel -> {y, z}, ImageSize -> {400, 400}, PlotLabel -> Grid[ 
	{{If[cros > 0, Style["acute or obtuse angle", RGBColor[0.98, 0.56, 0.17]], Style["reflex angle", RGBColor[0.4, 0.6, 1]]], Norm["OverscriptBox[v, ⇀] ⨯ OverscriptBox[w, ⇀]"]  == DecimalForm[Abs[cros], {4, 3}]}}, ItemSize -> 10]]], 
	{{showPar, True, "show parallelogram"}, {True, False}}, 
	{{v, {1., 0.5}}, {-3, -3}, {3, 3}, Locator, Appearance -> None, Exclusions -> {0, 0}}, 
	{{w, {-2., 1.}}, {-3, -3}, {3, 3}, Locator, Appearance -> None, Exclusions -> {0, 0}}
	]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

Cross

詳細

例題

例 (3)

スコープ (9)

アプリケーション (10)

幾何学のアプリケーション (5)

物理のアプリケーション (5)

特性と関係 (10)

インタラクティブな例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

Cross

詳細

例題

例 (3)

スコープ (9)

アプリケーション (10)

幾何学のアプリケーション (5)

物理のアプリケーション (5)

特性と関係 (10)

インタラクティブな例題 (1)

関連項目

テクニカルノート

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX