WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CylindricalDecomposition[expr,{x1,x2,…}]

文 expr で表される領域を連続する xiの方向に対応した円柱部分へと分割する．

CylindricalDecomposition[expr,{x1,x2,…},op]

文 expr で表される領域に位相操作 op を適用した結果の分解を求める．

CylindricalDecomposition[expr,{x1,x2,…},"Function"]

後の計算で使用できる結果をCylindricalDecompositionFunction[…][x1,x2,…]として表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
位相操作  
オプション  
Method  
WorkingPrecision  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

CylindricalDecomposition

CylindricalDecomposition[expr,{x1,x2,…}]

文 expr で表される領域を連続する xiの方向に対応した円柱部分へと分割する．

CylindricalDecomposition[expr,{x1,x2,…},op]

文 expr で表される領域に位相操作 op を適用した結果の分解を求める．

CylindricalDecomposition[expr,{x1,x2,…},"Function"]

後の計算で使用できる結果をCylindricalDecompositionFunction[…][x1,x2,…]として表す．

詳細とオプション

  • 文 expr は以下の任意の論理結合でよい．
  • lhs==rhs等式
    lhs!=rhs等式ではない
    lhs>rhs または lhs>=rhs 不等式
    CylindricalDecompositionFunction[…][x,y,…]円柱代数式
    ForAll[x,cond,expr]全称記号
    Exists[x,cond,expr]存在記号
  • 等式と不等式は，多項式，有理関数，実代数関数を含むことがある．
  • CylindricalDecompositionはすべての変数が実数であると仮定する．
  • CylindricalDecompositionは一般に上下限に代数関数を含むような不等式を返す．
  • 位相操作 op は次のいずれかである．
  • "Boundary"解集合の境界
    "Closure"解集合の閉包
    "Interior"解集合の内側
    "Exterior"解集合の外側
    "ClosureOfInterior"解集合の内側の閉包
    "InteriorOfClosure"解集合の閉包の内側
    "Components"解集合の連結成分
  • CylindricalDecompositionFunctionオブジェクトは，さらなる計算で効率的に使用できる半代数集合の明示的なコンパクト表現を提供する．
  • CylindricalDecompositionFunctionオブジェクトは，通常，集合のブール値の組合せの計算，追加の条件による集合の制限，一部の変数の削除，集合の最適化等，半代数集合を使用した繰り返しの計算に使用される．
  • x1,…,xnにおける円柱代数式は の形をしている．ただし，である．各 の形は または である．ただし と は，の解集合上で定義され連続代数関数である．上の の解集合 はセルと呼ばれる．セル とセル のへの写像は，任意の について，互いに素であるか同一であるかのどちらかである．
  • CylindricalDecompositionは，"Function"指定がなければ，等式と不等式の論理結合として明示的に書かれた円柱代数式を返す．
  • CylindricalDecompositionFunctionは，CylindricalDecompositionの入力として，あるいはReduce，Resolve，FindInstance，Solve，Minimize等のソルバとして使う際にしばしばより効率的な，円柱代数式のカプセル化表現を与える．
  • Normalは，CylindricalDecompositionFunctionオブジェクトを，等式と不等式の明示的な論理結合に変換する．
  • トポロジー操作と出力形式の指定は組み合せることができる．つまり，CylindricalDecomposition[ineqs,{x1,x2,…},"BoundaryFunction"]は，CylindricalDecompositionFunctionオブジェクトとして表された ineqs の解集合の境界を与える．

例題

すべて開く すべて閉じる

例  (2)

単位円板の円柱分解を求める：

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 < 1, {x, y}]

単位円板の境界の円柱分解を求める：

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 < 1, {x, y}, "Boundary"]

スコープ  (14)

基本的な用法  (9)

一変数多項式の場合，結果は区間からなる：

Wolfram Language code: CylindricalDecomposition[(x - 1)(x - 2) ^ 2(x - 3)(x - 4)(x - 5) > 0, x]
Wolfram Language code: Show[Plot[(x - 1)(x - 2) ^ 2(x - 3)(x - 4)(x - 5), {x, 0.5, 5.5}], Graphics[{Red, Point[{{1, 0}, {2, 0}, {3, 0}, {4, 0}, {5, 0}}]}]]
Wolfram Language code: NumberLinePlot[%%, {x, 0.5, 5.5}]

一般に，個々の点が現れる：

Wolfram Language code: CylindricalDecomposition[(x - 1)(x - 2) ^ 2(x - 3)(x - 4)(x - 5) ≥ 0, x]
Wolfram Language code: NumberLinePlot[%, {x, 0.5, 5.5}]

これは任意の論理結合の形でもある：

Wolfram Language code: CylindricalDecomposition[(x - 1)(x - 2) ≥ 0 && (x - 1 / 2)(x - 3 / 2) ≥ 0, x]
Wolfram Language code: NumberLinePlot[%, {x, 0, 3}]
Wolfram Language code: CylindricalDecomposition[Xor[(x - 1)(x - 2) ≥ 0, (x - 1 / 2)(x - 3 / 2) ≥ 0], x]
Wolfram Language code: NumberLinePlot[%, {x, 0, 3}]

多変数多項式の場合は，結果は円柱形 になる：

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 < 1, {x, y}]

一般に結果として複数の円柱が与えられる：

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 < 1 && y > x, {x, y}]

RegionPlotを使って個々の円柱をプロットする：

Wolfram Language code: {cyl1, cyl2} = List@@%;
Wolfram Language code: RegionPlot[{cyl1, cyl2}, {x, -1, 1}, {y, -1, 1}, PlotLegends -> "Expressions"]

変数の順序を変えると，円柱の形が になる：

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 < 1 && y > x, {y, x}]

それぞれの円柱をプロットする：

Wolfram Language code: {cyl1, cyl2} = List@@%;
Wolfram Language code: RegionPlot[{cyl1, cyl2}, {x, -1, 1}, {y, -1, 1}, PlotLegends -> "Expressions"]

次では，結果として次元が0，2，1の円柱が現れている：

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 ≤ 1 || x == 1, {x, y}]

三次元および四次元の分解：

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 + z ^ 2 < 1, {x, y, z}]
Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 + z ^ 2 + w ^ 2 < 1, {x, y, z, w}]

CylindricalDecompositionには定量化された式を使うことができる：

Wolfram Language code: CylindricalDecomposition[Exists[y, x ^ 2 + y ^ 2 < 1 && y > x], x]

係数には実代数的数を含めることができる：

Wolfram Language code: CylindricalDecomposition[Sqrt[2]x ^ 2 + Root[# ^ 5 - 2# - 11&, 1]y ^ 2 < 1, {x, y}]

係数には実厳密超越数を含めることができる：

Wolfram Language code: CylindricalDecomposition[E ^ Pi x ^ 2 + Pi ^ E y ^ 2 ≤ 77 && Log[2]x + Log[3]y == 2, {x, y}]

関数は実代数関数でよい：

Wolfram Language code: CylindricalDecomposition[Sqrt[x - y] ≤ Root[# ^ 3 - y # + x&, 1], {x, y}]

位相操作  (5)

解の領域とその境界の分解を求める：

Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}]
Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}, "Boundary"]

解の領域とその閉包の分解を求める：

Wolfram Language code: CylindricalDecomposition[x^4 > x^2 + y^2, {x, y}]
Wolfram Language code: CylindricalDecomposition[x^4 > x^2 + y^2, {x, y}, "Closure"]

解の領域とその内側の分解を求める：

Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}]
Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}, "Interior"]

解の領域とその外側の分解を求める：

Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}]
Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}, "Exterior"]

解の領域とその連結成分の分解を求める：

Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}]
Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}, "Components"]

オプション  (2)

Method  (1)

以下は，"InequalitySolvingOptions"グループのシステムオプションをローカルに設定する：

Wolfram Language code: CylindricalDecomposition[46 v ^ 2 + 42 u w + 28 u x + 64 v y + 68 u z - 66 w z ≤ 21, {x, y, z, u, v, w}, Method -> {"CADConstruction" -> "LocalProjection"}];//AbsoluteTiming

自動的メソッドによる選択ヒューリスティックは，ここではより低速の"GlobalProjection"を選択する：

Wolfram Language code: CylindricalDecomposition[46 v ^ 2 + 42 u w + 28 u x + 64 v y + 68 u z - 66 w z ≤ 21, {x, y, z, u, v, w}];//AbsoluteTiming

WorkingPrecision  (1)

次の計算は，数値係数の次数が高いため，非常に時間がかかる：

Wolfram Language code: TimeConstrained[CylindricalDecomposition[E x ^ 2 + Pi y ^ 2 + E ^ 77 z ^ 2 <= Pi ^ 33 && x ^ 3 - 9y ^ 3 + 7z ^ 3 >= 1, {x, y, z}, "Function"], 60]

WorkingPrecision->1000を使って分解を求めるが，結果が正しくない可能性がある：

Wolfram Language code: CylindricalDecomposition[E x ^ 2 + Pi y ^ 2 + E ^ 77 z ^ 2 <= Pi ^ 33 && x ^ 3 - 9y ^ 3 + 7z ^ 3 >= 1, {x, y, z}, "Function", WorkingPrecision -> 1000]//Timing

アプリケーション  (2)

代数曲線の連結成分を求める：

Wolfram Language code: CylindricalDecomposition[y^2 == x (-1 + x^4), {x, y}]
Wolfram Language code: CylindricalDecomposition[y^2 == x (-1 + x^4), {x, y}, "Components"]

領域の連結成分を求める：

Wolfram Language code: CylindricalDecomposition[(x^2 + y^2) (x (2 + x) + y^2) < 8 x y^2, {x, y}]
Wolfram Language code: CylindricalDecomposition[(x^2 + y^2) (x (2 + x) + y^2) < 8 x y^2, {x, y}, "Components"]

特性と関係  (8)

RegionPlotを使って2Dの半代数的集合を可視化する：

Wolfram Language code: RegionPlot[x ^ 2 + y ^ 2 < 1 && y > x, {x, -1, 1}, {y, -1, 1}]

RegionPlot3Dを使って3Dの半代数的集合を可視化する：

Wolfram Language code: RegionPlot3D[x ^ 2 + y ^ 2 + z ^ 2 < 1, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

Resolveは限定子を除去するので，円柱分解の計算を回避できるかもしれない：

Wolfram Language code: CylindricalDecomposition[Exists[z, x ^ 2 + y ^ 2 + z ^ 2 < 1 && y > x], {x, y}]
Wolfram Language code: Resolve[Exists[z, x ^ 2 + y ^ 2 + z ^ 2 < 1 && y > x]]

これに加え，Reduceは異なる領域と超越関数も扱う：

Wolfram Language code: Reduce[x ^ 2 - 2y ^ 2 == 1, {x, y}, Complexes]
Wolfram Language code: Reduce[x ^ 2 - 2y ^ 2 == 1 && x > 0 && y > 0, {x, y}, Reals]
Wolfram Language code: Reduce[x ^ 2 - 2y ^ 2 == 1 && x > 0 && y > 0, {x, y}, Integers]
Wolfram Language code: Reduce[Exp[x] - 2y == 1 && y == x + 1, {x, y}]

FindInstanceを使って方程式および不等式を満足する点を求める：

Wolfram Language code: FindInstance[x ^ 2 + y ^ 2 < 1, {x, y}, 5]
Wolfram Language code: x ^ 2 + y ^ 2 < 1 /. %

SemialgebraicComponentInstancesは各円柱のサンプル点を与える：

Wolfram Language code: SemialgebraicComponentInstances[x ^ 2 + y ^ 2 < 1, {x, y}]

CylindricalDecompositionはいくつかの円柱を組み合せてよりコンパクトに表示する：

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 < 1, {x, y}]

GenericCylindricalDecompositionは全次元の部分のみを計算する：

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 ≤ 1 || x == 1, {x, y}]
Wolfram Language code: GenericCylindricalDecomposition[x ^ 2 + y ^ 2 ≤ 1 || x == 1, {x, y}]

出力と入力は集合として等しい：

Wolfram Language code: set1 = x ^ 2 + y ^ 2 < 1 && y > x
Wolfram Language code: set2 = CylindricalDecomposition[set1, {x, y}]
Wolfram Language code: set3 = CylindricalDecomposition[set1, {y, x}]

点は同時に集合の内側または外側にある：

Wolfram Language code: {set1, set2, set3} /. {{x -> 1, y -> 1}, {x -> 0, y -> 1 / 2}}

考えられる問題  (2)

CylindricalDecompositionには，厳密な無限大精度の入力が必要である：

Wolfram Language code: CylindricalDecomposition[1.2x ^ 2 + 3.2y ^ 2 < 1.0, {x, y}]

Rationalizeは厳密ではない数を厳密な数に変換する：

Wolfram Language code: Rationalize[1.2x ^ 2 + 3.2y ^ 2 < 1.0, 0]
Wolfram Language code: CylindricalDecomposition[%, {x, y}]

一般に，出力はネストしたよりコンパクトな形になり得る：

Wolfram Language code: cd = CylindricalDecomposition[x ^ 2 + y ^ 2 + y ^ 2 <= 1 && x ^ 2 + 2y ^ 2 + 3z ^ 2 ≥ 4x y z + 1, {x, y, z}]

結果を平坦化して，不等式を分割せずに論理和標準形にする：

Wolfram Language code: ToDNF[e_Or] := ToDNF /@ e; ToDNF[And[a___, b_Or, c___]] := ToDNF[And[a, #, c]]& /@ b; ToDNF[e_] := e;
Wolfram Language code: ToDNF[cd]

おもしろい例題  (1)

半代数的な集合は極めて一般的である：

Wolfram Language code: disk[{x0_, y0_}, r_] := (x - x0) ^ 2 + (y - y0) ^ 2 < r ^ 2
Wolfram Language code: disk[{-7 / 4, 9 / 4}, 1 / 3] || disk[{9 / 4, 9 / 4}, 1 / 3] || (disk[{0, 0}, 5] && !disk[{2, 2}, 1] && !disk[{-2, 2}, 1] && (!disk[{0, -1}, Sqrt[5]] || disk[{0, 1}, 3]))
Wolfram Language code: RegionPlot[%, {x, -5, 5}, {y, -5, 5}]
Wolfram Research (2003), CylindricalDecomposition, Wolfram言語関数， https://reference.wolfram.com/language/ref/CylindricalDecomposition.html （2020年に更新）.

テキスト

Wolfram Research (2003), CylindricalDecomposition, Wolfram言語関数， https://reference.wolfram.com/language/ref/CylindricalDecomposition.html （2020年に更新）.

CMS

Wolfram Language. 2003. "CylindricalDecomposition." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/CylindricalDecomposition.html.

APA

Wolfram Language. (2003). CylindricalDecomposition. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CylindricalDecomposition.html

BibTeX

@misc{reference.wolfram_2026_cylindricaldecomposition, author="Wolfram Research", title="{CylindricalDecomposition}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/CylindricalDecomposition.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cylindricaldecomposition, organization={Wolfram Research}, title={CylindricalDecomposition}, year={2020}, url={https://reference.wolfram.com/language/ref/CylindricalDecomposition.html}, note=[Accessed: 08-September-2026]}