Cuboid

Cuboid[p_min]

下のコーナーが p_minにある単位超直方体を表す．

Cuboid[p_min,p_max]

下のコーナーが p_min，上のコーナーが p_maxにある，軸に平行な塗り潰された直方体を表す．

詳細とオプション

Cuboidは，区間，長方形，正方形，立方体，四次元直方体，超直方体，超長方形，ボックスとしても知られている．
Cuboidは領域を表す．ただし，かつである．

Cuboid[]はCuboid[{0,0,0}]に等しい．
CanonicalizePolyhedronを使って直方体を明示的なPolyhedronオブジェクトに変換できる．
CuboidはGraphicsおよびGraphics3Dで使うことができる．
グラフィックスでは，点 p_minおよび p_maxは，Scaled，ImageScaled，Offset，Dynamicの各式でよい．
グラフィックスの描画は，FaceForm，EdgeForm，Opacity，色等の指示子の影響を受ける．

例題

すべて開くすべて閉じる

例 (5)

単位直方体：

Wolfram Language code: Graphics3D[Cuboid[]]

2つの単位直方体：

Wolfram Language code: Graphics3D[{Yellow, Cuboid[{0, 0, 0}], Blue, Cuboid[{0.5, 0.5, 0.5}]}]

異なる大きさの直方体：

Wolfram Language code: Graphics3D[{Yellow, Cuboid[{0, 0, 0}, {1, 3, 1}], Blue, Cuboid[{2, 1, 1}, {4, 2, 3}]}]

さまざまなスタイルの直方体：

Wolfram Language code:

{Graphics3D[{Pink, Cuboid[]}], Graphics3D[{EdgeForm[Thick], Cuboid[]}], Graphics3D[{EdgeForm[Dashed], Cuboid[]}], Graphics3D[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, Cuboid[]}]}

体積と重心：

Wolfram Language code: Volume[Cuboid[{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}]]

Wolfram Language code:

RegionCentroid[Cuboid[{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}]]

スコープ (21)

グラフィックス (11)

指定 (3)

単位直方体：

Wolfram Language code: Graphics3D[Cuboid[{1, 1, 1}]]

単位正方形：

Wolfram Language code: Graphics[Cuboid[{1, 1}]]

各軸に平行の直方体：

Wolfram Language code: Graphics3D[Cuboid[{0, 0, 0}, {3, 2, 1}]]

コーナーが原点にある単位直方体の短縮形：

Wolfram Language code: Graphics3D[Cuboid[], Axes -> True]

スタイリング (5)

色指示子で直方体の面の色を指定する：

Wolfram Language code: Table[Graphics3D[{c, Cuboid[]}], {c, {Red, Green, Blue, Yellow}}]

FaceFormとEdgeFormで面と辺のスタイルが指定できる：

Wolfram Language code: Graphics3D[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], Cuboid[]}]

FaceFormを使って表面と裏面に異なる特性が指定できる：

Wolfram Language code:

Graphics3D[{FaceForm[Yellow, Blue], Cuboid[Scaled[{.1, -.5, .1}], Scaled[{.9, .8, .9}]]}, PlotRange -> {{-1 / 4, 5 / 4}, {1 / 4, 5 / 4}, {-1 / 4, 5 / 4}}]

異なる鏡面反射指数の直方体：

Wolfram Language code:

Table[Graphics3D[{Orange, Specularity[White, n], Cuboid[]}, Lighting -> {{"Point", White, Scaled[{2, -1, 1.2}]}}], {n, {5, 20, 100}}]

赤く輝く白い直方体：

Wolfram Language code: Graphics3D[{Glow[Red], Black, Cuboid[]}]

Opacityは面の透明度を指定する：

Wolfram Language code: Table[Graphics3D[{Opacity[o], Cuboid[]}, Boxed -> False], {o, {0.1, 0.5, 0.9}}]

座標 (3)

Scaled座標を使う：

Wolfram Language code: Graphics3D[Cuboid[Scaled[{0, .2, .4}], Scaled[{1, .8, .6}]], PlotRange -> {{0, 10}, {0, 10}, {0, 10}}, Axes -> True]

通常の座標からのスケールされたオフセットを指定する：

Wolfram Language code: Graphics3D[Cuboid[Scaled[{0, 0, 0.5}, {0, 0, 1}]], PlotRange -> {{0, 5}, {0, 5}, {0, 5}}, Axes -> True]

点はDynamicでもよい：

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x], {0, 0.5}], Graphics3D[{Cuboid[Dynamic[{x, 0, 0}], {1, 1, 1}]}]}]

領域 (10)

埋込み次元は，直方体がある空間の次元である：

Wolfram Language code:

RegionEmbeddingDimension[Cuboid[{Subscript[l, 1], Subscript[l, 2], Subscript[l, 3]}, {Subscript[u, 1], Subscript[u, 2], Subscript[u, 3]}]]

幾何次元は形それ自身の次元である：

Wolfram Language code:

RegionDimension[Cuboid[{Subscript[l, 1], Subscript[l, 2], Subscript[l, 3]}, {Subscript[u, 1], Subscript[u, 2], Subscript[u, 3]}]]

帰属判定：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, {2, 2, 2}];

Wolfram Language code: {RegionMember[ℛ, {1, 1, 1}], RegionMember[ℛ, {3, 3, 3}]}

点の帰属条件を得る：

Wolfram Language code:

RegionMember[Cuboid[{Subscript[l, 1], Subscript[l, 2], Subscript[l, 3]}, {Subscript[u, 1], Subscript[u, 2], Subscript[u, 3]}], {x, y, z}]

体積：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, {2, 2, 2}];

Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

重心：

Wolfram Language code: c = RegionCentroid[ℛ]

Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

点からの距離：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, {2, 2, 2}];

Wolfram Language code: {RegionDistance[ℛ, {1, 1, 1}], RegionDistance[ℛ, {3, 3, 3}]}

直方体の等距離等高線：

Wolfram Language code:

ContourPlot3D[Evaluate@RegionDistance[Cuboid[{-1, -1, -1}, {1, 1, 1}], {x, y, z}], {x, -2.1, 2.1}, {y, -2.1, 2.1}, {z, -2.1, 2.1}, Mesh -> None, Contours -> {0.25, 0.5, 1}, ContourStyle -> ColorData[94, "ColorList"], Lighting -> "Neutral", BaseStyle -> Opacity[0.5], BoxRatios -> Automatic]

点からの符号付き距離：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, {2, 2, 2}];

Wolfram Language code: {SignedRegionDistance[ℛ, {1, 1, 1}], SignedRegionDistance[ℛ, {3, 3, 3}]}

領域内の最近点：

Wolfram Language code: ℛ = Cuboid[{-1, -1, -1}, {1, 1, 1}];

Wolfram Language code: {RegionNearest[ℛ, {0, 0, 0}], RegionNearest[ℛ, {2, 2, 2}]}

包み込んでいる球までの最近点：

Wolfram Language code:

spherePoints[{n_, m_}, c_, r_] := 
	Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];

Wolfram Language code:

pl = spherePoints[{16, 8}, RegionCentroid[ℛ], 3];
npl = Table[RegionNearest[ℛ, p], {p, pl}];

Wolfram Language code:

Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

直方体は有界である：

Wolfram Language code:

BoundedRegionQ[Cuboid[{Subscript[l, 1], Subscript[l, 2], Subscript[l, 3]}, {Subscript[u, 1], Subscript[u, 2], Subscript[u, 3]}]]

Wolfram Language code: ℛ = Cuboid[{-1, -1, -1}, {1, 1, 1}];

Wolfram Language code: BoundedRegionQ[ℛ]

領域を求める：

Wolfram Language code: r = RegionBounds[ℛ]

直方体領域上で積分する：

Wolfram Language code: ℛ = Cuboid[{Subscript[l, 1], Subscript[l, 2], Subscript[l, 3]}, {Subscript[u, 1], Subscript[u, 2], Subscript[u, 3]}];

Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ]

直方体領域上で最適化する：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, {1, 1, 1}];

Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]

直方体領域内で方程式を解く：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, {1, 1, 1}];

Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && x - y - z == -(1/2) && z^2 == x y + (1/4) && {x, y, z}∈ℛ, {x, y, z}]

アプリケーション (8)

縦，横，高さで直方体領域を定義する：

Wolfram Language code: cuboid[l_, w_, h_] := Cuboid[{0, 0, 0}, {l, w, h}]

その体積を計算する：

Wolfram Language code: Volume[cuboid[l, w, h]]

いくつかの例を可視化する：

Wolfram Language code: Region /@ {cuboid[5, 1, 1], cuboid[2, 2, 4], cuboid[3, 3, 3]}

で密度が与えられる直方体領域の全質量：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, {l, w, h}];

Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ, Assumptions -> l > 0 && w > 0 && h > 0]

直方体中のエタノールの質量を求める：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, Quantity[{4, 3, 2}, "Centimeters"]];

エタノールの密度：

Wolfram Language code: d = ChemicalData["Ethanol", "Density"]

直方体の体積：

Wolfram Language code: v = Volume[ℛ]

直方体中のエタノールの質量：

Wolfram Language code: FormulaData["MassDensity", {"ρ" -> d, "V" -> v}]

RegionBoundsで境界ボックスを作る：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {0, 0, 3}}, 1];

Wolfram Language code: bounds = RegionBounds[ℛ];

境界ボックスを計算する：

Wolfram Language code: boundingBox = Cuboid@@Transpose[bounds];

Volumeの相違を計算する：

Wolfram Language code: Volume[boundingBox] - Volume[ℛ]

境界ボックスを可視化する：

Wolfram Language code: Show[Graphics3D[{ℛ, EdgeForm[White], Opacity[0.2, Yellow], boundingBox}], Boxed -> False]

簡単な3D棒グラフ：

Wolfram Language code: data = RandomReal[{1, 10}, {12, 4}];

Wolfram Language code:

Graphics3D[MapIndexed[{Hue[(Last[#2] - 1) / 4], Cuboid[Append[{1, 2}#2 - {.5, .5}, 0], Append[{1, 2}#2 + {.5, .5}, #1]]}&, data, {2}], Axes -> {False, False, True}, Lighting -> "Neutral"]

3Dセルオートマトンの一連の進化のステップを示す：

Wolfram Language code:

Graphics3D[Cuboid /@ Position[#, 1], ImageSize -> Tiny, Boxed -> False]& /@ Take[CellularAutomaton[{14, {2, 1}, {1, 1, 1}}, {{{{1}}}, 0}, 10], {1, -1, 2}]

体積を表す簡単な方法として使用する：

Wolfram Language code:

cuboidRegionPlot3D[p_, {x_, xmin_, xmax_, dx_}, {y_, ymin_, ymax_, dy_}, {z_, zmin_, zmax_, dz_}] := Module[{f = Function@@{{x, y, z}, p}}, Graphics3D[Table[If[f[x, y, z], Cuboid[{x, y, z}, {x, y, z} + {dx, dy, dz}], {}], {x, xmin, xmax, dx}, {y, ymin, ymax, dy}, {z, zmin, zmax, dz}]]]

Wolfram Language code: cuboidRegionPlot3D[1 ≤ x ^ 2 + y ^ 2 + z ^ 2 ≤ 2 && x y z ≥ 0, {x, -2, 2, .1}, {y, -2, 2, 0.1}, {z, -2, 2, 0.1}]

双曲面：

Wolfram Language code:

Table[Graphics3D[With[{p = First@v, q = Last@v}, {Red, Thick, Line[{1.5p - .5q, 1.5q - .5p}], Yellow, EdgeForm[], Table[Rotate[Cuboid[], 2Pi k / 20, p - q, q], {k, 20}]}]], 
	{v, {{{1, 1, 1}, {0, 0, 0}}, {{1, .5, 1}, {0, .5, 0}}, {{.7, .7, 1}, {.3, .3, 0}}}}]

特性と関係 (8)

Transposeを使ってCuboidを範囲指定に変換する：

Wolfram Language code: Transpose[List@@Cuboid[{0, 0, 0}, {1, 2, 3}]]

逆に，範囲指定をCuboid指定に変換する：

Wolfram Language code: RegionBounds[Ball[]]

Wolfram Language code: Cuboid@@Transpose[%]

Rotateを使ってGraphics3D中の可能なすべての直方体を得る：

Wolfram Language code: Graphics3D[Rotate[Cuboid[{0, 0, 0}, {1, 2, 1}], -30 Degree, {0, 0, 1}], Axes -> True]

PolygonはCuboidの2Dにおける一般化である：

Wolfram Language code:

Subscript[ℛ, 1] = Polygon[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}];
Subscript[ℛ, 2] = Cuboid[{0, 0}, {1, 1}];