WOLFRAM

Wolfram 语言与系统参考资料中心

Cuboid[pmin]

表示一个单位超立方体，其左下角为 pmin.

Cuboid[pmin,pmax]

表示与坐标轴对齐的实心长方体，其左下角为 pmin，右上角为 pmax.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
图形  
规范  
样式化  
坐标  
区域  
应用  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Cuboid

Cuboid[pmin]

表示一个单位超立方体，其左下角为 pmin.

Cuboid[pmin,pmax]

表示与坐标轴对齐的实心长方体，其左下角为 pmin，右上角为 pmax.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (5)

单位长方体：

Wolfram Language code: Graphics3D[Cuboid[]]

两个单位长方体：

Wolfram Language code: Graphics3D[{Yellow, Cuboid[{0, 0, 0}], Blue, Cuboid[{0.5, 0.5, 0.5}]}]

不同大小的长方体：

Wolfram Language code: Graphics3D[{Yellow, Cuboid[{0, 0, 0}, {1, 3, 1}], Blue, Cuboid[{2, 1, 1}, {4, 2, 3}]}]

不同样式的长方体：

Wolfram Language code: {Graphics3D[{Pink, Cuboid[]}], Graphics3D[{EdgeForm[Thick], Cuboid[]}], Graphics3D[{EdgeForm[Dashed], Cuboid[]}], Graphics3D[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, Cuboid[]}]}

体积和质心：

Wolfram Language code: Volume[Cuboid[{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}]]
Wolfram Language code: RegionCentroid[Cuboid[{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}]]

范围  (21)

图形  (11)

规范  (3)

单位立方体：

Wolfram Language code: Graphics3D[Cuboid[{1, 1, 1}]]

单位正方形：

Wolfram Language code: Graphics[Cuboid[{1, 1}]]

平行于各轴的长方体：

Wolfram Language code: Graphics3D[Cuboid[{0, 0, 0}, {3, 2, 1}]]

以原点为中心的单位立方体的简写形式：

Wolfram Language code: Graphics3D[Cuboid[], Axes -> True]

样式化  (5)

颜色指示指定长方体各面的颜色：

Wolfram Language code: Table[Graphics3D[{c, Cuboid[]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm 和 EdgeForm 可用于指定表面和边的样式：

Wolfram Language code: Graphics3D[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], Cuboid[]}]

可以通过使用 FaceForm 指定前面和背面的不同属性：

Wolfram Language code: Graphics3D[{FaceForm[Yellow, Blue], Cuboid[Scaled[{.1, -.5, .1}], Scaled[{.9, .8, .9}]]}, PlotRange -> {{-1 / 4, 5 / 4}, {1 / 4, 5 / 4}, {-1 / 4, 5 / 4}}]

具有不同镜面指数的长方体：

Wolfram Language code: Table[Graphics3D[{Orange, Specularity[White, n], Cuboid[]}, Lighting -> {{"Point", White, Scaled[{2, -1, 1.2}]}}], {n, {5, 20, 100}}]

闪着红光的白色长方体：

Wolfram Language code: Graphics3D[{Glow[Red], Black, Cuboid[]}]

Opacity 指定表面不透明度：

Wolfram Language code: Table[Graphics3D[{Opacity[o], Cuboid[]}, Boxed -> False], {o, {0.1, 0.5, 0.9}}]

坐标  (3)

使用 Scaled 坐标：

Wolfram Language code: Graphics3D[Cuboid[Scaled[{0, .2, .4}], Scaled[{1, .8, .6}]], PlotRange -> {{0, 10}, {0, 10}, {0, 10}}, Axes -> True]

指定从普通坐标缩放的偏移量：

Wolfram Language code: Graphics3D[Cuboid[Scaled[{0, 0, 0.5}, {0, 0, 1}]], PlotRange -> {{0, 5}, {0, 5}, {0, 5}}, Axes -> True]

点可以是 Dynamic：

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x], {0, 0.5}], Graphics3D[{Cuboid[Dynamic[{x, 0, 0}], {1, 1, 1}]}]}]

区域  (10)

嵌入维数是长方体所在空间的维数：

Wolfram Language code: RegionEmbeddingDimension[Cuboid[{Subscript[l, 1], Subscript[l, 2], Subscript[l, 3]}, {Subscript[u, 1], Subscript[u, 2], Subscript[u, 3]}]]

几何维数是形状自身的维数：

Wolfram Language code: RegionDimension[Cuboid[{Subscript[l, 1], Subscript[l, 2], Subscript[l, 3]}, {Subscript[u, 1], Subscript[u, 2], Subscript[u, 3]}]]

成员检验：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, {2, 2, 2}];
Wolfram Language code: {RegionMember[ℛ, {1, 1, 1}], RegionMember[ℛ, {3, 3, 3}]}

获取点成员的条件：

Wolfram Language code: RegionMember[Cuboid[{Subscript[l, 1], Subscript[l, 2], Subscript[l, 3]}, {Subscript[u, 1], Subscript[u, 2], Subscript[u, 3]}], {x, y, z}]

体积：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, {2, 2, 2}];
Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

质心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

从一个点的距离：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, {2, 2, 2}];
Wolfram Language code: {RegionDistance[ℛ, {1, 1, 1}], RegionDistance[ℛ, {3, 3, 3}]}

长方体的等距轮廓：

Wolfram Language code: ContourPlot3D[Evaluate@RegionDistance[Cuboid[{-1, -1, -1}, {1, 1, 1}], {x, y, z}], {x, -2.1, 2.1}, {y, -2.1, 2.1}, {z, -2.1, 2.1}, Mesh -> None, Contours -> {0.25, 0.5, 1}, ContourStyle -> ColorData[94, "ColorList"], Lighting -> "Neutral", BaseStyle -> Opacity[0.5], BoxRatios -> Automatic]

距一个点的带符号距离：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, {2, 2, 2}];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 1, 1}], SignedRegionDistance[ℛ, {3, 3, 3}]}

区域上的最近点：

Wolfram Language code: ℛ = Cuboid[{-1, -1, -1}, {1, 1, 1}];
Wolfram Language code: {RegionNearest[ℛ, {0, 0, 0}], RegionNearest[ℛ, {2, 2, 2}]}

到一个封闭球体的最近点：

Wolfram Language code: spherePoints[{n_, m_}, c_, r_] := Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];
Wolfram Language code: pl = spherePoints[{16, 8}, RegionCentroid[ℛ], 3]; npl = Table[RegionNearest[ℛ, p], {p, pl}];
Wolfram Language code: Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

长方体是有界的：

Wolfram Language code: BoundedRegionQ[Cuboid[{Subscript[l, 1], Subscript[l, 2], Subscript[l, 3]}, {Subscript[u, 1], Subscript[u, 2], Subscript[u, 3]}]]
Wolfram Language code: ℛ = Cuboid[{-1, -1, -1}, {1, 1, 1}];
Wolfram Language code: BoundedRegionQ[ℛ]

求它的范围：

Wolfram Language code: r = RegionBounds[ℛ]

在长方体区域上积分：

Wolfram Language code: ℛ = Cuboid[{Subscript[l, 1], Subscript[l, 2], Subscript[l, 3]}, {Subscript[u, 1], Subscript[u, 2], Subscript[u, 3]}];
Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ]

在长方体区域上进行最优化：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, {1, 1, 1}];
Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]

在长方体区域上解方程：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, {1, 1, 1}];
Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && x - y - z == -(1/2) && z^2 == x y + (1/4) && {x, y, z}∈ℛ, {x, y, z}]

应用  (8)

通过长、宽、高定义长方体：

Wolfram Language code: cuboid[l_, w_, h_] := Cuboid[{0, 0, 0}, {l, w, h}]

计算体积：

Wolfram Language code: Volume[cuboid[l, w, h]]

可视化某些特例：

Wolfram Language code: Region /@ {cuboid[5, 1, 1], cuboid[2, 2, 4], cuboid[3, 3, 3]}

密度由 给出的长方体的总质量：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, {l, w, h}];
Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ, Assumptions -> l > 0 && w > 0 && h > 0]

求长方体中乙醇的质量：

Wolfram Language code: ℛ = Cuboid[{0, 0, 0}, Quantity[{4, 3, 2}, "Centimeters"]];

乙醇的密度：

Wolfram Language code: d = ChemicalData["Ethanol", "Density"]

长方体的体积：

Wolfram Language code: v = Volume[ℛ]

长方体中乙醇的质量：

Wolfram Language code: FormulaData["MassDensity", {"ρ" -> d, "V" -> v}]

从 RegionBounds 创建一个定界框：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {0, 0, 3}}, 1];
Wolfram Language code: bounds = RegionBounds[ℛ];

计算定界框：

Wolfram Language code: boundingBox = Cuboid@@Transpose[bounds];

计算 Volume 的不同：

Wolfram Language code: Volume[boundingBox] - Volume[ℛ]

可视化定界框：

Wolfram Language code: Show[Graphics3D[{ℛ, EdgeForm[White], Opacity[0.2, Yellow], boundingBox}], Boxed -> False]

一个简单的三维条形图：

Wolfram Language code: data = RandomReal[{1, 10}, {12, 4}];
Wolfram Language code: Graphics3D[MapIndexed[{Hue[(Last[#2] - 1) / 4], Cuboid[Append[{1, 2}#2 - {.5, .5}, 0], Append[{1, 2}#2 + {.5, .5}, #1]]}&, data, {2}], Axes -> {False, False, True}, Lighting -> "Neutral"]

显示三维元胞自动机的一系列演变步骤：

Wolfram Language code: Graphics3D[Cuboid /@ Position[#, 1], ImageSize -> Tiny, Boxed -> False]& /@ Take[CellularAutomaton[{14, {2, 1}, {1, 1, 1}}, {{{{1}}}, 0}, 10], {1, -1, 2}]

用简单的方式可视化体积：

Wolfram Language code: cuboidRegionPlot3D[p_, {x_, xmin_, xmax_, dx_}, {y_, ymin_, ymax_, dy_}, {z_, zmin_, zmax_, dz_}] := Module[{f = Function@@{{x, y, z}, p}}, Graphics3D[Table[If[f[x, y, z], Cuboid[{x, y, z}, {x, y, z} + {dx, dy, dz}], {}], {x, xmin, xmax, dx}, {y, ymin, ymax, dy}, {z, zmin, zmax, dz}]]]
Wolfram Language code: cuboidRegionPlot3D[1 ≤ x ^ 2 + y ^ 2 + z ^ 2 ≤ 2 && x y z ≥ 0, {x, -2, 2, .1}, {y, -2, 2, 0.1}, {z, -2, 2, 0.1}]

双曲线体：

Wolfram Language code: Table[Graphics3D[With[{p = First@v, q = Last@v}, {Red, Thick, Line[{1.5p - .5q, 1.5q - .5p}], Yellow, EdgeForm[], Table[Rotate[Cuboid[], 2Pi k / 20, p - q, q], {k, 20}]}]], {v, {{{1, 1, 1}, {0, 0, 0}}, {{1, .5, 1}, {0, .5, 0}}, {{.7, .7, 1}, {.3, .3, 0}}}}]

属性和关系  (8)

使用 Transpose 将 Cuboid 转换为范围规范：

Wolfram Language code: Transpose[List@@Cuboid[{0, 0, 0}, {1, 2, 3}]]

相反地，将范围规范转换为 Cuboid 规范：

Wolfram Language code: RegionBounds[Ball[]]
Wolfram Language code: Cuboid@@Transpose[%]

使用 Rotate 得到 Graphics3D 中所有可能的长方体：

Wolfram Language code: Graphics3D[Rotate[Cuboid[{0, 0, 0}, {1, 2, 1}], -30 Degree, {0, 0, 1}], Axes -> True]

Polygon 是二维中 Cuboid 的推广：

Wolfram Language code: Subscript[ℛ, 1] = Polygon[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}]; Subscript[ℛ, 2] = Cuboid[{0, 0}, {1, 1}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Rectangle 是 Cuboid 的特殊情形：

Wolfram Language code: Subscript[ℛ, 1] = Rectangle[{0, 0}, {1, 1}]; Subscript[ℛ, 2] = Cuboid[{0, 0}, {1, 1}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Hexahedron 是 Cuboid 的推广：

Wolfram Language code: Subscript[ℛ, 1] = Hexahedron[{{0, 0, 0}, {0, 1, 0}, {1, 1, 0}, {1, 0, 0}, {0, 0, 1}, {0, 1, 1}, {1, 1, 1}, {1, 0, 1}}]; Subscript[ℛ, 2] = Cuboid[{0, 0, 0}, {1, 1, 1}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegion 可以表示任何 Cuboid：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[0 ≤ Subscript[t, 1] ≤ 1 && 0 ≤ Subscript[t, 2] ≤ 1 && 0 ≤ Subscript[t, 3] ≤ 1, {Subscript[t, 1], Subscript[t, 2], Subscript[t, 3]}]; Subscript[ℛ, 2] = Cuboid[{0, 0, 0}, {1, 1, 1}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Parallelepiped 可以表示任何 Cuboid：

Wolfram Language code: Subscript[ℛ, 1] = Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {0, 2, 0}, {0, 0, 3}}]; Subscript[ℛ, 2] = Cuboid[{0, 0, 0}, {1, 2, 3}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Cuboid 是 -范数的范数球：

Wolfram Language code: ℛ = Cuboid[{-1, -1, -1}, {1, 1, 1}];
Wolfram Language code: Reduce[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}∈ℛ⧦Norm[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, ∞] ≤ 1, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, Reals]

巧妙范例  (3)

随机立方体的集合：

Wolfram Language code: Graphics3D[Table[{EdgeForm[Opacity[.3]], Hue[RandomReal[]], Cuboid[RandomReal[4, 3]]}, {40}]]

将立方体绕轴扫过：

Wolfram Language code: Graphics3D[{Opacity[0.3], EdgeForm[], Table[{ColorData["Rainbow"][Rescale[c, {0, 2Pi}]], GeometricTransformation[Cuboid[], RotationTransform[c, {-1, 2, -3}, {1.5, 0, 0}]]}, {c, 0, 2Pi, 2Pi / 12}]}]

用随机颜色的立方体组成的金字塔：

Wolfram Language code: Graphics3D[{EdgeForm[Opacity[.3]], Table[{Hue[RandomReal[], .8], Cuboid[{#[[1]], #[[2]], -n}]}& /@ Tuples[Range[-n, n], 2], {n, 0, 10}]}, Lighting -> "Neutral", Boxed -> False]
Wolfram Research (1991)，Cuboid，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Cuboid.html （更新于 2019 年）.

文本

Wolfram Research (1991)，Cuboid，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Cuboid.html （更新于 2019 年）.

CMS

Wolfram 语言. 1991. "Cuboid." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2019. https://reference.wolfram.com/language/ref/Cuboid.html.

APA

Wolfram 语言. (1991). Cuboid. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Cuboid.html 年

BibTeX

@misc{reference.wolfram_2026_cuboid, author="Wolfram Research", title="{Cuboid}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Cuboid.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_cuboid, organization={Wolfram Research}, title={Cuboid}, year={2019}, url={https://reference.wolfram.com/language/ref/Cuboid.html}, note=[Accessed: 17-August-2026]}