WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DatePlus[date,n]

date の n 日後の日付を返す．

DatePlus[date,{n,step}]

date の n 暦刻み後の日付を返す．

DatePlus[date,{{n1,step1},{n2,step2},…}]

各指定サイズの ni刻み幅をオフセットとする日付を返す．

DatePlus[n]

現行の日付から n 日後の日付を返す．

DatePlus[offset]

現行の日付から指定のオフセットの日付を返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
日付形式  
増分  
オプション  
CalendarType  
HolidayCalendar  
Method  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

DatePlus

DatePlus[date,n]

date の n 日後の日付を返す．

DatePlus[date,{n,step}]

date の n 暦刻み後の日付を返す．

DatePlus[date,{{n1,step1},{n2,step2},…}]

各指定サイズの ni刻み幅をオフセットとする日付を返す．

DatePlus[n]

現行の日付から n 日後の日付を返す．

DatePlus[offset]

現行の日付から指定のオフセットの日付を返す．

詳細とオプション

  • DatePlusは，物理的な期間または暦のステップ数として与えられた任意の時間量分日付をシフトする．
  • DatePlus[date,-n]は，date の n 日前の日付を返す．
  • 日付は以下の形式で指定できる．
  • DateObject[…]日付オブジェクト
    {y,m,d}年，月，日
    {y,m}指定した月の第1日
    {y}y 年の1月1日
    "string"文字列としての日付 ("Jan. 1, 2000")
    {y,m,d,h,m,s}厳密な時間
    time絶対時間指定
  • 使用可能な刻み幅は"Year"，"Quarter"，"Month"，"Week"，"Day"，"Hour"，"Minute"，"Second"，"Weekday"，"Weekend"，MondayからSundayまで，"EndOfMonth"，"BeginningOfMonth"，"BusinessDay"の暦刻みと日付タイプである．
  • オフセットはQuantityのフレームワークを使って指定することができる．
  • {y,m,d}は{y,m,d,0,0,0}等と等しいとみなされる．
  • DatePlus[date,offset]は，date と同じ一般的な形式の結果を返す．
  • date がリストのとき，結果は date と同じ長さで，offset の最小ステップを含むように拡張されることもある． »
  • date が文字列のとき，結果は$DateStringFormatで指定された形式になる．
  • DatePlusが取り得るオプション
  • CalendarType "Gregorian"日付が指定された暦
    HolidayCalendar Automatic休日のスケジュールおよび営業日と非営業日の計算のための部分指定
    Method Automatic使用する日付の計算法
  • 変数の期間（例："Month"）を伴う追加の時間ステップについては，日付の計算はステップを物理的な期間に変換する（連続計算）かすべてを離散的な暦のステップとして扱う（離散計算）かする．
  • オプション値Method"Continuous"は連続計算を実装する．離散計算はMethodrolling で実装される．この際使用可能なオプションには "RollForward"，"RollBackward"，"RollOver"がある．デフォルトは"RollBackward"である．
  • 離散計算の場合，例えば1ヶ月を加えると存在しない日（例：February 30）になる可能性がある．そのような場合に日付を解決するオプションには以下の3つがある．
  • "RollBackward"既存の最終日付(Feb 28)まで戻る
    "RollForward"次の既存の日付(Mar 1)まで進む
    "RollOver"次の既存の日付(Mar …)から増分する

例題

すべて開く すべて閉じる

例  (6)

2017年1月1日に35日加える：

Wolfram Language code: DatePlus[DateObject[{2022, 1, 1}, "Day"], 35]

日付文字列を入力として使う：

Wolfram Language code: DatePlus["Jan. 1, 2022", 35]

日付から35日引く：

Wolfram Language code: DatePlus[DateObject[{2022, 1, 1}, "Day"], -35]

日付に14週加える：

Wolfram Language code: DatePlus[DateObject[{2022, 1, 1}, "Day"], Quantity[14, "Weeks"]]

現在の日付に34日加える：

Wolfram Language code: DatePlus[34]

現在から1か月後の日付を取得する：

Wolfram Language code: DatePlus[Quantity[1, "Month"]]

スコープ  (13)

日付形式  (5)

DatePlusはDateListにおける標準的な{y,m,d,h,m,s}形式の日付を取る：

Wolfram Language code: DatePlus[{2022, 1, 6, 17, 44}, 15]

DatePlusはDateStringがサポートしている任意の形式の日付を取る：

Wolfram Language code: DatePlus["Jan. 1, 2022 06:17:44", 15]
Wolfram Language code: DatePlus["1/1/2022 06:17:44", 15]

日付が{y,m,d}で与えられた場合，DatePlusは同じ形式で返す：

Wolfram Language code: DatePlus[{2022, 1, 1}, 15]

{y,m}は指定された月の第1日として解釈される：

Wolfram Language code: DatePlus[{2022, 1}, 15]

{y}は指定された年の1月1日として解釈される：

Wolfram Language code: DatePlus[{2022}, 15]

増分  (8)

日付に10ヶ月加える：

Wolfram Language code: DatePlus[DateObject[{2022, 1, 1}, "Day"], Quantity[10, "Months"]]

日付に40週加える：

Wolfram Language code: DatePlus[DateObject[{2022, 1, 1}, "Day"], Quantity[40, "Weeks"]]

7週と2日加える：

Wolfram Language code: DatePlus[DateObject[{2022, 1, 1}, "Day"], {{7, "Week"}, {2, "Day"}}]

日付のリストに1年加える：

Wolfram Language code: DatePlus[DateObject[{2022, 1, 1}, "Day"], {1, "Year"}]

指定の日付に1ヶ月と15日加える：

Wolfram Language code: DatePlus[DateObject[{1990, 2, 3, 1, 12, 0.}, "Instant", "Gregorian", -6.], {{1, "Month"}, {15, "Day"}}]

増分指定には数量の枠組みを使うことができる：

Wolfram Language code: DatePlus[{2022, 2, 3, 1, 12, 0}, Quantity[3, "Months"]]

2.45日加える：

Wolfram Language code: DatePlus[DateObject[{2022, 1, 1, 6, 17, 44}, "Instant", "Gregorian", -5.], 2.45]

4.6時間引く：

Wolfram Language code: DatePlus[DateObject[{2022, 1, 1, 6, 17, 44}, "Instant", "Gregorian", -5.], {-4.6, "Hour"}]

オプション  (7)

CalendarType  (2)

ユダヤ暦で先の日付を得る：

Wolfram Language code: DatePlus[{5373, 4, 3}, {4, "Week"}, CalendarType -> "Jewish"]

イスラム暦の年はグレゴリオ歴の年より短い：

Wolfram Language code: CurrentDate["Day", CalendarType -> "Islamic"]
Wolfram Language code: DatePlus[%, 365]

HolidayCalendar  (2)

異なる国の250営業日先の日付を比べる：

Wolfram Language code: Table[DatePlus[{2022}, {250, "BusinessDay"}, HolidayCalendar -> i], {i, {"China", "UnitedStates"}}]

同じ国内でも市場によって休日のスケジュールが異なることがある：

Wolfram Language code: Table[DatePlus[DateObject[{2022, 4, 1}, "Day"], {30, "BusinessDay"}, HolidayCalendar -> {"UnitedStates", i}], {i, CalendarData["UnitedStates"]}]

Method  (3)

デフォルトで，5月31日に1ヶ月加えると6月30日になる：

Wolfram Language code: DatePlus[DateObject[{2012, 5, 31}, "Day"], "Month"]

Method"RollForward"とすると次の有効な日付の7月1日になる：

Wolfram Language code: DatePlus[DateObject[{2012, 5, 31}, "Day"], "Month", Method -> "RollForward"]

DatePlus[date,"Year"]は年に応じて365日あるいは366日前に進む：

Wolfram Language code: With[{start = DateObject[{2020, 8, 25}]}, DateDifference[start, DatePlus[start, "Year"]] ]
Wolfram Language code: With[{start = DateObject[{2019, 8, 25}]}, DateDifference[start, DatePlus[start, "Year"]] ]

Quantity[1,"Years"]はQuantityフレームワークの中のQuantity[365,"Days"]に等しい：

Wolfram Language code: UnitConvert[Quantity[1, "Years"], "Days"]

したがって，Method"Continuous"は常に365日を加える：

Wolfram Language code: With[{start = DateObject[{2020, 8, 25}]}, DateDifference[start, DatePlus[start, "Year", Method -> "Continuous"]] ]
Wolfram Language code: With[{start = DateObject[{2019, 8, 25}]}, DateDifference[start, DatePlus[start, "Year", Method -> "Continuous"]] ]

2021年1月30日に1ヶ月加える際の計算法による結果の違いを比較する：

Wolfram Language code: DatePlus[DateObject[{2021, 1, 30, 0, 0, 0}], "Month", Method -> #]& /@ {"Continuous", "RollForward", "RollBackward", "RollOver"}

1月27日から2月1日までの計算法による結果の違いを比較する：

Wolfram Language code: range = DateRange[DateObject[{2021, 1, 27}], {2021, 2, 1}]; methods = {"RollForward", "RollBackward", "RollOver"}; TableForm[Outer[DatePlus[#, Quantity[1, "Months"], Method -> #2]&, range, methods], TableHeadings -> {range, methods}]

アプリケーション  (1)

2000年の初めから秒単位で10の累乗を加算する：

Wolfram Language code: date = DateObject[{2000, 1, 1, 0, 0, 0}]
Wolfram Language code: TableForm[Table[{Superscript[10, n], DatePlus[date, {10 ^ n, "Second"}]}, {n, 0, 12}], TableHeadings -> {None, {"Power", "Date"}}]

特性と関係  (2)

DatePlusは日付に暦刻みを加えるのに対しDateDifferenceは日付間の距離を計算する：

Wolfram Language code: DateDifference[{2022, 1}, {2022, 3}, "Month"]
Wolfram Language code: DatePlus[{2022, 1}, %]

逆の関係：

Wolfram Language code: DatePlus[{2022, 1}, {2, "Month"}]
Wolfram Language code: DateDifference[{2022, 1}, %, "Month"]

$DateStringFormatを使って日付の文字列のデフォルト形式を設定する：

Wolfram Language code: Block[{$DateStringFormat = {"Month", "/", "Day", "/", "Year"}}, DatePlus[DateString[], {4, "Month"}]]

考えられる問題  (3)

日付文字列は曖昧なことがある：

Wolfram Language code: DatePlus["2/4/22", 4]

DateListを使って解釈間の曖昧さを回避する：

Wolfram Language code: DatePlus[DateList[{"2/4/22", {"Day", "Month", "YearShort"}}], 4]

リストの増分が指定されたときは，最高次から低い方へと加えられる：

Wolfram Language code: DatePlus[DateObject[{2022, 2, 1}], {"Month", "Day"}]
Wolfram Language code: DatePlus[DateObject[{2022, 2, 1}], {{2, "Month"}, {2, "Day"}}]
Wolfram Language code: DatePlus[DateObject[{2022, 2, 1}], {{2, "Day"}, {2, "Month"}}]

月と年が可変長であるため，暦の単位が加えられる順序で算術演算の結果が変わることがある：

Wolfram Language code: Fold[DatePlus, DateObject[{2022, 2, 28}], {"Month", "Month", "Week", "Week"}]
Wolfram Language code: Fold[DatePlus, DateObject[{2022, 2, 28}], {"Month", "Week", "Month", "Week"}]
Wolfram Language code: Fold[DatePlus, DateObject[{2022, 2, 28}], {"Week", "Week", "Month", "Month"}]
Wolfram Research (2007), DatePlus, Wolfram言語関数， https://reference.wolfram.com/language/ref/DatePlus.html （2023年に更新）.

テキスト

Wolfram Research (2007), DatePlus, Wolfram言語関数， https://reference.wolfram.com/language/ref/DatePlus.html （2023年に更新）.

CMS

Wolfram Language. 2007. "DatePlus." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/DatePlus.html.

APA

Wolfram Language. (2007). DatePlus. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DatePlus.html

BibTeX

@misc{reference.wolfram_2026_dateplus, author="Wolfram Research", title="{DatePlus}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/DatePlus.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dateplus, organization={Wolfram Research}, title={DatePlus}, year={2023}, url={https://reference.wolfram.com/language/ref/DatePlus.html}, note=[Accessed: 04-September-2026]}