Wolfram 语言与系统参考资料中心

DiffusionPDETerm

DiffusionPDETerm[vars]

表示模型变量为 vars 的扩散项 .

DiffusionPDETerm[vars,c]

表示扩散系数为的扩散项 .

DiffusionPDETerm[vars,c,pars]

使用模型参数 pars.

范例

打开所有单元关闭所有单元

基本范例 (6)

定义平稳扩散项：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, 1]

激活该项：

Wolfram Language code: Activate[%]

定义一个平稳扩散项，并用参数扩散系数替换：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, κ, <|{κ -> {{1}}}|>]

激活该项：

Wolfram Language code: Activate[%]

定义符号扩散项：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, {{κ[x]}}]

激活该项：

Wolfram Language code: Activate[%]

求扩散项的特征值：

Wolfram Language code: NDEigenvalues[DiffusionPDETerm[{u[x], {x}}], u, {x}∈Line[{{0}, {1}}], 3]

从基本的项构造一个泊松方程，并进行符号求解：

Wolfram Language code:

vars = {u[x, y], {x, y}};
DSolveValue[Activate[DiffusionPDETerm[vars] == SourcePDETerm[vars, 1]], u[x, y], {x, y}]

求解与时间有关并具有高斯初始条件的扩散方程：

Wolfram Language code:

ufun = NDSolveValue[{D[u[t, x], t] + DiffusionPDETerm[{u[t, x], {x}}, 1] == 0, u[0, x] == Exp[-x ^ 2]}, u, {t, 0, 1}, {x, -π, π}]

可视化初始条件随时间的平滑：

Wolfram Language code: Plot[Evaluate[Table[ufun[t, x], {t, 0, 1, 0.25}]], {x, -π, π}, Rule[...]]

查看曲线下的面积是否保持不变：

Wolfram Language code: NIntegrate[ufun[0, x], {x, -π, π}] - NIntegrate[ufun[1, x], {x, -π, π}]

范围 (36)

一维 (6)

定义符号矩阵扩散项：

Wolfram Language code: DiffusionPDETerm[{u[t, x], {x}}, MatrixSymbol["c", {1, 1}]]

激活该项：

Wolfram Language code: Activate[%]

不指定扩散系数将产生单位矩阵系数：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}]

定义与时间相关的扩散项：

Wolfram Language code: DiffusionPDETerm[{u[t, x], {x}}, {{1 + t}}]

激活该项：

Wolfram Language code: Activate[%]

定义一个用参数扩散系数替换的固定扩散项：

Wolfram Language code:

κ = MatrixSymbol["c", {1, 1}];
DiffusionPDETerm[{u[x], {x}}, κ, <|{κ -> {{1}}}|>]

激活该项：

Wolfram Language code: Activate[%]

使用 DiffusionPDETerm 模拟特征值问题：

Wolfram Language code: NDEigensystem[DiffusionPDETerm[{u[x], {x}}, 1], u, {x, 0, 1}, 3]

使用 DiffusionPDETerm 建立一维泊松方程：

Wolfram Language code: NDSolveValue[{DiffusionPDETerm[{u[x], {x}}, 1] == 1, DirichletCondition[u[x] == 0, True]}, u, {x, 0, 1}]

可视化结果：

Wolfram Language code: Plot[%[x], {x, 0, 1}]

一维轴对称 (1)

建立一维轴对称扩散方程：

Wolfram Language code: DiffusionPDETerm[{u[r], {r}}, 1, <|"RegionSymmetry" -> "Axisymmetric"|>]

将 Activate 应用于该项：

Wolfram Language code: Activate[%]

使用构成扩散方程的算子验证轴对称情况是使用截断圆柱坐标系的结果：

Wolfram Language code: Div[-1 * Grad[u[r], {r, θ, z}, "Cylindrical"], {r, θ, z}, "Cylindrical"]

二维 (13)

定义二维平稳扩散项：

Wolfram Language code: DiffusionPDETerm[{u[x, y], {x, y}}, 1]

激活该项：

Wolfram Language code: Activate[%]

不指定扩散系数将导致单位矩阵系数：

Wolfram Language code: DiffusionPDETerm[{u[x, y], {x, y}}]

建立二维平稳扩散方程：

Wolfram Language code: DiffusionPDETerm[{u[x, y], {x, y}}, 1] == 0

激活该项：

Wolfram Language code: Activate[%]

定义符号矩阵扩散项：

Wolfram Language code: DiffusionPDETerm[{u[x, y], {x, y}}, MatrixSymbol["c", {2, 2}]]

激活该项：

Wolfram Language code: Activate[%]

建立与时间相关的二维扩散方程：

Wolfram Language code: D[u[t, x, y]] + DiffusionPDETerm[{u[t, x, y], {x, y}}, 1] == 0

激活该项：

Wolfram Language code: Activate[%]

使用向量扩散系数定义二维正交各向异性平稳扩散项：

Wolfram Language code: DiffusionPDETerm[{u[x, y], {x, y}}, {10, 20}]

使用各向异性扩散矩阵定义二维平稳扩散项：

Wolfram Language code: DiffusionPDETerm[{u[x, y], {x, y}}, {{2, 1}, {0, 1}}]

使用各向异性扩散矩阵定义二维扩散项：

Wolfram Language code: DiffusionPDETerm[{u[t, x, y], t, {x, y}}, {{2, 1}, {0, 1}}]

使用 DiffusionPDETerm 建立二维泊松方程：

Wolfram Language code:

NDSolveValue[{DiffusionPDETerm[{u[x, y], {x, y}}, 1] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Rectangle[]]

可视化结果：

Wolfram Language code: ContourPlot[%[x, y], {x, y}∈Rectangle[]]

用偏微分方程的基本项构造一个泊松方程，并用数值方法求解：

Wolfram Language code:

vars = {u[x, y], {x, y}};
NDSolveValue[{DiffusionPDETerm[vars] == SourcePDETerm[vars, 1], DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Disk[]]

可视化结果：

Wolfram Language code: Plot3D[%, {x, y}∈Disk[]]

使用向量值扩散系数，该系数在方向的扩散常数大于方向的扩散常数：

Wolfram Language code:

NDSolveValue[{DiffusionPDETerm[{u[x, y], {x, y}}, {10, 1}] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Rectangle[]]

可视化结果：

Wolfram Language code: ContourPlot[%[x, y], {x, y}∈Rectangle[]]

使用向量值扩散系数，该系数在方向的扩散常数大于方向的扩散常数：

Wolfram Language code:

NDSolveValue[{DiffusionPDETerm[{u[x, y], {x, y}}, {1, 10}] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Rectangle[]]

可视化结果：

Wolfram Language code: ContourPlot[%[x, y], {x, y}∈Rectangle[]]

使用各向异性扩散系数：

Wolfram Language code:

NDSolveValue[{DiffusionPDETerm[{u[x, y], {x, y}}, {{1, 1 / 2}, {1 / 2, 1}}] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Rectangle[]]

可视化结果：

Wolfram Language code: ContourPlot[%[x, y], {x, y}∈Rectangle[]]

二维轴对称 (3)

建立一个二维轴对称扩散方程：

Wolfram Language code: DiffusionPDETerm[{u[r, z], {r, z}}, 1, <|"RegionSymmetry" -> "Axisymmetric"|>] == 0

将 Activate 应用于项：

Wolfram Language code: Activate[%]

使用构成扩散方程的算子验证轴对称情况是使用截断圆柱坐标系的结果：

Wolfram Language code: Div[{{-1, 0, 0}, {0, -1, 0}, {0, 0, -1}}. Grad[u[r, z], {r, θ, z}, "Cylindrical"], {r, θ, z}, "Cylindrical"]

建立一个二维轴对称时间相关扩散方程：

Wolfram Language code: D[u[t, r, z]] + DiffusionPDETerm[{u[t, r, z], {r, z}}, 1, <|"RegionSymmetry" -> "Axisymmetric"|>] == 0

将 Activate 应用于项：

Wolfram Language code: Activate[%]

建立一个二维轴对称时依扩散方程：

Wolfram Language code: D[u[t, r, z]] + DiffusionPDETerm[{u[t, r, z], {r, z}}, 1, <|"RegionSymmetry" -> "Axisymmetric"|>] == 0

将 Activate 应用于项：

Wolfram Language code: Activate[%]

三维 (1)

使用 DiffusionPDETerm 建立三维泊松方程：

Wolfram Language code:

usol  = NDSolveValue[
	{DiffusionPDETerm[{u[x, y, z], {x, y, z}}, -1] == 1, 
	DirichletCondition[u[x, y, z] == x y z, True]}, u, {x, y, z}∈ Ball[]]

可视化结果：

Wolfram Language code: DensityPlot3D[usol[x, y, z], {x, y, z}∈Ball[], PlotLegends -> Automatic, AxesLabel -> Automatic]

坐标系 (3)

定义用指定坐标系表示的扩散项：

Wolfram Language code: DiffusionPDETerm[{u[r, z], {r, z}}, 1, <|"CoordinateChart" -> "Polar"|>]

激活该算符：

Wolfram Language code: Activate[%]

与 Laplacian 相比较：

Wolfram Language code: Laplacian[u[r, z], {r, z}, "Polar"]

求用极坐标表示的扩散项的特征值和特征向量：

Wolfram Language code:

{vals, funs} = NDEigensystem[{DiffusionPDETerm[{u[r, θ], {r, θ}}, 1, <|"CoordinateChart" -> "Polar"|>], DirichletCondition[u[r, θ] == 0, r == π], PeriodicBoundaryCondition[u[r, θ], θ == -π && r < π, Function[X, X + {0, 2π}]]}, u, {r, θ}∈Rectangle[{0, -π}, {π, π}], 4]

可视化用极坐标表示的拉普拉斯项的特征向量：

Wolfram Language code: RevolutionPlot3D[#[r, θ], {r, 0, π}, {θ, -π, π}, PlotRange -> All]& /@ funs

在极坐标系中求解 PDE：

Wolfram Language code:

ifun = NDSolveValue[{DiffusionPDETerm[{u[r, θ], {r, θ}}, 1, <|"CoordinateChart" -> "Polar"|>] == 0, DirichletCondition[u[r, θ] == Sin[4 θ], r == 3]}, u, {r, θ}∈Rectangle[{-3, -3}, {3, 3}]]

在直角坐标系中绘制解：

Wolfram Language code: Plot3D[Evaluate[ifun[r, θ] /. {r -> Sqrt[x ^ 2 + y ^ 2], θ -> ArcTan[y / x]}], {x, y}∈Disk[{0, 0}, 3]]

耦合 (6)

定义具有多个因变量的扩散项：

Wolfram Language code: DiffusionPDETerm[{{u[x], v[x]}, {x}}]

定义具有多个因变量的扩散项：

Wolfram Language code: DiffusionPDETerm[{{u[x], v[x]}, {x}}, 1]

定义具有多个因变量和多个扩散系数的扩散项：

Wolfram Language code: DiffusionPDETerm[{{u[x], v[x]}, {x}}, {{Subscript[c, 11], Subscript[c, 12]}, {Subscript[c, 21], Subscript[c, 22]}}]

定义具有多个因变量和各向异性扩散系数的扩散项：

Wolfram Language code:

DiffusionPDETerm[{{u[x, y], v[x, y]}, {x, y}}, {{Subscript[c, 11], {Subscript[c, 1211], Subscript[c, 1222]}}, {0, {{Subscript[c, 2211], Subscript[c, 2212]}, {Subscript[c, 2221], Subscript[c, 2222]}}}}]

定义具有多个因变量和所有指定系数的扩散项：

Wolfram Language code: cIn = Array[Subscript[c, ##]&, {2, 2, 2, 2}]

Wolfram Language code: DiffusionPDETerm[{{u[x, y], v[x, y]}, {x, y}}, cIn]

在耦合 PDE 中可能存在非对角线扩散系数：

Wolfram Language code: MatrixForm[coefficients = {{{{1, 0}, {0, 1}}, {{0, 2}, {2, 0}}}, {{{0, 0}, {0, 0}}, {{1, 0}, {0, 1}}}}]

求解方程：

Wolfram Language code:

{uif, vif} = NDSolveValue[{DiffusionPDETerm[{{u[x, y], v[x, y]}, {x, y}}, coefficients] == {1, 1}, DirichletCondition[{u[x, y] == 0, v[x, y] == 0}, True]}, {u, v}, {x, y}∈Rectangle[]];

可视化结果：

Wolfram Language code: GraphicsRow[{ContourPlot[uif[x, y], {x, y}∈Rectangle[]], ContourPlot[vif[x, y], {x, y}∈Rectangle[]]}]

耦合轴对称 (3)

使用 DiffusionPDETerm 建立具有多个因变量的一维轴对称方程：

Wolfram Language code: eqn = DiffusionPDETerm[{{u[r], v[r]}, {r}}, {{2.4, 3}, {3, 3}}, <|"RegionSymmetry" -> "Axisymmetric"|>] == {1, 1}

指定边界条件：

Wolfram Language code: bcs = {u[0.1] == 200, v[0.1] == 200, u[0.5] == 50, v[0.5] == 5};

数值求解方程：

Wolfram Language code: {uif, vif} = NDSolveValue[{eqn, bcs}, {u, v}, {r, 0.1, 0.5}]

符号求解相同的方程：

Wolfram Language code: {fufun, fvfun} = DSolveValue[{eqn, bcs}, {u, v}, {r}]

可视化结果之间的差异：

Wolfram Language code: Plot[{fufun[r] - uif[r], fvfun[r] - vif[r]}, {r, 0.1, 0.5}, PlotLegends -> "Expressions", PlotRange -> All]

定义具有多个因变量的轴对称扩散项：

Wolfram Language code: DiffusionPDETerm[{{u[r, z], v[r, z]}, {r, z}}, 1, <|"RegionSymmetry" -> "Axisymmetric"|>]

将 Activate 应用于项：

Wolfram Language code: Activate[%]

定义具有多个因变量和多个扩散系数的二维扩散轴对称项：

Wolfram Language code:

MatrixForm[
	coefficients = {{{{25, 0}, {0, 25}}, {{0, 10}, {5, 0}}}, {{{0, 15}, {20, 0}}, {{50, 0}, {0, 25}}}}]

Wolfram Language code: coupledPDEs = DiffusionPDETerm[{{u[r, z], v[r, z]}, {r, z}}, coefficients, <|"RegionSymmetry" -> "Axisymmetric"|>];

求解耦合偏微分方程：

Wolfram Language code:

{uif, vif} = NDSolveValue[{coupledPDEs == {1, 1}, DirichletCondition[{u[r, z] == 0, v[r, z] == 0}, z == 0]}, {u, v}, {r, z}∈Rectangle[]];

可视化结果：

Wolfram Language code: GraphicsRow[{ContourPlot[uif[r, z], {r, z}∈Rectangle[]], ContourPlot[vif[r, z], {r, z}∈Rectangle[]]}]

应用 (9)

使用带有可变扩散系数的 DiffusionPDETerm：

Wolfram Language code: model = DiffusionPDETerm[{u[x], {x}}, {{If[x ≤ 3 / 4, 1, 2]}}]

解方程：

Wolfram Language code:

solution = NDSolveValue[{model == 0, DirichletCondition[u[x] == 1, x == 0], DirichletCondition[u[x] == 0, x == 1]}, u, {x, 0, 1}]

计算通量：

Wolfram Language code: flux = model /. Inactive[Div][flux_, _] :> Activate[flux]

可视化结果：

Wolfram Language code: Plot[Evaluate[{solution[x], flux /. u -> solution}], {x, 0, 1}, ...]

将 DiffusionPDETerm 用于轴对称几何对传导热传递进行建模中.

分析区域是二维区域. 除了在笛卡尔坐标中定义完整的二维区域，您还可以在一维中定义具有截断圆柱坐标的区域. 因为方程组围绕轴旋转对称因此柱坐标变量和消失.

建立方程：

Wolfram Language code: eqn = DiffusionPDETerm[{u[r], {r}}, 2.4, <|"RegionSymmetry" -> "Axisymmetric"|>] == 0

指定边界条件：

Wolfram Language code: bcs = {u[1 / 10] == 200, u[1 / 2] == 50};

解方程：

Wolfram Language code: numericSolution = NDSolveValue[{eqn, bcs}, u, {r, 0.1, 0.5}]

或用 DSolveValue 符号求解：

Wolfram Language code: analytocalSolution = DSolveValue[{eqn, bcs}, u, r]

可视化结果之间的差异：

Wolfram Language code: Plot[analytocalSolution[r] - numericSolution[r], {r, 0.1, 0.5}, PlotRange -> All]

使用 DiffusionPDETerm 模拟大坝下的物种扩散. 设置区域：

Wolfram Language code:

Subscript[Ω, dam] = Rectangle[{6, 3}, {12, 18}];
Subscript[Ω, sediment] = RegionDifference[Rectangle[{0, 0}, {18, 6}], Subscript[Ω, dam]];

设置模型：

Wolfram Language code: model = DiffusionPDETerm[{u[x, y], {x, y}}, 10 ^ -4]

解方程：

Wolfram Language code:

solution = NDSolveValue[{model == 0, DirichletCondition[u[x, y] == 16, x ≤ 6 && y == 6], DirichletCondition[u[x, y] == 8, x ≥ 12 && y == 6]}, u, {x, y}∈Subscript[Ω, sediment]]

计算通量：

Wolfram Language code: flux = model /. Inactive[Div][flux_, _] :> Activate[flux]

可视化结果：

Wolfram Language code:

Show[
	..., 
	VectorPlot[Evaluate[flux /. u -> solution], {x, y}∈Subscript[Ω, sediment], Rule[...]]]

求大坝下的物种浓度. 构造模型：

Wolfram Language code:

op = DiffusionPDETerm[{c[x, y], {x, y}}, 1] + ConvectionPDETerm[{c[x, y], {x, y}}, flux /. u -> solution] + 2 * 10 ^ -5c[x, y];

解方程：

Wolfram Language code:

concentration = NDSolveValue[{op == 0, 
	DirichletCondition[c[x, y] == 100, x ≤ 6 && y == 6], DirichletCondition[c[x, y] == 50, x ≥ 12 && y == 6]
	}, c, {x, y}∈Subscript[Ω, sediment]]

可视化物种浓度：

Wolfram Language code:

Show[
	..., 
	ContourPlot[concentration[x, y], {x, y}∈Subscript[Ω, sediment], ...], 
	VectorPlot[Evaluate[flux /. u -> solution], {x, y}∈Subscript[Ω, sediment], Rule[...]]
	]

定义亥姆霍兹模型：

Wolfram Language code: helmholtzModel[vars_, k_] := DiffusionPDETerm[vars, 1] + ReactionPDETerm[vars, k]

求解亥姆霍兹方程的特征值：

Wolfram Language code: NDEigenvalues[{helmholtzModel[{u[x, y], {x, y}}, 4]}, u, {x, y}∈Disk[], 5]

求解带有源项的亥姆霍兹方程：

Wolfram Language code:

vars = {u[x, y], {x, y}};
NDSolveValue[{helmholtzModel[vars, 4] == SourcePDETerm[vars, 1], DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Disk[]]

可视化解：

Wolfram Language code: Plot3D[%, {x, y}∈Disk[]]

将 DiffusionPDETerm 用于轴对称几何对传导热传递进行的建模. 分析区域是一个三维空心圆柱体. 除了在笛卡尔坐标中定义完整的三维区域，您还可以在二维中定义具有截断圆柱坐标的区域. 因为方程组围绕轴旋转对称因此柱坐标变量消失.

设置区域：

Wolfram Language code: Ω = Rectangle[{0.02, 0}, {0.1, 0.14}];

设置 PDE 模型：

Wolfram Language code: model = DiffusionPDETerm[{u[r, z], {r, z}}, 52, <|"RegionSymmetry" -> "Axisymmetric"|>]

求解轴对称方程：

Wolfram Language code:

solution = NDSolveValue[{model == NeumannValue[5 * 10 ^ 5, r == 0.02  && (0.04 <= z <= 0.1)], DirichletCondition[u[r, z] == 273.15, z == 0 || r == 0.1 || z == 0.14]}, u, {r, z}∈Ω]

可视化结果：

Wolfram Language code: ContourPlot[solution[r, z], {r, z}∈Ω, ...]

在三维空间中可视化部分圆柱体的结果：

Wolfram Language code:

Legended[RegionPlot3D[0.02^2 ≤ x^2 + y^2 ≤ 0.1^2 && 0 ≤ PlanarAngle[{0, 0} -> {{0.02, 0}, {x, y}}] ≤ (4 π/3), {x, -0.1, 0.1}, {y, -0.1, 0.1}, {z, 0, 0.14}, ...], BarLegend[...]]

使用 DiffusionPDETerm 使用轴对称几何对非线性传导热传递进行建模.

设置区域：

Wolfram Language code:

radius = 3;
height = 8;
Ω2D = Rectangle[{0, 0}, {radius, height}];

求空气的热导率：

Wolfram Language code: Subscript[k, air] = QuantityMagnitude[ThermodynamicData["Air", "ThermalConductivity"]];

设置 PDE 模型：

Wolfram Language code:

flux = 10;
temperature = 10;
model2D = {DiffusionPDETerm[{u[r, z], {r, z}}, (Subscript[k, air] + 10^-3u[r, z]) * IdentityMatrix[2], <|"RegionSymmetry" -> "Axisymmetric"|>] == NeumannValue[flux, r == radius], DirichletCondition[u[r, z] == temperature, z == 0]};

求解方程并衡量这样做所需的时间和内存：

Wolfram Language code:

measure2D  = 
	AbsoluteTiming[
	MaxMemoryUsed[
	solution2D = NDSolveValue[model2D, u, {r, z}∈Ω2D]]];

可视化轴对称结果：

Wolfram Language code: ContourPlot[solution2D[r, z], {r, z}∈Ω2D, ...]

打印计算的总时间和评估期间使用的兆字节数：

Wolfram Language code:

Print["Time -> ", measure2D[[1]], " s", "
Memory -> ", measure2D[[2]] / (1024. ^ 2), " MB"]

使用 DiffusionPDETerm 设置平面应力算子. 设置耦合系数：

Wolfram Language code:

MatrixForm[coefficients = {{{{(Y/1 - ν^2), 0}, {0, (Y (1 - ν)/2 (1 - ν^2))}}, {{0, (Y ν/1 - ν^2)}, {(Y (1 - ν)/2 (1 - ν^2)), 0}}}, {{{0, (Y (1 - ν)/2 (1 - ν^2))}, {(Y ν/1 - ν^2), 0}}, {{(Y (1 - ν)/2 (1 - ν^2)), 0}, {0, (Y/1 - ν^2)}}}}]

设置模型：

Wolfram Language code: model = DiffusionPDETerm[{{u[x, y], v[x, y]}, {x, y}}, coefficients, <|ν -> 1 / 3, Y -> 10 ^ 3|>]

设置区域：

Wolfram Language code: Ω = Rectangle[{0, 0}, {5, 1}]

解方程：

Wolfram Language code:

{uif, vif} = NDSolveValue[{model == {0, NeumannValue[-1, x == 5]}, DirichletCondition[{u[x, y] == 0., v[x, y] == 0.}, x == 0]}, {u, v}, {x, y}∈Ω]

可视化结果：

Wolfram Language code: ContourPlot[uif[x, y], {x, y}∈Ω, ...]

Wolfram Language code: ContourPlot[vif[x, y], {x, y}∈Ω, ...]

计算通量：

Wolfram Language code: flux = model /. Inactive[Div][flux_, _] :> Activate[flux]

定义斯托克斯流模型：

Wolfram Language code:

stokesModel[vars_, μ_] := DiffusionPDETerm[vars, {{μ, 0, 0}, {0, μ, 0}, {0, 0, 0}}] + ConvectionPDETerm[vars, {{0, 0, {1, 0}}, {0, 0, {0, 1}}, {{1, 0}, {0, 1}, 0}}]

建立方程：

Wolfram Language code: eqn = stokesModel[{{u[x, y], v[x, y], p[x, y]}, {x, y}}, 1] == {0, 0, 0}

定义一个逐渐缩小的区域：

Wolfram Language code: Ω = RegionUnion[Rectangle[{0, 0}, {1, 1 / 2}], Rectangle[{1, 1 / 10}, {2, 2 / 5}]];

设置边界条件：

Wolfram Language code:

bcs = {DirichletCondition[
	{u[x, y] == 4 * 0.3 * y * (0.5 - y) / (0.41) ^ 2, v[x, y] == 0.}, x == 0.], DirichletCondition[{u[x, y] == 0., v[x, y] == 0.}, 0 < x < 2], 
	DirichletCondition[p[x, y] == 0., x == 2]};

解方程：

Wolfram Language code:

{xVel, yVel, pressure} = NDSolveValue[{eqn, bcs}, {u, v, p}, {x, y}∈Ω, Method -> {"FiniteElement", "InterpolationOrder" -> {u -> 2, v -> 2, p -> 1}, "MeshOptions" -> {"MaxCellMeasure" -> 0.0005}}];

可视化解：

Wolfram Language code:

VectorPlot[{xVel[x, y], yVel[x, y]}, {x, y}∈Ω, AspectRatio -> Automatic, StreamPoints -> 6, StreamColorFunction -> "TemperatureMap", StreamColorFunctionScaling -> False]//Quiet

将斯托克斯流模型扩展为纳维-斯托克斯流模型. 定义斯托克斯流模型：

Wolfram Language code:

stokesModel[vars_, μ_] := DiffusionPDETerm[vars, {{μ, 0, 0}, {0, μ, 0}, {0, 0, 0}}] + ConvectionPDETerm[vars, {{0, 0, {1, 0}}, {0, 0, {0, 1}}, {{1, 0}, {0, 1}, 0}}]

定义纳维-斯托克斯流模型：

Wolfram Language code:

navierStokesModel[vars_, μ_, ρ_] := stokesModel[vars, μ] + ConvectionPDETerm[vars, {{ρ vars[[1, {1, 2}]], 0, 0}, {0, ρ vars[[1, {1, 2}]], 0}, {0, 0, 0}}]

建立方程：

Wolfram Language code: eqn = navierStokesModel[{{u[x, y], v[x, y], p[x, y]}, {x, y}}, 1, 10 ^ -3] == {0, 0, 0}

定义区域：

Wolfram Language code: Ω = Rectangle[{0, 0}, {1, 1}];

设置边界条件：

Wolfram Language code:

bcs = {DirichletCondition[
	{u[x, y] == 1, v[x, y] == 0}, y == 1], DirichletCondition[{u[x, y] == 0, v[x, y] == 0}, y < 1], 
	DirichletCondition[p[x, y] == 0, x == 0 && y == 1]};

解方程：

Wolfram Language code:

{xVel, yVel, pressure} = NDSolveValue[{eqn, bcs}, {u, v, p}, {x, y}∈Ω, Method -> {"FiniteElement", "InterpolationOrder" -> {u -> 2, v -> 2, p -> 1}, "MeshOptions" -> {"MaxCellMeasure" -> 0.0005}}];

可视化解：

Wolfram Language code:

VectorPlot[{xVel[x, y], yVel[x, y]}, {x, y}∈Ω, AspectRatio -> Automatic, StreamPoints -> 6, StreamColorFunction -> "TemperatureMap", StreamColorFunctionScaling -> False]//Quiet

属性和关系 (3)

验证各向异性扩散与相同：

Wolfram Language code:

sol1 = NDSolveValue[{DiffusionPDETerm[{u[x, y], {x, y}}, {{1, 1 / 2}, {0, 1}}] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Rectangle[]]

Wolfram Language code:

sol2 = NDSolveValue[{DiffusionPDETerm[{u[x, y], {x, y}}, {{1, 1 / 4}, {1 / 4, 1}}] == 1, DirichletCondition[u[x, y] == 0, True]}, u, {x, y}∈Rectangle[]]

用视图说明两种解决方案没有区别：

Wolfram Language code: Plot3D[Chop[sol1[x, y] - sol2[x, y]], {x, y}∈Rectangle[]]

求解高斯初始条件下的与时间有关的扩散方程：

Wolfram Language code:

nfun = NDSolveValue[{D[u[t, x], t] + DiffusionPDETerm[{u[t, x], {x}}, 1] == 0, DirichletCondition[u[t, x] == 0, True], u[0, x] == Exp[-x ^ 2]}, u[t, x], {t, 0, 1}, {x, -π, π}]

解析解是一个无限级数：

Wolfram Language code:

afun = DSolveValue[{Activate[D[u[t, x], t] + DiffusionPDETerm[{u[t, x], {x}}, 1] == 0], u[t, -π] == 0, u[t, π] == 0, u[0, x] == Exp[-x ^ 2]}, u, {t, 0, 1}, {x, -π, π}]

从 Inactive 和中提取几个项：

Wolfram Language code: asol = afun[t, x] /. {∞ -> 15}//Activate;

可视化数值解和解析解之差：

Wolfram Language code: Plot3D[asol - nfun, {x, -π, π}, {t, 0, 1}, AxesLabel -> {"x", "t"}, PlotRange -> All]

扩散项的平衡特性在不连续初始条件的平滑过程中表现出来：

Wolfram Language code:

ufun = NDSolveValue[{D[u[t, x], t] + DiffusionPDETerm[{u[t, x], {x}}, 1] == 0, DirichletCondition[u[t, x] == 0, True], u[0, x] == 1 / 2 - Abs[x - 1 / 2]}, u, {t, 0, 0.001}, x∈Line[{{0}, {1}}]]

可视化不连续初始条件和初始条件的平滑演化：

Wolfram Language code: Plot[{(1 / 2 - Abs[x - 1 / 2]), ufun[0.001, x]}, {x, 0, 1}, PlotRange -> {{0.35, 0.65}, {0.4, 0.51}}]

可能存在的问题 (3)

算子中的负号不需要给出：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, c]

在下面的式子中，符号扩散系数被解释为标量系数：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, c]

随后的替换必须说明这一点：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, c, <|c -> 1|>]

激活该项：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, c]//Activate

数值扩散系数将自动乘以适当大小的 IdentityMatrix：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, 1]

指定符号矩阵扩散系数的一个方式是通过 MatrixSymbol:

Wolfram Language code:

cs = MatrixSymbol["c", {1, 1}];
DiffusionPDETerm[{u[x], {x}}, cs, <|cs -> {{1}}|>]

使用 MatrixSymbol 则允许激活算符：

Wolfram Language code: DiffusionPDETerm[{u[x], {x}}, cs]//Activate

DiffusionPDETerm 模拟，而不是：

Wolfram Language code:

c = 1 / (x + 1);
model = DiffusionPDETerm[{u[x], {x}}, {{c}}];
solution1 = NDSolveValue[{model == 1, DirichletCondition[u[x] == 1, x == 0], DirichletCondition[u[x] == 0, x == 1]}, u, {x, 0, 1}];

Wolfram Language code:

solution2 = NDSolveValue[{-c Laplacian[u[x], {x}] == 0, DirichletCondition[u[x] == 1, x == 0], DirichletCondition[u[x] == 0, x == 1]}, u, {x, 0, 1}];

可视化解之间的差异：

Wolfram Language code: Plot[{solution1[x], solution2[x]}, {x, 0, 1}, PlotLegends -> {"solution1", "solution2"}]

Top

			标量，各向同性扩散
	{c₁,…,c_n}		向量，正交各向异性扩散
	{{c₁₁,…,c_1n},…,{c_n1,…,c_nn}}		矩阵，各向异性扩散

维度	简化	方程式
1D
2D

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

DiffusionPDETerm

更多信息

范例

基本范例 (6)

范围 (36)

一维 (6)

一维轴对称 (1)

二维 (13)

二维轴对称 (3)

三维 (1)

坐标系 (3)

耦合 (6)

耦合轴对称 (3)

应用 (9)

属性和关系 (3)

可能存在的问题 (3)

文本

CMS

APA

BibTeX

BibLaTeX

Italic	参数	默认	符号
	"CoordinateChart"	"Cartesian"
	"RegionSymmetry"	None

DiffusionPDETerm

更多信息

范例

基本范例 (6)

范围 (36)

一维 (6)

一维轴对称 (1)

二维 (13)

二维轴对称 (3)

三维 (1)

坐标系 (3)

耦合 (6)

耦合轴对称 (3)

应用 (9)

属性和关系 (3)

可能存在的问题 (3)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX