WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DateDistribution[dist,dscale,dorig]

日付の分布 dist を，日付スケール単位 dscale．日付の起点 dorig で表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
CalendarType  
TimeSystem  
TimeZone  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

DateDistribution

DateDistribution[dist,dscale,dorig]

日付の分布 dist を，日付スケール単位 dscale．日付の起点 dorig で表す．

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

連続した日付の分布を定義する：

Wolfram Language code: dd = DateDistribution[NormalDistribution[0, 3], "Days", DateObject[{2023, 11, 11, 12, 0, 0}]]

分布の平均を計算する：

Wolfram Language code: Mean[dd]

この分布からランダムな日付のシミュレーションを行う：

Wolfram Language code: RandomVariate[dd]

日付のリストのシミュレーションを行なって分布を可視化する：

Wolfram Language code: DateHistogram[RandomVariate[dd, 10 ^ 3], "Day"]

離散的な日付の分布を定義する：

Wolfram Language code: dd = DateDistribution[PoissonDistribution[3], "Years", Now]

分布の中央値を計算する：

Wolfram Language code: Median[dd]

この分布からのシミュレーションによるランダムな日付の粒度は年である：

Wolfram Language code: RandomVariate[dd]

日付のリストのシミュレーションを行なって，その分布を可視化する：

Wolfram Language code: DateHistogram[RandomVariate[dd, 10 ^ 3], "Year"]

スコープ  (5)

今日の午前零時から始まる日付の非対称分布を定義する：

Wolfram Language code: dd = DateDistribution[GammaDistribution[2, 3], "Hours", Today]

例のシミュレーションを行う：

Wolfram Language code: sim = RandomVariate[dd, 10 ^ 4];
Wolfram Language code: DateHistogram[sim, "Hour"]

日付の集合からDateDistributionを推定する：

Wolfram Language code: data = {...};
Wolfram Language code: MinMax[data]
Wolfram Language code: DateHistogram[data]

データのヒストグラムはベルの形をしているので，データに正規分布をフィットする：

Wolfram Language code: Clear[a, b]; EstimatedDistribution[data, NormalDistribution[a, b]]

DateDistributionの分布関数の引数は日付でなければならない：

Wolfram Language code: dd = DateDistribution[ParetoDistribution[2, .3], "Hours", DateObject[{2024, 4, 4}]]
Wolfram Language code: date = DateObject[{2024, 4, 10}];
Wolfram Language code: PDF[dd, date]
Wolfram Language code: CDF[dd, date]
Wolfram Language code: SurvivalFunction[dd, date]
Wolfram Language code: HazardFunction[dd, date]

DateDistributionの分布のモーメントを計算する：

Wolfram Language code: dd = DateDistribution[PoissonDistribution[12.1], "Days", DateObject[{2024, 3, 12}, "Day"]]
Wolfram Language code: {Mean[dd], Median[dd], Quantile[dd, .3]}
Wolfram Language code: {Variance[dd], StandardDeviation[dd], InterquartileRange[dd]}
Wolfram Language code: {Skewness[dd], Kurtosis[dd], QuartileSkewness[dd]}
Wolfram Language code: {CentralMoment[dd, 3], Cumulant[dd, 4]}

MomentとFactorialMomentは定義されていない：

Wolfram Language code: {Moment[dd, 3]//Head, FactorialMoment[dd, 2]//Head}

非パラメトリック分布を使ってDateDistributionを定義する：

Wolfram Language code: ExampleData[{"Statistics", "EarthquakeWaitingTimes"}, "LongDescription"]

起点の日付から重大な地震までの一連の時間データを作成する：

Wolfram Language code: data = Accumulate@ExampleData[{"Statistics", "EarthquakeWaitingTimes"}]

このデータの非パラメトリックモデルを作成する：

Wolfram Language code: dist = SmoothKernelDistribution[data]
Wolfram Language code: Plot[PDF[dist, x], {x, Min[data], Max[data]}]

このモデルを使って日付の分布を作成する：

Wolfram Language code: dd = DateDistribution[dist, "Days", DateObject[{1902, 12, 16}]]

サンプルのシミュレーションを行なって可視化する：

Wolfram Language code: sim = RandomVariate[dd, 10 ^ 3];
Wolfram Language code: DateHistogram[sim, "Years"]

オプション  (3)

CalendarType  (1)

CalendarTypeを指定すると日付の起点の入力が無効になる：

Wolfram Language code: orig = DateObject[{2024, 4, 4, 10, 0, 0}]
Wolfram Language code: orig["CalendarType"]
Wolfram Language code: DateDistribution[NormalDistribution[], "Hours", orig, CalendarType -> "Julian"]
Wolfram Language code: %["CalendarType"]

TimeSystem  (1)

TimeSystemを指定すると日付の起点の入力が無効になる：

Wolfram Language code: orig = DateObject[{2024, 4, 4, 10, 0, 0}]
Wolfram Language code: orig["TimeSystem"]
Wolfram Language code: DateDistribution[NormalDistribution[], "Hours", orig, TimeSystem -> "TAI"]
Wolfram Language code: %["TimeSystem"]

TimeZone  (1)

TimeZoneを指定すると日付の起点の入力が無効になる：

Wolfram Language code: orig = DateObject[{2024, 4, 4, 10, 0, 0}]
Wolfram Language code: orig["TimeZone"]
Wolfram Language code: DateDistribution[NormalDistribution[], "Hours", orig, TimeZone -> 0]
Wolfram Language code: %["TimeZone"]

アプリケーション  (1)

クラスの生徒が宿題を提出した日付のリスト：

Wolfram Language code: submissions = {...};

日付の分布を可視化する：

Wolfram Language code: dh = DateHistogram[submissions, 10, "Probability"]

GammaDistributionをデータにフィットする：

Wolfram Language code: Clear[a, b]; edist = EstimatedDistribution[submissions, GammaDistribution[a, b]]

1分刻みのPDFをプロットしてヒストグラムと比較する：

Wolfram Language code: Show[dh, DateListPlot[Table[{DateObject[{2024, 5, 1, 1, x}], PDF[edist, DateObject[{2024, 5, 1, 1, x}]]}, {x, 0, 7 * 24 * 60}]]]

特性と関係  (3)

DateDistributionの特性を抽出する：

Wolfram Language code: dd = DateDistribution[NormalDistribution[], "Hours", Sunset[]]
Wolfram Language code: Information[dd]

特性のリスト：

Wolfram Language code: props = dd["Properties"]
Wolfram Language code: TableForm[Map[dd[#]&, props], TableHeadings -> {props}]

離散的な日付分布の粒度は日付の尺度単位で与えられる：

Wolfram Language code: dist = DateDistribution[PoissonDistribution[4], "Month", Now]
Wolfram Language code: RandomVariate[dist]
Wolfram Language code: %["Granularity"]

連続的な日付分布の粒度は常に"Instant"である：

Wolfram Language code: dist = DateDistribution[GammaDistribution[2, 3], "Months", Now]
Wolfram Language code: RandomVariate[dist]
Wolfram Language code: %["Granularity"]

考えられる問題  (2)

入力分布は有効な分布でなければならない：

Wolfram Language code: dist = NormalDistribution[0, -3];
Wolfram Language code: DateDistribution[dist, "Days"]

分布が有効かどうかをチェックする：

Wolfram Language code: DistributionParameterQ[dist]

有効な分布を作成する：

Wolfram Language code: dist2 = NormalDistribution[0, 3];
Wolfram Language code: DistributionParameterQ[dist2]
Wolfram Language code: DateDistribution[dist2, "Days"]

単位は有効な時間の単位でなければならない：

Wolfram Language code: DateDistribution[NormalDistribution[0, 3], "Grams", DateObject[{2023, 11, 11, 12, 0, 0}]];

単位が時間の単位かどうかをチェックする：

Wolfram Language code: UnitDimensions["Grams"]

時間の単位の場合：

Wolfram Language code: UnitDimensions["Seconds"]

第2引数を"Time"に設定してKnownUnitQを使うこともできる：

Wolfram Language code: KnownUnitQ["Seconds", "Time"]
Wolfram Research (2024), DateDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/DateDistribution.html.

テキスト

Wolfram Research (2024), DateDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/DateDistribution.html.

CMS

Wolfram Language. 2024. "DateDistribution." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DateDistribution.html.

APA

Wolfram Language. (2024). DateDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DateDistribution.html

BibTeX

@misc{reference.wolfram_2026_datedistribution, author="Wolfram Research", title="{DateDistribution}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/DateDistribution.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_datedistribution, organization={Wolfram Research}, title={DateDistribution}, year={2024}, url={https://reference.wolfram.com/language/ref/DateDistribution.html}, note=[Accessed: 09-September-2026]}