Wolfram 语言与系统参考资料中心

Cross

参见
- 函数
- Dot
- Signature
- Outer
- Curl
- TensorWedge
- LeviCivitaTensor
- HodgeDual
- KroneckerProduct
- Orthogonalize
- VectorAngle
- 字符
- \[Cross]
相关指南
技术笔记
- 向量和矩阵
- 算符
- 参见
  - 函数
  - Dot
  - Signature
  - Outer
  - Curl
  - TensorWedge
  - LeviCivitaTensor
  - HodgeDual
  - KroneckerProduct
  - Orthogonalize
  - VectorAngle
  - 字符
  - \[Cross]
- 相关指南
- 技术笔记
  - 向量和矩阵
  - 算符

Cross

Cross[a,b]

给出了 a 和 b 的向量叉积.

范例

打开所有单元关闭所有单元

基本范例 (3)

两个三维向量的叉积：

Wolfram Language code:

u = {1, 2, -1};
v = {-1, 1, 0};

Wolfram Language code: w = Cross[u, v]

可视化两个初始向量、它们所在的平面和积：

Wolfram Language code:

Graphics3D[{Black, Arrow[Tube[{{0, 0, 0}, u}]], Arrow[Tube[{{0, 0, 0}, v}]], StandardRed, Arrow[{{0, 0, 0}, w}], White, InfinitePlane[{0, 0, 0}, {u, v}]}, Axes -> True, PlotRangePadding -> 2]

一个二维向量的叉积：

Wolfram Language code: Cross[{1, Sqrt[3]}]

可视化两个向量：

Wolfram Language code: Graphics[{Arrow[{{0, 0}, {1, Sqrt[3]}}], StandardRed, Arrow[{{0, 0}, {-Sqrt[3], 1}}]}, Axes -> True]

用 cross 输入：

Wolfram Language code: {a, b, c}⨯{x, y, z}

范围 (9)

求机器精度向量的叉积：

Wolfram Language code: Cross[{3.2, 4.2, 5.2}, {0.75, 0.09, 0.06}]

复向量的叉积：

Wolfram Language code: Cross[{1.3 + I, 2, 3 - 2 I}, {6. + I, 4, 5 - 7 I}]

精确向量的叉积：

Wolfram Language code: {1, 2, 3}⨯{1, 8, 9}

任意精度向量的叉积：

Wolfram Language code: {u, v} = RandomReal[4, {2, 3}, WorkingPrecision -> 20]

Wolfram Language code: u⨯v

符号向量的叉积：

Wolfram Language code: Cross[{x, 0, x}, {x, y, 2x}]

计算 QuantityArray 向量的叉积：

Wolfram Language code: e = QuantityArray[{1, 2, 3}, "Newtons" / "Coulombs"]

Wolfram Language code: b = QuantityArray[{4, 5, 6}, "Teslas"]

保留了 QuantityArray 结构：

Wolfram Language code: e⨯b

格式化结果：

Wolfram Language code: %//MatrixForm

二维向量的叉积：

Wolfram Language code: Cross[{x, y}]

结果垂直于原来的向量：

Wolfram Language code: {x, y}.%

定义两个三维向量：

Wolfram Language code: a = {1, 2, 3};

Wolfram Language code: b = {4, 5, 6};

验证 Cross 是反对称的：

Wolfram Language code: Cross[a, b] == -Cross[b, a]

定义三个四维向量：

Wolfram Language code: {a, b, c} = {{1, 2, 3, 4}, {1, 4, 9, 16}, {1, 8, 27, 81}};

计算向量的叉积：

Wolfram Language code: d = a⨯b⨯c

验证积与三个向量正交：

Wolfram Language code: {d.a, d.b, d.c}

计算所有顺序的积；两个向量每次交换顺序只是改变了结果的正负：

Wolfram Language code: Cross @@@ Permutations[{a, b, c}]

应用 (10)

几何应用 (5)

求 2 个向量所在平面的法向量：

Wolfram Language code:

u = {1, 2, 3};
v = {1, 4, 9};

Wolfram Language code: w = Cross[u, v]

验证结果垂直于两个输入：

Wolfram Language code: {w.u, w.v}

平面的方程：

Wolfram Language code: w.{x, y, z} == 0

求在平面内与一个向量垂直的向量：

Wolfram Language code: u = RandomReal[1, 2]

Wolfram Language code: v = Cross[u]

验证 u 和 v 互相垂直：

Wolfram Language code: u.v

求一个向量，正交于 n 维空间的 n-1 个向量：

Wolfram Language code:

n = 5;
uu = RandomReal[1, {n - 1, n}];
v = Apply[Cross, uu]

Wolfram Language code: Chop[uu.v]

求由两个向量定义的平行四边形的面积：

Wolfram Language code:

a = {1, 2, -2};
b = {1, -1, 2};
Norm[a⨯b]

与用 Area 直接计算的结果相比较：

Wolfram Language code: Area[Parallelepiped[{0, 0, 0}, {a, b}]]

也可用来计算，其中是向量间的夹角：

Wolfram Language code: Norm[a]Norm[b]Sin[VectorAngle[a, b]]

可视化平行四边形：

Wolfram Language code: Graphics3D[Parallelepiped[{0, 0, 0}, {a, b}]]

Frenet–Serret 系统用向量基和标量函数中对每个空间曲线的属性进行编码. 考虑以下曲线：

Wolfram Language code: c[t_] := {Cos[t], Sin[t], (t/2π)}

用前两个导数的叉积定义切线、法线和副法线向量：

Wolfram Language code:

{Subscript[e, 1], Subscript[e, 2], Subscript[e, 3]} = Simplify[{Normalize[c'[t]], Normalize[c'[t]⨯(c''[t]⨯c'[t])], Normalize[c'[t]⨯c''[t]]}, t∈Reals]

这三个向量定义了的右手定则的标准正交基：

Wolfram Language code: {Table[Subscript[e, i].Subscript[e, j], {i, 3}, {j, 3}], Subscript[e, 1]⨯Subscript[e, 2] == Subscript[e, 3]}//Simplify

计算曲率和扭矩，它们量化了曲线的弯曲程度：

Wolfram Language code:

{κ, τ} = Simplify[{(Norm[c''[t]⨯c'[t]]/Norm[c'[t]]^3), (c'[t].(c''[t]⨯c'''[t])/Norm[c'[t]⨯c''[t]]^2)}, t∈Reals]

用 FrenetSerretSystem 可视化答案：

Wolfram Language code: Simplify[{{κ, τ}, {Subscript[e, 1], Subscript[e, 2], Subscript[e, 3]}} == FrenetSerretSystem[c[t], t], t∈Reals]

可视化曲线和相关的移动基，也称为框架：

Wolfram Language code:

DynamicModule[{s}, Labeled[Show[ParametricPlot3D[c[t], {t, 0, 6π}, PlotRangePadding -> {.5, .5, .9}], Graphics3D[{AbsoluteThickness[2], StandardBlue, Arrow[{c[t], c[t] + Subscript[e, 1]}], StandardRed, Arrow[{c[t], c[t] + Subscript[e, 2]}], StandardPurple, Arrow[{c[t], c[t] + Subscript[e, 3]}]}] /. t -> Dynamic[s]], Animator[Dynamic[s], {0, 6π}], Top]]

物理应用 (5)

求在点处垂直向下施加的力相对于原点的扭矩：

Wolfram Language code:

F = Quantity[{0, 0, -10}, "Newtons"];
r  = Quantity[{1.5, 3.2, 1.25}, "Meters"];

扭矩由公式给出：

Wolfram Language code: r⨯F

求质量为，速度为，相对于原点的位置为的粒子的角动量：

Wolfram Language code:

m = Quantity[3, "Kilograms"];
v = Quantity[{1.5, 2.3, -3.4}, "Meters" / "Seconds"];
r = Quantity[{2.5, -3.3, 1.4}, "Meters"];

角动量由给出，其线性动量等于：

Wolfram Language code: r⨯(m v)

求带有电荷，速度为，穿过的磁场向正方向移动的粒子受到的磁力：

Wolfram Language code:

q = Quantity[2, "Coulombs"];
v = QuantityArray[{3, -4, 5}, "Meters" / "Seconds"];
B = QuantityArray[{0, 0, 0.075}, "Teslas"];

磁力由公式给出：

Wolfram Language code: q v ⨯B

用 UnitSimplify 获取预期的单位：牛顿，用 MatrixForm 格式化向量：

Wolfram Language code: UnitSimplify[%]//MatrixForm

考虑一个被约束在离轴固定距离旋转的粒子：

Wolfram Language code: r[t_] := {0, Cos[t^2], Sin[t^2]}

以叉积的形式定义角速度：

Wolfram Language code: ω = (r'[t]⨯r''[t]/r'[t].r'[t])//Simplify

可用表示许多属性. 线速度等于：

Wolfram Language code: r'[t] == ω⨯r[t]

垂直或向心加速度等于：

Wolfram Language code: Subscript[a, perp] = ω⨯r'[t]

由于和正交，则有 $TemplateBox[{{a, _, {(, perp, )}}}, Norm]=TemplateBox[{omega}, Norm] TemplateBox[{{r, ^, {(, ', )}}}, Norm]$ ：

Wolfram Language code: Simplify[Norm[Subscript[a, perp]] == Norm[ω]Norm[r'[t]] == (r'[t].r'[t]/Norm[r[t]]), t∈Reals]

著名的向心加速度公式 $TemplateBox[{{a, _, {(, perp, )}}}, Norm]=(TemplateBox[{{r, ^, {(, ', )}}}, Norm]^2)/(TemplateBox[{r}, Norm])=(TemplateBox[{v}, Norm]^2)/(TemplateBox[{r}, Norm])$ 同样成立：

Wolfram Language code: Simplify[Norm[Subscript[a, perp]] == (r'[t].r'[t]/Norm[r[t]]), t∈Reals]

的导数是角速度：

Wolfram Language code: α = D[ω, t]

平行于运动方向的加速度等于：

Wolfram Language code: Subscript[a, par] = α⨯r[t]

注意线加速度等于：

Wolfram Language code: r''[t] == Subscript[a, par] + Subscript[a, perp]

固定三维向量的叉积可以用矩阵乘法表示，这在研究旋转运动时很有用. 构建表示线性算符的反对称矩阵，其中是关于轴的角速度：

Wolfram Language code: Overscript[ω, ⇀] = {0, 0, 2};

Wolfram Language code: (Subscript[ℒ, L] = Map[Cross[#, Overscript[ω, ⇀]]&, IdentityMatrix[3]])//MatrixForm

验证的操作即相当于执行与的叉积：

Wolfram Language code: Subscript[ℒ, L]. {x, y, z} == Overscript[ω, ⇀]⨯{x, y, z}

时间时的旋转矩阵是乘以上面矩阵的矩阵指数：

Wolfram Language code: (rot[t_] = MatrixExp[t Subscript[ℒ, L]])//MatrixForm

用 RotationMatrix 验证：

Wolfram Language code: rot[t] == RotationMatrix[Norm[Overscript[ω, ⇀]]t, {0, 0, 1}]

时间零时的点将为时间时的：

Wolfram Language code: Overscript[r, ⇀] = rot[t].{x, y, z}

速度将由给出：

Wolfram Language code: Overscript[v, ⇀] = Overscript[ω, ⇀]⨯Overscript[r, ⇀]

从旋转轴到的向量为 $(v(t)xomega)/(TemplateBox[{omega}, Norm]^2)$ ：

Wolfram Language code: (Overscript[v, ⇀]⨯Overscript[ω, ⇀]/Overscript[ω, ⇀].Overscript[ω, ⇀])//Expand

可视化该运动及相关向量：

Wolfram Language code:

With[{w = Overscript[ω, ⇀], x = rot[s].{1, 1, 1}}, Animate[Legended[Graphics3D[{AbsoluteThickness[3], StandardRed, Arrow[{{0, 0, 0}, w}], StandardBlue, Arrow[{{0, 0, 0}, x}], StandardCyan, Arrow[{{0, 0, 1}, x}], StandardPurple, Translate[Arrow[{{0, 0, 0}, w⨯x}], x]}, PlotRange -> {{-3, 3}, {-3, 3}, {0, 2}}], SwatchLegend[{StandardRed, StandardBlue, StandardPurple, StandardCyan}, {ω, r[t], v[t] == ω⨯r[t], Subscript[r, "⟂"] == (v[t]⨯ω/ω.ω)}]], {{s, 0, t}, 0, 2π}]]

属性和关系 (10)

如果 u 和 v 是线性无关的，u×v 是非零向量，并垂直于 u 和 v：

Wolfram Language code: {u, v} = RandomInteger[{-9, 9}, {2, 3}]

Wolfram Language code: w = Cross[u, v]

Wolfram Language code: {u.w, v.w}

如果 u 和 v 是线性相关的，u×v 是零：

Wolfram Language code:

u = RandomReal[1, 3];
v = RandomReal[1] u;

Wolfram Language code: Chop[Cross[u, v]]

对于三维向量， $TemplateBox[{{{u, _, 1}, x, {u, _, 2}}}, Norm]=TemplateBox[{{u, _, 1}}, Norm] TemplateBox[{{u, _, 2}}, Norm]sin(theta)$ ，其中是和之间的夹角：

Wolfram Language code:

{u1, u2} = RandomReal[1, {2, 3}];
Norm[u1⨯u2] == Norm[u1]Norm[u2]Sin[VectorAngle[u1, u2]]

Cross[u₁,…,u_k] 的范数是 u_i 形成的 k 维平行六面体的度量：

Wolfram Language code:

{u1, u2} = {{5, -9, 6}, {-7, 5, 3}};
p  = Parallelepiped[{0, 0, 0}, {u1, u2}];
Norm[u1⨯u2] == Area[p] == RegionMeasure[p, 2]

Wolfram Language code:

{v1, v2, v3} = {{8, -5, 5, -1}, {6, 7, 8, -2}, {-7, 6, -3, 2}};
p  = Parallelepiped[{0, 0, 0, 0}, {v1, v2, v3}];
Norm[v1⨯v2⨯v3] == Volume[p] == RegionMeasure[p, 3]

Cross 是反对称的：

Wolfram Language code: {u, v} = RandomReal[1, {2, 3}];

Wolfram Language code: Cross[u, v] == -Cross[v, u]

Cross 关于每个参数都是线性的：

Wolfram Language code:

Subscript[u, 1] = {Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]};
Subscript[u, 2] = {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]};
Subscript[u, 3] = {Subscript[x, 3], Subscript[y, 3], Subscript[z, 3]};

Wolfram Language code:

Expand[Cross[a Subscript[u, 1] + Subscript[u, 3], Subscript[u, 2]] == a Cross[Subscript[u, 1], Subscript[u, 2]] + Cross[Subscript[u, 3], Subscript[u, 2]]]

Wolfram Language code:

Expand[Cross[Subscript[u, 1], b Subscript[u, 2] + Subscript[u, 3]] == b Cross[Subscript[u, 1], Subscript[u, 2]] + Cross[Subscript[u, 1], Subscript[u, 3]]]

由于 Cross 是线性的，可用矩阵乘法表示算符：

Wolfram Language code: Overscript[ω, ⇀] = {Subscript[ω, x], Subscript[ω, y], Subscript[ω, z]};

Wolfram Language code: (Subscript[ℒ, L] = Map[Cross[#, Overscript[ω, ⇀]]&, IdentityMatrix[3]])//MatrixForm

用反对称矩阵乘以向量即相当于：

Wolfram Language code: Subscript[ℒ, L].{a, b, c} == Overscript[ω, ⇀]⨯{a, b, c}

对应的算符以相反的顺序计算叉积：

Wolfram Language code: (Subscript[ℒ, R] = Map[Cross[Overscript[ω, ⇀], #]&, IdentityMatrix[3]])//MatrixForm

Wolfram Language code: Subscript[ℒ, R].{a, b, c} == {a, b, c}⨯Overscript[ω, ⇀]

由于反对称，这两个矩阵互为转置或互为负矩阵：

Wolfram Language code: Subscript[ℒ, R] == Transpose[Subscript[ℒ, L]] == -Subscript[ℒ, L]

维中的 Cross 是将个向量缩并为 Levi-Civita 张量：

Wolfram Language code:

α = Array[a, {4}];
β = Array[b, {4}];
γ = Array[c, {4}];
Cross[α, β, γ] === TensorContract[αβγLeviCivitaTensor[4, List], {{1, 4}, {2, 5}, {3, 6}}]

维中的个向量的 Cross 是 ( 乘以张量积的霍奇对偶：

Wolfram Language code: {a, b, c, d}⨯{d, e, f, g}⨯{h, i, j, k}

Wolfram Language code: (4 - 1)!HodgeDual[{a, b, c, d}{d, e, f, g}{h, i, j, k}]

Wolfram Language code: % == %%

个 -向量的 TensorWedge 的霍奇对偶与这些向量的 Cross 相同：

Wolfram Language code:

v1 = {a, b, c};
v2 = {x, y, z};

Wolfram Language code: Normal@HodgeDual[v1v2] === Cross[v1, v2]

Wolfram Language code:

v1 = {a, b, c, d};
v2 = {x, y, z, t};
v3 = {p, q, r, s};

Wolfram Language code: Normal@HodgeDual[v1v2v3] === Cross[v1, v2, v3]

TensorWedge 可以处理更高阶的形式：

Wolfram Language code:

M = Array[m, {5, 5}];
Q = Array[q, {5, 5}];

Wolfram Language code: HodgeDual[MQ]

互动范例 (1)

可视化 - 平面中两个可拖动的向量、它们的叉积（平行于轴）以及它们形成的平行四边形：

Wolfram Language code:

Manipulate[
	DynamicModule[{vv, ww, angles, cros}, 
	vv = Normalize[v];ww = Normalize[w];
	cros = First[PadLeft[v, 3]⨯PadLeft[w, 3]];
	angles = Sort[N@{ArcTan@@vv, ArcTan@@ww}];Graphics[{IconizedObject[«x ticks»], {If[showPar, {If[cros > 0, RGBColor[1, 0.6, 0.7000000000000001, 0.5], RGBColor[0.6, 0.7000000000000001, 1, 0.5]], Polygon[{{0, 0}, v, v + w, w}]}]}, 
	{LightDarkSwitched[GrayLevel[0]], Arrow[{{0, 0}, v}]}, {LightDarkSwitched[GrayLevel[0]], Arrow[{{0, 0}, w}]}, AbsoluteThickness[3], {If[cros < 0, RGBColor[0.4, 0.6, 1], RGBColor[0.98, 0.56, 0.17]], Circle[{0, 0}, .3, If[-Subtract@@angles < π, angles, Reverse[angles] + {0, 2π}]]}, {If[cros > 0, RGBColor[0.98, 0.56, 0.17], RGBColor[0.4, 0.6, 1]], Arrow[{{0, 0}, cros{-1 / 2, -1 / 2}}]}, Text["OverscriptBox[v, ⇀]", v 3 / 4, {1, 1}], Text["OverscriptBox[w, ⇀]", 3w / 4, {1, 1}], Text["OverscriptBox[v, ⇀] ⨯ OverscriptBox[w, ⇀]", cros{-1 / 2, -1 / 2}, {1, 1}]}, Axes -> True, PlotRange -> 3, AxesLabel -> {y, z}, ImageSize -> {400, 400}, PlotLabel -> Grid[ 
	{{If[cros > 0, Style["acute or obtuse angle", RGBColor[0.98, 0.56, 0.17]], Style["reflex angle", RGBColor[0.4, 0.6, 1]]], Norm["OverscriptBox[v, ⇀] ⨯ OverscriptBox[w, ⇀]"]  == DecimalForm[Abs[cros], {4, 3}]}}, ItemSize -> 10]]], 
	{{showPar, True, "show parallelogram"}, {True, False}}, 
	{{v, {1., 0.5}}, {-3, -3}, {3, 3}, Locator, Appearance -> None, Exclusions -> {0, 0}}, 
	{{w, {-2., 1.}}, {-3, -3}, {3, 3}, Locator, Appearance -> None, Exclusions -> {0, 0}}
	]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Cross

更多信息

范例

基本范例 (3)

范围 (9)

应用 (10)

几何应用 (5)

物理应用 (5)

属性和关系 (10)

互动范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

Cross

更多信息

范例

基本范例 (3)

范围 (9)

应用 (10)

几何应用 (5)

物理应用 (5)

属性和关系 (10)

互动范例 (1)

参见

技术笔记

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX