WOLFRAM

Wolfram 语言与系统参考资料中心

DateDistribution[dist,dunit,dorig]

表示日期分布 dist，其中，dunit 为日期尺度单位，dorig 为日期原点.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
CalendarType  
TimeSystem  
TimeZone  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

DateDistribution

DateDistribution[dist,dunit,dorig]

表示日期分布 dist，其中，dunit 为日期尺度单位，dorig 为日期原点.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

定义一个连续日期分布：

Wolfram Language code: dd = DateDistribution[NormalDistribution[0, 3], "Days", DateObject[{2023, 11, 11, 12, 0, 0}]]

计算分布的均值：

Wolfram Language code: Mean[dd]

根据此分布模拟随机日期：

Wolfram Language code: RandomVariate[dd]

模拟一组日期并可视化其分布：

Wolfram Language code: DateHistogram[RandomVariate[dd, 10 ^ 3], "Day"]

定义一个离散日期分布：

Wolfram Language code: dd = DateDistribution[PoissonDistribution[3], "Years", Now]

计算分布的中值：

Wolfram Language code: Median[dd]

该分布模拟的随机日期的粒度为年：

Wolfram Language code: RandomVariate[dd]

模拟一组日期并可视化其分布：

Wolfram Language code: DateHistogram[RandomVariate[dd, 10 ^ 3], "Year"]

范围  (5)

定义从今天午夜开始的非对称日期分布：

Wolfram Language code: dd = DateDistribution[GammaDistribution[2, 3], "Hours", Today]

模拟实例：

Wolfram Language code: sim = RandomVariate[dd, 10 ^ 4];
Wolfram Language code: DateHistogram[sim, "Hour"]

根据日期集合估计 DateDistribution：

Wolfram Language code: data = {...};
Wolfram Language code: MinMax[data]
Wolfram Language code: DateHistogram[data]

由于数据直方图是钟形的，因此对数据进行正态分布拟合：

Wolfram Language code: Clear[a, b]; EstimatedDistribution[data, NormalDistribution[a, b]]

DateDistribution 分布函数的参数必须是日期：

Wolfram Language code: dd = DateDistribution[ParetoDistribution[2, .3], "Hours", DateObject[{2024, 4, 4}]]
Wolfram Language code: date = DateObject[{2024, 4, 10}];
Wolfram Language code: PDF[dd, date]
Wolfram Language code: CDF[dd, date]
Wolfram Language code: SurvivalFunction[dd, date]
Wolfram Language code: HazardFunction[dd, date]

计算 DateDistribution 的分布矩：

Wolfram Language code: dd = DateDistribution[PoissonDistribution[12.1], "Days", DateObject[{2024, 3, 12}, "Day"]]
Wolfram Language code: {Mean[dd], Median[dd], Quantile[dd, .3]}
Wolfram Language code: {Variance[dd], StandardDeviation[dd], InterquartileRange[dd]}
Wolfram Language code: {Skewness[dd], Kurtosis[dd], QuartileSkewness[dd]}
Wolfram Language code: {CentralMoment[dd, 3], Cumulant[dd, 4]}

未定义 Moment 和 FactorialMoment：

Wolfram Language code: {Moment[dd, 3]//Head, FactorialMoment[dd, 2]//Head}

使用非参数分布定义 DateDistribution：

Wolfram Language code: ExampleData[{"Statistics", "EarthquakeWaitingTimes"}, "LongDescription"]

创建起始日期和强烈地震之间的时间序列数据：

Wolfram Language code: data = Accumulate@ExampleData[{"Statistics", "EarthquakeWaitingTimes"}]

创建数据的非参数模型：

Wolfram Language code: dist = SmoothKernelDistribution[data]
Wolfram Language code: Plot[PDF[dist, x], {x, Min[data], Max[data]}]

用模型创建日期分布：

Wolfram Language code: dd = DateDistribution[dist, "Days", DateObject[{1902, 12, 16}]]

模拟并可视化样本：

Wolfram Language code: sim = RandomVariate[dd, 10 ^ 3];
Wolfram Language code: DateHistogram[sim, "Years"]

选项  (3)

CalendarType  (1)

指定 CalendarType 将覆盖原来输入的日期的类型：

Wolfram Language code: orig = DateObject[{2024, 4, 4, 10, 0, 0}]
Wolfram Language code: orig["CalendarType"]
Wolfram Language code: DateDistribution[NormalDistribution[], "Hours", orig, CalendarType -> "Julian"]
Wolfram Language code: %["CalendarType"]

TimeSystem  (1)

指定 TimeSystem 将覆盖原来输入的日期：

Wolfram Language code: orig = DateObject[{2024, 4, 4, 10, 0, 0}]
Wolfram Language code: orig["TimeSystem"]
Wolfram Language code: DateDistribution[NormalDistribution[], "Hours", orig, TimeSystem -> "TAI"]
Wolfram Language code: %["TimeSystem"]

TimeZone  (1)

指定 TimeZone 将覆盖原来输入的日期：

Wolfram Language code: orig = DateObject[{2024, 4, 4, 10, 0, 0}]
Wolfram Language code: orig["TimeZone"]
Wolfram Language code: DateDistribution[NormalDistribution[], "Hours", orig, TimeZone -> 0]
Wolfram Language code: %["TimeZone"]

应用  (1)

班级学生提交作业的日期列表：

Wolfram Language code: submissions = {...};

可视化该日期分布：

Wolfram Language code: dh = DateHistogram[submissions, 10, "Probability"]

将 GammaDistribution 拟合到日期：

Wolfram Language code: Clear[a, b]; edist = EstimatedDistribution[submissions, GammaDistribution[a, b]]

以一分钟的步长绘制 PDF 并与直方图进行比较：

Wolfram Language code: Show[dh, DateListPlot[Table[{DateObject[{2024, 5, 1, 1, x}], PDF[edist, DateObject[{2024, 5, 1, 1, x}]]}, {x, 0, 7 * 24 * 60}]]]

属性和关系  (3)

提取 DateDistribution 的属性：

Wolfram Language code: dd = DateDistribution[NormalDistribution[], "Hours", Sunset[]]
Wolfram Language code: Information[dd]

属性列表：

Wolfram Language code: props = dd["Properties"]
Wolfram Language code: TableForm[Map[dd[#]&, props], TableHeadings -> {props}]

离散日期分布的粒度由日期尺度单位给出：

Wolfram Language code: dist = DateDistribution[PoissonDistribution[4], "Month", Now]
Wolfram Language code: RandomVariate[dist]
Wolfram Language code: %["Granularity"]

连续日期分布的粒度始终是 "Instant"：

Wolfram Language code: dist = DateDistribution[GammaDistribution[2, 3], "Months", Now]
Wolfram Language code: RandomVariate[dist]
Wolfram Language code: %["Granularity"]

可能存在的问题  (2)

输入分布必须是有效分布：

Wolfram Language code: dist = NormalDistribution[0, -3];
Wolfram Language code: DateDistribution[dist, "Days"]

检查分布是否有效：

Wolfram Language code: DistributionParameterQ[dist]

创建有效分布：

Wolfram Language code: dist2 = NormalDistribution[0, 3];
Wolfram Language code: DistributionParameterQ[dist2]
Wolfram Language code: DateDistribution[dist2, "Days"]

单位必须是有效的时间单位：

Wolfram Language code: DateDistribution[NormalDistribution[0, 3], "Grams", DateObject[{2023, 11, 11, 12, 0, 0}]];

检查单位是否是时间单位：

Wolfram Language code: UnitDimensions["Grams"]

对于时间单位：

Wolfram Language code: UnitDimensions["Seconds"]

或使用 KnownUnitQ，将第二个参数设置为 "Time"：

Wolfram Language code: KnownUnitQ["Seconds", "Time"]
Wolfram Research (2024)，DateDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DateDistribution.html.

文本

Wolfram Research (2024)，DateDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DateDistribution.html.

CMS

Wolfram 语言. 2024. "DateDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DateDistribution.html.

APA

Wolfram 语言. (2024). DateDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DateDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_datedistribution, author="Wolfram Research", title="{DateDistribution}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/DateDistribution.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_datedistribution, organization={Wolfram Research}, title={DateDistribution}, year={2024}, url={https://reference.wolfram.com/language/ref/DateDistribution.html}, note=[Accessed: 14-September-2026]}