DiffusionPDETerm

DiffusionPDETerm[vars]

モデル変数 vars の拡散項を表す．

DiffusionPDETerm[vars,c]

拡散係数がの拡散項を表す．

DiffusionPDETerm[vars,c,pars]

モデルパラメータ pars を使う．

詳細

拡散は物理学における中心概念で，熱力学，音響学，構造力学，流体力学等，数多くの分野で使われている．
拡散は伝導としても知られている．
拡散係数がある拡散は，従属変数の勾配のみに駆動される平衡過程である．

DiffusionPDETermは，偏微分方程式の一部として使われる微分演算子項を返す．

DiffusionPDETermを使って，従属変数，独立変数，時間変数の拡散方程式がモデル化できる．
定常モデル変数 vars は vars={u[x₁,…,x_n],{x₁,…,x_n}}である．
時間依存モデル変数 vars は vars={u[t,x₁,…,x_n],{x₁,…,x_n}}または vars={u[t,x₁,…,x_n],t,{x₁,…,x_n}}である．
他のPDE項との関連における拡散項は以下で与えられる．

拡散の間，拡散が起こる媒体は静止したままであるのに対し，対流の場合は媒体が輸送機構となる．
拡散係数は次の形を持つことができる．

			スカラー，等方性拡散
	{c₁,…,c_n}		ベクトル，直交異方性拡散
	{{c₁₁,…,c_1n},…,{c_n1,…,c_nn}}		行列，異方性拡散

従属変数が{u₁,…,u_m}の偏微分方程式系についての拡散は以下を表す．

PDE項の系との関連における拡散項．

拡散係数はの形の階数4のテンソルである．各部分行列は単一の従属変数と同じ方法で指定できる行列である．
記号拡散係数はMatrixSymbolで指定できる． »
拡散係数は，時間，空間，パラメータ，従属変数に依存することがある．
次は，使用可能なパラメータ pars である．
パラメータデフォルトシンボル

"CoordinateChart" "Cartesian"

"RegionSymmetry" None
パラメータ"RegionSymmetry"の可能な選択肢には"Axisymmetric"がある．
"Axisymmetric"領域対称性は，以下のように角度変数を削除することで円柱座標が縮小された，切り取られた円柱座標系を表す．
次元縮小方程式

1D

2D
係数はNeumannValueの意味をもたらす．
与えられた独立変数に明示的に依存しないすべての数量の偏導関数は0であるとみなされる．

例題

すべて開くすべて閉じる

例 (6)

定常拡散項を定義する：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, 1]

項をアクティベートする：

Wolfram Language code: Activate[%]

パラメトリック拡散係数を置換して定常拡散項を定義する：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, κ, <|κ -> 1|>]

項をアクティブにする：

Wolfram Language code: Activate[%]

記号拡散項を定義する：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, {{κ[x]}}]

項をアクティブにする：

Wolfram Language code: Activate[%]

拡散項の固有値を求める：

Wolfram Language code: NDEigenvalues[DiffusionPDETerm[{u[x], {x}}], u, {x}∈Line[{{0}, {1}}], 3]

基本項で構築されたポアソン(Poisson)方程式を構築し，記号的に解く：

Wolfram Language code:

vars = {u[x, y], {x, y}};
DSolveValue[Activate[DiffusionPDETerm[vars] == SourcePDETerm[vars, 1]], u[x, y], {x, y}]

ガウスの初期条件がある時間依存拡散方程式を解く：

Wolfram Language code:

ufun = NDSolveValue[{D[u[t, x], t] + DiffusionPDETerm[{u[t, x], {x}}, 1] == 0, u[0, x] == Exp[-x ^ 2]}, u, {t, 0, 1}, {x, -π, π}]

初期条件が時間につれて平滑化される様子を可視化する：

Wolfram Language code: Plot[Evaluate[Table[ufun[t, x], {t, 0, 1, 0.25}]], {x, -π, π}, Rule[...]]

曲線の下の面積が一定であることを確認する：

Wolfram Language code: NIntegrate[ufun[0, x], {x, -π, π}] - NIntegrate[ufun[1, x], {x, -π, π}]

スコープ (36)

1D (6)

記号行列拡散項を定義する：

Wolfram Language code: DiffusionPDETerm[{u[t, x], {x}}, MatrixSymbol["c", {1, 1}]]

項をアクティブにする：

Wolfram Language code: Activate[%]

拡散項を指定しないと恒等行列係数になってしまう：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}]

時間依存拡散項を定義する：

Wolfram Language code: DiffusionPDETerm[{u[t, x], {x}}, {{1 + t}}]

項をアクティブにする：

Wolfram Language code: Activate[%]

パラメトリック拡散係数を置き換えて定常拡散項を定義する：

Wolfram Language code:

κ = MatrixSymbol["c", {1, 1}];
DiffusionPDETerm[{u[x], {x}}, κ, <|{κ -> {{1}}}|>]

項をアクティブにする：

Wolfram Language code: Activate[%]

固有値問題のモデル化にDiffusionPDETermを使う：

Wolfram Language code: NDEigensystem[DiffusionPDETerm[{u[x], {x}}, 1], u, {x, 0, 1}, 3]

DiffusionPDETermを使って1Dポアソン方程式を設定する：

Wolfram Language code: NDSolveValue[{DiffusionPDETerm[{u[x], {x}}, 1] == 1, DirichletCondition[u[x] == 0, True]}, u, {x, 0, 1}]

結果を可視化する：

Wolfram Language code: Plot[%[x], {x, 0, 1}]

1D線対称 (1)

1D軸対称拡散方程式を設定する：

Wolfram Language code: DiffusionPDETerm[{u[r], {r}}, 1, <|"RegionSymmetry" -> "Axisymmetric"|>]

これにActivateを適用する：

Wolfram Language code: Activate[%]

軸対称のケースは拡散方程式を構成する演算子を使って切り取られた円柱座標系を使った結果であることを確認する：

Wolfram Language code: Div[-1 * Grad[u[r], {r, θ, z}, "Cylindrical"], {r, θ, z}, "Cylindrical"]

2D (13)

2D定常拡散項を定義する：

Wolfram Language code: DiffusionPDETerm[{u[x, y], {x, y}}, 1]

項をアクティブにする：

Wolfram Language code: Activate[%]

拡散項を指定しないと恒等行列係数になってしまう：

Wolfram Language code: DiffusionPDETerm[{u[x, y], {x, y}}]

2D定常拡散方程式を設定する：

Wolfram Language code: DiffusionPDETerm[{u[x, y], {x, y}}, 1] == 0

項をアクティブにする：

Wolfram Language code: Activate[%]

記号行列拡散項を定義する：

Wolfram Language code: DiffusionPDETerm[{u[x, y], {x, y}}, MatrixSymbol["c", {2, 2}]]

項をアクティブにする：

Wolfram Language code: Activate[%]

2D時間依存拡散方程式を設定する：

Wolfram Language code: D[u[t, x, y]] + DiffusionPDETerm[{u[t, x, y], {x, y}}, 1] == 0

項をアクティブにする：

Wolfram Language code: Activate[%]

拡散ベクトル係数で2D直交異方性の定常拡散項を定義する：

Wolfram Language code: DiffusionPDETerm[{u[x, y], {x, y}}, {10, 20}]

異方性拡散行列で2D定常拡散項を定義する：

Wolfram Language code: DiffusionPDETerm[{u[x, y], {x, y}}, {{2, 1}, {0, 1}}]

異方性拡散行列で2D拡散項を定義する：

Wolfram Language code: DiffusionPDETerm[{u[t, x, y], t, {x, y}}, {{2, 1}, {0, 1}}]

DiffusionPDETermを使って2Dポアソン方程式を設定する：

Wolfram Language code:

NDSolveValue[{DiffusionPDETerm[{u[x, y], {x, y}}, 1] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Rectangle[]]

結果を可視化する：

Wolfram Language code: ContourPlot[%[x, y], {x, y}∈Rectangle[]]

基本的なPDE項からポアソン方程式を構築し，これを数値的に解く：

Wolfram Language code:

vars = {u[x, y], {x, y}};
NDSolveValue[{DiffusionPDETerm[vars] == SourcePDETerm[vars, 1], DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Disk[]]

結果を可視化する：

Wolfram Language code: Plot3D[%, {x, y}∈Disk[]]

方向の拡散定数の方が方向よりも大きいベクトル値拡散係数を使う：

Wolfram Language code:

NDSolveValue[{DiffusionPDETerm[{u[x, y], {x, y}}, {10, 1}] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Rectangle[]]

結果を可視化する：

Wolfram Language code: ContourPlot[%[x, y], {x, y}∈Rectangle[]]

方向の拡散定数の方が方向よりも大きいベクトル値拡散係数を使う：

Wolfram Language code:

NDSolveValue[{DiffusionPDETerm[{u[x, y], {x, y}}, {1, 10}] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Rectangle[]]

結果を可視化する：

Wolfram Language code: ContourPlot[%[x, y], {x, y}∈Rectangle[]]

異方性拡散係数を使う：

Wolfram Language code:

NDSolveValue[{DiffusionPDETerm[{u[x, y], {x, y}}, {{1, 1 / 2}, {1 / 2, 1}}] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Rectangle[]]

結果を可視化する：

Wolfram Language code: ContourPlot[%[x, y], {x, y}∈Rectangle[]]

2D線対称 (3)

2D軸対称性拡散方程式を設定する：

Wolfram Language code: DiffusionPDETerm[{u[r, z], {r, z}}, 1, <|"RegionSymmetry" -> "Axisymmetric"|>] == 0

これにActivateを適用する：

Wolfram Language code: Activate[%]

軸対称性のケースは，拡散方程式を構成する演算子を使って切り取られた円柱座標系を使った結果であることを確認する：

Wolfram Language code: Div[{{-1, 0, 0}, {0, -1, 0}, {0, 0, -1}}. Grad[u[r, z], {r, θ, z}, "Cylindrical"], {r, θ, z}, "Cylindrical"]

2D軸対称拡散方程式を設定する：

Wolfram Language code: DiffusionPDETerm[{u[r, z], {r, θ, z}}, 1, <|"RegionSymmetry" -> "Axisymmetric"|>]

これにActivateを適用する：

Wolfram Language code: Activate[%]

2D軸対称時間依存拡散方程式を設定する：

Wolfram Language code: D[u[t, r, z]] + DiffusionPDETerm[{u[t, r, z], {r, z}}, 1, <|"RegionSymmetry" -> "Axisymmetric"|>] == 0

これにActivateを適用する：

Wolfram Language code: Activate[%]

3D (1)

DiffusionPDETermを使って3Dポアソン方程式を設定する：

Wolfram Language code:

usol  = NDSolveValue[
	{DiffusionPDETerm[{u[x, y, z], {x, y, z}}, -1] == 1, 
	DirichletCondition[u[x, y, z] == x y z, True]}, u, {x, y, z}∈ Ball[]]

結果を可視化する：

Wolfram Language code: DensityPlot3D[usol[x, y, z], {x, y, z}∈Ball[], PlotLegends -> Automatic, AxesLabel -> Automatic]

座標チャート (3)

座標チャートを使用して拡散項を定義する：

Wolfram Language code: DiffusionPDETerm[{u[r, z], {r, z}}, 1, <|"CoordinateChart" -> "Polar"|>]

演算子をアクティブにする：

Wolfram Language code: Activate[%]

Laplacianと比較する：

Wolfram Language code: Laplacian[u[r, z], {r, z}, "Polar"]

極座標における拡散項の固有値および固有ベクトルを求める：

Wolfram Language code:

{vals, funs} = NDEigensystem[{DiffusionPDETerm[{u[r, θ], {r, θ}}, 1, <|"CoordinateChart" -> "Polar"|>], DirichletCondition[u[r, θ] == 0, r == π], PeriodicBoundaryCondition[u[r, θ], θ == -π && r < π, Function[X, X + {0, 2π}]]}, u, {r, θ}∈Rectangle[{0, -π}, {π, π}], 4]

ラプラス項の固有ベクトルを極座標で可視化する：

Wolfram Language code: RevolutionPlot3D[#[r, θ], {r, 0, π}, {θ, -π, π}, PlotRange -> All]& /@ funs

極座標のPDEを解く：

Wolfram Language code:

ifun = NDSolveValue[{DiffusionPDETerm[{u[r, θ], {r, θ}}, 1, <|"CoordinateChart" -> "Polar"|>] == 0, DirichletCondition[u[r, θ] == Sin[4 θ], r == π], DirichletCondition[u[r, θ] == 0, θ == -π || θ == π]}, u, {r, θ}∈Rectangle[{0, -π}, {π, π}]]

解を直交座標でプロットする：

Wolfram Language code: Plot3D[Evaluate[ifun[r, θ] /. {r -> Sqrt[x ^ 2 + y ^ 2], θ -> ArcTan[x, y]}], {x, y}∈Disk[{0, 0}, π]]

連結 (6)

複数の従属変数がある拡散項を定義する：

Wolfram Language code: DiffusionPDETerm[{{u[x], v[x]}, {x}}]

複数の従属変数がある拡散項を定義する：

Wolfram Language code: DiffusionPDETerm[{{u[x], v[x]}, {x}}, 1]

複数の従属変数と複数の拡散係数がある拡散項を定義する：

Wolfram Language code: DiffusionPDETerm[{{u[x], v[x]}, {x}}, {{Subscript[c, 11], Subscript[c, 12]}, {Subscript[c, 21], Subscript[c, 22]}}]

複数の従属変数と異方性拡散係数がある拡散項を定義する：

Wolfram Language code:

DiffusionPDETerm[{{u[x, y], v[x, y]}, {x, y}}, {{Subscript[c, 11], {Subscript[c, 1211], Subscript[c, 1222]}}, {0, {{Subscript[c, 2211], Subscript[c, 2212]}, {Subscript[c, 2221], Subscript[c, 2222]}}}}]

複数の従属変数とすべての係数が指定された拡散項を定義する：

Wolfram Language code: cIn = Array[Subscript[c, ##]&, {2, 2, 2, 2}]

Wolfram Language code: DiffusionPDETerm[{{u[x, y], v[x, y]}, {x, y}}, cIn]

非対角拡散係数は結合偏微分方程式においては可能である：

Wolfram Language code: MatrixForm[coefficients = {{{{1, 0}, {0, 1}}, {{0, 2}, {2, 0}}}, {{{0, 0}, {0, 0}}, {{1, 0}, {0, 1}}}}]

方程式を解く：

Wolfram Language code:

{uif, vif} = NDSolveValue[{DiffusionPDETerm[{{u[x, y], v[x, y]}, {x, y}}, coefficients] == {1, 1}, DirichletCondition[{u[x, y] == 0, v[x, y] == 0}, True]}, {u, v}, {x, y}∈Rectangle[]];

結果を可視化する：

Wolfram Language code: GraphicsRow[{ContourPlot[uif[x, y], {x, y}∈Rectangle[]], ContourPlot[vif[x, y], {x, y}∈Rectangle[]]}]

連結線対称 (3)

DiffusionPDETermを使って複数の従属変数を持つ1D軸対称方程式を設定する：

Wolfram Language code: eqn = DiffusionPDETerm[{{u[r], v[r]}, {r}}, {{2.4, 3}, {3, 3}}, <|"RegionSymmetry" -> "Axisymmetric"|>] == {1, 1}

境界条件を指定する：

Wolfram Language code: bcs = {u[0.1] == 200, v[0.1] == 200, u[0.5] == 50, v[0.5] == 5};

方程式を数値的に解く：

Wolfram Language code: {uif, vif} = NDSolveValue[{eqn, bcs}, {u, v}, {r, 0.1, 0.5}]

同じ方程式を記号的に解く：

Wolfram Language code: {fufun, fvfun} = DSolveValue[{eqn, bcs}, {u, v}, {r}]

両結果の差を可視化する：

Wolfram Language code: Plot[{fufun[r] - uif[r], fvfun[r] - vif[r]}, {r, 0.1, 0.5}, PlotLegends -> "Expressions", PlotRange -> All]

複数の従属変数を持つ軸対称拡散項を定義する：

Wolfram Language code: DiffusionPDETerm[{{u[r, z], v[r, z]}, {r, z}}, 1, <|"RegionSymmetry" -> "Axisymmetric"|>]

これにActivateを適用する：

Wolfram Language code: Activate[%]

複数の従属変数と複数の拡散係数を持つ2D拡散軸対称項を定義する：

Wolfram Language code:

MatrixForm[
	coefficients = {{{{25, 0}, {0, 25}}, {{0, 10}, {5, 0}}}, {{{0, 15}, {20, 0}}, {{50, 0}, {0, 25}}}}]

Wolfram Language code: coupledPDEs = DiffusionPDETerm[{{u[r, z], v[r, z]}, {r, z}}, coefficients, <|"RegionSymmetry" -> "Axisymmetric"|>];

連立偏微分方程式を解く：

Wolfram Language code:

{uif, vif} = NDSolveValue[{coupledPDEs == {1, 1}, DirichletCondition[{u[r, z] == 0, v[r, z] == 0}, z == 0]}, {u, v}, {r, z}∈Rectangle[]];

結果を可視化する：

Wolfram Language code: GraphicsRow[{ContourPlot[uif[r, z], {r, z}∈Rectangle[]], ContourPlot[vif[r, z], {r, z}∈Rectangle[]]}]

アプリケーション (9)

DiffusionPDETermを変数拡散係数と一緒に使う：

Wolfram Language code: model = DiffusionPDETerm[{u[x], {x}}, {{If[x ≤ 3 / 4, 1, 2]}}]

方程式を解く：

Wolfram Language code:

solution = NDSolveValue[{model == 0, DirichletCondition[u[x] == 1, x == 0], DirichletCondition[u[x] == 0, x == 1]}, u, {x, 0, 1}]

流束を計算する：

Wolfram Language code: flux = model /. Inactive[Div][flux_, _] :> Activate[flux]

結果を可視化する：

Wolfram Language code: Plot[Evaluate[{solution[x], flux /. u -> solution}], {x, 0, 1}, ...]

DiffusionPDETermと軸対称幾何学を使って伝導性熱伝達をモデル化する．

分析領域は2D領域である．直交座標で完全な2D領域を定義する代りに，1Dの切取り円柱座標で領域を定義することができる．この系は軸の周りで回転対称なので，円柱座標の変数とは消失する．

方程式を設定する：

Wolfram Language code: eqn = DiffusionPDETerm[{u[r], {r}}, 2.4, <|"RegionSymmetry" -> "Axisymmetric"|>] == 0

境界条件を指定する：

Wolfram Language code: bcs = {u[1 / 10] == 200, u[1 / 2] == 50};

方程式を解く：

Wolfram Language code: numericSolution = NDSolveValue[{eqn, bcs}, u, {r, 0.1, 0.5}]

DSolveValueで記号的に解くこともできる：

Wolfram Language code: analytocalSolution = DSolveValue[{eqn, bcs}, u, r]

結果間の差を可視化する：

Wolfram Language code: Plot[analytocalSolution[r] - numericSolution[r], {r, 0.1, 0.5}, PlotRange -> All]

DiffusionPDETermを使ってダムの下の種の拡散をモデル化する．領域を設定する：

Wolfram Language code:

Subscript[Ω, dam] = Rectangle[{6, 3}, {12, 18}];
Subscript[Ω, sediment] = RegionDifference[Rectangle[{0, 0}, {18, 6}], Subscript[Ω, dam]];

モデルを設定する：

Wolfram Language code: model = DiffusionPDETerm[{u[x, y], {x, y}}, 10 ^ -4]

方程式を解く：

Wolfram Language code:

solution = NDSolveValue[{model == 0, DirichletCondition[u[x, y] == 16, x ≤ 6 && y == 6], DirichletCondition[u[x, y] == 8, x ≥ 12 && y == 6]}, u, {x, y}∈Subscript[Ω, sediment]]

流束を計算する：

Wolfram Language code: flux = model /. Inactive[Div][flux_, _] :> Activate[flux]

結果を可視化する：

Wolfram Language code:

Show[
	..., 
	VectorPlot[Evaluate[flux /. u -> solution], {x, y}∈Subscript[Ω, sediment], Rule[...]]]

ダムの下の種の濃度を求める．モデルを構築する：

Wolfram Language code:

op = DiffusionPDETerm[{c[x, y], {x, y}}, 1] + ConvectionPDETerm[{c[x, y], {x, y}}, flux /. u -> solution] + 2 * 10 ^ -5c[x, y];

方程式を解く：

Wolfram Language code:

concentration = NDSolveValue[{op == 0, 
	DirichletCondition[c[x, y] == 100, x ≤ 6 && y == 6], DirichletCondition[c[x, y] == 50, x ≥ 12 && y == 6]
	}, c, {x, y}∈Subscript[Ω, sediment]]

種の濃度を可視化する：

Wolfram Language code:

Show[
	..., 
	ContourPlot[concentration[x, y], {x, y}∈Subscript[Ω, sediment], ...], 
	VectorPlot[Evaluate[flux /. u -> solution], {x, y}∈Subscript[Ω, sediment], Rule[...]]
	]

ヘルムホルツ(Helmholtz)モデルを定義する：

Wolfram Language code: helmholtzModel[vars_, k_] := DiffusionPDETerm[vars, 1] + ReactionPDETerm[vars, k]

ヘルムホルツ方程式の固有値について解く：

Wolfram Language code: NDEigenvalues[{helmholtzModel[{u[x, y], {x, y}}, 4]}, u, {x, y}∈Disk[], 5]

ソース項があるヘルムホルツ方程式を解く：

Wolfram Language code:

vars = {u[x, y], {x, y}};
NDSolveValue[{helmholtzModel[vars, 4] == SourcePDETerm[vars, 1], DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Disk[]]

解を可視化する：

Wolfram Language code: Plot3D[%, {x, y}∈Disk[]]

DiffusionPDETermと軸対称幾何学を使って伝導性熱伝達をモデル化する．分析領域は3Dの中空の円柱である．直交座標で完全な3D領域を定義する代りに，2Dの切取り円柱座標で領域を定義することができる．この系は軸の周りで回転対称なので，円柱座標の変数は消失する．

領域を設定する：

Wolfram Language code: Ω = Rectangle[{0.02, 0}, {0.1, 0.14}];

偏微分方程式モデルを設定する：

Wolfram Language code: model = DiffusionPDETerm[{u[r, z], {r, z}}, 52, <|"RegionSymmetry" -> "Axisymmetric"|>]

軸対称方程式を解く：

Wolfram Language code:

solution = NDSolveValue[{model == NeumannValue[5 * 10 ^ 5, r == 0.02  && (0.04 <= z <= 0.1)], DirichletCondition[u[r, z] == 273.15, z == 0 || r == 0.1 || z == 0.14]}, u, {r, z}∈Ω]

結果を可視化する：

Wolfram Language code: ContourPlot[solution[r, z], {r, z}∈Ω, ...]

円柱の一部について結果を3D空間で可視化する：

Wolfram Language code:

Legended[RegionPlot3D[0.02^2 ≤ x^2 + y^2 ≤ 0.1^2 && 0 ≤ PlanarAngle[{0, 0} -> {{0.02, 0}, {x, y}}] ≤ (4 π/3), {x, -0.1, 0.1}, {y, -0.1, 0.1}, {z, 0, 0.14}, ...], BarLegend[...]]

DiffusionPDETermと軸対称幾何学を使って非線形伝達性熱伝導をモデル化する．

領域を設定する：

Wolfram Language code:

radius = 3;
height = 8;
Ω2D = Rectangle[{0, 0}, {radius, height}];

空気の熱伝導率を求める：

Wolfram Language code: Subscript[k, air] = QuantityMagnitude[ThermodynamicData["Air", "ThermalConductivity"]];

偏微分方程式モデルを設定する：

Wolfram Language code:

flux = 10;
temperature = 10;
model2D = {DiffusionPDETerm[{u[r, z], {r, z}}, (Subscript[k, air] + 10^-3u[r, z]) * IdentityMatrix[2], <|"RegionSymmetry" -> "Axisymmetric"|>] == NeumannValue[flux, r == radius], DirichletCondition[u[r, z] == temperature, z == 0]};

方程式を解き，かかった時間とメモリを測定する：

Wolfram Language code:

measure2D  = 
	AbsoluteTiming[
	MaxMemoryUsed[
	solution2D = NDSolveValue[model2D, u, {r, z}∈Ω2D]]];

軸対称の結果を可視化する：

Wolfram Language code: ContourPlot[solution2D[r, z], {r, z}∈Ω2D, ...]

計算にかかった合計時間と計算に使われたバイト数(MB)を出力する：

Wolfram Language code:

Print["Time -> ", measure2D[[1]], " s", "
Memory -> ", measure2D[[2]] / (1024. ^ 2), " MB"]

DiffusionPDETermを使って平面応力演算子を設定する：

Wolfram Language code:

MatrixForm[coefficients = {{{{(Y/1 - ν^2), 0}, {0, (Y (1 - ν)/2 (1 - ν^2))}}, {{0, (Y ν/1 - ν^2)}, {(Y (1 - ν)/2 (1 - ν^2)), 0}}}, {{{0, (Y (1 - ν)/2 (1 - ν^2))}, {(Y ν/1 - ν^2), 0}}, {{(Y (1 - ν)/2 (1 - ν^2)), 0}, {0, (Y/1 - ν^2)}}}}]

モデルを設定する：

Wolfram Language code: model = DiffusionPDETerm[{{u[x, y], v[x, y]}, {x, y}}, coefficients, <|ν -> 1 / 3, Y -> 10 ^ 3|>]

領域を設定する：

Wolfram Language code: Ω = Rectangle[{0, 0}, {5, 1}]

方程式を解く：

Wolfram Language code:

{uif, vif} = NDSolveValue[{model == {0, NeumannValue[-1, x == 5]}, DirichletCondition[{u[x, y] == 0., v[x, y] == 0.}, x == 0]}, {u, v}, {x, y}∈Ω]

結果を可視化する：

Wolfram Language code: ContourPlot[uif[x, y], {x, y}∈Ω, ...]

Wolfram Language code: ContourPlot[vif[x, y], {x, y}∈Ω, ...]

流束を計算する：

Wolfram Language code: flux = model /. Inactive[Div][flux_, _] :> Activate[flux]

ストークス(Stokes)流れのモデルを定義する：

Wolfram Language code:

stokesModel[vars_, μ_] := DiffusionPDETerm[vars, {{μ, 0, 0}, {0, μ, 0}, {0, 0, 0}}] + ConvectionPDETerm[vars, {{0, 0, {1, 0}}, {0, 0, {0, 1}}, {{1, 0}, {0, 1}, 0}}]

方程式を設定する：

Wolfram Language code: eqn = stokesModel[{{u[x, y], v[x, y], p[x, y]}, {x, y}}, 1] == {0, 0, 0}

狭まる領域を定義する：

Wolfram Language code: Ω = RegionUnion[Rectangle[{0, 0}, {1, 1 / 2}], Rectangle[{1, 1 / 10}, {2, 2 / 5}]];

境界条件を設定する：

Wolfram Language code:

bcs = {DirichletCondition[
	{u[x, y] == 4 * 0.3 * y * (0.5 - y) / (0.41) ^ 2, v[x, y] == 0.}, x == 0.], DirichletCondition[{u[x, y] == 0., v[x, y] == 0.}, 0 < x < 2], 
	DirichletCondition[p[x, y] == 0., x == 2]};

方程式を解く：

Wolfram Language code:

{xVel, yVel, pressure} = NDSolveValue[{eqn, bcs}, {u, v, p}, {x, y}∈Ω, Method -> {"FiniteElement", "InterpolationOrder" -> {u -> 2, v -> 2, p -> 1}, "MeshOptions" -> {"MaxCellMeasure" -> 0.0005}}];

解を可視化する：

Wolfram Language code:

VectorPlot[{xVel[x, y], yVel[x, y]}, {x, y}∈Ω, AspectRatio -> Automatic, StreamPoints -> 6, StreamColorFunction -> "TemperatureMap", StreamColorFunctionScaling -> False]//Quiet

ストークス流れのモデルを拡張してナビエ(Navier)・ストークス流れのモデルにする．ストークス流れのモデルを定義する：

Wolfram Language code:

stokesModel[vars_, μ_] := DiffusionPDETerm[vars, {{μ, 0, 0}, {0, μ, 0}, {0, 0, 0}}] + ConvectionPDETerm[vars, {{0, 0, {1, 0}}, {0, 0, {0, 1}}, {{1, 0}, {0, 1}, 0}}]

ナビエ・ストークス流れのモデルを定義する：

Wolfram Language code:

navierStokesModel[vars_, μ_, ρ_] := stokesModel[vars, μ] + ConvectionPDETerm[vars, {{ρ vars[[1, {1, 2}]], 0, 0}, {0, ρ vars[[1, {1, 2}]], 0}, {0, 0, 0}}]

方程式を設定する：

Wolfram Language code: eqn = navierStokesModel[{{u[x, y], v[x, y], p[x, y]}, {x, y}}, 1, 10 ^ -3] == {0, 0, 0}

領域を定義する：

Wolfram Language code: Ω = Rectangle[{0, 0}, {1, 1}];

境界条件を設定する：

Wolfram Language code:

bcs = {DirichletCondition[
	{u[x, y] == 1, v[x, y] == 0}, y == 1], DirichletCondition[{u[x, y] == 0, v[x, y] == 0}, y < 1], 
	DirichletCondition[p[x, y] == 0, x == 0 && y == 1]};

方程式を解く：

Wolfram Language code:

{xVel, yVel, pressure} = NDSolveValue[{eqn, bcs}, {u, v, p}, {x, y}∈Ω, Method -> {"FiniteElement", "InterpolationOrder" -> {u -> 2, v -> 2, p -> 1}, "MeshOptions" -> {"MaxCellMeasure" -> 0.0005}}];

解を可視化する：

Wolfram Language code:

VectorPlot[{xVel[x, y], yVel[x, y]}, {x, y}∈Ω, AspectRatio -> Automatic, StreamPoints -> 6, StreamColorFunction -> "TemperatureMap", StreamColorFunctionScaling -> False]//Quiet

特性と関係 (3)

異方性の拡散はと同じであることを確かめる：

Wolfram Language code:

sol1 = NDSolveValue[{DiffusionPDETerm[{u[x, y], {x, y}}, {{1, 1 / 2}, {0, 1}}] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Rectangle[]]

Wolfram Language code:

sol2 = NDSolveValue[{DiffusionPDETerm[{u[x, y], {x, y}}, {{1, 1 / 4}, {1 / 4, 1}}] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Rectangle[]]

2つの解には差がないことを可視化する：

Wolfram Language code: Plot3D[Chop[sol1[x, y] - sol2[x, y]], {x, y}∈Rectangle[]]

ガウスの初期条件がある時間依存拡散方程式を解く：

Wolfram Language code:

nfun = NDSolveValue[{D[u[t, x], t] + DiffusionPDETerm[{u[t, x], {x}}, 1] == 0, DirichletCondition[u[t, x] == 0, True], u[0, x] == Exp[-x ^ 2]}, u[t, x], {t, 0, 1}, {x, -π, π}]

解析的解は無限級数である：

Wolfram Language code:

afun = DSolveValue[{Activate[D[u[t, x], t] + DiffusionPDETerm[{u[t, x], {x}}, 1] == 0], u[t, -π] == 0, u[t, π] == 0, u[0, x] == Exp[-x ^ 2]}, u, {t, 0, 1}, {x, -π, π}]

Inactive和から数項取り出す：

Wolfram Language code: asol = afun[t, x] /. {∞ -> 15}//Activate;

数値解と解析的解の違いを可視化する：

Wolfram Language code: Plot3D[asol - nfun, {x, -π, π}, {t, 0, 1}, AxesLabel -> {"x", "t"}, PlotRange -> All]

DiffusionPDETermの平衡特性は，不連続初期条件平滑化に現れている：

Wolfram Language code:

ufun = NDSolveValue[{D[u[t, x], t] + DiffusionPDETerm[{u[t, x], {x}}, 1] == 0, DirichletCondition[u[t, x] == 0, True], u[0, x] == 1 / 2 - Abs[x - 1 / 2]}, u, {t, 0, 0.001}, x∈Line[{{0}, {1}}]]

不連続初期条件と初期条件の平滑化された進化を可視化する：

Wolfram Language code: Plot[{(1 / 2 - Abs[x - 1 / 2]), ufun[0.001, x]}, {x, 0, 1}, PlotRange -> {{0.35, 0.65}, {0.4, 0.51}}]

考えられる問題 (3)

演算子中の負の符号は与える必要がない：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, c]

記号拡散係数は，以下の入力ではスカラー係数と解釈される：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, c]

後続の置換でそれを考慮しなければならない：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, c, <|c -> 1|>]

項をアクティブにする：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, c]//Activate

数値拡散係数は，自動的に，適切な次元のIdentityMatrixと乗算される：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, 1]

記号拡散係数を指定するよりよい方法はMatrixSymbolを使うことである：

Wolfram Language code:

cs = MatrixSymbol["c", {1, 1}];
DiffusionPDETerm[{u[x], {x}}, cs, <|cs -> {{1}}|>]

MatrixSymbolを使うと演算子がアクティブにできる：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, cs]//Activate

DiffusionPDETermは，ではなくをモデル化する：

Wolfram Language code:

c = 1 / (x + 1);
model = DiffusionPDETerm[{u[x], {x}}, {{c}}];
solution1 = NDSolveValue[{model == 1, DirichletCondition[u[x] == 1, x == 0], DirichletCondition[u[x] == 0, x == 1]}, u, {x, 0, 1}];

Wolfram Language code:

solution2 = NDSolveValue[{-c Laplacian[u[x], {x}] == 0, DirichletCondition[u[x] == 1, x == 0], DirichletCondition[u[x] == 0, x == 1]}, u, {x, 0, 1}];

解の差を可視化する：

Wolfram Language code: Plot[{solution1[x], solution2[x]}, {x, 0, 1}, PlotLegends -> {"solution1", "solution2"}]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

DiffusionPDETerm

詳細

例題

例 (6)

スコープ (36)

1D (6)

1D線対称 (1)

2D (13)

2D線対称 (3)

3D (1)

座標チャート (3)

連結 (6)

連結線対称 (3)

アプリケーション (9)

特性と関係 (3)

考えられる問題 (3)

テキスト

CMS

APA

BibTeX

BibLaTeX

パラメータ	デフォルト	シンボル
"CoordinateChart"	"Cartesian"
"RegionSymmetry"	None

次元	縮小	方程式
1D
2D

DiffusionPDETerm

詳細

例題

例 (6)

スコープ (36)

1D (6)

1D線対称 (1)

2D (13)

2D線対称 (3)

3D (1)

座標チャート (3)

連結 (6)

連結線対称 (3)

アプリケーション (9)

特性と関係 (3)

考えられる問題 (3)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX