WOLFRAM

Wolfram 语言与系统参考资料中心

CylindricalDecomposition[expr,{x1,x2,…}]

将由语句 expr 表示的区域分解为圆柱分量，其方向依次对应于 xi.

CylindricalDecomposition[expr,{x1,x2,…},op]

求对由语句 expr 表示的区域应用拓扑运算的结果的分解.

CylindricalDecomposition[expr,{x1,x2,…},"Function"]

将结果表示为 CylindricalDecompositionFunction[…][x1,x2,…]，以便有效运用于以后的计算中.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用途  
拓扑运算  
选项  
Method  
WorkingPrecision  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

CylindricalDecomposition

CylindricalDecomposition[expr,{x1,x2,…}]

将由语句 expr 表示的区域分解为圆柱分量，其方向依次对应于 xi.

CylindricalDecomposition[expr,{x1,x2,…},op]

求对由语句 expr 表示的区域应用拓扑运算的结果的分解.

CylindricalDecomposition[expr,{x1,x2,…},"Function"]

将结果表示为 CylindricalDecompositionFunction[…][x1,x2,…]，以便有效运用于以后的计算中.

更多信息和选项

  • 语句 expr 可以是以下内容的逻辑组合：
  • lhs==rhs等式
    lhs!=rhs非等式
    lhs>rhs 或 lhs>=rhs 不等式
    CylindricalDecompositionFunction[…][x,y,…]圆柱代数公式
    ForAll[x,cond,expr]通用量词
    Exists[x,cond,expr]存在量词
  • 等式和不等式可涉及多项式、有理函数或实代数函数.
  • CylindricalDecomposition 假定所有的变量都是实数.
  • CylindricalDecomposition 返回不等式，其边界通常包含代数函数.
  • 拓扑运算 op 可以是下列任何一种：
  • "Boundary"解集的边界
    "Closure"解集的闭包
    "Interior"解集的内部
    "Exterior"解集的外部
    "ClosureOfInterior"解集内部的闭包
    "InteriorOfClosure"解集闭包的内部
    "Components"解集的连通分量
  • CylindricalDecompositionFunction 对象提供半代数集的显式紧凑表示，可有效运用于以后的计算中.
  • CylindricalDecompositionFunction 对象通常用于半代数集的重复计算，包括计算集合的布尔组合，用附加条件限制集合，消除一些变量或优化集合.
  • 含有 x1,…,xn 的圆柱代数公式的形式为 ，其中 . 每个 的形式为 或 ，其中 和 是在解集 上定义并连续的代数函数. 中的 的解集 被称为 cell. 当 时，cell 和 在 上的投影要么不相交，要么相同.
  • 如果没有指定 "Function"，CylindricalDecomposition 返回以等式或不等式的布尔组合给出的圆柱代数公式.
  • CylindricalDecompositionFunction 给出圆柱代数公式的压缩 (encapsulated) 表示，当用于 CylindricalDecomposition 的输入时，或用于如 Reduce、Resolve、FindInstance、Solve 或 Minimize 这样的求解器时会更加高效.
  • Normal 将 CylindricalDecompositionFunction 对象转换成等式或不等式的布尔组合.
  • 可将拓扑运算的指定和输出格式组合在一起，如 CylindricalDecomposition[ineqs,{x1,x2,…},"BoundaryFunction"] 给出了解集的边界，并将解集 ineqs 表示为 CylindricalDecompositionFunction 对象.

范例

打开所有单元 关闭所有单元

基本范例  (2)

找出单位盘的柱形分解：

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 < 1, {x, y}]

找到单位圆盘边界的圆柱分解：

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 < 1, {x, y}, "Boundary"]

范围  (14)

基本用途  (9)

对于单变量多项式结果由区间组成：

Wolfram Language code: CylindricalDecomposition[(x - 1)(x - 2) ^ 2(x - 3)(x - 4)(x - 5) > 0, x]
Wolfram Language code: Show[Plot[(x - 1)(x - 2) ^ 2(x - 3)(x - 4)(x - 5), {x, 0.5, 5.5}], Graphics[{Red, Point[{{1, 0}, {2, 0}, {3, 0}, {4, 0}, {5, 0}}]}]]
Wolfram Language code: NumberLinePlot[%%, {x, 0.5, 5.5}]

通常会出现单点：

Wolfram Language code: CylindricalDecomposition[(x - 1)(x - 2) ^ 2(x - 3)(x - 4)(x - 5) ≥ 0, x]
Wolfram Language code: NumberLinePlot[%, {x, 0.5, 5.5}]

这也可以是任何逻辑组合的形式：

Wolfram Language code: CylindricalDecomposition[(x - 1)(x - 2) ≥ 0 && (x - 1 / 2)(x - 3 / 2) ≥ 0, x]
Wolfram Language code: NumberLinePlot[%, {x, 0, 3}]
Wolfram Language code: CylindricalDecomposition[Xor[(x - 1)(x - 2) ≥ 0, (x - 1 / 2)(x - 3 / 2) ≥ 0], x]
Wolfram Language code: NumberLinePlot[%, {x, 0, 3}]

对于多变量多项式，结果为柱形 :

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 < 1, {x, y}]

通常将生成若干柱形:

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 < 1 && y > x, {x, y}]

利用 RegionPlot 绘制各个柱形：

Wolfram Language code: {cyl1, cyl2} = List@@%;
Wolfram Language code: RegionPlot[{cyl1, cyl2}, {x, -1, 1}, {y, -1, 1}, PlotLegends -> "Expressions"]

通过变换变量的顺序，柱形采取形式 ：

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 < 1 && y > x, {y, x}]

绘制各个柱形：

Wolfram Language code: {cyl1, cyl2} = List@@%;
Wolfram Language code: RegionPlot[{cyl1, cyl2}, {x, -1, 1}, {y, -1, 1}, PlotLegends -> "Expressions"]

这里维数为 0、2 和 1 的柱形出现在结果中：

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 ≤ 1 || x == 1, {x, y}]

三维和四维分解：

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 + z ^ 2 < 1, {x, y, z}]
Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 + z ^ 2 + w ^ 2 < 1, {x, y, z, w}]

CylindricalDecomposition 接受量化的公式：

Wolfram Language code: CylindricalDecomposition[Exists[y, x ^ 2 + y ^ 2 < 1 && y > x], x]

系数可以包括实代数数：

Wolfram Language code: CylindricalDecomposition[Sqrt[2]x ^ 2 + Root[# ^ 5 - 2# - 11&, 1]y ^ 2 < 1, {x, y}]

系数可以包括精确的超越实数：

Wolfram Language code: CylindricalDecomposition[E ^ Pi x ^ 2 + Pi ^ E y ^ 2 ≤ 77 && Log[2]x + Log[3]y == 2, {x, y}]

函数可以是实代数的：

Wolfram Language code: CylindricalDecomposition[Sqrt[x - y] ≤ Root[# ^ 3 - y # + x&, 1], {x, y}]

拓扑运算  (5)

求解的区域及其边界的分解：

Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}]
Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}, "Boundary"]

求解的区域及其闭包的分解：

Wolfram Language code: CylindricalDecomposition[x^4 > x^2 + y^2, {x, y}]
Wolfram Language code: CylindricalDecomposition[x^4 > x^2 + y^2, {x, y}, "Closure"]

求解的区域及其内部的分解：

Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}]
Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}, "Interior"]

求解的区域及其外部的分解：

Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}]
Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}, "Exterior"]

求解的区域及其连通分量的分解；

Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}]
Wolfram Language code: CylindricalDecomposition[x^4 ≥ x^2 + y^2, {x, y}, "Components"]

选项  (2)

Method  (1)

下面在本地设置 "InequalitySolvingOptions" 中的系统选项：

Wolfram Language code: CylindricalDecomposition[46 v ^ 2 + 42 u w + 28 u x + 64 v y + 68 u z - 66 w z ≤ 21, {x, y, z, u, v, w}, Method -> {"CADConstruction" -> "LocalProjection"}];//AbsoluteTiming

自动选择的方法“启发式”会选用 "GlobalProjection"，计算速度较慢：

Wolfram Language code: CylindricalDecomposition[46 v ^ 2 + 42 u w + 28 u x + 64 v y + 68 u z - 66 w z ≤ 21, {x, y, z, u, v, w}];//AbsoluteTiming

WorkingPrecision  (1)

由于包含的代数数的高次方，这项计算将需要较长时间：

Wolfram Language code: TimeConstrained[CylindricalDecomposition[E x ^ 2 + Pi y ^ 2 + E ^ 77 z ^ 2 <= Pi ^ 33 && x ^ 3 - 9y ^ 3 + 7z ^ 3 >= 1, {x, y, z}, "Function"], 60]

下面用 WorkingPrecision->1000, 得出一个分解，但结果可能是不正确的：

Wolfram Language code: CylindricalDecomposition[E x ^ 2 + Pi y ^ 2 + E ^ 77 z ^ 2 <= Pi ^ 33 && x ^ 3 - 9y ^ 3 + 7z ^ 3 >= 1, {x, y, z}, "Function", WorkingPrecision -> 1000]//Timing

应用  (2)

求代数曲线的连接分量：

Wolfram Language code: CylindricalDecomposition[y^2 == x (-1 + x^4), {x, y}]
Wolfram Language code: CylindricalDecomposition[y^2 == x (-1 + x^4), {x, y}, "Components"]

求区域的连通分量：

Wolfram Language code: CylindricalDecomposition[(x^2 + y^2) (x (2 + x) + y^2) < 8 x y^2, {x, y}]
Wolfram Language code: CylindricalDecomposition[(x^2 + y^2) (x (2 + x) + y^2) < 8 x y^2, {x, y}, "Components"]

属性和关系  (8)

利用 RegionPlot 图形显示二维半代数集：

Wolfram Language code: RegionPlot[x ^ 2 + y ^ 2 < 1 && y > x, {x, -1, 1}, {y, -1, 1}]

利用 RegionPlot3D 图形显示三维半代数集：

Wolfram Language code: RegionPlot3D[x ^ 2 + y ^ 2 + z ^ 2 < 1, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

Resolve 完成量词消去，并且可以避免计算柱形分解:

Wolfram Language code: CylindricalDecomposition[Exists[z, x ^ 2 + y ^ 2 + z ^ 2 < 1 && y > x], {x, y}]
Wolfram Language code: Resolve[Exists[z, x ^ 2 + y ^ 2 + z ^ 2 < 1 && y > x]]

Reduce 也处理不同的定义域和超越函数：

Wolfram Language code: Reduce[x ^ 2 - 2y ^ 2 == 1, {x, y}, Complexes]
Wolfram Language code: Reduce[x ^ 2 - 2y ^ 2 == 1 && x > 0 && y > 0, {x, y}, Reals]
Wolfram Language code: Reduce[x ^ 2 - 2y ^ 2 == 1 && x > 0 && y > 0, {x, y}, Integers]
Wolfram Language code: Reduce[Exp[x] - 2y == 1 && y == x + 1, {x, y}]

利用 FindInstance 得出满足方程式和不等式的点：

Wolfram Language code: FindInstance[x ^ 2 + y ^ 2 < 1, {x, y}, 5]
Wolfram Language code: x ^ 2 + y ^ 2 < 1 /. %

SemialgebraicComponentInstances 将给出每一个柱体中的样本点：

Wolfram Language code: SemialgebraicComponentInstances[x ^ 2 + y ^ 2 < 1, {x, y}]

CylindricalDecomposition 合并若干柱体以得到更紧凑的表达式：

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 < 1, {x, y}]

GenericCylindricalDecomposition 将仅仅计算全维数部分:

Wolfram Language code: CylindricalDecomposition[x ^ 2 + y ^ 2 ≤ 1 || x == 1, {x, y}]
Wolfram Language code: GenericCylindricalDecomposition[x ^ 2 + y ^ 2 ≤ 1 || x == 1, {x, y}]

输出和输入作为集合是相等的：

Wolfram Language code: set1 = x ^ 2 + y ^ 2 < 1 && y > x
Wolfram Language code: set2 = CylindricalDecomposition[set1, {x, y}]
Wolfram Language code: set3 = CylindricalDecomposition[set1, {y, x}]

点同时出现在集合内或集合外：

Wolfram Language code: {set1, set2, set3} /. {{x -> 1, y -> 1}, {x -> 0, y -> 1 / 2}}

可能存在的问题  (2)

CylindricalDecomposition 需要精确的、无限精度的输入：

Wolfram Language code: CylindricalDecomposition[1.2x ^ 2 + 3.2y ^ 2 < 1.0, {x, y}]

Rationalize 将不精确的数字转换为精确的数字：

Wolfram Language code: Rationalize[1.2x ^ 2 + 3.2y ^ 2 < 1.0, 0]
Wolfram Language code: CylindricalDecomposition[%, {x, y}]

通常输出可以是更紧凑的嵌套形式:

Wolfram Language code: cd = CylindricalDecomposition[x ^ 2 + y ^ 2 + y ^ 2 <= 1 && x ^ 2 + 2y ^ 2 + 3z ^ 2 ≥ 4x y z + 1, {x, y, z}]

把结果展平成析取范式而不分离不等式：

Wolfram Language code: ToDNF[e_Or] := ToDNF /@ e; ToDNF[And[a___, b_Or, c___]] := ToDNF[And[a, #, c]]& /@ b; ToDNF[e_] := e;
Wolfram Language code: ToDNF[cd]

巧妙范例  (1)

半代数集是相当普通的:

Wolfram Language code: disk[{x0_, y0_}, r_] := (x - x0) ^ 2 + (y - y0) ^ 2 < r ^ 2
Wolfram Language code: disk[{-7 / 4, 9 / 4}, 1 / 3] || disk[{9 / 4, 9 / 4}, 1 / 3] || (disk[{0, 0}, 5] && !disk[{2, 2}, 1] && !disk[{-2, 2}, 1] && (!disk[{0, -1}, Sqrt[5]] || disk[{0, 1}, 3]))
Wolfram Language code: RegionPlot[%, {x, -5, 5}, {y, -5, 5}]
Wolfram Research (2003)，CylindricalDecomposition，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CylindricalDecomposition.html （更新于 2020 年）.

文本

Wolfram Research (2003)，CylindricalDecomposition，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CylindricalDecomposition.html （更新于 2020 年）.

CMS

Wolfram 语言. 2003. "CylindricalDecomposition." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2020. https://reference.wolfram.com/language/ref/CylindricalDecomposition.html.

APA

Wolfram 语言. (2003). CylindricalDecomposition. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CylindricalDecomposition.html 年

BibTeX

@misc{reference.wolfram_2026_cylindricaldecomposition, author="Wolfram Research", title="{CylindricalDecomposition}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/CylindricalDecomposition.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cylindricaldecomposition, organization={Wolfram Research}, title={CylindricalDecomposition}, year={2020}, url={https://reference.wolfram.com/language/ref/CylindricalDecomposition.html}, note=[Accessed: 04-September-2026]}